lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5
   6 our %TYPE_MAP;
   7
   8 sub import { inject_all() }
   9
  10 sub inject_all {
  11   require Class::MOP;
  12   inject_fake_metaclass_for($_) for grep $_ ne 'Moo::Object', keys %Moo::MAKERS;
  13   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  14 }
  15
  16 sub inject_fake_metaclass_for {
  17   my ($name) = @_;
  18   require Class::MOP;
  19   Class::MOP::store_metaclass_by_name(
  20     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  21   );
  22 }
  23
  24 our %DID_INJECT;
  25
  26 sub inject_real_metaclass_for {
  27   my ($name) = @_;
  28   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  29   require Moose; require Moo; require Moo::Role;
  30   Class::MOP::remove_metaclass_by_name($name);
  31   my ($am_role, $meta, $attr_specs) = do {
  32     if (my $info = $Moo::Role::INFO{$name}) {
  33       (1, Moose::Meta::Role->initialize($name), $info->{attributes})
  34     } else {
  35       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  36       (0, Moose::Meta::Class->initialize($name), $specs);
  37     }
  38   };
  39   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  40   my @attrs;
  41   {
  42     # This local is completely not required for roles but harmless
  43     local @{_getstash($name)}{keys %methods};
  44     foreach my $name (keys %$attr_specs) {
  45       my %spec = %{$attr_specs->{$name}};
  46       $spec{is} = 'ro' if $spec{is} eq 'lazy';
  47       if (my $isa = $spec{isa}) {
  48         $spec{isa} = do {
  49           if (my $mapped = $TYPE_MAP{$isa}) {
  50             _load_module($mapped->[1]) if $mapped->[1];
  51             Moose::Util::TypeConstraints::find_type_constraint($mapped->[0])
  52           } else {
  53             Moose::Meta::TypeConstraint->new(
  54               constraint => sub { eval { &$isa; 1 } }
  55             );
  56           }
  57         };
  58       }
  59       push @attrs, $meta->add_attribute($name => %spec);
  60     }
  61   }
  62   if ($am_role) {
  63     my $info = $Moo::Role::INFO{$name};
  64     $meta->add_required_methods(@{$info->{requires}});
  65     foreach my $modifier (@{$info->{modifiers}}) {
  66       my ($type, @args) = @$modifier;
  67       $meta->${\"add_${type}_method_modifier"}(@args);
  68     }
  69   } else {
  70     foreach my $attr (@attrs) {
  71       foreach my $method (@{$attr->associated_methods}) {
  72         $method->{body} = $name->can($method->name);
  73       }
  74     }
  75   }
  76   $DID_INJECT{$name} = 1;
  77   $meta;
  78 }
  79
  80 {
  81   package Moo::HandleMoose::FakeMetaClass;
  82
  83   sub DESTROY { }
  84
  85   sub AUTOLOAD {
  86     my ($meth) = (our $AUTOLOAD =~ /([^:]+)$/);
  87     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->$meth(@_)
  88   }
  89   sub can {
  90     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->can(@_)
  91   }
  92   sub isa {
  93     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->isa(@_)
  94   }
  95 }
  96
  97 1;