lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B qw(perlstring);
   6
   7 our %TYPE_MAP;
   8
   9 our $SETUP_DONE;
  10
  11 sub import { return if $SETUP_DONE; inject_all(); $SETUP_DONE = 1; }
  12
  13 sub inject_all {
  14   require Class::MOP;
  15   inject_fake_metaclass_for($_)
  16     for grep $_ ne 'Moo::Object', do { no warnings 'once'; keys %Moo::MAKERS };
  17   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  18   require Moose::Meta::Method::Constructor;
  19   @Moo::HandleMoose::FakeConstructor::ISA = 'Moose::Meta::Method::Constructor';
  20 }
  21
  22 sub maybe_reinject_fake_metaclass_for {
  23   my ($name) = @_;
  24   our %DID_INJECT;
  25   if (delete $DID_INJECT{$name}) {
  26     inject_fake_metaclass_for($name);
  27   }
  28 }
  29
  30 sub inject_fake_metaclass_for {
  31   my ($name) = @_;
  32   require Class::MOP;
  33   require Moo::HandleMoose::FakeMetaClass;
  34   Class::MOP::store_metaclass_by_name(
  35     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  36   );
  37 }
  38
  39 {
  40   package Moo::HandleMoose::FakeConstructor;
  41
  42   sub _uninlined_body { \&Moose::Object::new }
  43 }
  44
  45
  46 sub inject_real_metaclass_for {
  47   my ($name) = @_;
  48   our %DID_INJECT;
  49   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  50   require Moose; require Moo; require Moo::Role;
  51   Class::MOP::remove_metaclass_by_name($name);
  52   my ($am_role, $meta, $attr_specs, $attr_order) = do {
  53     if (my $info = $Moo::Role::INFO{$name}) {
  54       my @attr_info = @{$info->{attributes}||[]};
  55       (1, Moose::Meta::Role->initialize($name),
  56        { @attr_info },
  57        [ @attr_info[grep !($_ % 2), 0..$#attr_info] ]
  58       )
  59     } else {
  60       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  61       (0, Moose::Meta::Class->initialize($name), $specs,
  62        [ sort { $specs->{$a}{index} <=> $specs->{$b}{index} } keys %$specs ]
  63       );
  64     }
  65   };
  66
  67   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  68
  69   # if stuff gets added afterwards, _maybe_reset_handlemoose should
  70   # trigger the recreation of the metaclass but we need to ensure the
  71   # Role::Tiny cache is cleared so we don't confuse Moo itself.
  72   if (my $info = $Role::Tiny::INFO{$name}) {
  73     delete $info->{methods};
  74   }
  75
  76   # needed to ensure the method body is stable and get things named
  77   Sub::Defer::undefer_sub($_) for grep defined, values %methods;
  78   my @attrs;
  79   {
  80     # This local is completely not required for roles but harmless
  81     local @{_getstash($name)}{keys %methods};
  82     my %seen_name;
  83     foreach my $name (@$attr_order) {
  84       $seen_name{$name} = 1;
  85       my %spec = %{$attr_specs->{$name}};
  86       delete $spec{index};
  87       $spec{is} = 'ro' if $spec{is} eq 'lazy' or $spec{is} eq 'rwp';
  88       delete $spec{asserter};
  89       if (my $isa = $spec{isa}) {
  90         my $tc = $spec{isa} = do {
  91           if (my $mapped = $TYPE_MAP{$isa}) {
  92             $mapped->();
  93           } else {
  94             Moose::Meta::TypeConstraint->new(
  95               constraint => sub { eval { &$isa; 1 } }
  96             );
  97           }
  98         };
  99         if (my $coerce = $spec{coerce}) {
 100           $tc->coercion(Moose::Meta::TypeCoercion->new)
 101              ->_compiled_type_coercion($coerce);
 102           $spec{coerce} = 1;
 103         }
 104       } elsif (my $coerce = $spec{coerce}) {
 105         my $attr = perlstring($name);
 106         my $tc = Moose::Meta::TypeConstraint->new(
 107                    constraint => sub { die "This is not going to work" },
 108                    inlined => sub {
 109                       'my $r = $_[42]{'.$attr.'}; $_[42]{'.$attr.'} = 1; $r'
 110                    },
 111                  );
 112         $tc->coercion(Moose::Meta::TypeCoercion->new)
 113            ->_compiled_type_coercion($coerce);
 114         $spec{isa} = $tc;
 115         $spec{coerce} = 1;
 116       }
 117       push @attrs, $meta->add_attribute($name => %spec);
 118     }
 119     foreach my $mouse (do { our %MOUSE; @{$MOUSE{$name}||[]} }) {
 120       foreach my $attr ($mouse->get_all_attributes) {
 121         my %spec = %{$attr};
 122         delete @spec{qw(
 123           associated_class associated_methods __METACLASS__
 124           provides curries
 125         )};
 126         my $name = delete $spec{name};
 127         next if $seen_name{$name}++;
 128         push @attrs, $meta->add_attribute($name => %spec);
 129       }
 130     }
 131   }
 132   if ($am_role) {
 133     my $info = $Moo::Role::INFO{$name};
 134     $meta->add_required_methods(@{$info->{requires}});
 135     foreach my $modifier (@{$info->{modifiers}}) {
 136       my ($type, @args) = @$modifier;
 137       $meta->${\"add_${type}_method_modifier"}(@args);
 138     }
 139   } else {
 140     foreach my $attr (@attrs) {
 141       foreach my $method (@{$attr->associated_methods}) {
 142         $method->{body} = $name->can($method->name);
 143       }
 144     }
 145     bless(
 146       $meta->find_method_by_name('new'),
 147       'Moo::HandleMoose::FakeConstructor',
 148     );
 149   }
 150   $meta->add_role(Class::MOP::class_of($_))
 151     for grep !/\|/ && $_ ne $name, # reject Foo|Bar and same-role-as-self
 152       do { no warnings 'once'; keys %{$Role::Tiny::APPLIED_TO{$name}} };
 153   $DID_INJECT{$name} = 1;
 154   $meta;
 155 }
 156
 157 1;