lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   9
  10 our $VERSION   = '0.04';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Generated';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (exists $options{options} && ref $options{options} eq 'HASH')
  21         || confess "You must pass a hash of options";
  22
  23     my $self = bless {
  24         # from our superclass
  25         '&!body'          => undef,
  26         # specific to this subclass
  27         '%!options'       => $options{options},
  28         '$!meta_instance' => $options{metaclass}->get_meta_instance,
  29         '@!attributes'    => [ $options{metaclass}->compute_all_applicable_attributes ],
  30         # ...
  31         '$!associated_metaclass' => $options{metaclass},
  32     } => $class;
  33
  34     # we don't want this creating
  35     # a cycle in the code, if not
  36     # needed
  37     weaken($self->{'$!associated_metaclass'});
  38
  39     $self->intialize_body;
  40
  41     return $self;
  42 }
  43
  44 ## accessors
  45
  46 sub options       { (shift)->{'%!options'}       }
  47 sub meta_instance { (shift)->{'$!meta_instance'} }
  48 sub attributes    { (shift)->{'@!attributes'}    }
  49
  50 sub associated_metaclass { (shift)->{'$!associated_metaclass'} }
  51
  52 ## method
  53
  54 sub intialize_body {
  55     my $self = shift;
  56     # TODO:
  57     # the %options should also include a both
  58     # a call 'initializer' and call 'SUPER::'
  59     # options, which should cover approx 90%
  60     # of the possible use cases (even if it
  61     # requires some adaption on the part of
  62     # the author, after all, nothing is free)
  63     my $source = 'sub {';
  64     $source .= "\n" . 'my $class = shift;';
  65
  66     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
  67     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
  68
  69     $source .= "\n" . 'my %params = (scalar @_ == 1) ? %{$_[0]} : @_;';
  70
  71     $source .= "\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
  72
  73     $source .= ";\n" . (join ";\n" => map {
  74         $self->_generate_slot_initializer($_)
  75     } 0 .. (@{$self->attributes} - 1));
  76
  77     $source .= ";\n" . $self->_generate_BUILDALL();
  78
  79     $source .= ";\n" . 'return $instance';
  80     $source .= ";\n" . '}';
  81     warn $source if $self->options->{debug};
  82
  83     my $code;
  84     {
  85         # NOTE:
  86         # create the nessecary lexicals
  87         # to be picked up in the eval
  88         my $attrs = $self->attributes;
  89
  90         my @type_constraints = map { $_->type_constraint } @$attrs;
  91         my @type_constraint_bodies = map {
  92             $_ && $_->_compiled_type_constraint;
  93         } @type_constraints;
  94
  95         $code = eval $source;
  96         confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@" if $@;
  97     }
  98     $self->{'&!body'} = $code;
  99 }
 100
 101 sub _generate_BUILDALL {
 102     my $self = shift;
 103     my @BUILD_calls;
 104     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 105         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD(\%params)';
 106     }
 107     return join ";\n" => @BUILD_calls;
 108 }
 109
 110 sub _generate_slot_initializer {
 111     my $self  = shift;
 112     my $index = shift;
 113
 114     my $attr = $self->attributes->[$index];
 115
 116     my @source = ('## ' . $attr->name);
 117
 118     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 119
 120     if ($is_moose && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 121         push @source => ('(exists $params{\'' . $attr->init_arg . '\'}) ' .
 122                         '|| confess "Attribute (' . $attr->name . ') is required";');
 123     }
 124
 125     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 126
 127         push @source => 'if (exists $params{\'' . $attr->init_arg . '\'}) {';
 128
 129             push @source => ('my $val = $params{\'' . $attr->init_arg . '\'};');
 130             if ($is_moose && $attr->has_type_constraint) {
 131                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 132                     push @source => $self->_generate_type_coercion($attr, '$type_constraints[' . $index . ']', '$val', '$val');
 133                 }
 134                 push @source => $self->_generate_type_constraint_check($attr, '$type_constraint_bodies[' . $index . ']', '$val');
 135             }
 136             push @source => $self->_generate_slot_assignment($attr, '$val');
 137
 138         push @source => "} else {";
 139
 140             my $default;
 141             if ( $attr->has_default ) {
 142                 $default = $self->_generate_default_value($attr, $index);
 143             }
 144             else {
 145                my $builder = $attr->builder;
 146                $default = '$instance->' . $builder;
 147             }
 148             push @source => ('my $val = ' . $default . ';');
 149             push @source => $self->_generate_type_constraint_check(
 150                 $attr,
 151                 ('$type_constraint_bodies[' . $index . ']'),
 152                 '$val'
 153             ) if ($is_moose && $attr->has_type_constraint);
 154             push @source => $self->_generate_slot_assignment($attr, $default);
 155
 156         push @source => "}";
 157     }
 158     else {
 159         push @source => '(exists $params{\'' . $attr->init_arg . '\'}) && do {';
 160
 161             push @source => ('my $val = $params{\'' . $attr->init_arg . '\'};');
 162             if ($is_moose && $attr->has_type_constraint) {
 163                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 164                     push @source => $self->_generate_type_coercion($attr, '$type_constraints[' . $index . ']', '$val', '$val');
 165                 }
 166                 push @source => $self->_generate_type_constraint_check($attr, '$type_constraint_bodies[' . $index . ']', '$val');
 167             }
 168             push @source => $self->_generate_slot_assignment($attr, '$val');
 169
 170         push @source => "}";
 171     }
 172
 173     return join "\n" => @source;
 174 }
 175
 176 sub _generate_slot_assignment {
 177     my ($self, $attr, $value) = @_;
 178     my $source = (
 179         $self->meta_instance->inline_set_slot_value(
 180             '$instance',
 181             ("'" . $attr->name . "'"),
 182             $value
 183         ) . ';'
 184     );
 185
 186     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 187
 188     if ($is_moose && $attr->is_weak_ref) {
 189         $source .= (
 190             "\n" .
 191             $self->meta_instance->inline_weaken_slot_value(
 192                 '$instance',
 193                 ("'" . $attr->name . "'")
 194             ) .
 195             ' if ref ' . $value . ';'
 196         );
 197     }
 198
 199     return $source;
 200 }
 201
 202 sub _generate_type_coercion {
 203     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 204     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 205 }
 206
 207 sub _generate_type_constraint_check {
 208     my ($self, $attr, $type_constraint_cv, $value_name) = @_;
 209     return (
 210         $type_constraint_cv . '->(' . $value_name . ')'
 211         . "\n\t" . '|| confess "Attribute (' . $attr->name . ') does not pass the type constraint ('
 212         . $attr->type_constraint->name
 213         . ') with " . (defined(' . $value_name . ') ? overload::StrVal(' . $value_name . ') : "undef");'
 214     );
 215 }
 216
 217 sub _generate_default_value {
 218     my ($self, $attr, $index) = @_;
 219     # NOTE:
 220     # default values can either be CODE refs
 221     # in which case we need to call them. Or
 222     # they can be scalars (strings/numbers)
 223     # in which case we can just deal with them
 224     # in the code we eval.
 225     if ($attr->is_default_a_coderef) {
 226         return '$attrs->[' . $index . ']->default($instance)';
 227     }
 228     else {
 229         my $default = $attr->default;
 230         # make sure to quote strings ...
 231         unless (looks_like_number($default)) {
 232             $default = "'$default'";
 233         }
 234
 235         return $default;
 236     }
 237 }
 238
 239 1;
 240
 241 __END__
 242
 243 =pod
 244
 245 =head1 NAME
 246
 247 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 248
 249 =head1 DESCRIPTION
 250
 251 This is a subclass of L<Class::MOP::Method> which handles
 252 constructing an approprate Constructor methods. This is primarily
 253 used in the making of immutable metaclasses, otherwise it is
 254 not particularly useful.
 255
 256 =head1 METHODS
 257
 258 =over 4
 259
 260 =item B<new>
 261
 262 =item B<attributes>
 263
 264 =item B<meta_instance>
 265
 266 =item B<options>
 267
 268 =item B<intialize_body>
 269
 270 =item B<associated_metaclass>
 271
 272 =back
 273
 274 =head1 AUTHORS
 275
 276 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 277
 278 =head1 COPYRIGHT AND LICENSE
 279
 280 Copyright 2006-2008 by Infinity Interactive, Inc.
 281
 282 L<http://www.iinteractive.com>
 283
 284 This library is free software; you can redistribute it and/or modify
 285 it under the same terms as Perl itself.
 286
 287 =cut
 288