lib/Module/Build/t/install.t

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use lib $ENV{PERL_CORE} ? '../lib/Module/Build/t/lib' : 't/lib';
   5 use MBTest tests => 34;
   6
   7 use Cwd ();
   8 my $cwd = Cwd::cwd;
   9 my $tmp = File::Spec->catdir( $cwd, 't', '_tmp' );
  10
  11 use DistGen;
  12 my $dist = DistGen->new( dir => $tmp );
  13 $dist->regen;
  14
  15 chdir( $dist->dirname ) or die "Can't chdir to '@{[$dist->dirname]}': $!";
  16
  17 #########################
  18
  19 use Module::Build;
  20 use Config;
  21
  22
  23 $dist->add_file( 'script', <<'---' );
  24 #!perl -w
  25 print "Hello, World!\n";
  26 ---
  27 $dist->change_file( 'Build.PL', <<"---" );
  28 use Module::Build;
  29
  30 my \$build = new Module::Build(
  31   module_name => @{[$dist->name]},
  32   scripts     => [ 'script' ],
  33   license     => 'perl',
  34   requires    => { 'File::Spec' => 0 },
  35 );
  36 \$build->create_build_script;
  37 ---
  38 $dist->regen;
  39
  40
  41 use File::Spec::Functions qw( catdir );
  42
  43 my $mb = Module::Build->new_from_context(
  44   # need default install paths to ensure manpages & HTML get generated
  45   installdirs => 'site',
  46   config => {
  47     installman1dir  => catdir($tmp, 'man', 'man1'),
  48     installman3dir  => catdir($tmp, 'man', 'man3'),
  49     installhtml1dir => catdir($tmp, 'html'),
  50     installhtml3dir => catdir($tmp, 'html'),
  51
  52     installsiteman1dir  => catdir($tmp, 'site', 'man', 'man1'),
  53     installsiteman3dir  => catdir($tmp, 'site', 'man', 'man3'),
  54     installsitehtml1dir => catdir($tmp, 'site', 'html'),
  55     installsitehtml3dir => catdir($tmp, 'site', 'html'),
  56   }
  57
  58 );
  59
  60 ok $mb;
  61
  62
  63 my $destdir = File::Spec->catdir($cwd, 't', 'install_test');
  64 $mb->add_to_cleanup($destdir);
  65
  66 {
  67   eval {$mb->dispatch('install', destdir => $destdir)};
  68   is $@, '';
  69
  70   my $libdir = strip_volume( $mb->install_destination('lib') );
  71   my $install_to = File::Spec->catfile($destdir, $libdir, $dist->name ) . '.pm';
  72   file_exists($install_to);
  73
  74   local @INC = (@INC, File::Spec->catdir($destdir, $libdir));
  75   eval "require @{[$dist->name]}";
  76   is $@, '';
  77
  78   # Make sure there's a packlist installed
  79   my $archdir = $mb->install_destination('arch');
  80   my ($v, $d) = File::Spec->splitpath($archdir, 1);
  81   my $packlist = File::Spec->catdir($destdir, $d, 'auto', $dist->name, '.packlist');
  82   is -e $packlist, 1, "$packlist should be written";
  83 }
  84
  85 {
  86   eval {$mb->dispatch('install', installdirs => 'core', destdir => $destdir)};
  87   is $@, '';
  88   my $libdir = strip_volume( $Config{installprivlib} );
  89   my $install_to = File::Spec->catfile($destdir, $libdir, $dist->name ) . '.pm';
  90   file_exists($install_to);
  91 }
  92
  93 {
  94   my $libdir = File::Spec->catdir(File::Spec->rootdir, 'foo', 'bar');
  95   eval {$mb->dispatch('install', install_path => {lib => $libdir}, destdir => $destdir)};
  96   is $@, '';
  97   my $install_to = File::Spec->catfile($destdir, $libdir, $dist->name ) . '.pm';
  98   file_exists($install_to);
  99 }
 100
 101 {
 102   my $libdir = File::Spec->catdir(File::Spec->rootdir, 'foo', 'base');
 103   eval {$mb->dispatch('install', install_base => $libdir, destdir => $destdir)};
 104   is $@, '';
 105   my $install_to = File::Spec->catfile($destdir, $libdir, 'lib', 'perl5', $dist->name ) . '.pm';
 106   file_exists($install_to);
 107 }
 108
 109 {
 110   # Test the ConfigData stuff
 111
 112   $mb->config_data(foo => 'bar');
 113   $mb->features(baz => 1);
 114   $mb->auto_features(auto_foo => {requires => {'File::Spec' => 0}});
 115   eval {$mb->dispatch('install', destdir => $destdir)};
 116   is $@, '';
 117
 118   my $libdir = strip_volume( $mb->install_destination('lib') );
 119   local @INC = (@INC, File::Spec->catdir($destdir, $libdir));
 120   eval "require @{[$dist->name]}::ConfigData";
 121
 122   is $mb->feature('auto_foo'), 1;
 123
 124   SKIP: {
 125     skip $@, 5 if @_;
 126
 127     # Make sure the values are present
 128     my $config = $dist->name . '::ConfigData';
 129     is( $config->config('foo'), 'bar' );
 130     ok( $config->feature('baz') );
 131     ok( $config->feature('auto_foo') );
 132     ok( not $config->feature('nonexistent') );
 133
 134     # Add a new value to the config set
 135     $config->set_config(floo => 'bhlar');
 136     is( $config->config('floo'), 'bhlar' );
 137
 138     # Make sure it actually got written
 139     $config->write;
 140     delete $INC{"@{[$dist->name]}/ConfigData.pm"};
 141     {
 142       local $^W;  # Avoid warnings for subroutine redefinitions
 143       eval "require $config";
 144     }
 145     is( $config->config('floo'), 'bhlar' );
 146   }
 147 }
 148
 149
 150 eval {$mb->dispatch('realclean')};
 151 is $@, '';
 152
 153 {
 154   # Try again by running the script rather than with programmatic interface
 155   my $libdir = File::Spec->catdir('', 'foo', 'lib');
 156   eval {$mb->run_perl_script('Build.PL', [], ['--install_path', "lib=$libdir"])};
 157   is $@, '';
 158
 159   eval {$mb->run_perl_script('Build', [], ['install', '--destdir', $destdir])};
 160   is $@, '';
 161   my $install_to = File::Spec->catfile($destdir, $libdir, $dist->name ) . '.pm';
 162   file_exists($install_to);
 163
 164   my $basedir = File::Spec->catdir('', 'bar');
 165   eval {$mb->run_perl_script('Build', [], ['install', '--destdir', $destdir,
 166                                               '--install_base', $basedir])};
 167   is $@, '';
 168
 169   $install_to = File::Spec->catfile($destdir, $libdir, $dist->name ) . '.pm';
 170   is -e $install_to, 1, "Look for file at $install_to";
 171
 172   eval {$mb->dispatch('realclean')};
 173   is $@, '';
 174 }
 175
 176 {
 177   # Make sure 'install_path' overrides 'install_base'
 178   my $mb = Module::Build->new( module_name  => $dist->name,
 179                                install_base => File::Spec->catdir('', 'foo'),
 180                                install_path => {
 181                                  lib => File::Spec->catdir('', 'bar')
 182                                }
 183                              );
 184   ok $mb;
 185   is $mb->install_destination('lib'), File::Spec->catdir('', 'bar');
 186 }
 187
 188 {
 189   $dist->add_file( 'lib/Simple/Docs.pod', <<'---' );
 190 =head1 NAME
 191
 192 Simple::Docs - Simple pod
 193
 194 =head1 AUTHOR
 195
 196 Simple Man <simple@example.com>
 197
 198 =cut
 199 ---
 200   $dist->regen;
 201
 202   # _find_file_by_type() isn't a public method, but this is currently
 203   # the only easy way to test that it works properly.
 204   my $pods = $mb->_find_file_by_type('pod', 'lib');
 205   is keys %$pods, 1;
 206   my $expect = $mb->localize_file_path('lib/Simple/Docs.pod');
 207   is $pods->{$expect}, $expect;
 208
 209   my $pms = $mb->_find_file_by_type('awefawef', 'lib');
 210   ok $pms;
 211   is keys %$pms, 0;
 212
 213   $pms = $mb->_find_file_by_type('pod', 'awefawef');
 214   ok $pms;
 215   is keys %$pms, 0;
 216
 217   # revert to pristine state
 218   chdir( $cwd ) or die "Can''t chdir to '$cwd': $!";
 219   $dist->remove;
 220   $dist = DistGen->new( dir => $tmp );
 221   $dist->regen;
 222   chdir( $dist->dirname ) or die "Can't chdir to '@{[$dist->dirname]}': $!";
 223 }
 224
 225 sub strip_volume {
 226   my $dir = shift;
 227   (undef, $dir) = File::Spec->splitpath( $dir, 1 );
 228   return $dir;
 229 }
 230
 231 sub file_exists {
 232   my $file = shift;
 233   ok -e $file or diag("Expected $file to exist, but it doesn't");
 234 }
 235
 236
 237 # cleanup
 238 chdir( $cwd ) or die "Can''t chdir to '$cwd': $!";
 239 $dist->remove;
 240
 241 use File::Path;
 242 rmtree( $tmp );