lib/Moose/Meta/Attribute.pm

   1
   2 package Moose::Meta::Attribute;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken';
   8 use overload     ();
   9
  10 our $VERSION   = '0.89_01';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use Moose::Meta::Method::Accessor;
  14 use Moose::Meta::Method::Delegation;
  15 use Moose::Util ();
  16 use Moose::Util::TypeConstraints ();
  17
  18 use base 'Class::MOP::Attribute';
  19
  20 # options which are not directly used
  21 # but we store them for metadata purposes
  22 __PACKAGE__->meta->add_attribute('isa'  => (reader    => '_isa_metadata'));
  23 __PACKAGE__->meta->add_attribute('does' => (reader    => '_does_metadata'));
  24 __PACKAGE__->meta->add_attribute('is'   => (reader    => '_is_metadata'));
  25
  26 # these are actual options for the attrs
  27 __PACKAGE__->meta->add_attribute('required'   => (reader => 'is_required'      ));
  28 __PACKAGE__->meta->add_attribute('lazy'       => (reader => 'is_lazy'          ));
  29 __PACKAGE__->meta->add_attribute('lazy_build' => (reader => 'is_lazy_build'    ));
  30 __PACKAGE__->meta->add_attribute('coerce'     => (reader => 'should_coerce'    ));
  31 __PACKAGE__->meta->add_attribute('weak_ref'   => (reader => 'is_weak_ref'      ));
  32 __PACKAGE__->meta->add_attribute('auto_deref' => (reader => 'should_auto_deref'));
  33 __PACKAGE__->meta->add_attribute('type_constraint' => (
  34     reader    => 'type_constraint',
  35     predicate => 'has_type_constraint',
  36 ));
  37 __PACKAGE__->meta->add_attribute('trigger' => (
  38     reader    => 'trigger',
  39     predicate => 'has_trigger',
  40 ));
  41 __PACKAGE__->meta->add_attribute('handles' => (
  42     reader    => 'handles',
  43     writer    => '_set_handles',
  44     predicate => 'has_handles',
  45 ));
  46 __PACKAGE__->meta->add_attribute('documentation' => (
  47     reader    => 'documentation',
  48     predicate => 'has_documentation',
  49 ));
  50 __PACKAGE__->meta->add_attribute('traits' => (
  51     reader    => 'applied_traits',
  52     predicate => 'has_applied_traits',
  53 ));
  54
  55 # we need to have a ->does method in here to
  56 # more easily support traits, and the introspection
  57 # of those traits. We extend the does check to look
  58 # for metatrait aliases.
  59 sub does {
  60     my ($self, $role_name) = @_;
  61     my $name = eval {
  62         Moose::Util::resolve_metatrait_alias(Attribute => $role_name)
  63     };
  64     return 0 if !defined($name); # failed to load class
  65     return $self->Moose::Object::does($name);
  66 }
  67
  68 sub throw_error {
  69     my $self = shift;
  70     my $class = ( ref $self && $self->associated_class ) || "Moose::Meta::Class";
  71     unshift @_, "message" if @_ % 2 == 1;
  72     unshift @_, attr => $self if ref $self;
  73     unshift @_, $class;
  74     my $handler = $class->can("throw_error"); # to avoid incrementing depth by 1
  75     goto $handler;
  76 }
  77
  78 sub new {
  79     my ($class, $name, %options) = @_;
  80     $class->_process_options($name, \%options) unless $options{__hack_no_process_options}; # used from clone()... YECHKKK FIXME ICKY YUCK GROSS
  81
  82     delete $options{__hack_no_process_options};
  83
  84     my %attrs =
  85         ( map { $_ => 1 }
  86           grep { defined }
  87           map { $_->init_arg() }
  88           $class->meta()->get_all_attributes()
  89         );
  90
  91     my @bad = sort grep { ! $attrs{$_} }  keys %options;
  92
  93     if (@bad)
  94     {
  95         Carp::cluck "Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad";
  96     }
  97
  98     return $class->SUPER::new($name, %options);
  99 }
 100
 101 sub interpolate_class_and_new {
 102     my ($class, $name, %args) = @_;
 103
 104     my ( $new_class, @traits ) = $class->interpolate_class(\%args);
 105
 106     $new_class->new($name, %args, ( scalar(@traits) ? ( traits => \@traits ) : () ) );
 107 }
 108
 109 sub interpolate_class {
 110     my ($class, $options) = @_;
 111
 112     $class = ref($class) || $class;
 113
 114     if ( my $metaclass_name = delete $options->{metaclass} ) {
 115         my $new_class = Moose::Util::resolve_metaclass_alias( Attribute => $metaclass_name );
 116
 117         if ( $class ne $new_class ) {
 118             if ( $new_class->can("interpolate_class") ) {
 119                 return $new_class->interpolate_class($options);
 120             } else {
 121                 $class = $new_class;
 122             }
 123         }
 124     }
 125
 126     my @traits;
 127
 128     if (my $traits = $options->{traits}) {
 129         my $i = 0;
 130         while ($i < @$traits) {
 131             my $trait = $traits->[$i++];
 132             next if ref($trait); # options to a trait we discarded
 133
 134             $trait = Moose::Util::resolve_metatrait_alias(Attribute => $trait)
 135                   || $trait;
 136
 137             next if $class->does($trait);
 138
 139             push @traits, $trait;
 140
 141             # are there options?
 142             push @traits, $traits->[$i++]
 143                 if $traits->[$i] && ref($traits->[$i]);
 144         }
 145
 146         if (@traits) {
 147             my $anon_class = Moose::Meta::Class->create_anon_class(
 148                 superclasses => [ $class ],
 149                 roles        => [ @traits ],
 150                 cache        => 1,
 151             );
 152
 153             $class = $anon_class->name;
 154         }
 155     }
 156
 157     return ( wantarray ? ( $class, @traits ) : $class );
 158 }
 159
 160 # ...
 161
 162 my @legal_options_for_inheritance = qw(
 163     default coerce required
 164     documentation lazy handles
 165     builder type_constraint
 166     definition_context
 167     lazy_build weak_ref
 168 );
 169
 170 sub legal_options_for_inheritance { @legal_options_for_inheritance }
 171
 172 # NOTE/TODO
 173 # This method *must* be able to handle
 174 # Class::MOP::Attribute instances as
 175 # well. Yes, I know that is wrong, but
 176 # apparently we didn't realize it was
 177 # doing that and now we have some code
 178 # which is dependent on it. The real
 179 # solution of course is to push this
 180 # feature back up into Class::MOP::Attribute
 181 # but I not right now, I am too lazy.
 182 # However if you are reading this and
 183 # looking for something to do,.. please
 184 # be my guest.
 185 # - stevan
 186 sub clone_and_inherit_options {
 187     my ($self, %options) = @_;
 188
 189     my %copy = %options;
 190
 191     my %actual_options;
 192
 193     # NOTE:
 194     # we may want to extends a Class::MOP::Attribute
 195     # in which case we need to be able to use the
 196     # core set of legal options that have always
 197     # been here. But we allows Moose::Meta::Attribute
 198     # instances to changes them.
 199     # - SL
 200     my @legal_options = $self->can('legal_options_for_inheritance')
 201         ? $self->legal_options_for_inheritance
 202         : @legal_options_for_inheritance;
 203
 204     foreach my $legal_option (@legal_options) {
 205         if (exists $options{$legal_option}) {
 206             $actual_options{$legal_option} = $options{$legal_option};
 207             delete $options{$legal_option};
 208         }
 209     }
 210
 211     if ($options{isa}) {
 212         my $type_constraint;
 213         if (blessed($options{isa}) && $options{isa}->isa('Moose::Meta::TypeConstraint')) {
 214             $type_constraint = $options{isa};
 215         }
 216         else {
 217             $type_constraint = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options{isa});
 218             (defined $type_constraint)
 219                 || $self->throw_error("Could not find the type constraint '" . $options{isa} . "'", data => $options{isa});
 220         }
 221
 222         $actual_options{type_constraint} = $type_constraint;
 223         delete $options{isa};
 224     }
 225
 226     if ($options{does}) {
 227         my $type_constraint;
 228         if (blessed($options{does}) && $options{does}->isa('Moose::Meta::TypeConstraint')) {
 229             $type_constraint = $options{does};
 230         }
 231         else {
 232             $type_constraint = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options{does});
 233             (defined $type_constraint)
 234                 || $self->throw_error("Could not find the type constraint '" . $options{does} . "'", data => $options{does});
 235         }
 236
 237         $actual_options{type_constraint} = $type_constraint;
 238         delete $options{does};
 239     }
 240
 241     # NOTE:
 242     # this doesn't apply to Class::MOP::Attributes,
 243     # so we can ignore it for them.
 244     # - SL
 245     if ($self->can('interpolate_class')) {
 246         ( $actual_options{metaclass}, my @traits ) = $self->interpolate_class(\%options);
 247
 248         my %seen;
 249         my @all_traits = grep { $seen{$_}++ } @{ $self->applied_traits || [] }, @traits;
 250         $actual_options{traits} = \@all_traits if @all_traits;
 251
 252         delete @options{qw(metaclass traits)};
 253     }
 254
 255     (scalar keys %options == 0)
 256         || $self->throw_error("Illegal inherited options => (" . (join ', ' => keys %options) . ")", data => \%options);
 257
 258
 259     $self->clone(%actual_options);
 260 }
 261
 262 sub clone {
 263     my ( $self, %params ) = @_;
 264
 265     my $class = delete $params{metaclass} || ref $self;
 266
 267     my ( @init, @non_init );
 268
 269     foreach my $attr ( grep { $_->has_value($self) } Class::MOP::class_of($self)->get_all_attributes ) {
 270         push @{ $attr->has_init_arg ? \@init : \@non_init }, $attr;
 271     }
 272
 273     my %new_params = ( ( map { $_->init_arg => $_->get_value($self) } @init ), %params );
 274
 275     my $name = delete $new_params{name};
 276
 277     my $clone = $class->new($name, %new_params, __hack_no_process_options => 1 );
 278
 279     foreach my $attr ( @non_init ) {
 280         $attr->set_value($clone, $attr->get_value($self));
 281     }
 282
 283     return $clone;
 284 }
 285
 286 sub _process_options {
 287     my ($class, $name, $options) = @_;
 288
 289     if (exists $options->{is}) {
 290
 291         ### -------------------------
 292         ## is => ro, writer => _foo    # turns into (reader => foo, writer => _foo) as before
 293         ## is => rw, writer => _foo    # turns into (reader => foo, writer => _foo)
 294         ## is => rw, accessor => _foo  # turns into (accessor => _foo)
 295         ## is => ro, accessor => _foo  # error, accesor is rw
 296         ### -------------------------
 297
 298         if ($options->{is} eq 'ro') {
 299             $class->throw_error("Cannot define an accessor name on a read-only attribute, accessors are read/write", data => $options)
 300                 if exists $options->{accessor};
 301             $options->{reader} ||= $name;
 302         }
 303         elsif ($options->{is} eq 'rw') {
 304             if ($options->{writer}) {
 305                 $options->{reader} ||= $name;
 306             }
 307             else {
 308                 $options->{accessor} ||= $name;
 309             }
 310         }
 311         elsif ($options->{is} eq 'bare') {
 312             # do nothing, but don't complain (later) about missing methods
 313         }
 314         else {
 315             $class->throw_error("I do not understand this option (is => " . $options->{is} . ") on attribute ($name)", data => $options->{is});
 316         }
 317     }
 318
 319     if (exists $options->{isa}) {
 320         if (exists $options->{does}) {
 321             if (eval { $options->{isa}->can('does') }) {
 322                 ($options->{isa}->does($options->{does}))
 323                     || $class->throw_error("Cannot have an isa option and a does option if the isa does not do the does on attribute ($name)", data => $options);
 324             }
 325             else {
 326                 $class->throw_error("Cannot have an isa option which cannot ->does() on attribute ($name)", data => $options);
 327             }
 328         }
 329
 330         # allow for anon-subtypes here ...
 331         if (blessed($options->{isa}) && $options->{isa}->isa('Moose::Meta::TypeConstraint')) {
 332             $options->{type_constraint} = $options->{isa};
 333         }
 334         else {
 335             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options->{isa});
 336         }
 337     }
 338     elsif (exists $options->{does}) {
 339         # allow for anon-subtypes here ...
 340         if (blessed($options->{does}) && $options->{does}->isa('Moose::Meta::TypeConstraint')) {
 341                 $options->{type_constraint} = $options->{does};
 342         }
 343         else {
 344             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options->{does});
 345         }
 346     }
 347
 348     if (exists $options->{coerce} && $options->{coerce}) {
 349         (exists $options->{type_constraint})
 350             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)", data => $options);
 351         $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)", data => $options)
 352             if $options->{weak_ref};
 353     }
 354
 355     if (exists $options->{trigger}) {
 356         ('CODE' eq ref $options->{trigger})
 357             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)", data => $options->{trigger});
 358     }
 359
 360     if (exists $options->{auto_deref} && $options->{auto_deref}) {
 361         (exists $options->{type_constraint})
 362             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)", data => $options);
 363         ($options->{type_constraint}->is_a_type_of('ArrayRef') ||
 364          $options->{type_constraint}->is_a_type_of('HashRef'))
 365             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)", data => $options);
 366     }
 367
 368     if (exists $options->{lazy_build} && $options->{lazy_build} == 1) {
 369         $class->throw_error("You can not use lazy_build and default for the same attribute ($name)", data => $options)
 370             if exists $options->{default};
 371         $options->{lazy}      = 1;
 372         $options->{builder} ||= "_build_${name}";
 373         if ($name =~ /^_/) {
 374             $options->{clearer}   ||= "_clear${name}";
 375             $options->{predicate} ||= "_has${name}";
 376         }
 377         else {
 378             $options->{clearer}   ||= "clear_${name}";
 379             $options->{predicate} ||= "has_${name}";
 380         }
 381     }
 382
 383     if (exists $options->{lazy} && $options->{lazy}) {
 384         (exists $options->{default} || defined $options->{builder} )
 385             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it", data => $options);
 386     }
 387
 388     if ( $options->{required} && !( ( !exists $options->{init_arg} || defined $options->{init_arg} ) || exists $options->{default} || defined $options->{builder} ) ) {
 389         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg", data => $options);
 390     }
 391
 392 }
 393
 394 sub initialize_instance_slot {
 395     my ($self, $meta_instance, $instance, $params) = @_;
 396     my $init_arg = $self->init_arg();
 397     # try to fetch the init arg from the %params ...
 398
 399     my $val;
 400     my $value_is_set;
 401     if ( defined($init_arg) and exists $params->{$init_arg}) {
 402         $val = $params->{$init_arg};
 403         $value_is_set = 1;
 404     }
 405     else {
 406         # skip it if it's lazy
 407         return if $self->is_lazy;
 408         # and die if it's required and doesn't have a default value
 409         $self->throw_error("Attribute (" . $self->name . ") is required", object => $instance, data => $params)
 410             if $self->is_required && !$self->has_default && !$self->has_builder;
 411
 412         # if nothing was in the %params, we can use the
 413         # attribute's default value (if it has one)
 414         if ($self->has_default) {
 415             $val = $self->default($instance);
 416             $value_is_set = 1;
 417         }
 418         elsif ($self->has_builder) {
 419             $val = $self->_call_builder($instance);
 420             $value_is_set = 1;
 421         }
 422     }
 423
 424     return unless $value_is_set;
 425
 426     $val = $self->_coerce_and_verify( $val, $instance );
 427
 428     $self->set_initial_value($instance, $val);
 429     $meta_instance->weaken_slot_value($instance, $self->name)
 430         if ref $val && $self->is_weak_ref;
 431 }
 432
 433 sub _call_builder {
 434     my ( $self, $instance ) = @_;
 435
 436     my $builder = $self->builder();
 437
 438     return $instance->$builder()
 439         if $instance->can( $self->builder );
 440
 441     $self->throw_error(  blessed($instance)
 442             . " does not support builder method '"
 443             . $self->builder
 444             . "' for attribute '"
 445             . $self->name
 446             . "'",
 447             object => $instance,
 448      );
 449 }
 450
 451 ## Slot management
 452
 453 # FIXME:
 454 # this duplicates too much code from
 455 # Class::MOP::Attribute, we need to
 456 # refactor these bits eventually.
 457 # - SL
 458 sub _set_initial_slot_value {
 459     my ($self, $meta_instance, $instance, $value) = @_;
 460
 461     my $slot_name = $self->name;
 462
 463     return $meta_instance->set_slot_value($instance, $slot_name, $value)
 464         unless $self->has_initializer;
 465
 466     my ($type_constraint, $can_coerce);
 467     if ($self->has_type_constraint) {
 468         $type_constraint = $self->type_constraint;
 469         $can_coerce      = ($self->should_coerce && $type_constraint->has_coercion);
 470     }
 471
 472     my $callback = sub {
 473         my $val = $self->_coerce_and_verify( shift, $instance );;
 474
 475         $meta_instance->set_slot_value($instance, $slot_name, $val);
 476     };
 477
 478     my $initializer = $self->initializer;
 479
 480     # most things will just want to set a value, so make it first arg
 481     $instance->$initializer($value, $callback, $self);
 482 }
 483
 484 sub set_value {
 485     my ($self, $instance, @args) = @_;
 486     my $value = $args[0];
 487
 488     my $attr_name = $self->name;
 489
 490     if ($self->is_required and not @args) {
 491         $self->throw_error("Attribute ($attr_name) is required", object => $instance);
 492     }
 493
 494     $value = $self->_coerce_and_verify( $value, $instance );
 495
 496     my $meta_instance = Class::MOP::Class->initialize(blessed($instance))
 497                                          ->get_meta_instance;
 498
 499     my @old;
 500     if ( $self->has_trigger && $self->has_value($instance) ) {
 501         @old = $self->get_value($instance, 'for trigger');
 502     }
 503
 504     $meta_instance->set_slot_value($instance, $attr_name, $value);
 505
 506     if (ref $value && $self->is_weak_ref) {
 507         $meta_instance->weaken_slot_value($instance, $attr_name);
 508     }
 509
 510     if ($self->has_trigger) {
 511         $self->trigger->($instance, $value, @old);
 512     }
 513 }
 514
 515 sub get_value {
 516     my ($self, $instance, $for_trigger) = @_;
 517
 518     if ($self->is_lazy) {
 519         unless ($self->has_value($instance)) {
 520             my $value;
 521             if ($self->has_default) {
 522                 $value = $self->default($instance);
 523             } elsif ( $self->has_builder ) {
 524                 $value = $self->_call_builder($instance);
 525             }
 526
 527             $value = $self->_coerce_and_verify( $value, $instance );
 528
 529             $self->set_initial_value($instance, $value);
 530         }
 531     }
 532
 533     if ( $self->should_auto_deref && ! $for_trigger ) {
 534
 535         my $type_constraint = $self->type_constraint;
 536
 537         if ($type_constraint->is_a_type_of('ArrayRef')) {
 538             my $rv = $self->SUPER::get_value($instance);
 539             return unless defined $rv;
 540             return wantarray ? @{ $rv } : $rv;
 541         }
 542         elsif ($type_constraint->is_a_type_of('HashRef')) {
 543             my $rv = $self->SUPER::get_value($instance);
 544             return unless defined $rv;
 545             return wantarray ? %{ $rv } : $rv;
 546         }
 547         else {
 548             $self->throw_error("Can not auto de-reference the type constraint '" . $type_constraint->name . "'", object => $instance, type_constraint => $type_constraint);
 549         }
 550
 551     }
 552     else {
 553
 554         return $self->SUPER::get_value($instance);
 555     }
 556 }
 557
 558 ## installing accessors
 559
 560 sub accessor_metaclass { 'Moose::Meta::Method::Accessor' }
 561
 562 sub install_accessors {
 563     my $self = shift;
 564     $self->SUPER::install_accessors(@_);
 565     $self->install_delegation if $self->has_handles;
 566     return;
 567 }
 568
 569 sub _check_associated_methods {
 570     my $self = shift;
 571     unless (
 572         @{ $self->associated_methods }
 573         || ($self->_is_metadata || '') eq 'bare'
 574     ) {
 575         Carp::cluck(
 576             'Attribute (' . $self->name . ') of class '
 577             . $self->associated_class->name
 578             . ' has no associated methods'
 579             . ' (did you mean to provide an "is" argument?)'
 580             . "\n"
 581         )
 582     }
 583 }
 584
 585 sub _looks_like_overwriting_local_method {
 586         my ($self, $accessor) = @_;
 587         my $method = $self->associated_class->get_method($accessor);
 588         return 0 unless $method;
 589
 590         # get ourselves down to the original method
 591         while ($method->isa('Class::MOP::Method::Wrapped')) {
 592                 $method = $method->get_original_method;
 593         }
 594         return 0 if $method->isa('Class::MOP::Method::Accessor');
 595         return 1 if !$self->definition_context;
 596         return 0 if $method->package_name ne $self->definition_context->{package};
 597         return 1;
 598 }
 599
 600 sub _process_accessors {
 601     my $self = shift;
 602     my ($type, $accessor, $generate_as_inline_methods) = @_;
 603     $accessor = (keys %$accessor)[0] if (ref($accessor)||'') eq 'HASH';
 604         if ($self->_looks_like_overwriting_local_method($accessor)) {
 605         Carp::cluck(
 606             "You are overwriting a locally defined method ($accessor) with "
 607           . "an accessor"
 608         );
 609     }
 610     $self->SUPER::_process_accessors(@_);
 611 }
 612
 613 sub remove_accessors {
 614     my $self = shift;
 615     $self->SUPER::remove_accessors(@_);
 616     $self->remove_delegation if $self->has_handles;
 617     return;
 618 }
 619
 620 sub install_delegation {
 621     my $self = shift;
 622
 623     # NOTE:
 624     # Here we canonicalize the 'handles' option
 625     # this will sort out any details and always
 626     # return an hash of methods which we want
 627     # to delagate to, see that method for details
 628     my %handles = $self->_canonicalize_handles;
 629
 630
 631     # install the delegation ...
 632     my $associated_class = $self->associated_class;
 633     foreach my $handle (keys %handles) {
 634         my $method_to_call = $handles{$handle};
 635         my $class_name = $associated_class->name;
 636         my $name = "${class_name}::${handle}";
 637
 638             (!$associated_class->has_method($handle))
 639                 || $self->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation", method_name => $handle);
 640
 641         # NOTE:
 642         # handles is not allowed to delegate
 643         # any of these methods, as they will
 644         # override the ones in your class, which
 645         # is almost certainly not what you want.
 646
 647         # FIXME warn when $handle was explicitly specified, but not if the source is a regex or something
 648         #cluck("Not delegating method '$handle' because it is a core method") and
 649         next if $class_name->isa("Moose::Object") and $handle =~ /^BUILD|DEMOLISH$/ || Moose::Object->can($handle);
 650
 651         my $method = $self->_make_delegation_method($handle, $method_to_call);
 652
 653         $self->associated_class->add_method($method->name, $method);
 654         $self->associate_method($method);
 655     }
 656 }
 657
 658 sub remove_delegation {
 659     my $self = shift;
 660     my %handles = $self->_canonicalize_handles;
 661     my $associated_class = $self->associated_class;
 662     foreach my $handle (keys %handles) {
 663         $self->associated_class->remove_method($handle);
 664     }
 665 }
 666
 667 # private methods to help delegation ...
 668
 669 sub _canonicalize_handles {
 670     my $self    = shift;
 671     my $handles = $self->handles;
 672     if (my $handle_type = ref($handles)) {
 673         if ($handle_type eq 'HASH') {
 674             return %{$handles};
 675         }
 676         elsif ($handle_type eq 'ARRAY') {
 677             return map { $_ => $_ } @{$handles};
 678         }
 679         elsif ($handle_type eq 'Regexp') {
 680             ($self->has_type_constraint)
 681                 || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)", data => $handles);
 682             return map  { ($_ => $_) }
 683                    grep { /$handles/ } $self->_get_delegate_method_list;
 684         }
 685         elsif ($handle_type eq 'CODE') {
 686             return $handles->($self, $self->_find_delegate_metaclass);
 687         }
 688         elsif (blessed($handles) && $handles->isa('Moose::Meta::TypeConstraint::DuckType')) {
 689             return map { $_ => $_ } @{ $handles->methods };
 690         }
 691         else {
 692             $self->throw_error("Unable to canonicalize the 'handles' option with $handles", data => $handles);
 693         }
 694     }
 695     else {
 696         Class::MOP::load_class($handles);
 697         my $role_meta = Class::MOP::class_of($handles);
 698
 699         (blessed $role_meta && $role_meta->isa('Moose::Meta::Role'))
 700             || $self->throw_error("Unable to canonicalize the 'handles' option with $handles because its metaclass is not a Moose::Meta::Role", data => $handles);
 701
 702         return map { $_ => $_ } (
 703             $role_meta->get_method_list,
 704             map { $_->name } $role_meta->get_required_method_list,
 705         );
 706     }
 707 }
 708
 709 sub _find_delegate_metaclass {
 710     my $self = shift;
 711     if (my $class = $self->_isa_metadata) {
 712         # we might be dealing with a non-Moose class,
 713         # and need to make our own metaclass. if there's
 714         # already a metaclass, it will be returned
 715         return Moose::Meta::Class->initialize($class);
 716     }
 717     elsif (my $role = $self->_does_metadata) {
 718         return Class::MOP::class_of($role);
 719     }
 720     else {
 721         $self->throw_error("Cannot find delegate metaclass for attribute " . $self->name);
 722     }
 723 }
 724
 725 sub _get_delegate_method_list {
 726     my $self = shift;
 727     my $meta = $self->_find_delegate_metaclass;
 728     if ($meta->isa('Class::MOP::Class')) {
 729         return map  { $_->name }  # NOTE: !never! delegate &meta
 730                grep { $_->package_name ne 'Moose::Object' && $_->name ne 'meta' }
 731                     $meta->get_all_methods;
 732     }
 733     elsif ($meta->isa('Moose::Meta::Role')) {
 734         return $meta->get_method_list;
 735     }
 736     else {
 737         $self->throw_error("Unable to recognize the delegate metaclass '$meta'", data => $meta);
 738     }
 739 }
 740
 741 sub delegation_metaclass { 'Moose::Meta::Method::Delegation' }
 742
 743 sub _make_delegation_method {
 744     my ( $self, $handle_name, $method_to_call ) = @_;
 745
 746     my $method_body;
 747
 748     $method_body = $method_to_call
 749         if 'CODE' eq ref($method_to_call);
 750
 751     my @curried_arguments;
 752
 753     ($method_to_call, @curried_arguments) = @$method_to_call
 754         if 'ARRAY' eq ref($method_to_call);
 755
 756     return $self->delegation_metaclass->new(
 757         name               => $handle_name,
 758         package_name       => $self->associated_class->name,
 759         attribute          => $self,
 760         delegate_to_method => $method_to_call,
 761         curried_arguments  => \@curried_arguments,
 762     );
 763 }
 764
 765 sub _coerce_and_verify {
 766     my $self     = shift;
 767     my $val      = shift;
 768     my $instance = shift;
 769
 770     return $val unless $self->has_type_constraint;
 771
 772     my $type_constraint = $self->type_constraint;
 773     if ($self->should_coerce && $type_constraint->has_coercion) {
 774         $val = $type_constraint->coerce($val);
 775     }
 776
 777     $self->verify_against_type_constraint($val, instance => $instance);
 778
 779     return $val;
 780 }
 781
 782 sub verify_against_type_constraint {
 783     my $self = shift;
 784     my $val  = shift;
 785
 786     return 1 if !$self->has_type_constraint;
 787
 788     my $type_constraint = $self->type_constraint;
 789
 790     $type_constraint->check($val)
 791         || $self->throw_error("Attribute ("
 792                  . $self->name
 793                  . ") does not pass the type constraint because: "
 794                  . $type_constraint->get_message($val), data => $val, @_);
 795 }
 796
 797 package Moose::Meta::Attribute::Custom::Moose;
 798 sub register_implementation { 'Moose::Meta::Attribute' }
 799
 800 1;
 801
 802 __END__
 803
 804 =pod
 805
 806 =head1 NAME
 807
 808 Moose::Meta::Attribute - The Moose attribute metaclass
 809
 810 =head1 DESCRIPTION
 811
 812 This class is a subclass of L<Class::MOP::Attribute> that provides
 813 additional Moose-specific functionality.
 814
 815 To really understand this class, you will need to start with the
 816 L<Class::MOP::Attribute> documentation. This class can be understood
 817 as a set of additional features on top of the basic feature provided
 818 by that parent class.
 819
 820 =head1 INHERITANCE
 821
 822 C<Moose::Meta::Attribute> is a subclass of L<Class::MOP::Attribute>.
 823
 824 =head1 METHODS
 825
 826 Many of the documented below override methods in
 827 L<Class::MOP::Attribute> and add Moose specific features.
 828
 829 =head2 Creation
 830
 831 =over 4
 832
 833 =item B<< Moose::Meta::Attribute->new(%options) >>
 834
 835 This method overrides the L<Class::MOP::Attribute> constructor.
 836
 837 Many of the options below are described in more detail in the
 838 L<Moose::Manual::Attributes> document.
 839
 840 It adds the following options to the constructor:
 841
 842 =over 8
 843
 844 =item * is => 'ro', 'rw', 'bare'
 845
 846 This provides a shorthand for specifying the C<reader>, C<writer>, or
 847 C<accessor> names. If the attribute is read-only ('ro') then it will
 848 have a C<reader> method with the same attribute as the name.
 849
 850 If it is read-write ('rw') then it will have an C<accessor> method
 851 with the same name. If you provide an explicit C<writer> for a
 852 read-write attribute, then you will have a C<reader> with the same
 853 name as the attribute, and a C<writer> with the name you provided.
 854
 855 Use 'bare' when you are deliberately not installing any methods
 856 (accessor, reader, etc.) associated with this attribute; otherwise,
 857 Moose will issue a deprecation warning when this attribute is added to a
 858 metaclass.
 859
 860 =item * isa => $type
 861
 862 This option accepts a type. The type can be a string, which should be
 863 a type name. If the type name is unknown, it is assumed to be a class
 864 name.
 865
 866 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 867
 868 If you I<also> provide a C<does> option, then your C<isa> option must
 869 be a class name, and that class must do the role specified with
 870 C<does>.
 871
 872 =item * does => $role
 873
 874 This is short-hand for saying that the attribute's type must be an
 875 object which does the named role.
 876
 877 =item * coerce => $bool
 878
 879 This option is only valid for objects with a type constraint
 880 (C<isa>). If this is true, then coercions will be applied whenever
 881 this attribute is set.
 882
 883 You can make both this and the C<weak_ref> option true.
 884
 885 =item * trigger => $sub
 886
 887 This option accepts a subroutine reference, which will be called after
 888 the attribute is set.
 889
 890 =item * required => $bool
 891
 892 An attribute which is required must be provided to the constructor. An
 893 attribute which is required can also have a C<default> or C<builder>,
 894 which will satisfy its required-ness.
 895
 896 A required attribute must have a C<default>, C<builder> or a
 897 non-C<undef> C<init_arg>
 898
 899 =item * lazy => $bool
 900
 901 A lazy attribute must have a C<default> or C<builder>. When an
 902 attribute is lazy, the default value will not be calculated until the
 903 attribute is read.
 904
 905 =item * weak_ref => $bool
 906
 907 If this is true, the attribute's value will be stored as a weak
 908 reference.
 909
 910 =item * auto_deref => $bool
 911
 912 If this is true, then the reader will dereference the value when it is
 913 called. The attribute must have a type constraint which defines the
 914 attribute as an array or hash reference.
 915
 916 =item * lazy_build => $bool
 917
 918 Setting this to true makes the attribute lazy and provides a number of
 919 default methods.
 920
 921   has 'size' => (
 922       is         => 'ro',
 923       lazy_build => 1,
 924   );
 925
 926 is equivalent to this:
 927
 928   has 'size' => (
 929       is        => 'ro',
 930       lazy      => 1,
 931       builder   => '_build_size',
 932       clearer   => 'clear_size',
 933       predicate => 'has_size',
 934   );
 935
 936 =item * documentation
 937
 938 An arbitrary string that can be retrieved later by calling C<<
 939 $attr->documentation >>.
 940
 941 =back
 942
 943 =item B<< $attr->clone(%options) >>
 944
 945 This creates a new attribute based on attribute being cloned. You must
 946 supply a C<name> option to provide a new name for the attribute.
 947
 948 The C<%options> can only specify options handled by
 949 L<Class::MOP::Attribute>.
 950
 951 =back
 952
 953 =head2 Value management
 954
 955 =over 4
 956
 957 =item B<< $attr->initialize_instance_slot($meta_instance, $instance, $params) >>
 958
 959 This method is used internally to initialize the attribute's slot in
 960 the object C<$instance>.
 961
 962 This overrides the L<Class::MOP::Attribute> method to handle lazy
 963 attributes, weak references, and type constraints.
 964
 965 =item B<get_value>
 966
 967 =item B<set_value>
 968
 969   eval { $point->meta->get_attribute('x')->set_value($point, 'forty-two') };
 970   if($@) {
 971     print "Oops: $@\n";
 972   }
 973
 974 I<Attribute (x) does not pass the type constraint (Int) with 'forty-two'>
 975
 976 Before setting the value, a check is made on the type constraint of
 977 the attribute, if it has one, to see if the value passes it. If the
 978 value fails to pass, the set operation dies with a L<throw_error>.
 979
 980 Any coercion to convert values is done before checking the type constraint.
 981
 982 To check a value against a type constraint before setting it, fetch the
 983 attribute instance using L<Class::MOP::Class/find_attribute_by_name>,
 984 fetch the type_constraint from the attribute using L<Moose::Meta::Attribute/type_constraint>
 985 and call L<Moose::Meta::TypeConstraint/check>. See L<Moose::Cookbook::Basics::Recipe4>
 986 for an example.
 987
 988 =back
 989
 990 =head2 Attribute Accessor generation
 991
 992 =over 4
 993
 994 =item B<< $attr->install_accessors >>
 995
 996 This method overrides the parent to also install delegation methods.
 997
 998 If, after installing all methods, the attribute object has no associated
 999 methods, it throws an error unless C<< is => 'bare' >> was passed to the
