lib/Moose/Meta/Method/Accessor/Native/Writer.pm

   1 package Moose::Meta::Method::Accessor::Native::Writer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use List::MoreUtils qw( any );
   7
   8 our $VERSION = '1.17';
   9 $VERSION = eval $VERSION;
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use Moose::Role;
  13
  14 with 'Moose::Meta::Method::Accessor::Native';
  15
  16 requires '_potential_value';
  17
  18 sub _generate_method {
  19     my $self = shift;
  20
  21     my $inv = '$self';
  22
  23     my $slot_access = $self->_inline_get($inv);
  24
  25     my $code = 'sub {';
  26
  27     $code .= "\n" . $self->_inline_pre_body(@_);
  28
  29     $code .= "\n" . 'my $self = shift;';
  30
  31     $code .= "\n" . $self->_inline_curried_arguments;
  32
  33     $code .= $self->_writer_core( $inv, $slot_access );
  34
  35     $code .= "\n" . $self->_inline_post_body(@_);
  36
  37     $code .= "\n}";
  38
  39     return $code;
  40 }
  41
  42 sub _writer_core {
  43     my ( $self, $inv, $slot_access ) = @_;
  44
  45     my $code = q{};
  46
  47     $code .= "\n" . $self->_inline_check_argument_count;
  48     $code .= "\n" . $self->_inline_process_arguments( $inv, $slot_access );
  49     $code .= "\n" . $self->_inline_check_arguments('for writer');
  50
  51     $code .= "\n" . $self->_inline_check_lazy($inv);
  52
  53     my $potential_value = $self->_potential_value($slot_access);
  54
  55     if ( $self->_return_value($slot_access) ) {
  56         # some writers will save the return value in this variable when they
  57         # generate the potential value.
  58         $code .= "\n" . 'my @return;';
  59     }
  60
  61     # This is only needed by collections.
  62     $code .= "\n" . $self->_inline_coerce_new_values;
  63     $code .= "\n" . $self->_inline_copy_native_value( \$potential_value );
  64     $code .= "\n"
  65         . $self->_inline_tc_code(
  66         $potential_value
  67         );
  68
  69     $code .= "\n" . $self->_inline_get_old_value_for_trigger($inv);
  70     $code .= "\n" . $self->_inline_capture_return_value($slot_access);
  71     $code .= "\n"
  72         . $self->_inline_set_new_value(
  73         $inv,
  74         $potential_value,
  75         $slot_access,
  76         ) . ';';
  77     $code .= "\n" . $self->_inline_trigger( $inv, $slot_access, '@old' );
  78     $code .= "\n" . $self->_return_value( $slot_access, 'for writer' );
  79
  80     return $code;
  81 }
  82
  83 sub _inline_process_arguments {q{}}
  84
  85 sub _inline_check_arguments {q{}}
  86
  87 sub _inline_coerce_new_values {q{}}
  88
  89 sub _value_needs_copy {
  90     my $self = shift;
  91
  92     return $self->_constraint_must_be_checked;
  93 }
  94
  95 sub _constraint_must_be_checked {
  96     my $self = shift;
  97
  98     my $attr = $self->associated_attribute;
  99
 100     return $attr->has_type_constraint
 101         && ( !$self->_is_root_type( $attr->type_constraint )
 102         || ( $attr->should_coerce && $attr->type_constraint->has_coercion ) );
 103 }
 104
 105 sub _is_root_type {
 106     my ($self, $type) = @_;
 107
 108     my $name = $type->name();
 109
 110     return any { $name eq $_ } @{ $self->root_types };
 111 }
 112
 113 sub _inline_copy_native_value {
 114     my ( $self, $potential_ref ) = @_;
 115
 116     return q{} unless $self->_value_needs_copy;
 117
 118     my $code = "my \$potential = ${$potential_ref};";
 119
 120     ${$potential_ref} = '$potential';
 121
 122     return $code;
 123 }
 124
 125 sub _inline_tc_code {
 126     my ( $self, $potential_value ) = @_;
 127
 128     return q{} unless $self->_constraint_must_be_checked;
 129
 130     return $self->_inline_check_coercion($potential_value) . "\n"
 131         . $self->_inline_check_constraint($potential_value);
 132 }
 133
 134 sub _inline_check_coercion {
 135     my ( $self, $value ) = @_;
 136
 137     my $attr = $self->associated_attribute;
 138
 139     return q{}
 140         unless $attr->should_coerce && $attr->type_constraint->has_coercion;
 141
 142     # We want to break the aliasing in @_ in case the coercion tries to make a
 143     # destructive change to an array member.
 144     return "$value = \$type_constraint_obj->coerce($value);";
 145 }
 146
 147 override _inline_check_constraint => sub {
 148     my $self = shift;
 149
 150     return q{} unless $self->_constraint_must_be_checked;
 151
 152     return super();
 153 };
 154
 155 sub _inline_capture_return_value { return q{} }
 156
 157 sub _inline_set_new_value {
 158     my $self = shift;
 159
 160     return $self->_inline_store(@_)
 161         if $self->_value_needs_copy
 162         || !$self->_slot_access_can_be_inlined
 163         || !$self->_inline_get_is_lvalue;
 164
 165     return $self->_inline_optimized_set_new_value(@_);
 166 }
 167
 168 sub _inline_get_is_lvalue {
 169     my $self = shift;
 170
 171     return $self->associated_attribute->associated_class->instance_metaclass->inline_get_is_lvalue;
 172 }
 173
 174 sub _inline_optimized_set_new_value {
 175     my $self = shift;
 176
 177     return $self->_inline_store(@_);
 178 }
 179
 180 sub _return_value {
 181     my ( $self, $slot_access ) = @_;
 182
 183     return $slot_access;
 184 }
 185
 186 no Moose::Role;
 187
 188 1;