lib/Module/Build/ModuleInfo.pm

   1 package Module::Build::ModuleInfo;
   2
   3 # This module provides routines to gather information about
   4 # perl modules (assuming this may be expanded in the distant
   5 # parrot future to look at other types of modules).
   6
   7 use strict;
   8
   9 use File::Spec;
  10 use IO::File;
  11 use Module::Build::Version;
  12
  13
  14 my $PKG_REGEXP  = qr/   # match a package declaration
  15   ^[\s\{;]*             # intro chars on a line
  16   package               # the word 'package'
  17   \s+                   # whitespace
  18   ([\w:]+)              # a package name
  19   \s*                   # optional whitespace
  20   ;                     # semicolon line terminator
  21 /x;
  22
  23 my $VARNAME_REGEXP = qr/ # match fully-qualified VERSION name
  24   ([\$*])         # sigil - $ or *
  25   (
  26     (             # optional leading package name
  27       (?:::|\')?  # possibly starting like just :: (ala $::VERSION)
  28       (?:\w+(?:::|\'))*  # Foo::Bar:: ...
  29     )?
  30     VERSION
  31   )\b
  32 /x;
  33
  34 my $VERS_REGEXP = qr/ # match a VERSION definition
  35   (?:
  36     \(\s*$VARNAME_REGEXP\s*\) # with parens
  37   |
  38     $VARNAME_REGEXP           # without parens
  39   )
  40   \s*
  41   =[^=~]  # = but not ==, nor =~
  42 /x;
  43
  44
  45 sub new_from_file {
  46   my $package  = shift;
  47   my $filename = File::Spec->rel2abs( shift );
  48   return undef unless defined( $filename ) && -f $filename;
  49   return $package->_init( undef, $filename, @_ );
  50 }
  51
  52 sub new_from_module {
  53   my $package = shift;
  54   my $module  = shift;
  55   my %props   = @_;
  56   $props{inc} ||= \@INC;
  57   my $filename = $package->find_module_by_name( $module, $props{inc} );
  58   return undef unless defined( $filename ) && -f $filename;
  59   return $package->_init( $module, $filename, %props );
  60 }
  61
  62 sub _init {
  63   my $package  = shift;
  64   my $module   = shift;
  65   my $filename = shift;
  66
  67   my %props = @_;
  68   my( %valid_props, @valid_props );
  69   @valid_props = qw( collect_pod inc );
  70   @valid_props{@valid_props} = delete( @props{@valid_props} );
  71   warn "Unknown properties: @{[keys %props]}\n" if scalar( %props );
  72
  73   my %data = (
  74     module   => $module,
  75     filename => $filename,
  76     version  => undef,
  77     packages => [],
  78     versions => {},
  79     pod          => {},
  80     pod_headings => [],
  81     collect_pod  => 0,
  82
  83     %valid_props,
  84   );
  85
  86   my $self = bless( \%data, $package );
  87
  88   $self->_parse_file();
  89
  90   unless ( $self->{module} && length( $self->{module} ) ) {
  91     my( $v, $d, $f ) = File::Spec->splitpath( $self->{filename} );
  92     if ( $f =~ /\.pm$/ ) {
  93       $f =~ s/\..+$//;
  94       my @candidates = grep /$f$/, @{$self->{packages}};
  95       $self->{module} = shift( @candidates ); # punt
  96     } else {
  97       if ( grep /main/, @{$self->{packages}} ) {
  98         $self->{module} = 'main';
  99       } else {
 100         $self->{module} = $self->{packages}[0] || '';
 101       }
 102     }
 103   }
 104
 105   $self->{version} = $self->{versions}{$self->{module}}
 106       if defined( $self->{module} );
 107
 108   return $self;
 109 }
 110
 111 # class method
 112 sub _do_find_module {
 113   my $package = shift;
 114   my $module  = shift || die 'find_module_by_name() requires a package name';
 115   my $dirs    = shift || \@INC;
 116
 117   my $file = File::Spec->catfile(split( /::/, $module));
 118   foreach my $dir ( @$dirs ) {
 119     my $testfile = File::Spec->catfile($dir, $file);
 120     return [ File::Spec->rel2abs( $testfile ), $dir ]
 121         if -e $testfile and !-d _;  # For stuff like ExtUtils::xsubpp
 122     return [ File::Spec->rel2abs( "$testfile.pm" ), $dir ]
 123         if -e "$testfile.pm";
 124   }
 125   return;
 126 }
 127
 128 # class method
 129 sub find_module_by_name {
 130   my $found = shift()->_do_find_module(@_) or return;
 131   return $found->[0];
 132 }
 133
 134 # class method
 135 sub find_module_dir_by_name {
 136   my $found = shift()->_do_find_module(@_) or return;
 137   return $found->[1];
 138 }
 139
 140
 141 # given a line of perl code, attempt to parse it if it looks like a
 142 # $VERSION assignment, returning sigil, full name, & package name
 143 sub _parse_version_expression {
 144   my $self = shift;
 145   my $line = shift;
 146
 147   my( $sig, $var, $pkg );
 148   if ( $line =~ $VERS_REGEXP ) {
 149     ( $sig, $var, $pkg ) = $2 ? ( $1, $2, $3 ) : ( $4, $5, $6 );
 150     if ( $pkg ) {
 151       $pkg = ($pkg eq '::') ? 'main' : $pkg;
 152       $pkg =~ s/::$//;
 153     }
 154   }
 155
 156   return ( $sig, $var, $pkg );
 157 }
 158
 159 sub _parse_file {
 160   my $self = shift;
 161
 162   my $filename = $self->{filename};
 163   my $fh = IO::File->new( $filename )
 164     or die( "Can't open '$filename': $!" );
 165
 166   my( $in_pod, $seen_end, $need_vers ) = ( 0, 0, 0 );
 167   my( @pkgs, %vers, %pod, @pod );
 168   my $pkg = 'main';
 169   my $pod_sect = '';
 170   my $pod_data = '';
 171
 172   while (defined( my $line = <$fh> )) {
 173
 174     chomp( $line );
 175     next if $line =~ /^\s*#/;
 176
 177     $in_pod = ($line =~ /^=(?!cut)/) ? 1 : ($line =~ /^=cut/) ? 0 : $in_pod;
 178
 179     if ( $in_pod || $line =~ /^=cut/ ) {
 180
 181       if ( $line =~ /^=head\d\s+(.+)\s*$/ ) {
 182         push( @pod, $1 );
 183         if ( $self->{collect_pod} && length( $pod_data ) ) {
 184           $pod{$pod_sect} = $pod_data;
 185           $pod_data = '';
 186         }
 187         $pod_sect = $1;
 188
 189
 190       } elsif ( $self->{collect_pod} ) {
 191         $pod_data .= "$line\n";
 192
 193       }
 194
 195     } else {
 196
 197       $pod_sect = '';
 198       $pod_data = '';
 199
 200       # parse $line to see if it's a $VERSION declaration
 201       my( $vers_sig, $vers_fullname, $vers_pkg ) =
 202           $self->_parse_version_expression( $line );
 203
 204       if ( $line =~ $PKG_REGEXP ) {
 205         $pkg = $1;
 206         push( @pkgs, $pkg ) unless grep( $pkg eq $_, @pkgs );
 207         $vers{$pkg} = undef unless exists( $vers{$pkg} );
 208         $need_vers = 1;
 209
 210       # VERSION defined with full package spec, i.e. $Module::VERSION
 211       } elsif ( $vers_fullname && $vers_pkg ) {
 212         push( @pkgs, $vers_pkg ) unless grep( $vers_pkg eq $_, @pkgs );
 213         $need_vers = 0 if $vers_pkg eq $pkg;
 214
 215         my $v =
 216           $self->_evaluate_version_line( $vers_sig, $vers_fullname, $line );
 217         unless ( defined $vers{$vers_pkg} && length $vers{$vers_pkg} ) {
 218           $vers{$vers_pkg} = $v;
 219         } else {
 220           warn <<"EOM";
 221 Package '$vers_pkg' already declared with version '$vers{$vers_pkg}'
 222 ignoring new version '$v'.
 223 EOM
 224         }
 225
 226       # first non-comment line in undeclared package main is VERSION
 227       } elsif ( !exists($vers{main}) && $pkg eq 'main' && $vers_fullname ) {
 228         $need_vers = 0;
 229         my $v =
 230           $self->_evaluate_version_line( $vers_sig, $vers_fullname, $line );
 231         $vers{$pkg} = $v;
 232         push( @pkgs, 'main' );
 233
 234       # first non-comement line in undeclared packge defines package main
 235       } elsif ( !exists($vers{main}) && $pkg eq 'main' && $line =~ /\w+/ ) {
 236         $need_vers = 1;
 237         $vers{main} = '';
 238         push( @pkgs, 'main' );
 239
 240       # only keep if this is the first $VERSION seen
 241       } elsif ( $vers_fullname && $need_vers ) {
 242         $need_vers = 0;
 243         my $v =
 244           $self->_evaluate_version_line( $vers_sig, $vers_fullname, $line );
 245
 246
 247         unless ( defined $vers{$pkg} && length $vers{$pkg} ) {
 248           $vers{$pkg} = $v;
 249         } else {
 250           warn <<"EOM";
 251 Package '$pkg' already declared with version '$vers{$pkg}'
 252 ignoring new version '$v'.
 253 EOM
 254         }
 255
 256       }
 257
 258     }
 259
 260   }
 261
 262   if ( $self->{collect_pod} && length($pod_data) ) {
 263     $pod{$pod_sect} = $pod_data;
 264   }
 265
 266   $self->{versions} = \%vers;
 267   $self->{packages} = \@pkgs;
 268   $self->{pod} = \%pod;
 269   $self->{pod_headings} = \@pod;
 270 }
 271
 272 sub _evaluate_version_line {
 273   my $self = shift;
 274   my( $sigil, $var, $line ) = @_;
 275
 276   # Some of this code came from the ExtUtils:: hierarchy.
 277
 278   my $eval = qq{q#  Hide from _packages_inside()
 279                  #; package Module::Build::ModuleInfo::_version;
 280                  no strict;
 281
 282                  local $sigil$var;
 283                  \$$var=undef; do {
 284                    $line
 285                  }; \$$var
 286                 };
 287
 288   local $^W;
 289   # Try and get the $VERSION
 290   my $result = eval $eval;
 291   warn "Error evaling version line '$eval' in $self->{filename}: $@\n" if $@;
 292
 293   # Bless it into our own version class
 294   $result = Module::Build::Version->new($result);
 295
 296   return $result;
 297 }
 298
 299
 300 ############################################################
 301
 302 # accessors
 303 sub name            { $_[0]->{module}           }
 304
 305 sub filename        { $_[0]->{filename}         }
 306 sub packages_inside { @{$_[0]->{packages}}      }
 307 sub pod_inside      { @{$_[0]->{pod_headings}}  }
 308 sub contains_pod    { $#{$_[0]->{pod_headings}} }
 309
 310 sub version {
 311     my $self = shift;
 312     my $mod  = shift || $self->{module};
 313     my $vers;
 314     if ( defined( $mod ) && length( $mod ) &&
 315          exists( $self->{versions}{$mod} ) ) {
 316         return $self->{versions}{$mod};
 317     } else {
 318         return undef;
 319     }
 320 }
 321
 322 sub pod {
 323     my $self = shift;
 324     my $sect = shift;
 325     if ( defined( $sect ) && length( $sect ) &&
 326          exists( $self->{pod}{$sect} ) ) {
 327         return $self->{pod}{$sect};
 328     } else {
 329         return undef;
 330     }
 331 }
 332
 333 1;
 334
 335 __END__
 336
 337 =head1 NAME
 338
 339 ModuleInfo - Gather package and POD information from a perl module files
 340
 341
 342 =head1 DESCRIPTION
 343
 344 =over 4
 345
 346 =item new_from_file($filename, collect_pod => 1)
 347
 348 Construct a ModuleInfo object given the path to a file. Takes an optional
 349 arguement C<collect_pod> which is a boolean that determines whether
 350 POD data is collected and stored for reference. POD data is not
 351 collected by default. POD headings are always collected.
 352
 353 =item new_from_module($module, collect_pod => 1, inc => \@dirs)
 354
 355 Construct a ModuleInfo object given a module or package name. In addition
 356 to accepting the C<collect_pod> argument as described above, this
 357 method accepts a C<inc> arguemnt which is a reference to an array of
 358 of directories to search for the module. If none are given, the
 359 default is @INC.
 360
 361 =item name()
 362
 363 Returns the name of the package represented by this module. If there
 364 are more than one packages, it makes a best guess based on the
 365 filename. If it's a script (i.e. not a *.pm) the package name is
 366 'main'.
 367
 368 =item version($package)
 369
 370 Returns the version as defined by the $VERSION variable for the
 371 package as returned by the C<name> method if no arguments are
 372 given. If given the name of a package it will attempt to return the
 373 version of that package if it is specified in the file.
 374
 375 =item filename()
 376
 377 Returns the absolute path to the file.
 378
 379 =item packages_inside()
 380
 381 Returns a list of packages.
 382
 383 =item pod_inside()
 384
 385 Returns a list of POD sections.
 386
 387 =item contains_pod()
 388
 389 Returns true if there is any POD in the file.
 390
 391 =item pod($section)
 392
 393 Returns the POD data in the given section.
 394
 395 =item find_module_by_name($module, \@dirs)
 396
 397 Returns the path to a module given the module or package name. A list
 398 of directories can be passed in as an optional paramater, otherwise
 399 @INC is searched.
 400
 401 Can be called as either an object or a class method.
 402
 403 =item find_module_dir_by_name($module, \@dirs)
 404
 405 Returns the entry in C<@dirs> (or C<@INC> by default) that contains
 406 the module C<$module>. A list of directories can be passed in as an
 407 optional paramater, otherwise @INC is searched.
 408
 409 Can be called as either an object or a class method.
 410
 411 =back
 412
 413
 414 =head1 AUTHOR
 415
 416 Ken Williams <ken@cpan.org>, Randy W. Sims <RandyS@ThePierianSpring.org>
 417
 418
 419 =head1 COPYRIGHT
 420
 421 Copyright (c) 2001-2005 Ken Williams.  All rights reserved.
 422
 423 This library is free software; you can redistribute it and/or
 424 modify it under the same terms as Perl itself.
 425
 426
 427 =head1 SEE ALSO
 428
 429 perl(1), L<Module::Build>(3)
 430
 431 =cut
 432