1000 attribute constructor.  (Trying to add an attribute that has no associated
1001 methods is almost always an error.)
1002
1003 =item B<< $attr->remove_accessors >>
1004
1005 This method overrides the parent to also remove delegation methods.
1006
1007 =item B<< $attr->install_delegation >>
1008
1009 This method adds its delegation methods to the attribute's associated
1010 class, if it has any to add.
1011
1012 =item B<< $attr->remove_delegation >>
1013
1014 This method remove its delegation methods from the attribute's
1015 associated class.
1016
1017 =item B<< $attr->accessor_metaclass >>
1018
1019 Returns the accessor metaclass name, which defaults to
1020 L<Moose::Meta::Method::Accessor>.
1021
1022 =item B<< $attr->delegation_metaclass >>
1023
1024 Returns the delegation metaclass name, which defaults to
1025 L<Moose::Meta::Method::Delegation>.
1026
1027 =back
1028
1029 =head2 Additional Moose features
1030
1031 These methods are not found in the superclass. They support features
1032 provided by Moose.
1033
1034 =over 4
1035
1036 =item B<< $attr->does($role) >>
1037
1038 This indicates whether the I<attribute itself> does the given
1039 role. The role can be given as a full class name, or as a resolvable
1040 trait name.
1041
1042 Note that this checks the attribute itself, not its type constraint,
1043 so it is checking the attribute's metaclass and any traits applied to
1044 the attribute.
1045
1046 =item B<< Moose::Meta::Class->interpolate_class_and_new($name, %options) >>
1047
1048 This is an alternate constructor that handles the C<metaclass> and
1049 C<traits> options.
1050
1051 Effectively, this method is a factory that finds or creates the
1052 appropriate class for the given C<metaclass> and/or C<traits>.
1053
1054 Once it has the appropriate class, it will call C<< $class->new($name,
1055 %options) >> on that class.
1056
1057 =item B<< $attr->clone_and_inherit_options(%options) >>
1058
1059 This method supports the C<has '+foo'> feature. It does various bits
1060 of processing on the supplied C<%options> before ultimately calling
1061 the C<clone> method.
1062
1063 One of its main tasks is to make sure that the C<%options> provided
1064 only includes the options returned by the
1065 C<legal_options_for_inheritance> method.
1066
1067 =item B<< $attr->legal_options_for_inheritance >>
1068
1069 This returns a whitelist of options that can be overridden in a
1070 subclass's attribute definition.
1071
1072 This exists to allow a custom metaclass to change or add to the list
1073 of options which can be changed.
1074
1075 =item B<< $attr->type_constraint >>
1076
1077 Returns the L<Moose::Meta::TypeConstraint> object for this attribute,
1078 if it has one.
1079
1080 =item B<< $attr->has_type_constraint >>
1081
1082 Returns true if this attribute has a type constraint.
1083
1084 =item B<< $attr->verify_against_type_constraint($value) >>
1085
1086 Given a value, this method returns true if the value is valid for the
1087 attribute's type constraint. If the value is not valid, it throws an
1088 error.
1089
1090 =item B<< $attr->handles >>
1091
1092 This returns the value of the C<handles> option passed to the
1093 constructor.
1094
1095 =item B<< $attr->has_handles >>
1096
1097 Returns true if this attribute performs delegation.
1098
1099 =item B<< $attr->is_weak_ref >>
1100
1101 Returns true if this attribute stores its value as a weak reference.
1102
1103 =item B<< $attr->is_required >>
1104
1105 Returns true if this attribute is required to have a value.
1106
1107 =item B<< $attr->is_lazy >>
1108
1109 Returns true if this attribute is lazy.
1110
1111 =item B<< $attr->is_lazy_build >>
1112
1113 Returns true if the C<lazy_build> option was true when passed to the
1114 constructor.
1115
1116 =item B<< $attr->should_coerce >>
1117
1118 Returns true if the C<coerce> option passed to the constructor was
1119 true.
1120
1121 =item B<< $attr->should_auto_deref >>
1122
1123 Returns true if the C<auto_deref> option passed to the constructor was
1124 true.
1125
1126 =item B<< $attr->trigger >>
1127
1128 This is the subroutine reference that was in the C<trigger> option
1129 passed to the constructor, if any.
1130
1131 =item B<< $attr->has_trigger >>
1132
1133 Returns true if this attribute has a trigger set.
1134
1135 =item B<< $attr->documentation >>
1136
1137 Returns the value that was in the C<documentation> option passed to
1138 the constructor, if any.
1139
1140 =item B<< $attr->has_documentation >>
1141
1142 Returns true if this attribute has any documentation.
1143
1144 =item B<< $attr->applied_traits >>
1145
1146 This returns an array reference of all the traits which were applied
1147 to this attribute. If none were applied, this returns C<undef>.
1148
1149 =item B<< $attr->has_applied_traits >>
1150
1151 Returns true if this attribute has any traits applied.
1152
1153 =back
1154
1155 =head1 BUGS
1156
1157 All complex software has bugs lurking in it, and this module is no
1158 exception. If you find a bug please either email me, or add the bug
1159 to cpan-RT.
1160
1161 =head1 AUTHOR
1162
1163 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1164
1165 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
1166
1167 =head1 COPYRIGHT AND LICENSE
1168
1169 Copyright 2006-2009 by Infinity Interactive, Inc.
1170
1171 L<http://www.iinteractive.com>
1172
1173 This library is free software; you can redistribute it and/or modify
1174 it under the same terms as Perl itself.
1175
1176 =cut