lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5
   6 sub import { inject_all() }
   7
   8 sub inject_all {
   9   require Class::MOP;
  10   inject_fake_metaclass_for($_) for grep $_ ne 'Moo::Object', keys %Moo::MAKERS;
  11   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  12 }
  13
  14 sub inject_fake_metaclass_for {
  15   my ($name) = @_;
  16   require Class::MOP;
  17   Class::MOP::store_metaclass_by_name(
  18     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  19   );
  20 }
  21
  22 our %DID_INJECT;
  23
  24 sub inject_real_metaclass_for {
  25   my ($name) = @_;
  26   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  27   require Moose; require Moo; require Moo::Role;
  28   Class::MOP::remove_metaclass_by_name($name);
  29   my ($am_role, $meta, $attr_specs) = do {
  30     if (my $info = $Moo::Role::INFO{$name}) {
  31       (1, Moose::Meta::Role->initialize($name), $info->{attributes})
  32     } else {
  33       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  34       (0, Moose::Meta::Class->initialize($name), $specs);
  35     }
  36   };
  37   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  38   my @attrs;
  39   {
  40     # This local is completely not required for roles but harmless
  41     local @{_getstash($name)}{keys %methods};
  42     foreach my $name (keys %$attr_specs) {
  43       my %spec = %{$attr_specs->{$name}};
  44       $spec{is} = 'ro' if $spec{is} eq 'lazy';
  45       push @attrs, $meta->add_attribute($name => %spec);
  46     }
  47   }
  48   if ($am_role) {
  49     $meta->add_required_methods(@{$Moo::Role::INFO{$name}{requires}});
  50   } else {
  51     foreach my $attr (@attrs) {
  52       foreach my $method (@{$attr->associated_methods}) {
  53         $method->{body} = $name->can($method->name);
  54       }
  55     }
  56   }
  57   $DID_INJECT{$name} = 1;
  58   $meta;
  59 }
  60
  61 {
  62   package Moo::HandleMoose::FakeMetaClass;
  63
  64   sub DESTROY { }
  65
  66   sub AUTOLOAD {
  67     my ($meth) = (our $AUTOLOAD =~ /([^:]+)$/);
  68     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->$meth(@_)
  69   }
  70   sub can {
  71     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->can(@_)
  72   }
  73   sub isa {
  74     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->isa(@_)
  75   }
  76 }
  77
  78 1;