lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B qw(perlstring);
   6
   7 our %TYPE_MAP;
   8
   9 our $SETUP_DONE;
  10
  11 sub import { return if $SETUP_DONE; inject_all(); $SETUP_DONE = 1; }
  12
  13 sub inject_all {
  14   require Class::MOP;
  15   inject_fake_metaclass_for($_)
  16     for grep $_ ne 'Moo::Object', do { no warnings 'once'; keys %Moo::MAKERS };
  17   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  18   require Moose::Meta::Method::Constructor;
  19   @Moo::HandleMoose::FakeConstructor::ISA = 'Moose::Meta::Method::Constructor';
  20 }
  21
  22 sub maybe_reinject_fake_metaclass_for {
  23   my ($name) = @_;
  24   our %DID_INJECT;
  25   if (delete $DID_INJECT{$name}) {
  26     unless ($Moo::Role::INFO{$name}) {
  27       Moo->_constructor_maker_for($name)->install_delayed;
  28     }
  29     inject_fake_metaclass_for($name);
  30   }
  31 }
  32
  33 sub inject_fake_metaclass_for {
  34   my ($name) = @_;
  35   require Class::MOP;
  36   require Moo::HandleMoose::FakeMetaClass;
  37   Class::MOP::store_metaclass_by_name(
  38     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  39   );
  40 }
  41
  42 {
  43   package Moo::HandleMoose::FakeConstructor;
  44
  45   sub _uninlined_body { \&Moose::Object::new }
  46 }
  47
  48
  49 sub inject_real_metaclass_for {
  50   my ($name) = @_;
  51   our %DID_INJECT;
  52   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  53   require Moose; require Moo; require Moo::Role;
  54   Class::MOP::remove_metaclass_by_name($name);
  55   my ($am_role, $meta, $attr_specs, $attr_order) = do {
  56     if (my $info = $Moo::Role::INFO{$name}) {
  57       my @attr_info = @{$info->{attributes}||[]};
  58       (1, Moose::Meta::Role->initialize($name),
  59        { @attr_info },
  60        [ @attr_info[grep !($_ % 2), 0..$#attr_info] ]
  61       )
  62     } else {
  63       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  64       (0, Moose::Meta::Class->initialize($name), $specs,
  65        [ sort { $specs->{$a}{index} <=> $specs->{$b}{index} } keys %$specs ]
  66       );
  67     }
  68   };
  69
  70   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  71
  72   while (my ($meth_name, $meth_code) = each %methods) {
  73     $meta->add_method($meth_name, $meth_code) if $meth_code;
  74   }
  75
  76   # if stuff gets added afterwards, _maybe_reset_handlemoose should
  77   # trigger the recreation of the metaclass but we need to ensure the
  78   # Role::Tiny cache is cleared so we don't confuse Moo itself.
  79   if (my $info = $Role::Tiny::INFO{$name}) {
  80     delete $info->{methods};
  81   }
  82
  83   # needed to ensure the method body is stable and get things named
  84   Sub::Defer::undefer_sub($_) for grep defined, values %methods;
  85   my @attrs;
  86   {
  87     # This local is completely not required for roles but harmless
  88     local @{_getstash($name)}{keys %methods};
  89     my %seen_name;
  90     foreach my $name (@$attr_order) {
  91       $seen_name{$name} = 1;
  92       my %spec = %{$attr_specs->{$name}};
  93       delete $spec{index};
  94       $spec{is} = 'ro' if $spec{is} eq 'lazy' or $spec{is} eq 'rwp';
  95       delete $spec{asserter};
  96       if (my $isa = $spec{isa}) {
  97         my $tc = $spec{isa} = do {
  98           if (my $mapped = $TYPE_MAP{$isa}) {
  99             $mapped->();
 100           } else {
 101             Moose::Meta::TypeConstraint->new(
 102               constraint => sub { eval { &$isa; 1 } }
 103             );
 104           }
 105         };
 106         if (my $coerce = $spec{coerce}) {
 107           $tc->coercion(Moose::Meta::TypeCoercion->new)
 108              ->_compiled_type_coercion($coerce);
 109           $spec{coerce} = 1;
 110         }
 111       } elsif (my $coerce = $spec{coerce}) {
 112         my $attr = perlstring($name);
 113         my $tc = Moose::Meta::TypeConstraint->new(
 114                    constraint => sub { die "This is not going to work" },
 115                    inlined => sub {
 116                       'my $r = $_[42]{'.$attr.'}; $_[42]{'.$attr.'} = 1; $r'
 117                    },
 118                  );
 119         $tc->coercion(Moose::Meta::TypeCoercion->new)
 120            ->_compiled_type_coercion($coerce);
 121         $spec{isa} = $tc;
 122         $spec{coerce} = 1;
 123       }
 124       push @attrs, $meta->add_attribute($name => %spec);
 125     }
 126     foreach my $mouse (do { our %MOUSE; @{$MOUSE{$name}||[]} }) {
 127       foreach my $attr ($mouse->get_all_attributes) {
 128         my %spec = %{$attr};
 129         delete @spec{qw(
 130           associated_class associated_methods __METACLASS__
 131           provides curries
 132         )};
 133         my $name = delete $spec{name};
 134         next if $seen_name{$name}++;
 135         push @attrs, $meta->add_attribute($name => %spec);
 136       }
 137     }
 138   }
 139   if ($am_role) {
 140     my $info = $Moo::Role::INFO{$name};
 141     $meta->add_required_methods(@{$info->{requires}});
 142     foreach my $modifier (@{$info->{modifiers}}) {
 143       my ($type, @args) = @$modifier;
 144       $meta->${\"add_${type}_method_modifier"}(@args);
 145     }
 146   } else {
 147     foreach my $attr (@attrs) {
 148       foreach my $method (@{$attr->associated_methods}) {
 149         $method->{body} = $name->can($method->name);
 150       }
 151     }
 152     bless(
 153       $meta->find_method_by_name('new'),
 154       'Moo::HandleMoose::FakeConstructor',
 155     );
 156   }
 157   $meta->add_role(Class::MOP::class_of($_))
 158     for grep !/\|/ && $_ ne $name, # reject Foo|Bar and same-role-as-self
 159       do { no warnings 'once'; keys %{$Role::Tiny::APPLIED_TO{$name}} };
 160   $DID_INJECT{$name} = 1;
 161   $meta;
 162 }
 163
 164 1;