lib/Module/Build/t/moduleinfo.t

   1 #!/usr/bin/perl -w
   2 # -*- mode: cperl; tab-width: 8; indent-tabs-mode: nil; basic-offset: 2 -*-
   3 # vim:ts=8:sw=2:et:sta:sts=2
   4
   5 use strict;
   6 use lib $ENV{PERL_CORE} ? '../lib/Module/Build/t/lib' : 't/lib';
   7 use MBTest tests => 82;
   8
   9 use_ok 'Module::Build::ModuleInfo';
  10 ensure_blib('Module::Build::ModuleInfo');
  11
  12 my $tmp = MBTest->tmpdir;
  13
  14 use DistGen;
  15 my $dist = DistGen->new( dir => $tmp );
  16 $dist->regen;
  17
  18 $dist->chdir_in;
  19
  20 #########################
  21
  22 # class method C<find_module_by_name>
  23 my $module = Module::Build::ModuleInfo->find_module_by_name(
  24                'Module::Build::ModuleInfo' );
  25 ok( -e $module, 'find_module_by_name() succeeds' );
  26
  27
  28 # fail on invalid module name
  29 my $pm_info = Module::Build::ModuleInfo->new_from_module(
  30                 'Foo::Bar', inc => [] );
  31 ok( !defined( $pm_info ), 'fail if can\'t find module by module name' );
  32
  33
  34 # fail on invalid filename
  35 my $file = File::Spec->catfile( 'Foo', 'Bar.pm' );
  36 $pm_info = Module::Build::ModuleInfo->new_from_file( $file, inc => [] );
  37 ok( !defined( $pm_info ), 'fail if can\'t find module by file name' );
  38
  39
  40 # construct from module filename
  41 $file = File::Spec->catfile( 'lib', split( /::/, $dist->name ) ) . '.pm';
  42 $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
  43 ok( defined( $pm_info ), 'new_from_file() succeeds' );
  44
  45 # construct from module name, using custom include path
  46 $pm_info = Module::Build::ModuleInfo->new_from_module(
  47              $dist->name, inc => [ 'lib', @INC ] );
  48 ok( defined( $pm_info ), 'new_from_module() succeeds' );
  49
  50
  51 # parse various module $VERSION lines
  52 my @modules = (
  53   <<'---', # declared & defined on same line with 'our'
  54 package Simple;
  55 our $VERSION = '1.23';
  56 ---
  57   <<'---', # declared & defined on seperate lines with 'our'
  58 package Simple;
  59 our $VERSION;
  60 $VERSION = '1.23';
  61 ---
  62   <<'---', # use vars
  63 package Simple;
  64 use vars qw( $VERSION );
  65 $VERSION = '1.23';
  66 ---
  67   <<'---', # choose the right default package based on package/file name
  68 package Simple::_private;
  69 $VERSION = '0';
  70 package Simple;
  71 $VERSION = '1.23'; # this should be chosen for version
  72 ---
  73   <<'---', # just read the first $VERSION line
  74 package Simple;
  75 $VERSION = '1.23'; # we should see this line
  76 $VERSION = eval $VERSION; # and ignore this one
  77 ---
  78   <<'---', # just read the first $VERSION line in reopened package (1)
  79 package Simple;
  80 $VERSION = '1.23';
  81 package Error::Simple;
  82 $VERSION = '2.34';
  83 package Simple;
  84 ---
  85   <<'---', # just read the first $VERSION line in reopened package (2)
  86 package Simple;
  87 package Error::Simple;
  88 $VERSION = '2.34';
  89 package Simple;
  90 $VERSION = '1.23';
  91 ---
  92   <<'---', # mentions another module's $VERSION
  93 package Simple;
  94 $VERSION = '1.23';
  95 if ( $Other::VERSION ) {
  96     # whatever
  97 }
  98 ---
  99   <<'---', # mentions another module's $VERSION in a different package
 100 package Simple;
 101 $VERSION = '1.23';
 102 package Simple2;
 103 if ( $Simple::VERSION ) {
 104     # whatever
 105 }
 106 ---
 107   <<'---', # $VERSION checked only in assignments, not regexp ops
 108 package Simple;
 109 $VERSION = '1.23';
 110 if ( $VERSION =~ /1\.23/ ) {
 111     # whatever
 112 }
 113 ---
 114   <<'---', # $VERSION checked only in assignments, not relational ops
 115 package Simple;
 116 $VERSION = '1.23';
 117 if ( $VERSION == 3.45 ) {
 118     # whatever
 119 }
 120 ---
 121   <<'---', # $VERSION checked only in assignments, not relational ops
 122 package Simple;
 123 $VERSION = '1.23';
 124 package Simple2;
 125 if ( $Simple::VERSION == 3.45 ) {
 126     # whatever
 127 }
 128 ---
 129   <<'---', # Fully qualified $VERSION declared in package
 130 package Simple;
 131 $Simple::VERSION = 1.23;
 132 ---
 133   <<'---', # Differentiate fully qualified $VERSION in a package
 134 package Simple;
 135 $Simple2::VERSION = '999';
 136 $Simple::VERSION = 1.23;
 137 ---
 138   <<'---', # Differentiate fully qualified $VERSION and unqualified
 139 package Simple;
 140 $Simple2::VERSION = '999';
 141 $VERSION = 1.23;
 142 ---
 143   <<'---', # $VERSION declared as package variable from within 'main' package
 144 $Simple::VERSION = '1.23';
 145 {
 146   package Simple;
 147   $x = $y, $cats = $dogs;
 148 }
 149 ---
 150   <<'---', # $VERSION wrapped in parens - space inside
 151 package Simple;
 152 ( $VERSION ) = '1.23';
 153 ---
 154   <<'---', # $VERSION wrapped in parens - no space inside
 155 package Simple;
 156 ($VERSION) = '1.23';
 157 ---
 158   <<'---', # $VERSION follows a spurious 'package' in a quoted construct
 159 package Simple;
 160 __PACKAGE__->mk_accessors(qw(
 161     program socket proc
 162     package filename line codeline subroutine finished));
 163
 164 our $VERSION = "1.23";
 165 ---
 166   <<'---', # $VERSION using version.pm
 167   package Simple;
 168   use version; our $VERSION = version->new('1.23');
 169 ---
 170   <<'---', # $VERSION using version.pm and qv()
 171   package Simple;
 172   use version; our $VERSION = qv('1.230');
 173 ---
 174   <<'---', # Two version assignments, should ignore second one
 175   $Simple::VERSION = '1.230';
 176   $Simple::VERSION = eval $Simple::VERSION;
 177 ---
 178 );
 179
 180 my( $i, $n ) = ( 1, scalar( @modules ) );
 181 foreach my $module ( @modules ) {
 182  SKIP: {
 183     skip( "No our() support until perl 5.6", 2 )
 184         if $] < 5.006 && $module =~ /\bour\b/;
 185
 186     $dist->change_file( 'lib/Simple.pm', $module );
 187     $dist->regen;
 188
 189     my $warnings = '';
 190     local $SIG{__WARN__} = sub { $warnings .= $_ for @_ };
 191     my $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
 192
 193     # Test::Builder will prematurely numify objects, so use this form
 194     ok( $pm_info->version eq '1.23',
 195         "correct module version ($i of $n)" );
 196     is( $warnings, '', 'no warnings from parsing' );
 197     $i++;
 198   }
 199 }
 200
 201 # revert to pristine state
 202 $dist->remove;
 203 $dist = DistGen->new( dir => $tmp );
 204 $dist->regen;
 205 $dist->chdir_in;
 206
 207
 208 # Find each package only once
 209 $dist->change_file( 'lib/Simple.pm', <<'---' );
 210 package Simple;
 211 $VERSION = '1.23';
 212 package Error::Simple;
 213 $VERSION = '2.34';
 214 package Simple;
 215 ---
 216
 217 $dist->regen;
 218
 219 $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
 220
 221 my @packages = $pm_info->packages_inside;
 222 is( @packages, 2, 'record only one occurence of each package' );
 223
 224
 225 # Module 'Simple.pm' does not contain package 'Simple';
 226 # constructor should not complain, no default module name or version
 227 $dist->change_file( 'lib/Simple.pm', <<'---' );
 228 package Simple::Not;
 229 $VERSION = '1.23';
 230 ---
 231
 232 $dist->regen;
 233 $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
 234
 235 is( $pm_info->name, undef, 'no default package' );
 236 is( $pm_info->version, undef, 'no version w/o default package' );
 237
 238 # Module 'Simple.pm' contains an alpha version
 239 # constructor should report first $VERSION found
 240 $dist->change_file( 'lib/Simple.pm', <<'---' );
 241 package Simple;
 242 $VERSION = '1.23_01';
 243 $VERSION = eval $VERSION;
 244 ---
 245
 246 $dist->regen;
 247 $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
 248
 249 is( $pm_info->version, '1.23_01', 'alpha version reported');
 250
 251 # NOTE the following test has be done this way because Test::Builder is
 252 # too smart for our own good and tries to see if the version object is a
 253 # dual-var, which breaks with alpha versions:
 254 #    Argument "1.23_0100" isn't numeric in addition (+) at
 255 #    /usr/lib/perl5/5.8.7/Test/Builder.pm line 505.
 256
 257 ok( $pm_info->version > 1.23, 'alpha version greater than non');
 258
 259 # revert to pristine state
 260 $dist->remove;
 261 $dist = DistGen->new( dir => $tmp );
 262 $dist->regen;
 263 $dist->chdir_in;
 264
 265
 266 # parse $VERSION lines scripts for package main
 267 my @scripts = (
 268   <<'---', # package main declared
 269 #!perl -w
 270 package main;
 271 $VERSION = '0.01';
 272 ---
 273   <<'---', # on first non-comment line, non declared package main
 274 #!perl -w
 275 $VERSION = '0.01';
 276 ---
 277   <<'---', # after non-comment line
 278 #!perl -w
 279 use strict;
 280 $VERSION = '0.01';
 281 ---
 282   <<'---', # 1st declared package
 283 #!perl -w
 284 package main;
 285 $VERSION = '0.01';
 286 package _private;
 287 $VERSION = '999';
 288 ---
 289   <<'---', # 2nd declared package
 290 #!perl -w
 291 package _private;
 292 $VERSION = '999';
 293 package main;
 294 $VERSION = '0.01';
 295 ---
 296   <<'---', # split package
 297 #!perl -w
 298 package main;
 299 package _private;
 300 $VERSION = '999';
 301 package main;
 302 $VERSION = '0.01';
 303 ---
 304   <<'---', # define 'main' version from other package
 305 package _private;
 306 $::VERSION = 0.01;
 307 $VERSION = '999';
 308 ---
 309   <<'---', # define 'main' version from other package
 310 package _private;
 311 $VERSION = '999';
 312 $::VERSION = 0.01;
 313 ---
 314 );
 315
 316 ( $i, $n ) = ( 1, scalar( @scripts ) );
 317 foreach my $script ( @scripts ) {
 318   $dist->change_file( 'bin/simple.plx', $script );
 319   $dist->regen;
 320   $pm_info = Module::Build::ModuleInfo->new_from_file(
 321                File::Spec->catfile( 'bin', 'simple.plx' ) );
 322
 323   is( $pm_info->version, '0.01', "correct script version ($i of $n)" );
 324   $i++;
 325 }
 326
 327
 328 # examine properties of a module: name, pod, etc
 329 $dist->change_file( 'lib/Simple.pm', <<'---' );
 330 package Simple;
 331 $VERSION = '0.01';
 332 package Simple::Ex;
 333 $VERSION = '0.02';
 334 =head1 NAME
 335
 336 Simple - It's easy.
 337
 338 =head1 AUTHOR
 339
 340 Simple Simon
 341
 342 =cut
 343 ---
 344 $dist->regen;
 345
 346 $pm_info = Module::Build::ModuleInfo->new_from_module(
 347              $dist->name, inc => [ 'lib', @INC ] );
 348
 349 is( $pm_info->name, 'Simple', 'found default package' );
 350 is( $pm_info->version, '0.01', 'version for default package' );
 351
 352 # got correct version for secondary package
 353 is( $pm_info->version( 'Simple::Ex' ), '0.02',
 354     'version for secondary package' );
 355
 356 my $filename = $pm_info->filename;
 357 ok( defined( $filename ) && -e $filename,
 358     'filename() returns valid path to module file' );
 359
 360 @packages = $pm_info->packages_inside;
 361 is( @packages, 2, 'found correct number of packages' );
 362 is( $packages[0], 'Simple', 'packages stored in order found' );
 363
 364 # we can detect presence of pod regardless of whether we are collecting it
 365 ok( $pm_info->contains_pod, 'contains_pod() succeeds' );
 366
 367 my @pod = $pm_info->pod_inside;
 368 is_deeply( \@pod, [qw(NAME AUTHOR)], 'found all pod sections' );
 369
 370 is( $pm_info->pod('NONE') , undef,
 371     'return undef() if pod section not present' );
 372
 373 is( $pm_info->pod('NAME'), undef,
 374     'return undef() if pod section not collected' );
 375
 376
 377 # collect_pod
 378 $pm_info = Module::Build::ModuleInfo->new_from_module(
 379              $dist->name, inc => [ 'lib', @INC ], collect_pod => 1 );
 380
 381 my $name = $pm_info->pod('NAME');
 382 if ( $name ) {
 383   $name =~ s/^\s+//;
 384   $name =~ s/\s+$//;
 385 }
 386 is( $name, q|Simple - It's easy.|, 'collected pod section' );
 387
 388
 389 {
 390   # Make sure processing stops after __DATA__
 391   $dist->change_file( 'lib/Simple.pm', <<'---' );
 392 package Simple;
 393 $VERSION = '0.01';
 394 __DATA__
 395 *UNIVERSAL::VERSION = sub {
 396   foo();
 397 };
 398 ---
 399   $dist->regen;
 400
 401   $pm_info = Module::Build::ModuleInfo->new_from_file('lib/Simple.pm');
 402   is( $pm_info->name, 'Simple', 'found default package' );
 403   is( $pm_info->version, '0.01', 'version for default package' );
 404   my @packages = $pm_info->packages_inside;
 405   is_deeply(\@packages, ['Simple']);
 406 }
 407
 408 {
 409   # Make sure we handle version.pm $VERSIONs well
 410   $dist->change_file( 'lib/Simple.pm', <<'---' );
 411 package Simple;
 412 $VERSION = version->new('0.60.' . (qw$Revision: 128 $)[1]);
 413 package Simple::Simon;
 414 $VERSION = version->new('0.61.' . (qw$Revision: 129 $)[1]);
 415 ---
 416   $dist->regen;
 417
 418   $pm_info = Module::Build::ModuleInfo->new_from_file('lib/Simple.pm');
 419   is( $pm_info->name, 'Simple', 'found default package' );
 420   is( $pm_info->version, '0.60.128', 'version for default package' );
 421   my @packages = $pm_info->packages_inside;
 422   is_deeply([sort @packages], ['Simple', 'Simple::Simon']);
 423   is( $pm_info->version('Simple::Simon'), '0.61.129', 'version for embedded package' );
 424 }
 425
 426
 427 # cleanup
 428 $dist->remove;