lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   9
  10 our $VERSION   = '0.03';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Generated';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (exists $options{options} && ref $options{options} eq 'HASH')
  21         || confess "You must pass a hash of options";
  22
  23     my $self = bless {
  24         # from our superclass
  25         '&!body'          => undef,
  26         # specific to this subclass
  27         '%!options'       => $options{options},
  28         '$!meta_instance' => $options{metaclass}->get_meta_instance,
  29         '@!attributes'    => [ $options{metaclass}->compute_all_applicable_attributes ],
  30         # ...
  31         '$!associated_metaclass' => $options{metaclass},
  32     } => $class;
  33
  34     # we don't want this creating
  35     # a cycle in the code, if not
  36     # needed
  37     weaken($self->{'$!associated_metaclass'});
  38
  39     $self->intialize_body;
  40
  41     return $self;
  42 }
  43
  44 ## accessors
  45
  46 sub options       { (shift)->{'%!options'}       }
  47 sub meta_instance { (shift)->{'$!meta_instance'} }
  48 sub attributes    { (shift)->{'@!attributes'}    }
  49
  50 sub associated_metaclass { (shift)->{'$!associated_metaclass'} }
  51
  52 ## method
  53
  54 sub intialize_body {
  55     my $self = shift;
  56     # TODO:
  57     # the %options should also include a both
  58     # a call 'initializer' and call 'SUPER::'
  59     # options, which should cover approx 90%
  60     # of the possible use cases (even if it
  61     # requires some adaption on the part of
  62     # the author, after all, nothing is free)
  63     my $source = 'sub {';
  64     $source .= "\n" . 'my $class = shift;';
  65
  66     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
  67     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
  68
  69     $source .= "\n" . 'my %params = (scalar @_ == 1) ? %{$_[0]} : @_;';
  70
  71     $source .= "\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
  72
  73     $source .= ";\n" . (join ";\n" => map {
  74         $self->_generate_slot_initializer($_)
  75     } 0 .. (@{$self->attributes} - 1));
  76
  77     $source .= ";\n" . $self->_generate_BUILDALL();
  78
  79     $source .= ";\n" . 'return $instance';
  80     $source .= ";\n" . '}';
  81     warn $source if $self->options->{debug};
  82
  83     my $code;
  84     {
  85         # NOTE:
  86         # create the nessecary lexicals
  87         # to be picked up in the eval
  88         my $attrs = $self->attributes;
  89
  90         $code = eval $source;
  91         confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@" if $@;
  92     }
  93     $self->{'&!body'} = $code;
  94 }
  95
  96 sub _generate_BUILDALL {
  97     my $self = shift;
  98     my @BUILD_calls;
  99     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 100         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD(\%params)';
 101     }
 102     return join ";\n" => @BUILD_calls;
 103 }
 104
 105 sub _generate_slot_initializer {
 106     my $self  = shift;
 107     my $index = shift;
 108
 109     my $attr = $self->attributes->[$index];
 110
 111     my @source = ('## ' . $attr->name);
 112
 113     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 114
 115     if ($is_moose && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 116         push @source => ('(exists $params{\'' . $attr->init_arg . '\'}) ' .
 117                         '|| confess "Attribute (' . $attr->name . ') is required";');
 118     }
 119
 120     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 121
 122         push @source => 'if (exists $params{\'' . $attr->init_arg . '\'}) {';
 123
 124             push @source => ('my $val = $params{\'' . $attr->init_arg . '\'};');
 125             if ($is_moose && $attr->has_type_constraint) {
 126                 push @source => ('my $type_constraint = $attrs->[' . $index . ']->type_constraint;');
 127
 128                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 129                     push @source => $self->_generate_type_coercion($attr, '$type_constraint', '$val', '$val');
 130                 }
 131                 push @source => $self->_generate_type_constraint_check($attr, '$type_constraint', '$val');
 132             }
 133             push @source => $self->_generate_slot_assignment($attr, '$val');
 134
 135         push @source => "} else {";
 136
 137             my $default;
 138             if ( $attr->has_default ) {
 139                 $default = $self->_generate_default_value($attr, $index);
 140             }
 141             else {
 142                my $builder = $attr->builder;
 143                $default = '$instance->' . $builder;
 144             }
 145             push @source => ('my $val = ' . $default . ';');
 146             push @source => $self->_generate_type_constraint_check(
 147                 $attr,
 148                 ('$attrs->[' . $index . ']->type_constraint'),
 149                 '$val'
 150             ) if ($is_moose && $attr->has_type_constraint);
 151             push @source => $self->_generate_slot_assignment($attr, $default);
 152
 153         push @source => "}";
 154     }
 155     else {
 156         push @source => '(exists $params{\'' . $attr->init_arg . '\'}) && do {';
 157
 158             push @source => ('my $val = $params{\'' . $attr->init_arg . '\'};');
 159             if ($is_moose && $attr->has_type_constraint) {
 160                 push @source => ('my $type_constraint = $attrs->[' . $index . ']->type_constraint;');
 161
 162                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 163                     push @source => $self->_generate_type_coercion($attr, '$type_constraint', '$val', '$val');
 164                 }
 165                 push @source => $self->_generate_type_constraint_check($attr, '$type_constraint', '$val');
 166             }
 167             push @source => $self->_generate_slot_assignment($attr, '$val');
 168
 169         push @source => "}";
 170     }
 171
 172     return join "\n" => @source;
 173 }
 174
 175 sub _generate_slot_assignment {
 176     my ($self, $attr, $value) = @_;
 177     my $source = (
 178         $self->meta_instance->inline_set_slot_value(
 179             '$instance',
 180             ("'" . $attr->name . "'"),
 181             $value
 182         ) . ';'
 183     );
 184
 185     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 186
 187     if ($is_moose && $attr->is_weak_ref) {
 188         $source .= (
 189             "\n" .
 190             $self->meta_instance->inline_weaken_slot_value(
 191                 '$instance',
 192                 ("'" . $attr->name . "'")
 193             ) .
 194             ' if ref ' . $value . ';'
 195         );
 196     }
 197
 198     return $source;
 199 }
 200
 201 sub _generate_type_coercion {
 202     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 203     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 204 }
 205
 206 sub _generate_type_constraint_check {
 207     my ($self, $attr, $type_constraint_name, $value_name) = @_;
 208     return (
 209         'defined(' . $type_constraint_name . '->_compiled_type_constraint->(' . $value_name . '))'
 210         . "\n\t" . '|| confess "Attribute (' . $attr->name . ') does not pass the type constraint ('
 211         . $attr->type_constraint->name
 212         . ') with " . (defined(' . $value_name . ') ? (Scalar::Util::blessed(' . $value_name . ') && overload::Overloaded(' . $value_name . ') ? overload::StrVal(' . $value_name . ') : ' . $value_name . ') : "undef");'
 213     );
 214 }
 215
 216 sub _generate_default_value {
 217     my ($self, $attr, $index) = @_;
 218     # NOTE:
 219     # default values can either be CODE refs
 220     # in which case we need to call them. Or
 221     # they can be scalars (strings/numbers)
 222     # in which case we can just deal with them
 223     # in the code we eval.
 224     if ($attr->is_default_a_coderef) {
 225         return '$attrs->[' . $index . ']->default($instance)';
 226     }
 227     else {
 228         my $default = $attr->default;
 229         # make sure to quote strings ...
 230         unless (looks_like_number($default)) {
 231             $default = "'$default'";
 232         }
 233
 234         return $default;
 235     }
 236 }
 237
 238 1;
 239
 240 __END__
 241
 242 =pod
 243
 244 =head1 NAME
 245
 246 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 247
 248 =head1 DESCRIPTION
 249
 250 This is a subclass of L<Class::MOP::Method> which handles
 251 constructing an approprate Constructor methods. This is primarily
 252 used in the making of immutable metaclasses, otherwise it is
 253 not particularly useful.
 254
 255 =head1 METHODS
 256
 257 =over 4
 258
 259 =item B<new>
 260
 261 =item B<attributes>
 262
 263 =item B<meta_instance>
 264
 265 =item B<options>
 266
 267 =item B<intialize_body>
 268
 269 =item B<associated_metaclass>
 270
 271 =back
 272
 273 =head1 AUTHORS
 274
 275 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 276
 277 =head1 COPYRIGHT AND LICENSE
 278
 279 Copyright 2006, 2007 by Infinity Interactive, Inc.
 280
 281 L<http://www.iinteractive.com>
 282
 283 This library is free software; you can redistribute it and/or modify
 284 it under the same terms as Perl itself.
 285
 286 =cut
 287