lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B qw(perlstring);
   6
   7 our %TYPE_MAP;
   8
   9 our $SETUP_DONE;
  10
  11 sub import { return if $SETUP_DONE; inject_all(); $SETUP_DONE = 1; }
  12
  13 sub inject_all {
  14   require Class::MOP;
  15   inject_fake_metaclass_for($_)
  16     for grep $_ ne 'Moo::Object', do { no warnings 'once'; keys %Moo::MAKERS };
  17   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  18   require Moose::Meta::Method::Constructor;
  19   @Moo::HandleMoose::FakeConstructor::ISA = 'Moose::Meta::Method::Constructor';
  20 }
  21
  22 sub maybe_reinject_fake_metaclass_for {
  23   my ($name) = @_;
  24   our %DID_INJECT;
  25   if (delete $DID_INJECT{$name}) {
  26     unless ($Moo::Role::INFO{$name}) {
  27       Moo->_constructor_maker_for($name)->install_delayed;
  28     }
  29     inject_fake_metaclass_for($name);
  30   }
  31 }
  32
  33 sub inject_fake_metaclass_for {
  34   my ($name) = @_;
  35   require Class::MOP;
  36   require Moo::HandleMoose::FakeMetaClass;
  37   Class::MOP::store_metaclass_by_name(
  38     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  39   );
  40   require Moose::Util::TypeConstraints;
  41   if ($Moo::Role::INFO{$name}) {
  42     Moose::Util::TypeConstraints::find_or_create_does_type_constraint($name);
  43   } else {
  44     Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($name);
  45   }
  46 }
  47
  48 {
  49   package Moo::HandleMoose::FakeConstructor;
  50
  51   sub _uninlined_body { \&Moose::Object::new }
  52 }
  53
  54 sub inject_real_metaclass_for {
  55   my ($name) = @_;
  56   our %DID_INJECT;
  57   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  58   require Moose; require Moo; require Moo::Role; require Scalar::Util;
  59   Class::MOP::remove_metaclass_by_name($name);
  60   my ($am_role, $meta, $attr_specs, $attr_order) = do {
  61     if (my $info = $Moo::Role::INFO{$name}) {
  62       my @attr_info = @{$info->{attributes}||[]};
  63       (1, Moose::Meta::Role->initialize($name),
  64        { @attr_info },
  65        [ @attr_info[grep !($_ % 2), 0..$#attr_info] ]
  66       )
  67     } elsif ( my $cmaker = Moo->_constructor_maker_for($name) ) {
  68       my $specs = $cmaker->all_attribute_specs;
  69       (0, Moose::Meta::Class->initialize($name), $specs,
  70        [ sort { $specs->{$a}{index} <=> $specs->{$b}{index} } keys %$specs ]
  71       );
  72     } else {
  73        # This codepath is used if $name does not exist in $Moo::MAKERS
  74        (0, Moose::Meta::Class->initialize($name), {}, [] )
  75     }
  76   };
  77
  78   for my $spec (values %$attr_specs) {
  79     if (my $inflators = delete $spec->{moosify}) {
  80       $_->($spec) for @$inflators;
  81     }
  82   }
  83
  84   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  85
  86   # if stuff gets added afterwards, _maybe_reset_handlemoose should
  87   # trigger the recreation of the metaclass but we need to ensure the
  88   # Role::Tiny cache is cleared so we don't confuse Moo itself.
  89   if (my $info = $Role::Tiny::INFO{$name}) {
  90     delete $info->{methods};
  91   }
  92
  93   # needed to ensure the method body is stable and get things named
  94   Sub::Defer::undefer_sub($_) for grep defined, values %methods;
  95   my @attrs;
  96   {
  97     # This local is completely not required for roles but harmless
  98     local @{_getstash($name)}{keys %methods};
  99     my %seen_name;
 100     foreach my $name (@$attr_order) {
 101       $seen_name{$name} = 1;
 102       my %spec = %{$attr_specs->{$name}};
 103       my %spec_map = (
 104         map { $_->name => $_->init_arg||$_->name }
 105         (
 106           (grep { $_->has_init_arg }
 107              $meta->attribute_metaclass->meta->get_all_attributes),
 108           grep { exists($_->{init_arg}) ? defined($_->init_arg) : 1 }
 109           map {
 110             my $meta = Moose::Util::resolve_metatrait_alias('Attribute', $_)
 111                          ->meta;
 112             map $meta->get_attribute($_), $meta->get_attribute_list
 113           }  @{$spec{traits}||[]}
 114         )
 115       );
 116       # have to hard code this because Moose's role meta-model is lacking
 117       $spec_map{traits} ||= 'traits';
 118
 119       $spec{is} = 'ro' if $spec{is} eq 'lazy' or $spec{is} eq 'rwp';
 120       my $coerce = $spec{coerce};
 121       if (my $isa = $spec{isa}) {
 122         my $tc = $spec{isa} = do {
 123           if (my $mapped = $TYPE_MAP{$isa}) {
 124             my $type = $mapped->();
 125             Scalar::Util::blessed($type) && $type->isa("Moose::Meta::TypeConstraint")
 126               or die "error inflating attribute '$name' for package '$_[0]': \$TYPE_MAP{$isa} did not return a valid type constraint'";
 127             $coerce ? $type->create_child_type(name => $type->name) : $type;
 128           } else {
 129             Moose::Meta::TypeConstraint->new(
 130               constraint => sub { eval { &$isa; 1 } }
 131             );
 132           }
 133         };
 134         if ($coerce) {
 135           $tc->coercion(Moose::Meta::TypeCoercion->new)
 136              ->_compiled_type_coercion($coerce);
 137           $spec{coerce} = 1;
 138         }
 139       } elsif ($coerce) {
 140         my $attr = perlstring($name);
 141         my $tc = Moose::Meta::TypeConstraint->new(
 142                    constraint => sub { die "This is not going to work" },
 143                    inlined => sub {
 144                       'my $r = $_[42]{'.$attr.'}; $_[42]{'.$attr.'} = 1; $r'
 145                    },
 146                  );
 147         $tc->coercion(Moose::Meta::TypeCoercion->new)
 148            ->_compiled_type_coercion($coerce);
 149         $spec{isa} = $tc;
 150         $spec{coerce} = 1;
 151       }
 152       %spec =
 153         map { $spec_map{$_} => $spec{$_} }
 154         grep { exists $spec_map{$_} }
 155         keys %spec;
 156       push @attrs, $meta->add_attribute($name => %spec);
 157     }
 158     foreach my $mouse (do { our %MOUSE; @{$MOUSE{$name}||[]} }) {
 159       foreach my $attr ($mouse->get_all_attributes) {
 160         my %spec = %{$attr};
 161         delete @spec{qw(
 162           associated_class associated_methods __METACLASS__
 163           provides curries
 164         )};
 165         my $name = delete $spec{name};
 166         next if $seen_name{$name}++;
 167         push @attrs, $meta->add_attribute($name => %spec);
 168       }
 169     }
 170   }
 171   for my $meth_name (keys %methods) {
 172     my $meth_code = $methods{$meth_name};
 173     $meta->add_method($meth_name, $meth_code) if $meth_code;
 174   }
 175
 176   if ($am_role) {
 177     my $info = $Moo::Role::INFO{$name};
 178     $meta->add_required_methods(@{$info->{requires}});
 179     foreach my $modifier (@{$info->{modifiers}}) {
 180       my ($type, @args) = @$modifier;
 181       my $code = pop @args;
 182       $meta->${\"add_${type}_method_modifier"}($_, $code) for @args;
 183     }
 184   } else {
 185     foreach my $attr (@attrs) {
 186       foreach my $method (@{$attr->associated_methods}) {
 187         $method->{body} = $name->can($method->name);
 188       }
 189     }
 190     bless(
 191       $meta->find_method_by_name('new'),
 192       'Moo::HandleMoose::FakeConstructor',
 193     );
 194     # a combination of Moo and Moose may bypass a Moo constructor but still
 195     # use a Moo DEMOLISHALL.  We need to make sure this is loaded before
 196     # global destruction.
 197     require Method::Generate::DemolishAll;
 198   }
 199   $meta->add_role(Class::MOP::class_of($_))
 200     for grep !/\|/ && $_ ne $name, # reject Foo|Bar and same-role-as-self
 201       do { no warnings 'once'; keys %{$Role::Tiny::APPLIED_TO{$name}} };
 202   $DID_INJECT{$name} = 1;
 203   $meta;
 204 }
 205
 206 1;