lib/Moose/Meta/Class.pm

   1
   2 package Moose::Meta::Class;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP;
   8
   9 use Carp         'confess';
  10 use Scalar::Util 'weaken', 'blessed', 'reftype';
  11
  12 our $VERSION   = '0.22';
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use Moose::Meta::Method::Overriden;
  16 use Moose::Meta::Method::Augmented;
  17
  18 use base 'Class::MOP::Class';
  19
  20 __PACKAGE__->meta->add_attribute('roles' => (
  21     reader  => 'roles',
  22     default => sub { [] }
  23 ));
  24
  25 sub initialize {
  26     my $class = shift;
  27     my $pkg   = shift;
  28     $class->SUPER::initialize($pkg,
  29         'attribute_metaclass' => 'Moose::Meta::Attribute',
  30         'method_metaclass'    => 'Moose::Meta::Method',
  31         'instance_metaclass'  => 'Moose::Meta::Instance',
  32         @_);
  33 }
  34
  35 sub create {
  36     my ($self, $package_name, %options) = @_;
  37
  38     (ref $options{roles} eq 'ARRAY')
  39         || confess "You must pass an ARRAY ref of roles"
  40             if exists $options{roles};
  41
  42     my $class = $self->SUPER::create($package_name, %options);
  43
  44     if (exists $options{roles}) {
  45         Moose::Util::apply_all_roles($class, @{$options{roles}});
  46     }
  47
  48     return $class;
  49 }
  50
  51 my %ANON_CLASSES;
  52
  53 sub create_anon_class {
  54     my ($self, %options) = @_;
  55
  56     my $cache_ok = delete $options{cache};
  57
  58     # something like Super::Class|Super::Class::2=Role|Role::1
  59     my $cache_key = join '=' => (
  60         join('|', sort @{$options{superclasses} || []}),
  61         join('|', sort @{$options{roles}        || []}),
  62     );
  63
  64     if ($cache_ok && defined $ANON_CLASSES{$cache_key}) {
  65         return $ANON_CLASSES{$cache_key};
  66     }
  67
  68     my $new_class = $self->SUPER::create_anon_class(%options);
  69
  70     $ANON_CLASSES{$cache_key} = $new_class
  71         if $cache_ok;
  72
  73     return $new_class;
  74 }
  75
  76 sub add_role {
  77     my ($self, $role) = @_;
  78     (blessed($role) && $role->isa('Moose::Meta::Role'))
  79         || confess "Roles must be instances of Moose::Meta::Role";
  80     push @{$self->roles} => $role;
  81 }
  82
  83 sub calculate_all_roles {
  84     my $self = shift;
  85     my %seen;
  86     grep { !$seen{$_->name}++ } map { $_->calculate_all_roles } @{ $self->roles };
  87 }
  88
  89 sub does_role {
  90     my ($self, $role_name) = @_;
  91     (defined $role_name)
  92         || confess "You must supply a role name to look for";
  93     foreach my $class ($self->class_precedence_list) {
  94         next unless $class->can('meta') && $class->meta->can('roles');
  95         foreach my $role (@{$class->meta->roles}) {
  96             return 1 if $role->does_role($role_name);
  97         }
  98     }
  99     return 0;
 100 }
 101
 102 sub excludes_role {
 103     my ($self, $role_name) = @_;
 104     (defined $role_name)
 105         || confess "You must supply a role name to look for";
 106     foreach my $class ($self->class_precedence_list) {
 107         next unless $class->can('meta');
 108         # NOTE:
 109         # in the pretty rare instance when a Moose metaclass
 110         # is itself extended with a role, this check needs to
 111         # be done since some items in the class_precedence_list
 112         # might in fact be Class::MOP based still.
 113         next unless $class->meta->can('roles');
 114         foreach my $role (@{$class->meta->roles}) {
 115             return 1 if $role->excludes_role($role_name);
 116         }
 117     }
 118     return 0;
 119 }
 120
 121 sub new_object {
 122     my ($class, %params) = @_;
 123     my $self = $class->SUPER::new_object(%params);
 124     foreach my $attr ($class->compute_all_applicable_attributes()) {
 125         # if we have a trigger, then ...
 126         if ($attr->can('has_trigger') && $attr->has_trigger) {
 127             # make sure we have an init-arg ...
 128             if (defined(my $init_arg = $attr->init_arg)) {
 129                 # now make sure an init-arg was passes ...
 130                 if (exists $params{$init_arg}) {
 131                     # and if get here, fire the trigger
 132                     $attr->trigger->(
 133                         $self,
 134                         # check if there is a coercion
 135                         ($attr->should_coerce
 136                             # and if so, we need to grab the
 137                             # value that is actually been stored
 138                             ? $attr->get_read_method_ref->($self)
 139                             # otherwise, just get the value from
 140                             # the constructor params
 141                             : $params{$init_arg}),
 142                         $attr
 143                     );
 144                 }
 145             }
 146         }
 147     }
 148     return $self;
 149 }
 150
 151 sub construct_instance {
 152     my ($class, %params) = @_;
 153     my $meta_instance = $class->get_meta_instance;
 154     # FIXME:
 155     # the code below is almost certainly incorrect
 156     # but this is foreign inheritence, so we might
 157     # have to kludge it in the end.
 158     my $instance = $params{'__INSTANCE__'} || $meta_instance->create_instance();
 159     foreach my $attr ($class->compute_all_applicable_attributes()) {
 160         $attr->initialize_instance_slot($meta_instance, $instance, \%params);
 161     }
 162     return $instance;
 163 }
 164
 165 # FIXME:
 166 # This is ugly
 167 sub get_method_map {
 168     my $self = shift;
 169
 170     if (defined $self->{'$!_package_cache_flag'} &&
 171                 $self->{'$!_package_cache_flag'} == Class::MOP::check_package_cache_flag($self->meta->name)) {
 172         return $self->{'%!methods'};
 173     }
 174
 175     my $map  = $self->{'%!methods'};
 176
 177     my $class_name       = $self->name;
 178     my $method_metaclass = $self->method_metaclass;
 179
 180     foreach my $symbol ($self->list_all_package_symbols('CODE')) {
 181
 182         my $code = $self->get_package_symbol('&' . $symbol);
 183
 184         next if exists  $map->{$symbol} &&
 185                 defined $map->{$symbol} &&
 186                         $map->{$symbol}->body == $code;
 187
 188         my ($pkg, $name) = Class::MOP::get_code_info($code);
 189
 190         if ($pkg->can('meta')
 191             # NOTE:
 192             # we don't know what ->meta we are calling
 193             # here, so we need to be careful cause it
 194             # just might blow up at us, or just complain
 195             # loudly (in the case of Curses.pm) so we
 196             # just be a little overly cautious here.
 197             # - SL
 198             && eval { no warnings; blessed($pkg->meta) }
 199             && $pkg->meta->isa('Moose::Meta::Role')) {
 200             #my $role = $pkg->meta->name;
 201             #next unless $self->does_role($role);
 202         }
 203         else {
 204             next if ($pkg  || '') ne $class_name &&
 205                     ($name || '') ne '__ANON__';
 206
 207         }
 208
 209         $map->{$symbol} = $method_metaclass->wrap($code);
 210     }
 211
 212     return $map;
 213 }
 214
 215 ### ---------------------------------------------
 216
 217 sub add_attribute {
 218     my $self = shift;
 219     $self->SUPER::add_attribute(
 220         (blessed $_[0] && $_[0]->isa('Class::MOP::Attribute')
 221             ? $_[0]
 222             : $self->_process_attribute(@_))
 223     );
 224 }
 225
 226 sub add_override_method_modifier {
 227     my ($self, $name, $method, $_super_package) = @_;
 228
 229     (!$self->has_method($name))
 230         || confess "Cannot add an override method if a local method is already present";
 231
 232     $self->add_method($name => Moose::Meta::Method::Overriden->new(
 233         method  => $method,
 234         class   => $self,
 235         package => $_super_package, # need this for roles
 236         name    => $name,
 237     ));
 238 }
 239
 240 sub add_augment_method_modifier {
 241     my ($self, $name, $method) = @_;
 242     (!$self->has_method($name))
 243         || confess "Cannot add an augment method if a local method is already present";
 244
 245     $self->add_method($name => Moose::Meta::Method::Augmented->new(
 246         method  => $method,
 247         class   => $self,
 248         name    => $name,
 249     ));
 250 }
 251
 252 ## Private Utility methods ...
 253
 254 sub _find_next_method_by_name_which_is_not_overridden {
 255     my ($self, $name) = @_;
 256     foreach my $method ($self->find_all_methods_by_name($name)) {
 257         return $method->{code}
 258             if blessed($method->{code}) && !$method->{code}->isa('Moose::Meta::Method::Overriden');
 259     }
 260     return undef;
 261 }
 262
 263 sub _fix_metaclass_incompatability {
 264     my ($self, @superclasses) = @_;
 265     foreach my $super (@superclasses) {
 266         # don't bother if it does not have a meta.
 267         next unless $super->can('meta');
 268         # get the name, make sure we take
 269         # immutable classes into account
 270         my $super_meta_name = ($super->meta->is_immutable
 271                                 ? $super->meta->get_mutable_metaclass_name
 272                                 : blessed($super->meta));
 273         # if it's meta is a vanilla Moose,
 274         # then we can safely ignore it.
 275         next if $super_meta_name eq 'Moose::Meta::Class';
 276         # but if we have anything else,
 277         # we need to check it out ...
 278         unless (# see if of our metaclass is incompatible
 279                 ($self->isa($super_meta_name) &&
 280                  # and see if our instance metaclass is incompatible
 281                  $self->instance_metaclass->isa($super->meta->instance_metaclass)) &&
 282                 # ... and if we are just a vanilla Moose
 283                 $self->isa('Moose::Meta::Class')) {
 284             # re-initialize the meta ...
 285             my $super_meta = $super->meta;
 286             # NOTE:
 287             # We might want to consider actually
 288             # transfering any attributes from the
 289             # original meta into this one, but in
 290             # general you should not have any there
 291             # at this point anyway, so it's very
 292             # much an obscure edge case anyway
 293             $self = $super_meta->reinitialize($self->name => (
 294                 'attribute_metaclass' => $super_meta->attribute_metaclass,
 295                 'method_metaclass'    => $super_meta->method_metaclass,
 296                 'instance_metaclass'  => $super_meta->instance_metaclass,
 297             ));
 298         }
 299     }
 300     return $self;
 301 }
 302
 303 # NOTE:
 304 # this was crap anyway, see
 305 # Moose::Util::apply_all_roles
 306 # instead
 307 sub _apply_all_roles {
 308     Carp::croak 'DEPRECATED: use Moose::Util::apply_all_roles($meta, @roles) instead'
 309 }
 310
 311 sub _process_attribute {
 312     my ( $self, $name, @args ) = @_;
 313
 314     @args = %{$args[0]} if scalar @args == 1 && ref($args[0]) eq 'HASH';
 315
 316     if ($name =~ /^\+(.*)/) {
 317         return $self->_process_inherited_attribute($1, @args);
 318     }
 319     else {
 320         return $self->_process_new_attribute($name, @args);
 321     }
 322 }
 323
 324 sub _process_new_attribute {
 325     my ( $self, $name, @args ) = @_;
 326
 327     $self->attribute_metaclass->interpolate_class_and_new($name, @args);
 328 }
 329
 330 sub _process_inherited_attribute {
 331     my ($self, $attr_name, %options) = @_;
 332     my $inherited_attr = $self->find_attribute_by_name($attr_name);
 333     (defined $inherited_attr)
 334         || confess "Could not find an attribute by the name of '$attr_name' to inherit from";
 335     if ($inherited_attr->isa('Moose::Meta::Attribute')) {
 336         return $inherited_attr->clone_and_inherit_options(%options);
 337     }
 338     else {
 339         # NOTE:
 340         # kind of a kludge to handle Class::MOP::Attributes
 341         return $inherited_attr->Moose::Meta::Attribute::clone_and_inherit_options(%options);
 342     }
 343 }
 344
 345 ## -------------------------------------------------
 346
 347 use Moose::Meta::Method::Constructor;
 348 use Moose::Meta::Method::Destructor;
 349
 350 # This could be done by using SUPER and altering ->options
 351 # I am keeping it this way to make it more explicit.
 352 sub create_immutable_transformer {
 353     my $self = shift;
 354     my $class = Class::MOP::Immutable->new($self, {
 355        read_only   => [qw/superclasses/],
 356        cannot_call => [qw/
 357            add_method
 358            alias_method
 359            remove_method
 360            add_attribute
 361            remove_attribute
 362            remove_package_symbol
 363            add_role
 364        /],
 365        memoize     => {
 366            class_precedence_list             => 'ARRAY',
 367            compute_all_applicable_attributes => 'ARRAY',
 368            get_meta_instance                 => 'SCALAR',
 369            get_method_map                    => 'SCALAR',
 370            # maybe ....
 371            calculate_all_roles               => 'ARRAY',
 372        },
 373        # NOTE:
 374        # this is ugly, but so are typeglobs,
 375        # so whattayahgonnadoboutit
 376        # - SL
 377        wrapped => {
 378            add_package_symbol => sub {
 379                my $original = shift;
 380                confess "Cannot add package symbols to an immutable metaclass"
 381                    unless (caller(2))[3] eq 'Class::MOP::Package::get_package_symbol';
 382                goto $original->body;
 383            },
 384        },
 385     });
 386     return $class;
 387 }
 388
 389 sub make_immutable {
 390     my $self = shift;
 391     $self->SUPER::make_immutable
 392       (
 393        constructor_class => 'Moose::Meta::Method::Constructor',
 394        destructor_class  => 'Moose::Meta::Method::Destructor',
 395        inline_destructor => 1,
 396        # NOTE:
 397        # no need to do this,
 398        # Moose always does it
 399        inline_accessors  => 0,
 400        @_,
 401       );
 402 }
 403
 404 1;
 405
 406 __END__
 407
 408 =pod
 409
 410 =head1 NAME
 411
 412 Moose::Meta::Class - The Moose metaclass
 413
 414 =head1 DESCRIPTION
 415
 416 This is a subclass of L<Class::MOP::Class> with Moose specific
 417 extensions.
 418
 419 For the most part, the only time you will ever encounter an
 420 instance of this class is if you are doing some serious deep
 421 introspection. To really understand this class, you need to refer
 422 to the L<Class::MOP::Class> documentation.
 423
 424 =head1 METHODS
 425
 426 =over 4
 427
 428 =item B<initialize>
 429
 430 =item B<create>
 431
 432 Overrides original to accept a list of roles to apply to
 433 the created class.
 434
 435    my $metaclass = Moose::Meta::Class->create( 'New::Class', roles => [...] );
 436
 437 =item B<create_anon_class>
 438
 439 Overrides original to support roles and caching.
 440
 441    my $metaclass = Moose::Meta::Class->create_anon_class(
 442        superclasses => ['Foo'],
 443        roles        => [qw/Some Roles Go Here/],
 444        cache        => 1,
 445    );
 446
 447 =item B<make_immutable>
 448
 449 Override original to add default options for inlining destructor
 450 and altering the Constructor metaclass.
 451
 452 =item B<create_immutable_transformer>
 453
 454 Override original to lock C<add_role> and memoize C<calculate_all_roles>
 455
 456 =item B<new_object>
 457
 458 We override this method to support the C<trigger> attribute option.
 459
 460 =item B<construct_instance>
 461
 462 This provides some Moose specific extensions to this method, you
 463 almost never call this method directly unless you really know what
 464 you are doing.
 465
 466 This method makes sure to handle the moose weak-ref, type-constraint
 467 and type coercion features.
 468
 469 =item B<get_method_map>
 470
 471 This accommodates Moose::Meta::Role::Method instances, which are
 472 aliased, instead of added, but still need to be counted as valid
 473 methods.
 474
 475 =item B<add_override_method_modifier ($name, $method)>
 476
 477 This will create an C<override> method modifier for you, and install
 478 it in the package.
 479
 480 =item B<add_augment_method_modifier ($name, $method)>
 481
 482 This will create an C<augment> method modifier for you, and install
 483 it in the package.
 484
 485 =item B<calculate_all_roles>
 486
 487 =item B<roles>
 488
 489 This will return an array of C<Moose::Meta::Role> instances which are
 490 attached to this class.
 491
 492 =item B<add_role ($role)>
 493
 494 This takes an instance of C<Moose::Meta::Role> in C<$role>, and adds it
 495 to the list of associated roles.
 496
 497 =item B<does_role ($role_name)>
 498
 499 This will test if this class C<does> a given C<$role_name>. It will
 500 not only check it's local roles, but ask them as well in order to
 501 cascade down the role hierarchy.
 502
 503 =item B<excludes_role ($role_name)>
 504
 505 This will test if this class C<excludes> a given C<$role_name>. It will
 506 not only check it's local roles, but ask them as well in order to
 507 cascade down the role hierarchy.
 508
 509 =item B<add_attribute ($attr_name, %params|$params)>
 510
 511 This method does the same thing as L<Class::MOP::Class::add_attribute>, but adds
 512 support for taking the C<$params> as a HASH ref.
 513
 514 =back
 515
 516 =head1 BUGS
 517
 518 All complex software has bugs lurking in it, and this module is no
 519 exception. If you find a bug please either email me, or add the bug
 520 to cpan-RT.
 521
 522 =head1 AUTHOR
 523
 524 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 525
 526 =head1 COPYRIGHT AND LICENSE
 527
 528 Copyright 2006-2008 by Infinity Interactive, Inc.
 529
 530 L<http://www.iinteractive.com>
 531
 532 This library is free software; you can redistribute it and/or modify
 533 it under the same terms as Perl itself.
 534
 535 =cut
 536