lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5
   6 sub import { inject_all() }
   7
   8 sub inject_all {
   9   require Class::MOP;
  10   inject_fake_metaclass_for($_) for grep $_ ne 'Moo::Object', keys %Moo::MAKERS;
  11   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  12 }
  13
  14 sub inject_fake_metaclass_for {
  15   my ($name) = @_;
  16   require Class::MOP;
  17   Class::MOP::store_metaclass_by_name(
  18     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  19   );
  20 }
  21
  22 our %DID_INJECT;
  23
  24 sub inject_real_metaclass_for {
  25   my ($name) = @_;
  26   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  27   require Moose; require Moo; require Moo::Role;
  28   Class::MOP::remove_metaclass_by_name($name);
  29   my ($am_role, $meta, $attr_specs) = do {
  30     if (my $info = $Moo::Role::INFO{$name}) {
  31       (1, Moose::Meta::Role->initialize($name), $info->{attributes})
  32     } else {
  33       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  34       (0, Moose::Meta::Class->initialize($name), $specs);
  35     }
  36   };
  37   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  38   my @attrs;
  39   {
  40     # This local is completely not required for roles but harmless
  41     local @{_getstash($name)}{keys %methods};
  42     foreach my $name (keys %$attr_specs) {
  43       my %spec = %{$attr_specs->{$name}};
  44       $spec{is} = 'ro' if $spec{is} eq 'lazy';
  45       push @attrs, $meta->add_attribute($name => %spec);
  46     }
  47   }
  48   if ($am_role) {
  49     my $info = $Moo::Role::INFO{$name};
  50     $meta->add_required_methods(@{$info->{requires}});
  51     foreach my $modifier (@{$info->{modifiers}}) {
  52       my ($type, @args) = @$modifier;
  53       $meta->${\"add_${type}_method_modifier"}(@args);
  54     }
  55   } else {
  56     foreach my $attr (@attrs) {
  57       foreach my $method (@{$attr->associated_methods}) {
  58         $method->{body} = $name->can($method->name);
  59       }
  60     }
  61   }
  62   $DID_INJECT{$name} = 1;
  63   $meta;
  64 }
  65
  66 {
  67   package Moo::HandleMoose::FakeMetaClass;
  68
  69   sub DESTROY { }
  70
  71   sub AUTOLOAD {
  72     my ($meth) = (our $AUTOLOAD =~ /([^:]+)$/);
  73     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->$meth(@_)
  74   }
  75   sub can {
  76     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->can(@_)
  77   }
  78   sub isa {
  79     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->isa(@_)
  80   }
  81 }
  82
  83 1;