lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number';
   9
  10 our $VERSION   = '0.05';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Generated';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (exists $options{options} && ref $options{options} eq 'HASH')
  21         || confess "You must pass a hash of options";
  22
  23     my $self = bless {
  24         # from our superclass
  25         '&!body'          => undef,
  26         # specific to this subclass
  27         '%!options'       => $options{options},
  28         '$!meta_instance' => $options{metaclass}->get_meta_instance,
  29         '@!attributes'    => [ $options{metaclass}->compute_all_applicable_attributes ],
  30         # ...
  31         '$!associated_metaclass' => $options{metaclass},
  32     } => $class;
  33
  34     # we don't want this creating
  35     # a cycle in the code, if not
  36     # needed
  37     weaken($self->{'$!associated_metaclass'});
  38
  39     $self->intialize_body;
  40
  41     return $self;
  42 }
  43
  44 ## accessors
  45
  46 sub options       { (shift)->{'%!options'}       }
  47 sub meta_instance { (shift)->{'$!meta_instance'} }
  48 sub attributes    { (shift)->{'@!attributes'}    }
  49
  50 sub associated_metaclass { (shift)->{'$!associated_metaclass'} }
  51
  52 ## method
  53
  54 sub intialize_body {
  55     my $self = shift;
  56     # TODO:
  57     # the %options should also include a both
  58     # a call 'initializer' and call 'SUPER::'
  59     # options, which should cover approx 90%
  60     # of the possible use cases (even if it
  61     # requires some adaption on the part of
  62     # the author, after all, nothing is free)
  63     my $source = 'sub {';
  64     $source .= "\n" . 'my $class = shift;';
  65
  66     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
  67     $source .= "\n" . '    if $class ne \'' . $self->associated_metaclass->name . '\';';
  68
  69     $source .= "\n" . 'my %params = (scalar @_ == 1) ? %{$_[0]} : @_;';
  70
  71     $source .= "\n" . 'my $instance = ' . $self->meta_instance->inline_create_instance('$class');
  72
  73     $source .= ";\n" . (join ";\n" => map {
  74         $self->_generate_slot_initializer($_)
  75     } 0 .. (@{$self->attributes} - 1));
  76
  77     $source .= ";\n" . $self->_generate_BUILDALL();
  78
  79     $source .= ";\n" . 'return $instance';
  80     $source .= ";\n" . '}';
  81     warn $source if $self->options->{debug};
  82
  83     my $code;
  84     {
  85         # NOTE:
  86         # create the nessecary lexicals
  87         # to be picked up in the eval
  88         my $attrs = $self->attributes;
  89
  90         # We need to check if the attribute ->can('type_constraint')
  91         # since we may be trying to immutabilize a Moose meta class,
  92         # which in turn has attributes which are Class::MOP::Attribute
  93         # objects, rather than Moose::Meta::Attribute. And
  94         # Class::MOP::Attribute attributes have no type constraints.
  95         # However we need to make sure we leave an undef value there
  96         # because the inlined code is using the index of the attributes
  97         # to determine where to find the type constraint
  98
  99         my @type_constraints = map {
 100             $_->can('type_constraint') ? $_->type_constraint : undef
 101         } @$attrs;
 102
 103         my @type_constraint_bodies = map {
 104             defined $_ ? $_->_compiled_type_constraint : undef;
 105         } @type_constraints;
 106
 107         $code = eval $source;
 108         confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$@" if $@;
 109     }
 110     $self->{'&!body'} = $code;
 111 }
 112
 113 sub _generate_BUILDALL {
 114     my $self = shift;
 115     my @BUILD_calls;
 116     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 117         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD(\%params)';
 118     }
 119     return join ";\n" => @BUILD_calls;
 120 }
 121
 122 sub _generate_slot_initializer {
 123     my $self  = shift;
 124     my $index = shift;
 125
 126     my $attr = $self->attributes->[$index];
 127
 128     my @source = ('## ' . $attr->name);
 129
 130     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 131
 132     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 133         push @source => ('(exists $params{\'' . $attr->init_arg . '\'}) ' .
 134                         '|| confess "Attribute (' . $attr->name . ') is required";');
 135     }
 136
 137     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 138
 139         if ( defined( my $init_arg = $attr->init_arg ) ) {
 140             push @source => 'if (exists $params{\'' . $init_arg . '\'}) {';
 141
 142                 push @source => ('my $val = $params{\'' . $init_arg . '\'};');
 143
 144                 if ($is_moose && $attr->has_type_constraint) {
 145                     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 146                         push @source => $self->_generate_type_coercion(
 147                             $attr,
 148                             '$type_constraints[' . $index . ']',
 149                             '$val',
 150                             '$val'
 151                         );
 152                     }
 153                     push @source => $self->_generate_type_constraint_check(
 154                         $attr,
 155                         '$type_constraint_bodies[' . $index . ']',
 156                         '$type_constraints[' . $index . ']',
 157                         '$val'
 158                     );
 159                 }
 160                 push @source => $self->_generate_slot_assignment($attr, '$val');
 161
 162             push @source => "} else {";
 163         }
 164             my $default;
 165             if ( $attr->has_default ) {
 166                 $default = $self->_generate_default_value($attr, $index);
 167             }
 168             else {
 169                my $builder = $attr->builder;
 170                $default = '$instance->' . $builder;
 171             }
 172
 173             push @source => '{'; # wrap this to avoid my $val overrite warnings
 174             push @source => ('my $val = ' . $default . ';');
 175             push @source => $self->_generate_type_constraint_check(
 176                 $attr,
 177                 ('$type_constraint_bodies[' . $index . ']'),
 178                 ('$type_constraints[' . $index . ']'),
 179                 '$val'
 180             ) if ($is_moose && $attr->has_type_constraint);
 181             push @source => $self->_generate_slot_assignment($attr, $default);
 182             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 183
 184         push @source => "}" if defined $attr->init_arg;
 185     }
 186     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 187         push @source => '(exists $params{\'' . $init_arg . '\'}) && do {';
 188
 189             push @source => ('my $val = $params{\'' . $init_arg . '\'};');
 190             if ($is_moose && $attr->has_type_constraint) {
 191                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 192                     push @source => $self->_generate_type_coercion(
 193                         $attr,
 194                         '$type_constraints[' . $index . ']',
 195                         '$val',
 196                         '$val'
 197                     );
 198                 }
 199                 push @source => $self->_generate_type_constraint_check(
 200                     $attr,
 201                     '$type_constraint_bodies[' . $index . ']',
 202                     '$type_constraints[' . $index . ']',
 203                     '$val'
 204                 );
 205             }
 206             push @source => $self->_generate_slot_assignment($attr, '$val');
 207
 208         push @source => "}";
 209     }
 210
 211     return join "\n" => @source;
 212 }
 213
 214 sub _generate_slot_assignment {
 215     my ($self, $attr, $value) = @_;
 216     my $source = (
 217         $self->meta_instance->inline_set_slot_value(
 218             '$instance',
 219             ("'" . $attr->name . "'"),
 220             $value
 221         ) . ';'
 222     );
 223
 224     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 225
 226     if ($is_moose && $attr->is_weak_ref) {
 227         $source .= (
 228             "\n" .
 229             $self->meta_instance->inline_weaken_slot_value(
 230                 '$instance',
 231                 ("'" . $attr->name . "'")
 232             ) .
 233             ' if ref ' . $value . ';'
 234         );
 235     }
 236
 237     return $source;
 238 }
 239
 240 sub _generate_type_coercion {
 241     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 242     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 243 }
 244
 245 sub _generate_type_constraint_check {
 246     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 247     return (
 248         $type_constraint_cv . '->(' . $value_name . ')'
 249         . "\n\t" . '|| confess "Attribute ('
 250         . $attr->name
 251         . ') does not pass the type constraint because: " . '
 252         . $type_constraint_obj . '->get_message(' . $value_name . ');'
 253     );
 254 }
 255
 256 sub _generate_default_value {
 257     my ($self, $attr, $index) = @_;
 258     # NOTE:
 259     # default values can either be CODE refs
 260     # in which case we need to call them. Or
 261     # they can be scalars (strings/numbers)
 262     # in which case we can just deal with them
 263     # in the code we eval.
 264     if ($attr->is_default_a_coderef) {
 265         return '$attrs->[' . $index . ']->default($instance)';
 266     }
 267     else {
 268         my $default = $attr->default;
 269         # make sure to quote strings ...
 270         unless (looks_like_number($default)) {
 271             $default = "'$default'";
 272         }
 273
 274         return $default;
 275     }
 276 }
 277
 278 1;
 279
 280 __END__
 281
 282 =pod
 283
 284 =head1 NAME
 285
 286 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 287
 288 =head1 DESCRIPTION
 289
 290 This is a subclass of L<Class::MOP::Method> which handles
 291 constructing an approprate Constructor methods. This is primarily
 292 used in the making of immutable metaclasses, otherwise it is
 293 not particularly useful.
 294
 295 =head1 METHODS
 296
 297 =over 4
 298
 299 =item B<new>
 300
 301 =item B<attributes>
 302
 303 =item B<meta_instance>
 304
 305 =item B<options>
 306
 307 =item B<intialize_body>
 308
 309 =item B<associated_metaclass>
 310
 311 =back
 312
 313 =head1 AUTHORS
 314
 315 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 316
 317 =head1 COPYRIGHT AND LICENSE
 318
 319 Copyright 2006-2008 by Infinity Interactive, Inc.
 320
 321 L<http://www.iinteractive.com>
 322
 323 This library is free software; you can redistribute it and/or modify
 324 it under the same terms as Perl itself.
 325
 326 =cut
 327