lib/Module/Build/Base.pm

   1 package Module::Build::Base;
   2
   3 use strict;
   4 BEGIN { require 5.00503 }
   5
   6 use Carp;
   7 use Config;
   8 use File::Copy ();
   9 use File::Find ();
  10 use File::Path ();
  11 use File::Basename ();
  12 use File::Spec 0.82 ();
  13 use File::Compare ();
  14 use Data::Dumper ();
  15 use IO::File ();
  16 use Text::ParseWords ();
  17
  18 use Module::Build::ModuleInfo;
  19 use Module::Build::Notes;
  20
  21
  22 #################### Constructors ###########################
  23 sub new {
  24   my $self = shift()->_construct(@_);
  25
  26   $self->{invoked_action} = $self->{action} ||= 'Build_PL';
  27   $self->cull_args(@ARGV);
  28
  29   die "Too early to specify a build action '$self->{action}'.  Do 'Build $self->{action}' instead.\n"
  30     if $self->{action} && $self->{action} ne 'Build_PL';
  31
  32   $self->dist_name;
  33   $self->dist_version;
  34
  35   $self->check_manifest;
  36   $self->check_prereq;
  37   $self->check_autofeatures;
  38
  39   $self->_set_install_paths;
  40   $self->_find_nested_builds;
  41
  42   return $self;
  43 }
  44
  45 sub resume {
  46   my $package = shift;
  47   my $self = $package->_construct(@_);
  48   $self->read_config;
  49
  50   # If someone called Module::Build->current() or
  51   # Module::Build->new_from_context() and the correct class to use is
  52   # actually a *subclass* of Module::Build, we may need to load that
  53   # subclass here and re-delegate the resume() method to it.
  54   unless ( UNIVERSAL::isa($package, $self->build_class) ) {
  55     my $build_class = $self->build_class;
  56     my $config_dir = $self->config_dir || '_build';
  57     my $build_lib = File::Spec->catdir( $config_dir, 'lib' );
  58     unshift( @INC, $build_lib );
  59     unless ( $build_class->can('new') ) {
  60       eval "require $build_class; 1" or die "Failed to re-load '$build_class': $@";
  61     }
  62     return $build_class->resume(@_);
  63   }
  64
  65   unless ($self->_perl_is_same($self->{properties}{perl})) {
  66     my $perl = $self->find_perl_interpreter;
  67     $self->log_warn(" * WARNING: Configuration was initially created with '$self->{properties}{perl}',\n".
  68                     "   but we are now using '$perl'.\n");
  69   }
  70
  71   my $mb_version = $Module::Build::VERSION;
  72   die(" * ERROR: Configuration was initially created with Module::Build version '$self->{properties}{mb_version}',\n".
  73       "   but we are now using version '$mb_version'.  Please re-run the Build.PL or Makefile.PL script.\n")
  74     unless $mb_version eq $self->{properties}{mb_version};
  75
  76   $self->cull_args(@ARGV);
  77   $self->{invoked_action} = $self->{action} ||= 'build';
  78
  79   return $self;
  80 }
  81
  82 sub new_from_context {
  83   my ($package, %args) = @_;
  84
  85   # XXX Read the META.yml and see whether we need to run the Build.PL?
  86
  87   # Run the Build.PL.  We use do() rather than run_perl_script() so
  88   # that it runs in this process rather than a subprocess, because we
  89   # need to make sure that the environment is the same during Build.PL
  90   # as it is during resume() (and thereafter).
  91   {
  92     local @ARGV = $package->unparse_args(\%args);
  93     do 'Build.PL';
  94     die $@ if $@;
  95   }
  96   return $package->resume;
  97 }
  98
  99 sub current {
 100   # hmm, wonder what the right thing to do here is
 101   local @ARGV;
 102   return shift()->resume;
 103 }
 104
 105 sub _construct {
 106   my ($package, %input) = @_;
 107
 108   my $args   = delete $input{args}   || {};
 109   my $config = delete $input{config} || {};
 110
 111   my $self = bless {
 112                     args => {%$args},
 113                     config => {%Config, %$config},
 114                     properties => {
 115                                    base_dir        => $package->cwd,
 116                                    mb_version      => $Module::Build::VERSION,
 117                                    %input,
 118                                   },
 119                     phash => {},
 120                    }, $package;
 121
 122   $self->_set_defaults;
 123   my ($p, $c, $ph) = ($self->{properties}, $self->{config}, $self->{phash});
 124
 125   foreach (qw(notes config_data features runtime_params cleanup auto_features)) {
 126     my $file = File::Spec->catfile($self->config_dir, $_);
 127     $ph->{$_} = Module::Build::Notes->new(file => $file);
 128     $ph->{$_}->restore if -e $file;
 129     if (exists $p->{$_}) {
 130       my $vals = delete $p->{$_};
 131       while (my ($k, $v) = each %$vals) {
 132         $self->$_($k, $v);
 133       }
 134     }
 135   }
 136
 137   # The following warning could be unnecessary if the user is running
 138   # an embedded perl, but there aren't too many of those around, and
 139   # embedded perls aren't usually used to install modules, and the
 140   # installation process sometimes needs to run external scripts
 141   # (e.g. to run tests).
 142   $p->{perl} = $self->find_perl_interpreter
 143     or $self->log_warn("Warning: Can't locate your perl binary");
 144
 145   my $blibdir = sub { File::Spec->catdir($p->{blib}, @_) };
 146   $p->{bindoc_dirs} ||= [ $blibdir->("script") ];
 147   $p->{libdoc_dirs} ||= [ $blibdir->("lib"), $blibdir->("arch") ];
 148
 149   $p->{dist_author} = [ $p->{dist_author} ] if defined $p->{dist_author} and not ref $p->{dist_author};
 150
 151   # Synonyms
 152   $p->{requires} = delete $p->{prereq} if defined $p->{prereq};
 153   $p->{script_files} = delete $p->{scripts} if defined $p->{scripts};
 154
 155   # Convert to arrays
 156   for ('extra_compiler_flags', 'extra_linker_flags') {
 157     $p->{$_} = [ $self->split_like_shell($p->{$_}) ] if exists $p->{$_};
 158   }
 159
 160   $self->add_to_cleanup( @{delete $p->{add_to_cleanup}} )
 161     if $p->{add_to_cleanup};
 162
 163   return $self;
 164 }
 165
 166 ################## End constructors #########################
 167
 168 sub log_info { print @_ unless shift()->quiet }
 169 sub log_verbose { shift()->log_info(@_) if $_[0]->verbose }
 170 sub log_warn {
 171   # Try to make our call stack invisible
 172   shift;
 173   if (@_ and $_[-1] !~ /\n$/) {
 174     my (undef, $file, $line) = caller();
 175     warn @_, " at $file line $line.\n";
 176   } else {
 177     warn @_;
 178   }
 179 }
 180
 181
 182 sub _set_install_paths {
 183   my $self = shift;
 184   my $c = $self->config;
 185   my $p = $self->{properties};
 186
 187   my @libstyle = $c->{installstyle} ?
 188       File::Spec->splitdir($c->{installstyle}) : qw(lib perl5);
 189   my $arch     = $c->{archname};
 190   my $version  = $c->{version};
 191
 192   my $bindoc  = $c->{installman1dir} || undef;
 193   my $libdoc  = $c->{installman3dir} || undef;
 194
 195   my $binhtml = $c->{installhtml1dir} || $c->{installhtmldir} || undef;
 196   my $libhtml = $c->{installhtml3dir} || $c->{installhtmldir} || undef;
 197
 198   $p->{install_sets} =
 199     {
 200      core   => {
 201                 lib     => $c->{installprivlib},
 202                 arch    => $c->{installarchlib},
 203                 bin     => $c->{installbin},
 204                 script  => $c->{installscript},
 205                 bindoc  => $bindoc,
 206                 libdoc  => $libdoc,
 207                 binhtml => $binhtml,
 208                 libhtml => $libhtml,
 209                },
 210      site   => {
 211                 lib     => $c->{installsitelib},
 212                 arch    => $c->{installsitearch},
 213                 bin     => $c->{installsitebin} || $c->{installbin},
 214                 script  => $c->{installsitescript} ||
 215                            $c->{installsitebin} || $c->{installscript},
 216                 bindoc  => $c->{installsiteman1dir} || $bindoc,
 217                 libdoc  => $c->{installsiteman3dir} || $libdoc,
 218                 binhtml => $c->{installsitehtml1dir} || $binhtml,
 219                 libhtml => $c->{installsitehtml3dir} || $libhtml,
 220                },
 221      vendor => {
 222                 lib     => $c->{installvendorlib},
 223                 arch    => $c->{installvendorarch},
 224                 bin     => $c->{installvendorbin} || $c->{installbin},
 225                 script  => $c->{installvendorscript} ||
 226                            $c->{installvendorbin} || $c->{installscript},
 227                 bindoc  => $c->{installvendorman1dir} || $bindoc,
 228                 libdoc  => $c->{installvendorman3dir} || $libdoc,
 229                 binhtml => $c->{installvendorhtml1dir} || $binhtml,
 230                 libhtml => $c->{installvendorhtml3dir} || $libhtml,
 231                },
 232     };
 233
 234   $p->{original_prefix} =
 235     {
 236      core   => $c->{installprefixexp} || $c->{installprefix} ||
 237                $c->{prefixexp}        || $c->{prefix} || '',
 238      site   => $c->{siteprefixexp},
 239      vendor => $c->{usevendorprefix} ? $c->{vendorprefixexp} : '',
 240     };
 241   $p->{original_prefix}{site} ||= $p->{original_prefix}{core};
 242
 243   # Note: you might be tempted to use $Config{installstyle} here
 244   # instead of hard-coding lib/perl5, but that's been considered and
 245   # (at least for now) rejected.  `perldoc Config` has some wisdom
 246   # about it.
 247   $p->{install_base_relpaths} =
 248     {
 249      lib     => ['lib', 'perl5'],
 250      arch    => ['lib', 'perl5', $arch],
 251      bin     => ['bin'],
 252      script  => ['bin'],
 253      bindoc  => ['man', 'man1'],
 254      libdoc  => ['man', 'man3'],
 255      binhtml => ['html'],
 256      libhtml => ['html'],
 257     };
 258
 259   $p->{prefix_relpaths} =
 260     {
 261      core => {
 262               lib        => [@libstyle],
 263               arch       => [@libstyle, $version, $arch],
 264               bin        => ['bin'],
 265               script     => ['bin'],
 266               bindoc     => ['man', 'man1'],
 267               libdoc     => ['man', 'man3'],
 268               binhtml    => ['html'],
 269               libhtml    => ['html'],
 270              },
 271      vendor => {
 272                 lib        => [@libstyle],
 273                 arch       => [@libstyle, $version, $arch],
 274                 bin        => ['bin'],
 275                 script     => ['bin'],
 276                 bindoc     => ['man', 'man1'],
 277                 libdoc     => ['man', 'man3'],
 278                 binhtml    => ['html'],
 279                 libhtml    => ['html'],
 280                },
 281      site => {
 282               lib        => [@libstyle, 'site_perl'],
 283               arch       => [@libstyle, 'site_perl', $version, $arch],
 284               bin        => ['bin'],
 285               script     => ['bin'],
 286               bindoc     => ['man', 'man1'],
 287               libdoc     => ['man', 'man3'],
 288               binhtml    => ['html'],
 289               libhtml    => ['html'],
 290              },
 291     };
 292
 293 }
 294
 295 sub _find_nested_builds {
 296   my $self = shift;
 297   my $r = $self->recurse_into or return;
 298
 299   my ($file, @r);
 300   if (!ref($r) && $r eq 'auto') {
 301     local *DH;
 302     opendir DH, $self->base_dir
 303       or die "Can't scan directory " . $self->base_dir . " for nested builds: $!";
 304     while (defined($file = readdir DH)) {
 305       my $subdir = File::Spec->catdir( $self->base_dir, $file );
 306       next unless -d $subdir;
 307       push @r, $subdir if -e File::Spec->catfile( $subdir, 'Build.PL' );
 308     }
 309   }
 310
 311   $self->recurse_into(\@r);
 312 }
 313
 314 sub cwd {
 315   require Cwd;
 316   return Cwd::cwd();
 317 }
 318
 319 sub _quote_args {
 320   # Returns a string that can become [part of] a command line with
 321   # proper quoting so that the subprocess sees this same list of args.
 322   my ($self, @args) = @_;
 323
 324   my $return_args = '';
 325   my @quoted;
 326
 327   for (@args) {
 328     if ( /^[^\s*?!$<>;\\|'"\[\]\{\}]+$/ ) {
 329       # Looks pretty safe
 330       push @quoted, $_;
 331     } else {
 332       # XXX this will obviously have to improve - is there already a
 333       # core module lying around that does proper quoting?
 334       s/"/"'"'"/g;
 335       push @quoted, qq("$_");
 336     }
 337   }
 338
 339   return join " ", @quoted;
 340 }
 341
 342 sub _backticks {
 343   my ($self, @cmd) = @_;
 344   if ($self->have_forkpipe) {
 345     local *FH;
 346     my $pid = open FH, "-|";
 347     if ($pid) {
 348       return wantarray ? <FH> : join '', <FH>;
 349     } else {
 350       die "Can't execute @cmd: $!\n" unless defined $pid;
 351       exec { $cmd[0] } @cmd;
 352     }
 353   } else {
 354     my $cmd = $self->_quote_args(@cmd);
 355     return `$cmd`;
 356   }
 357 }
 358
 359 sub have_forkpipe { 1 }
 360
 361 # Determine whether a given binary is the same as the perl
 362 # (configuration) that started this process.
 363 sub _perl_is_same {
 364   my ($self, $perl) = @_;
 365
 366   my @cmd = ($perl);
 367
 368   # When run from the perl core, @INC will include the directories
 369   # where perl is yet to be installed. We need to reference the
 370   # absolute path within the source distribution where it can find
 371   # it's Config.pm This also prevents us from picking up a Config.pm
 372   # from a different configuration that happens to be already
 373   # installed in @INC.
 374   if ($ENV{PERL_CORE}) {
 375     push @cmd, '-I' . File::Spec->catdir(File::Basename::dirname($perl), 'lib');
 376   }
 377
 378   push @cmd, qw(-MConfig=myconfig -e print -e myconfig);
 379   return $self->_backticks(@cmd) eq Config->myconfig;
 380 }
 381
 382 # Returns the absolute path of the perl interperter used to invoke
 383 # this process. The path is derived from $^X or $Config{perlpath}. On
 384 # some platforms $^X contains the complete absolute path of the
 385 # interpreter, on other it may contain a relative path, or simply
 386 # 'perl'. This can also vary depending on whether a path was supplied
 387 # when perl was invoked. Additionally, the value in $^X may omit the
 388 # executable extension on platforms that use one. It's a fatal error
 389 # if the interpreter can't be found because it can result in undefined
 390 # behavior by routines that depend on it (generating errors or
 391 # invoking the wrong perl.
 392 sub find_perl_interpreter {
 393   my $proto = shift;
 394   my $c     = ref($proto) ? $proto->config : \%Config::Config;
 395
 396   my $perl  = $^X;
 397   my $perl_basename = File::Basename::basename($perl);
 398
 399   my @potential_perls;
 400
 401   # Try 1, Check $^X for absolute path
 402   push( @potential_perls, $perl )
 403       if File::Spec->file_name_is_absolute($perl);
 404
 405   # Try 2, Check $^X for a valid relative path
 406   my $abs_perl = File::Spec->rel2abs($perl);
 407   push( @potential_perls, $abs_perl );
 408
 409   # Try 3, Last ditch effort: These two option use hackery to try to locate
 410   # a suitable perl. The hack varies depending on whether we are running
 411   # from an installed perl or an uninstalled perl in the perl source dist.
 412   if ($ENV{PERL_CORE}) {
 413
 414     # Try 3.A, If we are in a perl source tree, running an uninstalled
 415     # perl, we can keep moving up the directory tree until we find our
 416     # binary. We wouldn't do this under any other circumstances.
 417
 418     # CBuilder is also in the core, so it should be available here
 419     require ExtUtils::CBuilder;
 420     my $perl_src = ExtUtils::CBuilder->perl_src;
 421     if ( defined($perl_src) && length($perl_src) ) {
 422       my $uninstperl =
 423         File::Spec->rel2abs(File::Spec->catfile( $perl_src, $perl_basename ));
 424       push( @potential_perls, $uninstperl );
 425     }
 426
 427   } else {
 428
 429     # Try 3.B, First look in $Config{perlpath}, then search the users
 430     # PATH. We do not want to do either if we are running from an
 431     # uninstalled perl in a perl source tree.
 432
 433     push( @potential_perls, $c->{perlpath} );
 434
 435     push( @potential_perls,
 436           map File::Spec->catfile($_, $perl_basename), File::Spec->path() );
 437   }
 438
 439   # Now that we've enumerated the potential perls, it's time to test
 440   # them to see if any of them match our configuration, returning the
 441   # absolute path of the first successful match.
 442   my $exe = $c->{exe_ext};
 443   foreach my $thisperl ( @potential_perls ) {
 444
 445     if ($proto->os_type eq 'VMS') {
 446       # VMS might have a file version at the end
 447       $thisperl .= $exe unless $thisperl =~ m/$exe(;\d+)?$/i;
 448     } elsif (defined $exe) {
 449       $thisperl .= $exe unless $thisperl =~ m/$exe$/i;
 450     }
 451
 452     if ( -f $thisperl && $proto->_perl_is_same($thisperl) ) {
 453       return $thisperl;
 454     }
 455   }
 456
 457   # We've tried all alternatives, and didn't find a perl that matches
 458   # our configuration. Throw an exception, and list alternatives we tried.
 459   my @paths = map File::Basename::dirname($_), @potential_perls;
 460   die "Can't locate the perl binary used to run this script " .
 461       "in (@paths)\n";
 462 }
 463
 464 sub _is_interactive {
 465   return -t STDIN && (-t STDOUT || !(-f STDOUT || -c STDOUT)) ;   # Pipe?
 466 }
 467
 468 sub _is_unattended {
 469   my $self = shift;
 470   return $ENV{PERL_MM_USE_DEFAULT} || ( !$self->_is_interactive && eof STDIN );
 471 }
 472
 473 sub _readline {
 474   my $self = shift;
 475   return undef if $self->_is_unattended;
 476
 477   my $answer = <STDIN>;
 478   chomp $answer if defined $answer;
 479   return $answer;
 480 }
 481
 482 sub prompt {
 483   my $self = shift;
 484   my $mess = shift
 485     or die "prompt() called without a prompt message";
 486
 487   my $def;
 488   if ( $self->_is_unattended && !@_ ) {
 489     die <<EOF;
 490 ERROR: This build seems to be unattended, but there is no default value
 491 for this question.  Aborting.
 492 EOF
 493   }
 494   $def = shift if @_;
 495   ($def, my $dispdef) = defined $def ? ($def, "[$def] ") : ('', ' ');
 496
 497   local $|=1;
 498   print "$mess $dispdef";
 499
 500   my $ans = $self->_readline();
 501
 502   if ( !defined($ans) ) {     # Ctrl-D
 503     print "\n";
 504   } elsif ( !length($ans) ) { # Default
 505     print "$def\n";
 506     $ans = $def;
 507   }
 508
 509   return $ans;
 510 }
 511
 512 sub y_n {
 513   my $self = shift;
 514   my ($mess, $def)  = @_;
 515
 516   die "y_n() called without a prompt message" unless $mess;
 517   die "Invalid default value: y_n() default must be 'y' or 'n'"
 518     if $def && $def !~ /^[yn]/i;
 519
 520   if ( $self->_is_unattended && !$def ) {
 521     die <<EOF;
 522 ERROR: This build seems to be unattended, but there is no default value
 523 for this question.  Aborting.
 524 EOF
 525   }
 526
 527   my $answer;
 528   while (1) { # XXX Infinite or a large number followed by an exception ?
 529     $answer = $self->prompt(@_);
 530     return 1 if $answer =~ /^y/i;
 531     return 0 if $answer =~ /^n/i;
 532     local $|=1;
 533     print "Please answer 'y' or 'n'.\n";
 534   }
 535 }
 536
 537 sub current_action { shift->{action} }
 538 sub invoked_action { shift->{invoked_action} }
 539
 540 sub notes        { shift()->{phash}{notes}->access(@_) }
 541 sub config_data  { shift()->{phash}{config_data}->access(@_) }
 542 sub runtime_params { shift->{phash}{runtime_params}->read( @_ ? shift : () ) }  # Read-only
 543 sub auto_features  { shift()->{phash}{auto_features}->access(@_) }
 544
 545 sub features     {
 546   my $self = shift;
 547   my $ph = $self->{phash};
 548
 549   if (@_) {
 550     my $key = shift;
 551     if ($ph->{features}->exists($key)) {
 552       return $ph->{features}->access($key, @_);
 553     }
 554
 555     if (my $info = $ph->{auto_features}->access($key)) {
 556       my $failures = $self->prereq_failures($info);
 557       my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
 558                            keys %$failures ) ? 1 : 0;
 559       return !$disabled;
 560     }
 561
 562     return $ph->{features}->access($key, @_);
 563   }
 564
 565   # No args - get the auto_features & overlay the regular features
 566   my %features;
 567   my %auto_features = $ph->{auto_features}->access();
 568   while (my ($name, $info) = each %auto_features) {
 569     my $failures = $self->prereq_failures($info);
 570     my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
 571                          keys %$failures ) ? 1 : 0;
 572     $features{$name} = $disabled ? 0 : 1;
 573   }
 574   %features = (%features, $ph->{features}->access());
 575
 576   return wantarray ? %features : \%features;
 577 }
 578 BEGIN { *feature = \&features }
 579
 580 sub _mb_feature {
 581   my $self = shift;
 582
 583   if (($self->module_name || '') eq 'Module::Build') {
 584     # We're building Module::Build itself, so ...::ConfigData isn't
 585     # valid, but $self->features() should be.
 586     return $self->feature(@_);
 587   } else {
 588     require Module::Build::ConfigData;
 589     return Module::Build::ConfigData->feature(@_);
 590   }
 591 }
 592
 593
 594 sub add_build_element {
 595     my ($self, $elem) = @_;
 596     my $elems = $self->build_elements;
 597     push @$elems, $elem unless grep { $_ eq $elem } @$elems;
 598 }
 599
 600 sub ACTION_config_data {
 601   my $self = shift;
 602   return unless $self->has_config_data;
 603
 604   my $module_name = $self->module_name
 605     or die "The config_data feature requires that 'module_name' be set";
 606   my $notes_name = $module_name . '::ConfigData'; # TODO: Customize name ???
 607   my $notes_pm = File::Spec->catfile($self->blib, 'lib', split /::/, "$notes_name.pm");
 608
 609   return if $self->up_to_date(['Build.PL',
 610                                $self->config_file('config_data'),
 611                                $self->config_file('features')
 612                               ], $notes_pm);
 613
 614   $self->log_info("Writing config notes to $notes_pm\n");
 615   File::Path::mkpath(File::Basename::dirname($notes_pm));
 616
 617   Module::Build::Notes->write_config_data
 618       (
 619        file => $notes_pm,
 620        module => $module_name,
 621        config_module => $notes_name,
 622        config_data => scalar $self->config_data,
 623        feature => scalar $self->{phash}{features}->access(),
 624        auto_features => scalar $self->auto_features,
 625       );
 626 }
 627
 628 {
 629     my %valid_properties = ( __PACKAGE__,  {} );
 630     my %additive_properties;
 631
 632     sub _mb_classes {
 633       my $class = ref($_[0]) || $_[0];
 634       return ($class, $class->mb_parents);
 635     }
 636
 637     sub valid_property {
 638       my ($class, $prop) = @_;
 639       return grep exists( $valid_properties{$_}{$prop} ), $class->_mb_classes;
 640     }
 641
 642     sub valid_properties {
 643       return keys %{ shift->valid_properties_defaults() };
 644     }
 645
 646     sub valid_properties_defaults {
 647       my %out;
 648       for (reverse shift->_mb_classes) {
 649         @out{ keys %{ $valid_properties{$_} } } = values %{ $valid_properties{$_} };
 650       }
 651       return \%out;
 652     }
 653
 654     sub array_properties {
 655       for (shift->_mb_classes) {
 656         return @{$additive_properties{$_}->{ARRAY}}
 657           if exists $additive_properties{$_}->{ARRAY};
 658       }
 659     }
 660
 661     sub hash_properties {
 662       for (shift->_mb_classes) {
 663         return @{$additive_properties{$_}->{'HASH'}}
 664           if exists $additive_properties{$_}->{'HASH'};
 665       }
 666     }
 667
 668     sub add_property {
 669       my ($class, $property, $default) = @_;
 670       die "Property '$property' already exists" if $class->valid_property($property);
 671
 672       $valid_properties{$class}{$property} = $default;
 673
 674       my $type = ref $default;
 675       if ($type) {
 676         push @{$additive_properties{$class}->{$type}}, $property;
 677       }
 678
 679       unless ($class->can($property)) {
 680         no strict 'refs';
 681         if ( $type eq 'HASH' ) {
 682           *{"$class\::$property"} = sub {
 683             my $self = shift;
 684             my $x = ( $property eq 'config' ) ? $self : $self->{properties};
 685             return $x->{$property} unless @_;
 686
 687             if ( defined($_[0]) && !ref($_[0]) ) {
 688               if ( @_ == 1 ) {
 689                 return exists( $x->{$property}{$_[0]} ) ?
 690                          $x->{$property}{$_[0]} : undef;
 691               } elsif ( @_ % 2 == 0 ) {
 692                 my %args = @_;
 693                 while ( my($k, $v) = each %args ) {
 694                   $x->{$property}{$k} = $v;
 695                 }
 696               } else {
 697                 die "Unexpected arguments for property '$property'\n";
 698               }
 699             } else {
 700               $x->{$property} = $_[0];
 701             }
 702           };
 703
 704         } else {
 705           *{"$class\::$property"} = sub {
 706             my $self = shift;
 707             $self->{properties}{$property} = shift if @_;
 708             return $self->{properties}{$property};
 709           }
 710         }
 711
 712       }
 713       return $class;
 714     }
 715
 716     sub _set_defaults {
 717       my $self = shift;
 718
 719       # Set the build class.
 720       $self->{properties}{build_class} ||= ref $self;
 721
 722       # If there was no orig_dir, set to the same as base_dir
 723       $self->{properties}{orig_dir} ||= $self->{properties}{base_dir};
 724
 725       my $defaults = $self->valid_properties_defaults;
 726
 727       foreach my $prop (keys %$defaults) {
 728         $self->{properties}{$prop} = $defaults->{$prop}
 729           unless exists $self->{properties}{$prop};
 730       }
 731
 732       # Copy defaults for arrays any arrays.
 733       for my $prop ($self->array_properties) {
 734         $self->{properties}{$prop} = [@{$defaults->{$prop}}]
 735           unless exists $self->{properties}{$prop};
 736       }
 737       # Copy defaults for arrays any hashes.
 738       for my $prop ($self->hash_properties) {
 739         $self->{properties}{$prop} = {%{$defaults->{$prop}}}
 740           unless exists $self->{properties}{$prop};
 741       }
 742     }
 743
 744 }
 745
 746 # Add the default properties.
 747 __PACKAGE__->add_property(blib => 'blib');
 748 __PACKAGE__->add_property(build_class => 'Module::Build');
 749 __PACKAGE__->add_property(build_elements => [qw(PL support pm xs pod script)]);
 750 __PACKAGE__->add_property(build_script => 'Build');
 751 __PACKAGE__->add_property(build_bat => 0);
 752 __PACKAGE__->add_property(config_dir => '_build');
 753 __PACKAGE__->add_property(include_dirs => []);
 754 __PACKAGE__->add_property(installdirs => 'site');
 755 __PACKAGE__->add_property(metafile => 'META.yml');
 756 __PACKAGE__->add_property(recurse_into => []);
 757 __PACKAGE__->add_property(use_rcfile => 1);
 758 __PACKAGE__->add_property(create_packlist => 1);
 759
 760 {
 761   my $Is_ActivePerl = eval {require ActivePerl::DocTools};
 762   __PACKAGE__->add_property(html_css => $Is_ActivePerl ? 'Active.css' : '');
 763 }
 764
 765 {
 766   my @prereq_action_types = qw(requires build_requires conflicts recommends);
 767   foreach my $type (@prereq_action_types) {
 768     __PACKAGE__->add_property($type => {});
 769   }
 770   __PACKAGE__->add_property(prereq_action_types => \@prereq_action_types);
 771 }
 772
 773 __PACKAGE__->add_property($_ => {}) for qw(
 774   config
 775   get_options
 776   install_base_relpaths
 777   install_path
 778   install_sets
 779   meta_add
 780   meta_merge
 781   original_prefix
 782   prefix_relpaths
 783 );
 784
 785 __PACKAGE__->add_property($_) for qw(
 786   PL_files
 787   autosplit
 788   base_dir
 789   bindoc_dirs
 790   c_source
 791   create_makefile_pl
 792   create_readme
 793   debugger
 794   destdir
 795   dist_abstract
 796   dist_author
 797   dist_name
 798   dist_version
 799   dist_version_from
 800   extra_compiler_flags
 801   extra_linker_flags
 802   has_config_data
 803   install_base
 804   libdoc_dirs
 805   license
 806   magic_number
 807   mb_version
 808   module_name
 809   orig_dir
 810   perl
 811   pm_files
 812   pod_files
 813   pollute
 814   prefix
 815   quiet
 816   recursive_test_files
 817   script_files
 818   scripts
 819   test_files
 820   verbose
 821   xs_files
 822 );
 823
 824
 825 sub mb_parents {
 826     # Code borrowed from Class::ISA.
 827     my @in_stack = (shift);
 828     my %seen = ($in_stack[0] => 1);
 829
 830     my ($current, @out);
 831     while (@in_stack) {
 832         next unless defined($current = shift @in_stack)
 833           && $current->isa('Module::Build::Base');
 834         push @out, $current;
 835         next if $current eq 'Module::Build::Base';
 836         no strict 'refs';
 837         unshift @in_stack,
 838           map {
 839               my $c = $_; # copy, to avoid being destructive
 840               substr($c,0,2) = "main::" if substr($c,0,2) eq '::';
 841               # Canonize the :: -> main::, ::foo -> main::foo thing.
 842               # Should I ever canonize the Foo'Bar = Foo::Bar thing?
 843               $seen{$c}++ ? () : $c;
 844           } @{"$current\::ISA"};
 845
 846         # I.e., if this class has any parents (at least, ones I've never seen
 847         # before), push them, in order, onto the stack of classes I need to
 848         # explore.
 849     }
 850     shift @out;
 851     return @out;
 852 }
 853
 854 sub extra_linker_flags   { shift->_list_accessor('extra_linker_flags',   @_) }
 855 sub extra_compiler_flags { shift->_list_accessor('extra_compiler_flags', @_) }
 856
 857 sub _list_accessor {
 858   (my $self, local $_) = (shift, shift);
 859   my $p = $self->{properties};
 860   $p->{$_} = [@_] if @_;
 861   $p->{$_} = [] unless exists $p->{$_};
 862   return ref($p->{$_}) ? $p->{$_} : [$p->{$_}];
 863 }
 864
 865 # XXX Problem - if Module::Build is loaded from a different directory,
 866 # it'll look for (and perhaps destroy/create) a _build directory.
 867 sub subclass {
 868   my ($pack, %opts) = @_;
 869
 870   my $build_dir = '_build'; # XXX The _build directory is ostensibly settable by the user.  Shouldn't hard-code here.
 871   $pack->delete_filetree($build_dir) if -e $build_dir;
 872
 873   die "Must provide 'code' or 'class' option to subclass()\n"
 874     unless $opts{code} or $opts{class};
 875
 876   $opts{code}  ||= '';
 877   $opts{class} ||= 'MyModuleBuilder';
 878
 879   my $filename = File::Spec->catfile($build_dir, 'lib', split '::', $opts{class}) . '.pm';
 880   my $filedir  = File::Basename::dirname($filename);
 881   $pack->log_info("Creating custom builder $filename in $filedir\n");
 882
 883   File::Path::mkpath($filedir);
 884   die "Can't create directory $filedir: $!" unless -d $filedir;
 885
 886   my $fh = IO::File->new("> $filename") or die "Can't create $filename: $!";
 887   print $fh <<EOF;
 888 package $opts{class};
 889 use $pack;
 890 \@ISA = qw($pack);
 891 $opts{code}
 892 1;
 893 EOF
 894   close $fh;
 895
 896   unshift @INC, File::Spec->catdir(File::Spec->rel2abs($build_dir), 'lib');
 897   eval "use $opts{class}";
 898   die $@ if $@;
 899
 900   return $opts{class};
 901 }
 902
 903 sub dist_name {
 904   my $self = shift;
 905   my $p = $self->{properties};
 906   return $p->{dist_name} if defined $p->{dist_name};
 907
 908   die "Can't determine distribution name, must supply either 'dist_name' or 'module_name' parameter"
 909     unless $self->module_name;
 910
 911   ($p->{dist_name} = $self->module_name) =~ s/::/-/g;
 912
 913   return $p->{dist_name};
 914 }
 915
 916 sub dist_version_from {
 917   my ($self) = @_;
 918   my $p = $self->{properties};
 919   if ($self->module_name) {
 920     $p->{dist_version_from} ||=
 921         join( '/', 'lib', split(/::/, $self->module_name) ) . '.pm';
 922   }
 923   return $p->{dist_version_from} || undef;
 924 }
 925
 926 sub dist_version {
 927   my ($self) = @_;
 928   my $p = $self->{properties};
 929
 930   return $p->{dist_version} if defined $p->{dist_version};
 931
 932   if ( my $dist_version_from = $self->dist_version_from ) {
 933     my $version_from = File::Spec->catfile( split( qr{/}, $dist_version_from ) );
 934     my $pm_info = Module::Build::ModuleInfo->new_from_file( $version_from )
 935       or die "Can't find file $version_from to determine version";
 936     $p->{dist_version} = $pm_info->version();
 937   }
 938
 939   die ("Can't determine distribution version, must supply either 'dist_version',\n".
 940        "'dist_version_from', or 'module_name' parameter")
 941     unless $p->{dist_version};
 942
 943   return $p->{dist_version};
 944 }
 945
 946 sub dist_author   { shift->_pod_parse('author')   }
 947 sub dist_abstract { shift->_pod_parse('abstract') }
 948
 949 sub _pod_parse {
 950   my ($self, $part) = @_;
 951   my $p = $self->{properties};
 952   my $member = "dist_$part";
 953   return $p->{$member} if defined $p->{$member};
 954
 955   my $docfile = $self->_main_docfile
 956     or return;
 957   my $fh = IO::File->new($docfile)
 958     or return;
 959
 960   require Module::Build::PodParser;
 961   my $parser = Module::Build::PodParser->new(fh => $fh);
 962   my $method = "get_$part";
 963   return $p->{$member} = $parser->$method();
 964 }
 965
 966 sub version_from_file { # Method provided for backwards compatability
 967   return Module::Build::ModuleInfo->new_from_file($_[1])->version();
 968 }
 969
 970 sub find_module_by_name { # Method provided for backwards compatability
 971   return Module::Build::ModuleInfo->find_module_by_name(@_[1,2]);
 972 }
 973
 974 sub add_to_cleanup {
 975   my $self = shift;
 976   my %files = map {$self->localize_file_path($_), 1} @_;
 977   $self->{phash}{cleanup}->write(\%files);
 978 }
 979
 980 sub cleanup {
 981   my $self = shift;
 982   my $all = $self->{phash}{cleanup}->read;
 983   return keys %$all;
 984 }
 985
 986 sub config_file {
 987   my $self = shift;
 988   return unless -d $self->config_dir;
 989   return File::Spec->catfile($self->config_dir, @_);
 990 }
 991
 992 sub read_config {
 993   my ($self) = @_;
 994
 995   my $file = $self->config_file('build_params')
 996     or die "No build_params?";
 997   my $fh = IO::File->new($file) or die "Can't read '$file': $!";
 998   my $ref = eval do {local $/; <$fh>};
 999   die if $@;
1000   ($self->{args}, $self->{config}, $self->{properties}) = @$ref;
1001   close $fh;
1002 }
1003
1004 sub has_config_data {
1005   my $self = shift;
1006   return scalar grep $self->{phash}{$_}->has_data(), qw(config_data features auto_features);
1007 }
1008
1009 sub _write_data {
1010   my ($self, $filename, $data) = @_;
1011
1012   my $file = $self->config_file($filename);
1013   my $fh = IO::File->new("> $file") or die "Can't create '$file': $!";
1014   local $Data::Dumper::Terse = 1;
1015   print $fh ref($data) ? Data::Dumper::Dumper($data) : $data;
1016 }
1017
1018 sub write_config {
1019   my ($self) = @_;
1020
1021   File::Path::mkpath($self->{properties}{config_dir});
1022   -d $self->{properties}{config_dir} or die "Can't mkdir $self->{properties}{config_dir}: $!";
1023
1024   my @items = @{ $self->prereq_action_types };
1025   $self->_write_data('prereqs', { map { $_, $self->$_() } @items });
1026   $self->_write_data('build_params', [$self->{args}, $self->{config}, $self->{properties}]);
1027
1028   # Set a new magic number and write it to a file
1029   $self->_write_data('magicnum', $self->magic_number(int rand 1_000_000));
1030
1031   $self->{phash}{$_}->write() foreach qw(notes cleanup features auto_features config_data runtime_params);
1032 }
1033
1034 sub check_autofeatures {
1035   my ($self) = @_;
1036   my $features = $self->auto_features;
1037
1038   return unless %$features;
1039
1040   $self->log_info("Checking features:\n");
1041
1042   my $max_name_len;
1043   $max_name_len = ( length($_) > $max_name_len ) ?
1044                     length($_) : $max_name_len
1045     for keys %$features;
1046
1047   while (my ($name, $info) = each %$features) {
1048     $self->log_info("  $name" . '.' x ($max_name_len - length($name) + 4));
1049
1050     if ( my $failures = $self->prereq_failures($info) ) {
1051       my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
1052                            keys %$failures ) ? 1 : 0;
1053       $self->log_info( $disabled ? "disabled\n" : "enabled\n" );
1054
1055       my $log_text;
1056       while (my ($type, $prereqs) = each %$failures) {
1057         while (my ($module, $status) = each %$prereqs) {
1058           my $required =
1059             ($type =~ /^(?:\w+_)?(?:requires|conflicts)$/) ? 1 : 0;
1060           my $prefix = ($required) ? '-' : '*';
1061           $log_text .= "    $prefix $status->{message}\n";
1062         }
1063       }
1064       $self->log_warn("$log_text") unless $self->quiet;
1065     } else {
1066       $self->log_info("enabled\n");
1067     }
1068   }
1069
1070   $self->log_warn("\n");
1071 }
1072
1073 sub prereq_failures {
1074   my ($self, $info) = @_;
1075
1076   my @types = @{ $self->prereq_action_types };
1077   $info ||= {map {$_, $self->$_()} @types};
1078
1079   my $out;
1080
1081   foreach my $type (@types) {
1082     my $prereqs = $info->{$type};
1083     while ( my ($modname, $spec) = each %$prereqs ) {
1084       my $status = $self->check_installed_status($modname, $spec);
1085
1086       if ($type =~ /^(?:\w+_)?conflicts$/) {
1087         next if !$status->{ok};
1088         $status->{conflicts} = delete $status->{need};
1089         $status->{message} = "$modname ($status->{have}) conflicts with this distribution";
1090
1091       } elsif ($type =~ /^(?:\w+_)?recommends$/) {
1092         next if $status->{ok};
1093         $status->{message} = ($status->{have} eq '<none>'
1094                               ? "Optional prerequisite $modname is not installed"
1095                               : "$modname ($status->{have}) is installed, but we prefer to have $spec");
1096       } else {
1097         next if $status->{ok};
1098       }
1099
1100       $out->{$type}{$modname} = $status;
1101     }
1102   }
1103
1104   return $out;
1105 }
1106
1107 # returns a hash of defined prerequisites; i.e. only prereq types with values
1108 sub _enum_prereqs {
1109   my $self = shift;
1110   my %prereqs;
1111   foreach my $type ( @{ $self->prereq_action_types } ) {
1112     if ( $self->can( $type ) ) {
1113       my $prereq = $self->$type() || {};
1114       $prereqs{$type} = $prereq if %$prereq;
1115     }
1116   }
1117   return \%prereqs;
1118 }
1119
1120 sub check_prereq {
1121   my $self = shift;
1122
1123   # If we have XS files, make sure we can process them.
1124   my $xs_files = $self->find_xs_files;
1125   if (keys %$xs_files && !$self->_mb_feature('C_support')) {
1126     $self->log_warn("Warning: this distribution contains XS files, ".
1127                     "but Module::Build is not configured with C_support");
1128   }
1129
1130   # Check to see if there are any prereqs to check
1131   my $info = $self->_enum_prereqs;
1132   return 1 unless $info;
1133
1134   $self->log_info("Checking prerequisites...\n");
1135
1136   my $failures = $self->prereq_failures($info);
1137
1138   if ( $failures ) {
1139
1140     while (my ($type, $prereqs) = each %$failures) {
1141       while (my ($module, $status) = each %$prereqs) {
1142         my $prefix = ($type =~ /^(?:\w+_)?recommends$/) ? '*' : '- ERROR:';
1143         $self->log_warn(" $prefix $status->{message}\n");
1144       }
1145     }
1146
1147     $self->log_warn(<<EOF);
1148
1149 ERRORS/WARNINGS FOUND IN PREREQUISITES.  You may wish to install the versions
1150 of the modules indicated above before proceeding with this installation
1151
1152 EOF
1153     return 0;
1154
1155   } else {
1156
1157     $self->log_info("Looks good\n\n");
1158     return 1;
1159
1160   }
1161 }
1162
1163 sub perl_version {
1164   my ($self) = @_;
1165   # Check the current perl interpreter
1166   # It's much more convenient to use $] here than $^V, but 'man
1167   # perlvar' says I'm not supposed to.  Bloody tyrant.
1168   return $^V ? $self->perl_version_to_float(sprintf "%vd", $^V) : $];
1169 }
1170
1171 sub perl_version_to_float {
1172   my ($self, $version) = @_;
1173   $version =~ s/\./../;
1174   $version =~ s/\.(\d+)/sprintf '%03d', $1/eg;
1175   return $version;
1176 }
1177
1178 sub _parse_conditions {
1179   my ($self, $spec) = @_;
1180
1181   if ($spec =~ /^\s*([\w.]+)\s*$/) { # A plain number, maybe with dots, letters, and underscores
1182     return (">= $spec");
1183   } else {
1184     return split /\s*,\s*/, $spec;
1185   }
1186 }
1187
1188 sub check_installed_status {
1189   my ($self, $modname, $spec) = @_;
1190   my %status = (need => $spec);
1191
1192   if ($modname eq 'perl') {
1193     $status{have} = $self->perl_version;
1194
1195   } elsif (eval { no strict; $status{have} = ${"${modname}::VERSION"} }) {
1196     # Don't try to load if it's already loaded
1197
1198   } else {
1199     my $pm_info = Module::Build::ModuleInfo->new_from_module( $modname );
1200     unless (defined( $pm_info )) {
1201       @status{ qw(have message) } = ('<none>', "$modname is not installed");
1202       return \%status;
1203     }
1204
1205     $status{have} = $pm_info->version();
1206     if ($spec and !$status{have}) {
1207       @status{ qw(have message) } = (undef, "Couldn't find a \$VERSION in prerequisite $modname");
1208       return \%status;
1209     }
1210   }
1211
1212   my @conditions = $self->_parse_conditions($spec);
1213
1214   foreach (@conditions) {
1215     my ($op, $version) = /^\s*  (<=?|>=?|==|!=)  \s*  ([\w.]+)  \s*$/x
1216       or die "Invalid prerequisite condition '$_' for $modname";
1217
1218     $version = $self->perl_version_to_float($version)
1219       if $modname eq 'perl';
1220
1221     next if $op eq '>=' and !$version;  # Module doesn't have to actually define a $VERSION
1222
1223     unless ($self->compare_versions( $status{have}, $op, $version )) {
1224       $status{message} = "$modname ($status{have}) is installed, but we need version $op $version";
1225       return \%status;
1226     }
1227   }
1228
1229   $status{ok} = 1;
1230   return \%status;
1231 }
1232
1233 sub compare_versions {
1234   my $self = shift;
1235   my ($v1, $op, $v2) = @_;
1236
1237   # for alpha versions - this doesn't cover all cases, but should work for most:
1238   $v1 =~ s/_(\d+)\z/$1/;
1239   $v2 =~ s/_(\d+)\z/$1/;
1240
1241   my $eval_str = "\$v1 $op \$v2";
1242   my $result   = eval $eval_str;
1243   $self->log_warn("error comparing versions: '$eval_str' $@") if $@;
1244
1245   return $result;
1246 }
1247
1248 # I wish I could set $! to a string, but I can't, so I use $@
1249 sub check_installed_version {
1250   my ($self, $modname, $spec) = @_;
1251
1252   my $status = $self->check_installed_status($modname, $spec);
1253
1254   if ($status->{ok}) {
1255     return $status->{have} if $status->{have} and $status->{have} ne '<none>';
1256     return '0 but true';
1257   }
1258
1259   $@ = $status->{message};
1260   return 0;
1261 }
1262
1263 sub make_executable {
1264   # Perl's chmod() is mapped to useful things on various non-Unix
1265   # platforms, so we use it in the base class even though it looks
1266   # Unixish.
1267
1268   my $self = shift;
1269   foreach (@_) {
1270     my $current_mode = (stat $_)[2];
1271     chmod $current_mode | 0111, $_;
1272   }
1273 }
1274
1275 sub _startperl { shift()->config('startperl') }
1276
1277 # Return any directories in @INC which are not in the default @INC for
1278 # this perl.  For example, stuff passed in with -I or loaded with "use lib".
1279 sub _added_to_INC {
1280   my $self = shift;
1281
1282   my %seen;
1283   $seen{$_}++ foreach $self->_default_INC;
1284   return grep !$seen{$_}++, @INC;
1285 }
1286
1287 # Determine the default @INC for this Perl
1288 {
1289   my @default_inc; # Memoize
1290   sub _default_INC {
1291     my $self = shift;
1292     return @default_inc if @default_inc;
1293
1294     local $ENV{PERL5LIB};  # this is not considered part of the default.
1295
1296     my $perl = ref($self) ? $self->perl : $self->find_perl_interpreter;
1297
1298     my @inc = $self->_backticks($perl, '-le', 'print for @INC');
1299     chomp @inc;
1300
1301     return @default_inc = @inc;
1302   }
1303 }
1304
1305 sub print_build_script {
1306   my ($self, $fh) = @_;
1307
1308   my $build_package = $self->build_class;
1309
1310   my $closedata="";
1311
1312   my %q = map {$_, $self->$_()} qw(config_dir base_dir);
1313
1314   my $case_tolerant = 0+(File::Spec->can('case_tolerant')
1315                          && File::Spec->case_tolerant);
1316   $q{base_dir} = uc $q{base_dir} if $case_tolerant;
1317   $q{base_dir} = Win32::GetShortPathName($q{base_dir}) if $^O eq 'MSWin32';
1318
1319   $q{magic_numfile} = $self->config_file('magicnum');
1320
1321   my @myINC = $self->_added_to_INC;
1322   for (@myINC, values %q) {
1323     $_ = File::Spec->canonpath( $_ );
1324     s/([\\\'])/\\$1/g;
1325   }
1326
1327   my $quoted_INC = join ",\n", map "     '$_'", @myINC;
1328   my $shebang = $self->_startperl;
1329   my $magic_number = $self->magic_number;
1330
1331   print $fh <<EOF;
1332 $shebang
1333
1334 use strict;
1335 use Cwd;
1336 use File::Basename;
1337 use File::Spec;
1338
1339 sub magic_number_matches {
1340   return 0 unless -e '$q{magic_numfile}';
1341   local *FH;
1342   open FH, '$q{magic_numfile}' or return 0;
1343   my \$filenum = <FH>;
1344   close FH;
1345   return \$filenum == $magic_number;
1346 }
1347
1348 my \$progname;
1349 my \$orig_dir;
1350 BEGIN {
1351   \$^W = 1;  # Use warnings
1352   \$progname = basename(\$0);
1353   \$orig_dir = Cwd::cwd();
1354   my \$base_dir = '$q{base_dir}';
1355   if (!magic_number_matches()) {
1356     unless (chdir(\$base_dir)) {
1357       die ("Couldn't chdir(\$base_dir), aborting\\n");
1358     }
1359     unless (magic_number_matches()) {
1360       die ("Configuration seems to be out of date, please re-run 'perl Build.PL' again.\\n");
1361     }
1362   }
1363   unshift \@INC,
1364     (
1365 $quoted_INC
1366     );
1367 }
1368
1369 close(*DATA) unless eof(*DATA); # ensure no open handles to this script
1370
1371 use $build_package;
1372
1373 # Some platforms have problems setting \$^X in shebang contexts, fix it up here
1374 \$^X = Module::Build->find_perl_interpreter;
1375
1376 if (-e 'Build.PL' and not $build_package->up_to_date('Build.PL', \$progname)) {
1377    warn "Warning: Build.PL has been altered.  You may need to run 'perl Build.PL' again.\\n";
1378 }
1379
1380 # This should have just enough arguments to be able to bootstrap the rest.
1381 my \$build = $build_package->resume (
1382   properties => {
1383     config_dir => '$q{config_dir}',
1384     orig_dir => \$orig_dir,
1385   },
1386 );
1387
1388 \$build->dispatch;
1389 EOF
1390 }
1391
1392 sub create_build_script {
1393   my ($self) = @_;
1394   $self->write_config;
1395
1396   my ($build_script, $dist_name, $dist_version)
1397     = map $self->$_(), qw(build_script dist_name dist_version);
1398
1399   if ( $self->delete_filetree($build_script) ) {
1400     $self->log_info("Removed previous script '$build_script'\n\n");
1401   }
1402
1403   $self->log_info("Creating new '$build_script' script for ",
1404                   "'$dist_name' version '$dist_version'\n");
1405   my $fh = IO::File->new(">$build_script") or die "Can't create '$build_script': $!";
1406   $self->print_build_script($fh);
1407   close $fh;
1408
1409   $self->make_executable($build_script);
1410
1411   return 1;
1412 }
1413
1414 sub check_manifest {
1415   my $self = shift;
1416   return unless -e 'MANIFEST';
1417
1418   # Stolen nearly verbatim from MakeMaker.  But ExtUtils::Manifest
1419   # could easily be re-written into a modern Perl dialect.
1420
1421   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
1422   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
1423
1424   $self->log_info("Checking whether your kit is complete...\n");
1425   if (my @missed = ExtUtils::Manifest::manicheck()) {
1426     $self->log_warn("WARNING: the following files are missing in your kit:\n",
1427                     "\t", join("\n\t", @missed), "\n",
1428                     "Please inform the author.\n\n");
1429   } else {
1430     $self->log_info("Looks good\n\n");
1431   }
1432 }
1433
1434 sub dispatch {
1435   my $self = shift;
1436   local $self->{_completed_actions} = {};
1437
1438   if (@_) {
1439     my ($action, %p) = @_;
1440     my $args = $p{args} ? delete($p{args}) : {};
1441
1442     local $self->{invoked_action} = $action;
1443     local $self->{args} = {%{$self->{args}}, %$args};
1444     local $self->{properties} = {%{$self->{properties}}, %p};
1445     return $self->_call_action($action);
1446   }
1447
1448   die "No build action specified" unless $self->{action};
1449   local $self->{invoked_action} = $self->{action};
1450   $self->_call_action($self->{action});
1451 }
1452
1453 sub _call_action {
1454   my ($self, $action) = @_;
1455
1456   return if $self->{_completed_actions}{$action}++;
1457
1458   local $self->{action} = $action;
1459   my $method = "ACTION_$action";
1460   die "No action '$action' defined, try running the 'help' action.\n" unless $self->can($method);
1461   return $self->$method();
1462 }
1463
1464 sub cull_options {
1465     my $self = shift;
1466     my $specs = $self->get_options or return ({}, @_);
1467     require Getopt::Long;
1468     # XXX Should we let Getopt::Long handle M::B's options? That would
1469     # be easy-ish to add to @specs right here, but wouldn't handle options
1470     # passed without "--" as M::B currently allows. We might be able to
1471     # get around this by setting the "prefix_pattern" Configure option.
1472     my @specs;
1473     my $args = {};
1474     # Construct the specifications for GetOptions.
1475     while (my ($k, $v) = each %$specs) {
1476         # Throw an error if specs conflict with our own.
1477         die "Option specification '$k' conflicts with a " . ref $self
1478           . " option of the same name"
1479           if $self->valid_property($k);
1480         push @specs, $k . (defined $v->{type} ? $v->{type} : '');
1481         push @specs, $v->{store} if exists $v->{store};
1482         $args->{$k} = $v->{default} if exists $v->{default};
1483     }
1484
1485     local @ARGV = @_; # No other way to dupe Getopt::Long
1486
1487     # Get the options values and return them.
1488     # XXX Add option to allow users to set options?
1489     if ( @specs ) {
1490       Getopt::Long::Configure('pass_through');
1491       Getopt::Long::GetOptions($args, @specs);
1492     }
1493
1494     return $args, @ARGV;
1495 }
1496
1497 sub unparse_args {
1498   my ($self, $args) = @_;
1499   my @out;
1500   while (my ($k, $v) = each %$args) {
1501     push @out, (UNIVERSAL::isa($v, 'HASH')  ? map {+"--$k", "$_=$v->{$_}"} keys %$v :
1502                 UNIVERSAL::isa($v, 'ARRAY') ? map {+"--$k", $_} @$v :
1503                 ("--$k", $v));
1504   }
1505   return @out;
1506 }
1507
1508 sub args {
1509     my $self = shift;
1510     return wantarray ? %{ $self->{args} } : $self->{args} unless @_;
1511     my $key = shift;
1512     $self->{args}{$key} = shift if @_;
1513     return $self->{args}{$key};
1514 }
1515
1516 sub _translate_option {
1517   my $self = shift;
1518   my $opt  = shift;
1519
1520   (my $tr_opt = $opt) =~ tr/-/_/;
1521
1522   return $tr_opt if grep $tr_opt =~ /^(?:no_?)?$_$/, qw(
1523     create_makefile_pl
1524     create_readme
1525     extra_compiler_flags
1526     extra_linker_flags
1527     html_css
1528     install_base
1529     install_path
1530     meta_add
1531     meta_merge
1532     test_files
1533     use_rcfile
1534   ); # normalize only selected option names
1535
1536   return $opt;
1537 }
1538
1539 sub _read_arg {
1540   my ($self, $args, $key, $val) = @_;
1541
1542   $key = $self->_translate_option($key);
1543
1544   if ( exists $args->{$key} ) {
1545     $args->{$key} = [ $args->{$key} ] unless ref $args->{$key};
1546     push @{$args->{$key}}, $val;
1547   } else {
1548     $args->{$key} = $val;
1549   }
1550 }
1551
1552 sub _optional_arg {
1553   my $self = shift;
1554   my $opt  = shift;
1555   my $argv = shift;
1556
1557   $opt = $self->_translate_option($opt);
1558
1559   my @bool_opts = qw(
1560     build_bat
1561     create_readme
1562     pollute
1563     quiet
1564     uninst
1565     use_rcfile
1566     verbose
1567   );
1568
1569   # inverted boolean options; eg --noverbose or --no-verbose
1570   # converted to proper name & returned with false value (verbose, 0)
1571   if ( grep $opt =~ /^no[-_]?$_$/, @bool_opts ) {
1572     $opt =~ s/^no-?//;
1573     return ($opt, 0);
1574   }
1575
1576   # non-boolean option; return option unchanged along with its argument
1577   return ($opt, shift(@$argv)) unless grep $_ eq $opt, @bool_opts;
1578
1579   # we're punting a bit here, if an option appears followed by a digit
1580   # we take the digit as the argument for the option. If there is
1581   # nothing that looks like a digit, we pretent the option is a flag
1582   # that is being set and has no argument.
1583   my $arg = 1;
1584   $arg = shift(@$argv) if @$argv && $argv->[0] =~ /^\d+$/;
1585
1586   return ($opt, $arg);
1587 }
1588
1589 sub read_args {
1590   my $self = shift;
1591   my ($action, @argv);
1592   (my $args, @_) = $self->cull_options(@_);
1593   my %args = %$args;
1594
1595   my $opt_re = qr/[\w\-]+/;
1596
1597   while (@_) {
1598     local $_ = shift;
1599     if ( /^(?:--)?($opt_re)=(.*)$/ ) {
1600       $self->_read_arg(\%args, $1, $2);
1601     } elsif ( /^--($opt_re)$/ ) {
1602       my($opt, $arg) = $self->_optional_arg($1, \@_);
1603       $self->_read_arg(\%args, $opt, $arg);
1604     } elsif ( /^($opt_re)$/ and !defined($action)) {
1605       $action = $1;
1606     } else {
1607       push @argv, $_;
1608     }
1609   }
1610   $args{ARGV} = \@argv;
1611
1612   # Hashify these parameters
1613   for ($self->hash_properties) {
1614     next unless exists $args{$_};
1615     my %hash;
1616     $args{$_} ||= [];
1617     $args{$_} = [ $args{$_} ] unless ref $args{$_};
1618     foreach my $arg ( @{$args{$_}} ) {
1619       $arg =~ /(\w+)=(.*)/
1620         or die "Malformed '$_' argument: '$arg' should be something like 'foo=bar'";
1621       $hash{$1} = $2;
1622     }
1623     $args{$_} = \%hash;
1624   }
1625
1626   # De-tilde-ify any path parameters
1627   for my $key (qw(prefix install_base destdir)) {
1628     next if !defined $args{$key};
1629     $args{$key} = _detildefy($args{$key});
1630   }
1631
1632   for my $key (qw(install_path)) {
1633     next if !defined $args{$key};
1634
1635     for my $subkey (keys %{$args{$key}}) {
1636       next if !defined $args{$key}{$subkey};
1637       my $subkey_ext = _detildefy($args{$key}{$subkey});
1638       if ( $subkey eq 'html' ) { # translate for compatability
1639         $args{$key}{binhtml} = $subkey_ext;
1640         $args{$key}{libhtml} = $subkey_ext;
1641       } else {
1642         $args{$key}{$subkey} = $subkey_ext;
1643       }
1644     }
1645   }
1646
1647   if ($args{makefile_env_macros}) {
1648     require Module::Build::Compat;
1649     %args = (%args, Module::Build::Compat->makefile_to_build_macros);
1650   }
1651
1652   return \%args, $action;
1653 }
1654
1655
1656 sub _detildefy {
1657     my $arg = shift;
1658
1659     my($new_arg) = glob($arg) if $arg =~ /^~/;
1660
1661     return defined($new_arg) ? $new_arg : $arg;
1662 }
1663
1664
1665 # merge Module::Build argument lists that have already been parsed
1666 # by read_args(). Takes two references to option hashes and merges
1667 # the contents, giving priority to the first.
1668 sub _merge_arglist {
1669   my( $self, $opts1, $opts2 ) = @_;
1670
1671   my %new_opts = %$opts1;
1672   while (my ($key, $val) = each %$opts2) {
1673     if ( exists( $opts1->{$key} ) ) {
1674       if ( ref( $val ) eq 'HASH' ) {
1675         while (my ($k, $v) = each %$val) {
1676           $new_opts{$key}{$k} = $v unless exists( $opts1->{$key}{$k} );
1677         }
1678       }
1679     } else {
1680       $new_opts{$key} = $val
1681     }
1682   }
1683
1684   return %new_opts;
1685 }
1686
1687 # Look for a home directory on various systems.
1688 sub _home_dir {
1689   my @home_dirs;
1690   push( @home_dirs, $ENV{HOME} ) if $ENV{HOME};
1691
1692   push( @home_dirs, File::Spec->catpath($ENV{HOMEDRIVE}, $ENV{HOMEPATH}, '') )
1693       if $ENV{HOMEDRIVE} && $ENV{HOMEPATH};
1694
1695   my @other_home_envs = qw( USERPROFILE APPDATA WINDIR SYS$LOGIN );
1696   push( @home_dirs, map $ENV{$_}, grep $ENV{$_}, @other_home_envs );
1697
1698   my @real_home_dirs = grep -d, @home_dirs;
1699
1700   return wantarray ? @real_home_dirs : shift( @real_home_dirs );
1701 }
1702
1703 sub _find_user_config {
1704   my $self = shift;
1705   my $file = shift;
1706   foreach my $dir ( $self->_home_dir ) {
1707     my $path = File::Spec->catfile( $dir, $file );
1708     return $path if -e $path;
1709   }
1710   return undef;
1711 }
1712
1713 # read ~/.modulebuildrc returning global options '*' and
1714 # options specific to the currently executing $action.
1715 sub read_modulebuildrc {
1716   my( $self, $action ) = @_;
1717
1718   return () unless $self->use_rcfile;
1719
1720   my $modulebuildrc;
1721   if ( exists($ENV{MODULEBUILDRC}) && $ENV{MODULEBUILDRC} eq 'NONE' ) {
1722     return ();
1723   } elsif ( exists($ENV{MODULEBUILDRC}) && -e $ENV{MODULEBUILDRC} ) {
1724     $modulebuildrc = $ENV{MODULEBUILDRC};
1725   } elsif ( exists($ENV{MODULEBUILDRC}) ) {
1726     $self->log_warn("WARNING: Can't find resource file " .
1727                     "'$ENV{MODULEBUILDRC}' defined in environment.\n" .
1728                     "No options loaded\n");
1729     return ();
1730   } else {
1731     $modulebuildrc = $self->_find_user_config( '.modulebuildrc' );
1732     return () unless $modulebuildrc;
1733   }
1734
1735   my $fh = IO::File->new( $modulebuildrc )
1736       or die "Can't open $modulebuildrc: $!";
1737
1738   my %options; my $buffer = '';
1739   while (defined( my $line = <$fh> )) {
1740     chomp( $line );
1741     $line =~ s/#.*$//;
1742     next unless length( $line );
1743
1744     if ( $line =~ /^\S/ ) {
1745       if ( $buffer ) {
1746         my( $action, $options ) = split( /\s+/, $buffer, 2 );
1747         $options{$action} .= $options . ' ';
1748         $buffer = '';
1749       }
1750       $buffer = $line;
1751     } else {
1752       $buffer .= $line;
1753     }
1754   }
1755
1756   if ( $buffer ) { # anything left in $buffer ?
1757     my( $action, $options ) = split( /\s+/, $buffer, 2 );
1758     $options{$action} .= $options . ' '; # merge if more than one line
1759   }
1760
1761   my ($global_opts) =
1762     $self->read_args( $self->split_like_shell( $options{'*'} || '' ) );
1763   my ($action_opts) =
1764     $self->read_args( $self->split_like_shell( $options{$action} || '' ) );
1765
1766   # specific $action options take priority over global options '*'
1767   return $self->_merge_arglist( $action_opts, $global_opts );
1768 }
1769
1770 # merge the relevant options in ~/.modulebuildrc into Module::Build's
1771 # option list where they do not conflict with commandline options.
1772 sub merge_modulebuildrc {
1773   my( $self, $action, %cmdline_opts ) = @_;
1774   my %rc_opts = $self->read_modulebuildrc( $action || $self->{action} || 'build' );
1775   my %new_opts = $self->_merge_arglist( \%cmdline_opts, \%rc_opts );
1776   $self->merge_args( $action, %new_opts );
1777 }
1778
1779 sub merge_args {
1780   my ($self, $action, %args) = @_;
1781   $self->{action} = $action if defined $action;
1782
1783   my %additive = map { $_ => 1 } $self->hash_properties;
1784
1785   # Extract our 'properties' from $cmd_args, the rest are put in 'args'.
1786   while (my ($key, $val) = each %args) {
1787     $self->{phash}{runtime_params}->access( $key => $val )
1788       if $self->valid_property($key);
1789     my $add_to = ( $key eq 'config' ? $self->{config}
1790                   : $additive{$key} ? $self->{properties}{$key}
1791                   : $self->valid_property($key) ? $self->{properties}
1792                   : $self->{args});
1793
1794     if ($additive{$key}) {
1795       $add_to->{$_} = $val->{$_} foreach keys %$val;
1796     } else {
1797       $add_to->{$key} = $val;
1798     }
1799   }
1800 }
1801
1802 sub cull_args {
1803   my $self = shift;
1804   my ($args, $action) = $self->read_args(@_);
1805   $self->merge_args($action, %$args);
1806   $self->merge_modulebuildrc( $action, %$args );
1807 }
1808
1809 sub super_classes {
1810   my ($self, $class, $seen) = @_;
1811   $class ||= ref($self) || $self;
1812   $seen  ||= {};
1813
1814   no strict 'refs';
1815   my @super = grep {not $seen->{$_}++} $class, @{ $class . '::ISA' };
1816   return @super, map {$self->super_classes($_,$seen)} @super;
1817 }
1818
1819 sub known_actions {
1820   my ($self) = @_;
1821
1822   my %actions;
1823   no strict 'refs';
1824
1825   foreach my $class ($self->super_classes) {
1826     foreach ( keys %{ $class . '::' } ) {
1827       $actions{$1}++ if /^ACTION_(\w+)/;
1828     }
1829   }
1830
1831   return wantarray ? sort keys %actions : \%actions;
1832 }
1833
1834 sub get_action_docs {
1835   my ($self, $action, $actions) = @_;
1836   $actions ||= $self->known_actions;
1837   $@ = '';
1838   ($@ = "No known action '$action'\n"), return
1839     unless $actions->{$action};
1840
1841   my ($files_found, @docs) = (0);
1842   foreach my $class ($self->super_classes) {
1843     (my $file = $class) =~ s{::}{/}g;
1844     $file = $INC{$file . '.pm'} or next;
1845     my $fh = IO::File->new("< $file") or next;
1846     $files_found++;
1847
1848     # Code below modified from /usr/bin/perldoc
1849
1850     # Skip to ACTIONS section
1851     local $_;
1852     while (<$fh>) {
1853       last if /^=head1 ACTIONS\s/;
1854     }
1855
1856     # Look for our action
1857     my ($found, $inlist) = (0, 0);
1858     while (<$fh>) {
1859       if (/^=item\s+\Q$action\E\b/)  {
1860         $found = 1;
1861       } elsif (/^=(item|back)/) {
1862         last if $found > 1 and not $inlist;
1863       }
1864       next unless $found;
1865       push @docs, $_;
1866       ++$inlist if /^=over/;
1867       --$inlist if /^=back/;
1868       ++$found  if /^\w/; # Found descriptive text
1869     }
1870   }
1871
1872   unless ($files_found) {
1873     $@ = "Couldn't find any documentation to search";
1874     return;
1875   }
1876   unless (@docs) {
1877     $@ = "Couldn't find any docs for action '$action'";
1878     return;
1879   }
1880
1881   return join '', @docs;
1882 }
1883
1884 sub ACTION_prereq_report {
1885   my $self = shift;
1886   $self->log_info( $self->prereq_report );
1887 }
1888
1889 sub prereq_report {
1890   my $self = shift;
1891   my @types = @{ $self->prereq_action_types };
1892   my $info = { map { $_ => $self->$_() } @types };
1893
1894   my $output = '';
1895   foreach my $type (@types) {
1896     my $prereqs = $info->{$type};
1897     next unless %$prereqs;
1898     $output .= "\n$type:\n";
1899     my $mod_len = 2;
1900     my $ver_len = 4;
1901     my %mods;
1902     while ( my ($modname, $spec) = each %$prereqs ) {
1903       my $len  = length $modname;
1904       $mod_len = $len if $len > $mod_len;
1905       $spec    ||= '0';
1906       $len     = length $spec;
1907       $ver_len = $len if $len > $ver_len;
1908
1909       my $mod = $self->check_installed_status($modname, $spec);
1910       $mod->{name} = $modname;
1911       $mod->{ok} ||= 0;
1912       $mod->{ok} = ! $mod->{ok} if $type =~ /^(\w+_)?conflicts$/;
1913
1914       $mods{lc $modname} = $mod;
1915     }
1916
1917     my $space  = q{ } x ($mod_len - 3);
1918     my $vspace = q{ } x ($ver_len - 3);
1919     my $sline  = q{-} x ($mod_len - 3);
1920     my $vline  = q{-} x ($ver_len - 3);
1921     my $disposition = ($type =~ /^(\w+_)?conflicts$/) ?
1922                         'Clash' : 'Need';
1923     $output .=
1924       "    Module $space  $disposition $vspace  Have\n".
1925       "    ------$sline+------$vline-+----------\n";
1926
1927
1928     for my $k (sort keys %mods) {
1929       my $mod = $mods{$k};
1930       my $space  = q{ } x ($mod_len - length $k);
1931       my $vspace = q{ } x ($ver_len - length $mod->{need});
1932       my $f = $mod->{ok} ? ' ' : '!';
1933       $output .=
1934         "  $f $mod->{name} $space     $mod->{need}  $vspace   $mod->{have}\n";
1935     }
1936   }
1937   return $output;
1938 }
1939
1940 sub ACTION_help {
1941   my ($self) = @_;
1942   my $actions = $self->known_actions;
1943
1944   if (@{$self->{args}{ARGV}}) {
1945     my $msg = $self->get_action_docs($self->{args}{ARGV}[0], $actions) || "$@\n";
1946     print $msg;
1947     return;
1948   }
1949
1950   print <<EOF;
1951
1952  Usage: $0 <action> arg1=value arg2=value ...
1953  Example: $0 test verbose=1
1954
1955  Actions defined:
1956 EOF
1957
1958   print $self->_action_listing($actions);
1959
1960   print "\nRun `Build help <action>` for details on an individual action.\n";
1961   print "See `perldoc Module::Build` for complete documentation.\n";
1962 }
1963
1964 sub _action_listing {
1965   my ($self, $actions) = @_;
1966
1967   # Flow down columns, not across rows
1968   my @actions = sort keys %$actions;
1969   @actions = map $actions[($_ + ($_ % 2) * @actions) / 2],  0..$#actions;
1970
1971   my $out = '';
1972   while (my ($one, $two) = splice @actions, 0, 2) {
1973     $out .= sprintf("  %-12s                   %-12s\n", $one, $two||'');
1974   }
1975   return $out;
1976 }
1977
1978 sub ACTION_test {
1979   my ($self) = @_;
1980   my $p = $self->{properties};
1981   require Test::Harness;
1982
1983   $self->depends_on('code');
1984
1985   # Do everything in our power to work with all versions of Test::Harness
1986   my @harness_switches = $p->{debugger} ? qw(-w -d) : ();
1987   local $Test::Harness::switches    = join ' ', grep defined, $Test::Harness::switches, @harness_switches;
1988   local $Test::Harness::Switches    = join ' ', grep defined, $Test::Harness::Switches, @harness_switches;
1989   local $ENV{HARNESS_PERL_SWITCHES} = join ' ', grep defined, $ENV{HARNESS_PERL_SWITCHES}, @harness_switches;
1990
1991   $Test::Harness::switches = undef   unless length $Test::Harness::switches;
1992   $Test::Harness::Switches = undef   unless length $Test::Harness::Switches;
1993   delete $ENV{HARNESS_PERL_SWITCHES} unless length $ENV{HARNESS_PERL_SWITCHES};
1994
1995   local ($Test::Harness::verbose,
1996          $Test::Harness::Verbose,
1997          $ENV{TEST_VERBOSE},
1998          $ENV{HARNESS_VERBOSE}) = ($p->{verbose} || 0) x 4;
1999
2000   # Make sure we test the module in blib/
2001   local @INC = (File::Spec->catdir($p->{base_dir}, $self->blib, 'lib'),
2002                 File::Spec->catdir($p->{base_dir}, $self->blib, 'arch'),
2003                 @INC);
2004
2005   # Filter out nonsensical @INC entries - some versions of
2006   # Test::Harness will really explode the number of entries here
2007   @INC = grep {ref() || -d} @INC if @INC > 100;
2008
2009   my $tests = $self->find_test_files;
2010
2011   if (@$tests) {
2012     # Work around a Test::Harness bug that loses the particular perl
2013     # we're running under.  $self->perl is trustworthy, but $^X isn't.
2014     local $^X = $self->perl;
2015     Test::Harness::runtests(@$tests);
2016   } else {
2017     $self->log_info("No tests defined.\n");
2018   }
2019
2020   # This will get run and the user will see the output.  It doesn't
2021   # emit Test::Harness-style output.
2022   if (-e 'visual.pl') {
2023     $self->run_perl_script('visual.pl', '-Mblib='.$self->blib);
2024   }
2025 }
2026
2027 sub test_files {
2028   my $self = shift;
2029   my $p = $self->{properties};
2030   if (@_) {
2031     return $p->{test_files} = (@_ == 1 ? shift : [@_]);
2032   }
2033   return $self->find_test_files;
2034 }
2035
2036 sub expand_test_dir {
2037   my ($self, $dir) = @_;
2038   return sort @{$self->rscan_dir($dir, qr{^[^.].*\.t$})} if $self->recursive_test_files;
2039   return sort glob File::Spec->catfile($dir, "*.t");
2040 }
2041
2042 sub ACTION_testdb {
2043   my ($self) = @_;
2044   local $self->{properties}{debugger} = 1;
2045   $self->depends_on('test');
2046 }
2047
2048 sub ACTION_testcover {
2049   my ($self) = @_;
2050
2051   unless (Module::Build::ModuleInfo->find_module_by_name('Devel::Cover')) {
2052     warn("Cannot run testcover action unless Devel::Cover is installed.\n");
2053     return;
2054   }
2055
2056   $self->add_to_cleanup('coverage', 'cover_db');
2057   $self->depends_on('code');
2058
2059   # See whether any of the *.pm files have changed since last time
2060   # testcover was run.  If so, start over.
2061   if (-e 'cover_db') {
2062     my $pm_files = $self->rscan_dir(File::Spec->catdir($self->blib, 'lib'), qr{\.pm$} );
2063     my $cover_files = $self->rscan_dir('cover_db', sub {-f $_ and not /\.html$/});
2064
2065     $self->do_system(qw(cover -delete))
2066       unless $self->up_to_date($pm_files, $cover_files);
2067   }
2068
2069   local $Test::Harness::switches    =
2070   local $Test::Harness::Switches    =
2071   local $ENV{HARNESS_PERL_SWITCHES} = "-MDevel::Cover";
2072
2073   $self->depends_on('test');
2074   $self->do_system('cover');
2075 }
2076
2077 sub ACTION_code {
2078   my ($self) = @_;
2079
2080   # All installable stuff gets created in blib/ .
2081   # Create blib/arch to keep blib.pm happy
2082   my $blib = $self->blib;
2083   $self->add_to_cleanup($blib);
2084   File::Path::mkpath( File::Spec->catdir($blib, 'arch') );
2085
2086   if (my $split = $self->autosplit) {
2087     $self->autosplit_file($_, $blib) for ref($split) ? @$split : ($split);
2088   }
2089
2090   foreach my $element (@{$self->build_elements}) {
2091     my $method = "process_${element}_files";
2092     $method = "process_files_by_extension" unless $self->can($method);
2093     $self->$method($element);
2094   }
2095
2096   $self->depends_on('config_data');
2097 }
2098
2099 sub ACTION_build {
2100   my $self = shift;
2101   $self->depends_on('code');
2102   $self->depends_on('docs');
2103 }
2104
2105 sub process_files_by_extension {
2106   my ($self, $ext) = @_;
2107
2108   my $method = "find_${ext}_files";
2109   my $files = $self->can($method) ? $self->$method() : $self->_find_file_by_type($ext,  'lib');
2110
2111   while (my ($file, $dest) = each %$files) {
2112     $self->copy_if_modified(from => $file, to => File::Spec->catfile($self->blib, $dest) );
2113   }
2114 }
2115
2116 sub process_support_files {
2117   my $self = shift;
2118   my $p = $self->{properties};
2119   return unless $p->{c_source};
2120
2121   push @{$p->{include_dirs}}, $p->{c_source};
2122
2123   my $files = $self->rscan_dir($p->{c_source}, qr{\.c(pp)?$});
2124   foreach my $file (@$files) {
2125     push @{$p->{objects}}, $self->compile_c($file);
2126   }
2127 }
2128
2129 sub process_PL_files {
2130   my ($self) = @_;
2131   my $files = $self->find_PL_files;
2132
2133   while (my ($file, $to) = each %$files) {
2134     unless ($self->up_to_date( $file, $to )) {
2135       $self->run_perl_script($file, [], [@$to]);
2136       $self->add_to_cleanup(@$to);
2137     }
2138   }
2139 }
2140
2141 sub process_xs_files {
2142   my $self = shift;
2143   my $files = $self->find_xs_files;
2144   while (my ($from, $to) = each %$files) {
2145     unless ($from eq $to) {
2146       $self->add_to_cleanup($to);
2147       $self->copy_if_modified( from => $from, to => $to );
2148     }
2149     $self->process_xs($to);
2150   }
2151 }
2152
2153 sub process_pod_files { shift()->process_files_by_extension(shift()) }
2154 sub process_pm_files  { shift()->process_files_by_extension(shift()) }
2155
2156 sub process_script_files {
2157   my $self = shift;
2158   my $files = $self->find_script_files;
2159   return unless keys %$files;
2160
2161   my $script_dir = File::Spec->catdir($self->blib, 'script');
2162   File::Path::mkpath( $script_dir );
2163
2164   foreach my $file (keys %$files) {
2165     my $result = $self->copy_if_modified($file, $script_dir, 'flatten') or next;
2166     $self->fix_shebang_line($result) unless $self->os_type eq 'VMS';
2167     $self->make_executable($result);
2168   }
2169 }
2170
2171 sub find_PL_files {
2172   my $self = shift;
2173   if (my $files = $self->{properties}{PL_files}) {
2174     # 'PL_files' is given as a Unix file spec, so we localize_file_path().
2175
2176     if (UNIVERSAL::isa($files, 'ARRAY')) {
2177       return { map {$_, [/^(.*)\.PL$/]}
2178                map $self->localize_file_path($_),
2179                @$files };
2180
2181     } elsif (UNIVERSAL::isa($files, 'HASH')) {
2182       my %out;
2183       while (my ($file, $to) = each %$files) {
2184         $out{ $self->localize_file_path($file) } = [ map $self->localize_file_path($_),
2185                                                      ref $to ? @$to : ($to) ];
2186       }
2187       return \%out;
2188
2189     } else {
2190       die "'PL_files' must be a hash reference or array reference";
2191     }
2192   }
2193
2194   return unless -d 'lib';
2195   return { map {$_, [/^(.*)\.PL$/]} @{ $self->rscan_dir('lib', qr{\.PL$}) } };
2196 }
2197
2198 sub find_pm_files  { shift->_find_file_by_type('pm',  'lib') }
2199 sub find_pod_files { shift->_find_file_by_type('pod', 'lib') }
2200 sub find_xs_files  { shift->_find_file_by_type('xs',  'lib') }
2201
2202 sub find_script_files {
2203   my $self = shift;
2204   if (my $files = $self->script_files) {
2205     # Always given as a Unix file spec.  Values in the hash are
2206     # meaningless, but we preserve if present.
2207     return { map {$self->localize_file_path($_), $files->{$_}} keys %$files };
2208   }
2209
2210   # No default location for script files
2211   return {};
2212 }
2213
2214 sub find_test_files {
2215   my $self = shift;
2216   my $p = $self->{properties};
2217
2218   if (my $files = $p->{test_files}) {
2219     $files = [keys %$files] if UNIVERSAL::isa($files, 'HASH');
2220     $files = [map { -d $_ ? $self->expand_test_dir($_) : $_ }
2221               map glob,
2222               $self->split_like_shell($files)];
2223
2224     # Always given as a Unix file spec.
2225     return [ map $self->localize_file_path($_), @$files ];
2226
2227   } else {
2228     # Find all possible tests in t/ or test.pl
2229     my @tests;
2230     push @tests, 'test.pl'                          if -e 'test.pl';
2231     push @tests, $self->expand_test_dir('t')        if -e 't' and -d _;
2232     return \@tests;
2233   }
2234 }
2235
2236 sub _find_file_by_type {
2237   my ($self, $type, $dir) = @_;
2238
2239   if (my $files = $self->{properties}{"${type}_files"}) {
2240     # Always given as a Unix file spec
2241     return { map $self->localize_file_path($_), %$files };
2242   }
2243
2244   return {} unless -d $dir;
2245   return { map {$_, $_}
2246            map $self->localize_file_path($_),
2247            grep !/\.\#/,
2248            @{ $self->rscan_dir($dir, qr{\.$type$}) } };
2249 }
2250
2251 sub localize_file_path {
2252   my ($self, $path) = @_;
2253   $path =~ s/\.\z// if $self->os_type eq 'VMS';
2254   return File::Spec->catfile( split m{/}, $path );
2255 }
2256
2257 sub localize_dir_path {
2258   my ($self, $path) = @_;
2259   return File::Spec->catdir( split m{/}, $path );
2260 }
2261
2262 sub fix_shebang_line { # Adapted from fixin() in ExtUtils::MM_Unix 1.35
2263   my ($self, @files) = @_;
2264   my $c = $self->config;
2265
2266   my ($does_shbang) = $c->{sharpbang} =~ /^\s*\#\!/;
2267   for my $file (@files) {
2268     my $FIXIN = IO::File->new($file) or die "Can't process '$file': $!";
2269     local $/ = "\n";
2270     chomp(my $line = <$FIXIN>);
2271     next unless $line =~ s/^\s*\#!\s*//;     # Not a shbang file.
2272
2273     my ($cmd, $arg) = (split(' ', $line, 2), '');
2274     next unless $cmd =~ /perl/i;
2275     my $interpreter = $self->{properties}{perl};
2276
2277     $self->log_verbose("Changing sharpbang in $file to $interpreter");
2278     my $shb = '';
2279     $shb .= "$c->{sharpbang}$interpreter $arg\n" if $does_shbang;
2280
2281     # I'm not smart enough to know the ramifications of changing the
2282     # embedded newlines here to \n, so I leave 'em in.
2283     $shb .= qq{
2284 eval 'exec $interpreter $arg -S \$0 \${1+"\$\@"}'
2285     if 0; # not running under some shell
2286 } unless $self->os_type eq 'Windows'; # this won't work on win32, so don't
2287
2288     my $FIXOUT = IO::File->new(">$file.new")
2289       or die "Can't create new $file: $!\n";
2290
2291     # Print out the new #! line (or equivalent).
2292     local $\;
2293     undef $/; # Was localized above
2294     print $FIXOUT $shb, <$FIXIN>;
2295     close $FIXIN;
2296     close $FIXOUT;
2297
2298     rename($file, "$file.bak")
2299       or die "Can't rename $file to $file.bak: $!";
2300
2301     rename("$file.new", $file)
2302       or die "Can't rename $file.new to $file: $!";
2303
2304     unlink "$file.bak"
2305       or $self->log_warn("Couldn't clean up $file.bak, leaving it there");
2306
2307     $self->do_system($c->{eunicefix}, $file) if $c->{eunicefix} ne ':';
2308   }
2309 }
2310
2311
2312 sub ACTION_testpod {
2313   my $self = shift;
2314   $self->depends_on('docs');
2315
2316   eval q{use Test::Pod 0.95; 1}
2317     or die "The 'testpod' action requires Test::Pod version 0.95";
2318
2319   my @files = sort keys %{$self->_find_pods($self->libdoc_dirs)},
2320                    keys %{$self->_find_pods($self->bindoc_dirs, exclude => [ qr/\.bat$/ ])}
2321     or die "Couldn't find any POD files to test\n";
2322
2323   { package Module::Build::PodTester;  # Don't want to pollute the main namespace
2324     Test::Pod->import( tests => scalar @files );
2325     pod_file_ok($_) foreach @files;
2326   }
2327 }
2328
2329 sub ACTION_testpodcoverage {
2330   my $self = shift;
2331
2332   $self->depends_on('docs');
2333
2334   eval q{use Test::Pod::Coverage 1.00; 1}
2335     or die "The 'testpodcoverage' action requires ",
2336            "Test::Pod::Coverage version 1.00";
2337
2338   all_pod_coverage_ok();
2339 }
2340
2341 sub ACTION_docs {
2342   my $self = shift;
2343
2344   $self->depends_on('code');
2345   $self->depends_on('manpages', 'html');
2346 }
2347
2348 # Given a file type, will return true if the file type would normally
2349 # be installed when neither install-base nor prefix has been set.
2350 # I.e. it will be true only if the path is set from Config.pm or
2351 # set explicitly by the user via install-path.
2352 sub _is_default_installable {
2353   my $self = shift;
2354   my $type = shift;
2355   return ( $self->install_destination($type) &&
2356            ( $self->install_path($type) ||
2357              $self->install_sets($self->installdirs)->{$type} )
2358          ) ? 1 : 0;
2359 }
2360
2361 sub ACTION_manpages {
2362   my $self = shift;
2363
2364   return unless $self->_mb_feature('manpage_support');
2365
2366   $self->depends_on('code');
2367
2368   foreach my $type ( qw(bin lib) ) {
2369     my $files = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2370                                    exclude => [ qr/\.bat$/ ] );
2371     next unless %$files;
2372
2373     my $sub = $self->can("manify_${type}_pods");
2374     next unless defined( $sub );
2375
2376     if ( $self->invoked_action eq 'manpages' ) {
2377       $self->$sub();
2378     } elsif ( $self->_is_default_installable("${type}doc") ) {
2379       $self->$sub();
2380     }
2381   }
2382
2383 }
2384
2385 sub manify_bin_pods {
2386   my $self    = shift;
2387
2388   my $files   = $self->_find_pods( $self->{properties}{bindoc_dirs},
2389                                    exclude => [ qr/\.bat$/ ] );
2390   return unless keys %$files;
2391
2392   my $mandir = File::Spec->catdir( $self->blib, 'bindoc' );
2393   File::Path::mkpath( $mandir, 0, 0777 );
2394
2395   require Pod::Man;
2396   foreach my $file (keys %$files) {
2397     # Pod::Simple based parsers only support one document per instance.
2398     # This is expected to change in a future version (Pod::Simple > 3.03).
2399     my $parser  = Pod::Man->new( section => 1 ); # binaries go in section 1
2400     my $manpage = $self->man1page_name( $file ) . '.' .
2401                   $self->config( 'man1ext' );
2402     my $outfile = File::Spec->catfile($mandir, $manpage);
2403     next if $self->up_to_date( $file, $outfile );
2404     $self->log_info("Manifying $file -> $outfile\n");
2405     $parser->parse_from_file( $file, $outfile );
2406     $files->{$file} = $outfile;
2407   }
2408 }
2409
2410 sub manify_lib_pods {
2411   my $self    = shift;
2412
2413   my $files   = $self->_find_pods($self->{properties}{libdoc_dirs});
2414   return unless keys %$files;
2415
2416   my $mandir = File::Spec->catdir( $self->blib, 'libdoc' );
2417   File::Path::mkpath( $mandir, 0, 0777 );
2418
2419   require Pod::Man;
2420   while (my ($file, $relfile) = each %$files) {
2421     # Pod::Simple based parsers only support one document per instance.
2422     # This is expected to change in a future version (Pod::Simple > 3.03).
2423     my $parser  = Pod::Man->new( section => 3 ); # libraries go in section 3
2424     my $manpage = $self->man3page_name( $relfile ) . '.' .
2425                   $self->config( 'man3ext' );
2426     my $outfile = File::Spec->catfile( $mandir, $manpage);
2427     next if $self->up_to_date( $file, $outfile );
2428     $self->log_info("Manifying $file -> $outfile\n");
2429     $parser->parse_from_file( $file, $outfile );
2430     $files->{$file} = $outfile;
2431   }
2432 }
2433
2434 sub _find_pods {
2435   my ($self, $dirs, %args) = @_;
2436   my %files;
2437   foreach my $spec (@$dirs) {
2438     my $dir = $self->localize_dir_path($spec);
2439     next unless -e $dir;
2440     FILE: foreach my $file ( @{ $self->rscan_dir( $dir ) } ) {
2441       foreach my $regexp ( @{ $args{exclude} } ) {
2442         next FILE if $file =~ $regexp;
2443       }
2444       $files{$file} = File::Spec->abs2rel($file, $dir) if $self->contains_pod( $file )
2445     }
2446   }
2447   return \%files;
2448 }
2449
2450 sub contains_pod {
2451   my ($self, $file) = @_;
2452   return '' unless -T $file;  # Only look at text files
2453
2454   my $fh = IO::File->new( $file ) or die "Can't open $file: $!";
2455   while (my $line = <$fh>) {
2456     return 1 if $line =~ /^\=(?:head|pod|item)/;
2457   }
2458
2459   return '';
2460 }
2461
2462 sub ACTION_html {
2463   my $self = shift;
2464
2465   return unless $self->_mb_feature('HTML_support');
2466
2467   $self->depends_on('code');
2468
2469   foreach my $type ( qw(bin lib) ) {
2470     my $files = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2471                                    exclude => [ qr/\.(?:bat|com|html)$/ ] );
2472     next unless %$files;
2473
2474     if ( $self->invoked_action eq 'html' ) {
2475       $self->htmlify_pods( $type );
2476     } elsif ( $self->_is_default_installable("${type}html") ) {
2477       $self->htmlify_pods( $type );
2478     }
2479   }
2480
2481 }
2482
2483
2484 # 1) If it's an ActiveState perl install, we need to run
2485 #    ActivePerl::DocTools->UpdateTOC;
2486 # 2) Links to other modules are not being generated
2487 sub htmlify_pods {
2488   my $self = shift;
2489   my $type = shift;
2490   my $htmldir = shift || File::Spec->catdir($self->blib, "${type}html");
2491
2492   require Module::Build::PodParser;
2493   require Pod::Html;
2494
2495   $self->add_to_cleanup('pod2htm*');
2496
2497   my $pods = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2498                                 exclude => [ qr/\.(?:bat|com|html)$/ ] );
2499   next unless %$pods;  # nothing to do
2500
2501   unless ( -d $htmldir ) {
2502     File::Path::mkpath($htmldir, 0, 0755)
2503       or die "Couldn't mkdir $htmldir: $!";
2504   }
2505
2506   my @rootdirs = ($type eq 'bin') ? qw(bin) :
2507       $self->installdirs eq 'core' ? qw(lib) : qw(site lib);
2508
2509   my $podpath = join ':',
2510                 map  $_->[1],
2511                 grep -e $_->[0],
2512                 map  [File::Spec->catdir($self->blib, $_), $_],
2513                 qw( script lib );
2514
2515   foreach my $pod ( keys %$pods ) {
2516
2517     my ($name, $path) = File::Basename::fileparse($pods->{$pod},
2518                                                   qr{\.(?:pm|plx?|pod)$});
2519     my @dirs = File::Spec->splitdir( File::Spec->canonpath( $path ) );
2520     pop( @dirs ) if $dirs[-1] eq File::Spec->curdir;
2521
2522     my $fulldir = File::Spec->catfile($htmldir, @rootdirs, @dirs);
2523     my $outfile = File::Spec->catfile($fulldir, "${name}.html");
2524     my $infile  = File::Spec->abs2rel($pod);
2525
2526     next if $self->up_to_date($infile, $outfile);
2527
2528     unless ( -d $fulldir ){
2529       File::Path::mkpath($fulldir, 0, 0755)
2530         or die "Couldn't mkdir $fulldir: $!";
2531     }
2532
2533     my $path2root = join( '/', ('..') x (@rootdirs+@dirs) );
2534     my $htmlroot = join( '/',
2535                          ($path2root,
2536                           $self->installdirs eq 'core' ? () : qw(site) ) );
2537
2538     my $fh = IO::File->new($infile) or die "Can't read $infile: $!";
2539     my $abstract = Module::Build::PodParser->new(fh => $fh)->get_abstract();
2540
2541     my $title = join( '::', (@dirs, $name) );
2542     $title .= " - $abstract" if $abstract;
2543
2544     my @opts = (
2545                 '--flush',
2546                 "--title=$title",
2547                 "--podpath=$podpath",
2548                 "--infile=$infile",
2549                 "--outfile=$outfile",
2550                 '--podroot=' . $self->blib,
2551                 "--htmlroot=$htmlroot",
2552                );
2553
2554     if ( eval{Pod::Html->VERSION(1.03)} ) {
2555       push( @opts, ('--header', '--backlink=Back to Top') );
2556       push( @opts, "--css=$path2root/" . $self->html_css) if $self->html_css;
2557     }
2558
2559     $self->log_info("HTMLifying $infile -> $outfile\n");
2560     $self->log_verbose("pod2html @opts\n");
2561     Pod::Html::pod2html(@opts); # or warn "pod2html @opts failed: $!";
2562   }
2563
2564 }
2565
2566 # Adapted from ExtUtils::MM_Unix
2567 sub man1page_name {
2568   my $self = shift;
2569   return File::Basename::basename( shift );
2570 }
2571
2572 # Adapted from ExtUtils::MM_Unix and Pod::Man
2573 # Depending on M::B's dependency policy, it might make more sense to refactor
2574 # Pod::Man::begin_pod() to extract a name() methods, and use them...
2575 #    -spurkis
2576 sub man3page_name {
2577   my $self = shift;
2578   my ($vol, $dirs, $file) = File::Spec->splitpath( shift );
2579   my @dirs = File::Spec->splitdir( File::Spec->canonpath($dirs) );
2580
2581   # Remove known exts from the base name
2582   $file =~ s/\.p(?:od|m|l)\z//i;
2583
2584   return join( $self->manpage_separator, @dirs, $file );
2585 }
2586
2587 sub manpage_separator {
2588   return '::';
2589 }
2590
2591 # For systems that don't have 'diff' executable, should use Algorithm::Diff
2592 sub ACTION_diff {
2593   my $self = shift;
2594   $self->depends_on('build');
2595   my $local_lib = File::Spec->rel2abs('lib');
2596   my @myINC = grep {$_ ne $local_lib} @INC;
2597
2598   # The actual install destination might not be in @INC, so check there too.
2599   push @myINC, map $self->install_destination($_), qw(lib arch);
2600
2601   my @flags = @{$self->{args}{ARGV}};
2602   @flags = $self->split_like_shell($self->{args}{flags} || '') unless @flags;
2603
2604   my $installmap = $self->install_map;
2605   delete $installmap->{read};
2606   delete $installmap->{write};
2607
2608   my $text_suffix = qr{\.(pm|pod)$};
2609
2610   while (my $localdir = each %$installmap) {
2611     my @localparts = File::Spec->splitdir($localdir);
2612     my $files = $self->rscan_dir($localdir, sub {-f});
2613
2614     foreach my $file (@$files) {
2615       my @parts = File::Spec->splitdir($file);
2616       @parts = @parts[@localparts .. $#parts]; # Get rid of blib/lib or similar
2617
2618       my $installed = Module::Build::ModuleInfo->find_module_by_name(
2619                         join('::', @parts), \@myINC );
2620       if (not $installed) {
2621         print "Only in lib: $file\n";
2622         next;
2623       }
2624
2625       my $status = File::Compare::compare($installed, $file);
2626       next if $status == 0;  # Files are the same
2627       die "Can't compare $installed and $file: $!" if $status == -1;
2628
2629       if ($file =~ $text_suffix) {
2630         $self->do_system('diff', @flags, $installed, $file);
2631       } else {
2632         print "Binary files $file and $installed differ\n";
2633       }
2634     }
2635   }
2636 }
2637
2638 sub ACTION_pure_install {
2639   shift()->depends_on('install');
2640 }
2641
2642 sub ACTION_install {
2643   my ($self) = @_;
2644   require ExtUtils::Install;
2645   $self->depends_on('build');
2646   ExtUtils::Install::install($self->install_map, !$self->quiet, 0, $self->{args}{uninst}||0);
2647 }
2648
2649 sub ACTION_fakeinstall {
2650   my ($self) = @_;
2651   require ExtUtils::Install;
2652   $self->depends_on('build');
2653   ExtUtils::Install::install($self->install_map, !$self->quiet, 1, $self->{args}{uninst}||0);
2654 }
2655
2656 sub ACTION_versioninstall {
2657   my ($self) = @_;
2658
2659   die "You must have only.pm 0.25 or greater installed for this operation: $@\n"
2660     unless eval { require only; 'only'->VERSION(0.25); 1 };
2661
2662   $self->depends_on('build');
2663
2664   my %onlyargs = map {exists($self->{args}{$_}) ? ($_ => $self->{args}{$_}) : ()}
2665     qw(version versionlib);
2666   only::install::install(%onlyargs);
2667 }
2668
2669 sub ACTION_clean {
2670   my ($self) = @_;
2671   foreach my $item (map glob($_), $self->cleanup) {
2672     $self->delete_filetree($item);
2673   }
2674 }
2675
2676 sub ACTION_realclean {
2677   my ($self) = @_;
2678   $self->depends_on('clean');
2679   $self->delete_filetree($self->config_dir, $self->build_script);
2680 }
2681
2682 sub ACTION_ppd {
2683   my ($self) = @_;
2684   require Module::Build::PPMMaker;
2685   my $ppd = Module::Build::PPMMaker->new();
2686   my $file = $ppd->make_ppd(%{$self->{args}}, build => $self);
2687   $self->add_to_cleanup($file);
2688 }
2689
2690 sub ACTION_ppmdist {
2691   my ($self) = @_;
2692
2693   $self->depends_on( 'build' );
2694
2695   my $ppm = $self->ppm_name;
2696   $self->delete_filetree( $ppm );
2697   $self->log_info( "Creating $ppm\n" );
2698   $self->add_to_cleanup( $ppm, "$ppm.tar.gz" );
2699
2700   my %types = ( # translate types/dirs to those expected by ppm
2701     lib     => 'lib',
2702     arch    => 'arch',
2703     bin     => 'bin',
2704     script  => 'script',
2705     bindoc  => 'man1',
2706     libdoc  => 'man3',
2707     binhtml => undef,
2708     libhtml => undef,
2709   );
2710
2711   foreach my $type ($self->install_types) {
2712     next if exists( $types{$type} ) && !defined( $types{$type} );
2713
2714     my $dir = File::Spec->catdir( $self->blib, $type );
2715     next unless -e $dir;
2716
2717     my $files = $self->rscan_dir( $dir );
2718     foreach my $file ( @$files ) {
2719       next unless -f $file;
2720       my $rel_file =
2721         File::Spec->abs2rel( File::Spec->rel2abs( $file ),
2722                              File::Spec->rel2abs( $dir  ) );
2723       my $to_file  =
2724         File::Spec->catdir( $ppm, 'blib',
2725                             exists( $types{$type} ) ? $types{$type} : $type,
2726                             $rel_file );
2727       $self->copy_if_modified( from => $file, to => $to_file );
2728     }
2729   }
2730
2731   foreach my $type ( qw(bin lib) ) {
2732     local $self->{properties}{html_css} = 'Active.css';
2733     $self->htmlify_pods( $type, File::Spec->catdir($ppm, 'blib', 'html') );
2734   }
2735
2736   # create a tarball;
2737   # the directory tar'ed must be blib so we need to do a chdir first
2738   my $start_wd = $self->cwd;
2739   chdir( $ppm ) or die "Can't chdir to $ppm";
2740   $self->make_tarball( 'blib', File::Spec->catfile( $start_wd, $ppm ) );
2741   chdir( $start_wd ) or die "Can't chdir to $start_wd";
2742
2743   $self->depends_on( 'ppd' );
2744
2745   $self->delete_filetree( $ppm );
2746 }
2747
2748 sub ACTION_dist {
2749   my ($self) = @_;
2750
2751   $self->depends_on('distdir');
2752
2753   my $dist_dir = $self->dist_dir;
2754
2755   $self->make_tarball($dist_dir);
2756   $self->delete_filetree($dist_dir);
2757 }
2758
2759 sub ACTION_distcheck {
2760   my ($self) = @_;
2761
2762   require ExtUtils::Manifest;
2763   local $^W; # ExtUtils::Manifest is not warnings clean.
2764   my ($missing, $extra) = ExtUtils::Manifest::fullcheck();
2765
2766   return unless @$missing || @$extra;
2767
2768   my $msg = "MANIFEST appears to be out of sync with the distribution\n";
2769   if ( $self->invoked_action eq 'distcheck' ) {
2770     die $msg;
2771   } else {
2772     warn $msg;
2773   }
2774 }
2775
2776 sub _add_to_manifest {
2777   my ($self, $manifest, $lines) = @_;
2778   $lines = [$lines] unless ref $lines;
2779
2780   my $existing_files = $self->_read_manifest($manifest);
2781   return unless defined( $existing_files );
2782
2783   @$lines = grep {!exists $existing_files->{$_}} @$lines
2784     or return;
2785
2786   my $mode = (stat $manifest)[2];
2787   chmod($mode | 0222, $manifest) or die "Can't make $manifest writable: $!";
2788
2789   my $fh = IO::File->new("< $manifest") or die "Can't read $manifest: $!";
2790   my $last_line = (<$fh>)[-1] || "\n";
2791   my $has_newline = $last_line =~ /\n$/;
2792   $fh->close;
2793
2794   $fh = IO::File->new(">> $manifest") or die "Can't write to $manifest: $!";
2795   print $fh "\n" unless $has_newline;
2796   print $fh map "$_\n", @$lines;
2797   close $fh;
2798   chmod($mode, $manifest);
2799
2800   $self->log_info(map "Added to $manifest: $_\n", @$lines);
2801 }
2802
2803 sub _sign_dir {
2804   my ($self, $dir) = @_;
2805
2806   unless (eval { require Module::Signature; 1 }) {
2807     $self->log_warn("Couldn't load Module::Signature for 'distsign' action:\n $@\n");
2808     return;
2809   }
2810
2811   # Add SIGNATURE to the MANIFEST
2812   {
2813     my $manifest = File::Spec->catfile($dir, 'MANIFEST');
2814     die "Signing a distribution requires a MANIFEST file" unless -e $manifest;
2815     $self->_add_to_manifest($manifest, "SIGNATURE    Added here by Module::Build");
2816   }
2817
2818   # We protect the signing with an eval{} to make sure we get back to
2819   # the right directory after a signature failure.  Would be nice if
2820   # Module::Signature took a directory argument.
2821
2822   my $start_dir = $self->cwd;
2823   chdir $dir or die "Can't chdir() to $dir: $!";
2824   eval {local $Module::Signature::Quiet = 1; Module::Signature::sign()};
2825   my @err = $@ ? ($@) : ();
2826   chdir $start_dir or push @err, "Can't chdir() back to $start_dir: $!";
2827   die join "\n", @err if @err;
2828 }
2829
2830 sub ACTION_distsign {
2831   my ($self) = @_;
2832   {
2833     local $self->{properties}{sign} = 0;  # We'll sign it ourselves
2834     $self->depends_on('distdir') unless -d $self->dist_dir;
2835   }
2836   $self->_sign_dir($self->dist_dir);
2837 }
2838
2839 sub ACTION_skipcheck {
2840   my ($self) = @_;
2841
2842   require ExtUtils::Manifest;
2843   local $^W; # ExtUtils::Manifest is not warnings clean.
2844   ExtUtils::Manifest::skipcheck();
2845 }
2846
2847 sub ACTION_distclean {
2848   my ($self) = @_;
2849
2850   $self->depends_on('realclean');
2851   $self->depends_on('distcheck');
2852 }
2853
2854 sub do_create_makefile_pl {
2855   my $self = shift;
2856   require Module::Build::Compat;
2857   $self->delete_filetree('Makefile.PL');
2858   $self->log_info("Creating Makefile.PL\n");
2859   Module::Build::Compat->create_makefile_pl($self->create_makefile_pl, $self, @_);
2860   $self->_add_to_manifest('MANIFEST', 'Makefile.PL');
2861 }
2862
2863 sub do_create_readme {
2864   my $self = shift;
2865   $self->delete_filetree('README');
2866
2867   my $docfile = $self->_main_docfile;
2868   unless ( $docfile ) {
2869     $self->log_warn(<<EOF);
2870 Cannot create README: can't determine which file contains documentation;
2871 Must supply either 'dist_version_from', or 'module_name' parameter.
2872 EOF
2873     return;
2874   }
2875
2876   if ( eval {require Pod::Readme; 1} ) {
2877     $self->log_info("Creating README using Pod::Readme\n");
2878
2879     my $parser = Pod::Readme->new;
2880     $parser->parse_from_file($docfile, 'README', @_);
2881
2882   } elsif ( eval {require Pod::Text; 1} ) {
2883     $self->log_info("Creating README using Pod::Text\n");
2884
2885     my $fh = IO::File->new('> README');
2886     if ( defined($fh) ) {
2887       local $^W = 0;
2888       no strict "refs";
2889
2890       # work around bug in Pod::Text 3.01, which expects
2891       # Pod::Simple::parse_file to take input and output filehandles
2892       # when it actually only takes an input filehandle
2893
2894       my $old_parse_file;
2895       $old_parse_file = \&{"Pod::Simple::parse_file"}
2896         and
2897       local *{"Pod::Simple::parse_file"} = sub {
2898         my $self = shift;
2899         $self->output_fh($_[1]) if $_[1];
2900         $self->$old_parse_file($_[0]);
2901       }
2902         if $Pod::Text::VERSION
2903           == 3.01; # Split line to avoid evil version-finder
2904
2905       Pod::Text::pod2text( $docfile, $fh );
2906
2907       $fh->close;
2908     } else {
2909       $self->log_warn(
2910         "Cannot create 'README' file: Can't open file for writing\n" );
2911       return;
2912     }
2913
2914   } else {
2915     $self->log_warn("Can't load Pod::Readme or Pod::Text to create README\n");
2916     return;
2917   }
2918
2919   $self->_add_to_manifest('MANIFEST', 'README');
2920 }
2921
2922 sub _main_docfile {
2923   my $self = shift;
2924   if ( my $pm_file = $self->dist_version_from ) {
2925     (my $pod_file = $pm_file) =~ s/.pm$/.pod/;
2926     return (-e $pod_file ? $pod_file : $pm_file);
2927   } else {
2928     return undef;
2929   }
2930 }
2931
2932 sub ACTION_distdir {
2933   my ($self) = @_;
2934
2935   $self->depends_on('distmeta');
2936
2937   my $dist_files = $self->_read_manifest('MANIFEST')
2938     or die "Can't create distdir without a MANIFEST file - run 'manifest' action first";
2939   delete $dist_files->{SIGNATURE};  # Don't copy, create a fresh one
2940   die "No files found in MANIFEST - try running 'manifest' action?\n"
2941     unless ($dist_files and keys %$dist_files);
2942   my $metafile = $self->metafile;
2943   $self->log_warn("*** Did you forget to add $metafile to the MANIFEST?\n")
2944     unless exists $dist_files->{$metafile};
2945
2946   my $dist_dir = $self->dist_dir;
2947   $self->delete_filetree($dist_dir);
2948   $self->log_info("Creating $dist_dir\n");
2949   $self->add_to_cleanup($dist_dir);
2950
2951   foreach my $file (keys %$dist_files) {
2952     my $new = $self->copy_if_modified(from => $file, to_dir => $dist_dir, verbose => 0);
2953   }
2954
2955   $self->_sign_dir($dist_dir) if $self->{properties}{sign};
2956 }
2957
2958 sub ACTION_disttest {
2959   my ($self) = @_;
2960
2961   $self->depends_on('distdir');
2962
2963   my $start_dir = $self->cwd;
2964   my $dist_dir = $self->dist_dir;
2965   chdir $dist_dir or die "Cannot chdir to $dist_dir: $!";
2966   # XXX could be different names for scripts
2967
2968   $self->run_perl_script('Build.PL') # XXX Should this be run w/ --nouse-rcfile
2969       or die "Error executing 'Build.PL' in dist directory: $!";
2970   $self->run_perl_script('Build')
2971       or die "Error executing 'Build' in dist directory: $!";
2972   $self->run_perl_script('Build', [], ['test'])
2973       or die "Error executing 'Build test' in dist directory";
2974   chdir $start_dir;
2975 }
2976
2977 sub _write_default_maniskip {
2978   my $self = shift;
2979   my $file = shift || 'MANIFEST.SKIP';
2980   my $fh = IO::File->new("> $file")
2981     or die "Can't open $file: $!";
2982
2983   # This is derived from MakeMaker's default MANIFEST.SKIP file with
2984   # some new entries
2985
2986   print $fh <<'EOF';
2987 # Avoid version control files.
2988 \bRCS\b
2989 \bCVS\b
2990 ,v$
2991 \B\.svn\b
2992 \B\.cvsignore$
2993
2994 # Avoid Makemaker generated and utility files.
2995 \bMakefile$
2996 \bblib
2997 \bMakeMaker-\d
2998 \bpm_to_blib$
2999 \bblibdirs$
3000 ^MANIFEST\.SKIP$
3001
3002 # Avoid Module::Build generated and utility files.
3003 \bBuild$
3004 \bBuild.bat$
3005 \b_build
3006
3007 # Avoid Devel::Cover generated files
3008 \bcover_db
3009
3010 # Avoid temp and backup files.
3011 ~$
3012 \.tmp$
3013 \.old$
3014 \.bak$
3015 \#$
3016 \.#
3017 \.rej$
3018
3019 # Avoid OS-specific files/dirs
3020 #   Mac OSX metadata
3021 \B\.DS_Store
3022 #   Mac OSX SMB mount metadata files
3023 \B\._
3024 # Avoid archives of this distribution
3025 EOF
3026
3027   # Skip, for example, 'Module-Build-0.27.tar.gz'
3028   print $fh '\b'.$self->dist_name.'-[\d\.\_]+'."\n";
3029
3030   $fh->close();
3031 }
3032
3033 sub ACTION_manifest {
3034   my ($self) = @_;
3035
3036   my $maniskip = 'MANIFEST.SKIP';
3037   unless ( -e 'MANIFEST' || -e $maniskip ) {
3038     $self->log_warn("File '$maniskip' does not exist: Creating a default '$maniskip'\n");
3039     $self->_write_default_maniskip($maniskip);
3040   }
3041
3042   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
3043   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
3044   ExtUtils::Manifest::mkmanifest();
3045 }
3046
3047 sub dist_dir {
3048   my ($self) = @_;
3049   return "$self->{properties}{dist_name}-$self->{properties}{dist_version}";
3050 }
3051
3052 sub ppm_name {
3053   my $self = shift;
3054   return 'PPM-' . $self->dist_dir;
3055 }
3056
3057 sub _files_in {
3058   my ($self, $dir) = @_;
3059   return unless -d $dir;
3060
3061   local *DH;
3062   opendir DH, $dir or die "Can't read directory $dir: $!";
3063
3064   my @files;
3065   while (defined (my $file = readdir DH)) {
3066     my $full_path = File::Spec->catfile($dir, $file);
3067     next if -d $full_path;
3068     push @files, $full_path;
3069   }
3070   return @files;
3071 }
3072
3073 sub script_files {
3074   my $self = shift;
3075
3076   for ($self->{properties}{script_files}) {
3077     $_ = shift if @_;
3078     next unless $_;
3079
3080     # Always coerce into a hash
3081     return $_ if UNIVERSAL::isa($_, 'HASH');
3082     return $_ = { map {$_,1} @$_ } if UNIVERSAL::isa($_, 'ARRAY');
3083
3084     die "'script_files' must be a hashref, arrayref, or string" if ref();
3085
3086     return $_ = { map {$_,1} $self->_files_in( $_ ) } if -d $_;
3087     return $_ = {$_ => 1};
3088   }
3089
3090   return $_ = { map {$_,1} $self->_files_in( File::Spec->catdir( $self->base_dir, 'bin' ) ) };
3091 }
3092 BEGIN { *scripts = \&script_files; }
3093
3094 {
3095   my %licenses =
3096     (
3097      perl => 'http://dev.perl.org/licenses/',
3098      gpl => 'http://www.opensource.org/licenses/gpl-license.php',
3099      apache => 'http://apache.org/licenses/LICENSE-2.0',
3100      artistic => 'http://opensource.org/licenses/artistic-license.php',
3101      lgpl => 'http://opensource.org/licenses/artistic-license.php',
3102      bsd => 'http://www.opensource.org/licenses/bsd-license.php',
3103      gpl => 'http://www.opensource.org/licenses/gpl-license.php',
3104      mit => 'http://opensource.org/licenses/mit-license.php',
3105      mozilla => 'http://opensource.org/licenses/mozilla1.1.php',
3106      open_source => undef,
3107      unrestricted => undef,
3108      restrictive => undef,
3109      unknown => undef,
3110     );
3111   sub valid_licenses {
3112     return \%licenses;
3113   }
3114 }
3115
3116 sub _hash_merge {
3117   my ($self, $h, $k, $v) = @_;
3118   if (ref $h->{$k} eq 'ARRAY') {
3119     push @{$h->{$k}}, ref $v ? @$v : $v;
3120   } elsif (ref $h->{$k} eq 'HASH') {
3121     $h->{$k}{$_} = $v->{$_} foreach keys %$v;
3122   } else {
3123     $h->{$k} = $v;
3124   }
3125 }
3126
3127 sub ACTION_distmeta {
3128   my ($self) = @_;
3129
3130   $self->do_create_makefile_pl if $self->create_makefile_pl;
3131   $self->do_create_readme if $self->create_readme;
3132   $self->do_create_metafile;
3133 }
3134
3135 sub do_create_metafile {
3136   my $self = shift;
3137   return if $self->{wrote_metadata};
3138
3139   my $p = $self->{properties};
3140   my $metafile = $self->metafile;
3141
3142   unless ($p->{license}) {
3143     $self->log_warn("No license specified, setting license = 'unknown'\n");
3144     $p->{license} = 'unknown';
3145   }
3146   unless (exists $self->valid_licenses->{ $p->{license} }) {
3147     die "Unknown license type '$p->{license}'";
3148   }
3149
3150   # If we're in the distdir, the metafile may exist and be non-writable.
3151   $self->delete_filetree($metafile);
3152   $self->log_info("Creating $metafile\n");
3153
3154   # Since we're building ourself, we have to do some special stuff
3155   # here: the ConfigData module is found in blib/lib.
3156   local @INC = @INC;
3157   if (($self->module_name || '') eq 'Module::Build') {
3158     $self->depends_on('config_data');
3159     push @INC, File::Spec->catdir($self->blib, 'lib');
3160   }
3161
3162   $self->write_metafile;
3163 }
3164
3165 sub write_metafile {
3166   my $self = shift;
3167   my $metafile = $self->metafile;
3168
3169   if ($self->_mb_feature('YAML_support')) {
3170     require YAML;
3171     require YAML::Node;
3172
3173     # We use YAML::Node to get the order nice in the YAML file.
3174     $self->prepare_metadata( my $node = YAML::Node->new({}) );
3175
3176     # YAML API changed after version 0.30
3177     my $yaml_sub = $YAML::VERSION le '0.30' ? \&YAML::StoreFile : \&YAML::DumpFile;
3178     $self->{wrote_metadata} = $yaml_sub->($metafile, $node );
3179
3180   } else {
3181     require Module::Build::YAML;
3182     my (%node, @order_keys);
3183     $self->prepare_metadata(\%node, \@order_keys);
3184     $node{_order} = \@order_keys;
3185     &Module::Build::YAML::DumpFile($metafile, \%node);
3186     $self->{wrote_metadata} = 1;
3187   }
3188
3189   $self->_add_to_manifest('MANIFEST', $metafile);
3190 }
3191
3192 sub prepare_metadata {
3193   my ($self, $node, $keys) = @_;
3194   my $p = $self->{properties};
3195
3196   # A little helper sub
3197   my $add_node = sub {
3198     my ($name, $val) = @_;
3199     $node->{$name} = $val;
3200     push @$keys, $name if $keys;
3201   };
3202
3203   foreach (qw(dist_name dist_version dist_author dist_abstract license)) {
3204     (my $name = $_) =~ s/^dist_//;
3205     $add_node->($name, $self->$_());
3206     die "ERROR: Missing required field '$_' for META.yml\n"
3207       unless defined($node->{$name}) && length($node->{$name});
3208   }
3209
3210   if (defined( $self->license ) &&
3211       defined( my $url = $self->valid_licenses->{ $self->license } )) {
3212     $node->{resources}{license} = $url;
3213   }
3214
3215   foreach ( @{$self->prereq_action_types} ) {
3216     if (exists $p->{$_} and keys %{ $p->{$_} }) {
3217       $add_node->($_, $p->{$_});
3218     }
3219   }
3220
3221   if (exists $p->{dynamic_config}) {
3222     $add_node->('dynamic_config', $p->{dynamic_config});
3223   }
3224   my $pkgs = eval { $self->find_dist_packages };
3225   if ($@) {
3226     $self->log_warn("WARNING: Possible missing or corrupt 'MANIFEST' file.\n" .
3227                     "Nothing to enter for 'provides' field in META.yml\n");
3228   } else {
3229     $node->{provides} = $pkgs if %$pkgs;
3230   }
3231 ;
3232   if (exists $p->{no_index}) {
3233     $add_node->('no_index', $p->{no_index});
3234   }
3235
3236   $add_node->('generated_by', "Module::Build version $Module::Build::VERSION");
3237
3238   $add_node->('meta-spec',
3239               {version => '1.2',
3240                url     => 'http://module-build.sourceforge.net/META-spec-v1.2.html',
3241               });
3242
3243   while (my($k, $v) = each %{$self->meta_add}) {
3244     $add_node->($k, $v);
3245   }
3246
3247   while (my($k, $v) = each %{$self->meta_merge}) {
3248     $self->_hash_merge($node, $k, $v);
3249   }
3250
3251   return $node;
3252 }
3253
3254 sub _read_manifest {
3255   my ($self, $file) = @_;
3256   return undef unless -e $file;
3257
3258   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
3259   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
3260   return scalar ExtUtils::Manifest::maniread($file);
3261 }
3262
3263 sub find_dist_packages {
3264   my $self = shift;
3265
3266   # Only packages in .pm files are candidates for inclusion here.
3267   # Only include things in the MANIFEST, not things in developer's
3268   # private stock.
3269
3270   my $manifest = $self->_read_manifest('MANIFEST')
3271     or die "Can't find dist packages without a MANIFEST file - run 'manifest' action first";
3272
3273   # Localize
3274   my %dist_files = map { $self->localize_file_path($_) => $_ }
3275                        keys %$manifest;
3276
3277   my @pm_files = grep {exists $dist_files{$_}} keys %{ $self->find_pm_files };
3278
3279   # First, we enumerate all packages & versions,
3280   # seperating into primary & alternative candidates
3281   my( %prime, %alt );
3282   foreach my $file (@pm_files) {
3283     next if $dist_files{$file} =~ m{^t/};  # Skip things in t/
3284
3285     my @path = split( /\//, $dist_files{$file} );
3286     (my $prime_package = join( '::', @path[1..$#path] )) =~ s/\.pm$//;
3287
3288     my $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
3289
3290     foreach my $package ( $pm_info->packages_inside ) {
3291       next if $package eq 'main';  # main can appear numerous times, ignore
3292       next if grep /^_/, split( /::/, $package ); # private package, ignore
3293
3294       my $version = $pm_info->version( $package );
3295
3296       if ( $package eq $prime_package ) {
3297         if ( exists( $prime{$package} ) ) {
3298           # M::B::ModuleInfo will handle this conflict
3299           die "Unexpected conflict in '$package'; multiple versions found.\n";
3300         } else {
3301           $prime{$package}{file} = $dist_files{$file};
3302           $prime{$package}{version} = $version if defined( $version );
3303         }
3304       } else {
3305         push( @{$alt{$package}}, {
3306                                   file    => $dist_files{$file},
3307                                   version => $version,
3308                                  } );
3309       }
3310     }
3311   }
3312
3313   # Then we iterate over all the packages found above, identifying conflicts
3314   # and selecting the "best" candidate for recording the file & version
3315   # for each package.
3316   foreach my $package ( keys( %alt ) ) {
3317     my $result = $self->_resolve_module_versions( $alt{$package} );
3318
3319     if ( exists( $prime{$package} ) ) { # primary package selected
3320
3321       if ( $result->{err} ) {
3322         # Use the selected primary package, but there are conflicting
3323         # errors amoung multiple alternative packages that need to be
3324         # reported
3325         $self->log_warn(
3326           "Found conflicting versions for package '$package'\n" .
3327           "  $prime{$package}{file} ($prime{$package}{version})\n" .
3328           $result->{err}
3329         );
3330
3331       } elsif ( defined( $result->{version} ) ) {
3332         # There is a primary package selected, and exactly one
3333         # alternative package
3334
3335         if ( exists( $prime{$package}{version} ) &&
3336              defined( $prime{$package}{version} ) ) {
3337           # Unless the version of the primary package agrees with the
3338           # version of the alternative package, report a conflict
3339           if ( $self->compare_versions( $prime{$package}{version}, '!=',
3340                                         $result->{version} ) ) {
3341             $self->log_warn(
3342               "Found conflicting versions for package '$package'\n" .
3343               "  $prime{$package}{file} ($prime{$package}{version})\n" .
3344               "  $result->{file} ($result->{version})\n"
3345             );
3346           }
3347
3348         } else {
3349           # The prime package selected has no version so, we choose to
3350           # use any alternative package that does have a version
3351           $prime{$package}{file}    = $result->{file};
3352           $prime{$package}{version} = $result->{version};
3353         }
3354
3355       } else {
3356         # no alt package found with a version, but we have a prime
3357         # package so we use it whether it has a version or not
3358       }
3359
3360     } else { # No primary package was selected, use the best alternative
3361
3362       if ( $result->{err} ) {
3363         $self->log_warn(
3364           "Found conflicting versions for package '$package'\n" .
3365           $result->{err}
3366         );
3367       }
3368
3369       # Despite possible conflicting versions, we choose to record
3370       # something rather than nothing
3371       $prime{$package}{file}    = $result->{file};
3372       $prime{$package}{version} = $result->{version}
3373           if defined( $result->{version} );
3374     }
3375   }
3376
3377   return \%prime;
3378 }
3379
3380 # seperate out some of the conflict resolution logic from
3381 # $self->find_dist_packages(), above, into a helper function.
3382 #
3383 sub _resolve_module_versions {
3384   my $self = shift;
3385
3386   my $packages = shift;
3387
3388   my( $file, $version );
3389   my $err = '';
3390     foreach my $p ( @$packages ) {
3391       if ( defined( $p->{version} ) ) {
3392         if ( defined( $version ) ) {
3393           if ( $self->compare_versions( $version, '!=', $p->{version} ) ) {
3394             $err .= "  $p->{file} ($p->{version})\n";
3395           } else {
3396             # same version declared multiple times, ignore
3397           }
3398         } else {
3399           $file    = $p->{file};
3400           $version = $p->{version};
3401         }
3402       }
3403       $file ||= $p->{file} if defined( $p->{file} );
3404     }
3405
3406   if ( $err ) {
3407     $err = "  $file ($version)\n" . $err;
3408   }
3409
3410   my %result = (
3411     file    => $file,
3412     version => $version,
3413     err     => $err
3414   );
3415
3416   return \%result;
3417 }
3418
3419 sub make_tarball {
3420   my ($self, $dir, $file) = @_;
3421   $file ||= $dir;
3422
3423   $self->log_info("Creating $file.tar.gz\n");
3424
3425   if ($self->{args}{tar}) {
3426     my $tar_flags = $self->verbose ? 'cvf' : 'cf';
3427     $self->do_system($self->split_like_shell($self->{args}{tar}), $tar_flags, "$file.tar", $dir);
3428     $self->do_system($self->split_like_shell($self->{args}{gzip}), "$file.tar") if $self->{args}{gzip};
3429   } else {
3430     require Archive::Tar;
3431     # Archive::Tar versions >= 1.09 use the following to enable a compatibility
3432     # hack so that the resulting archive is compatible with older clients.
3433     $Archive::Tar::DO_NOT_USE_PREFIX = 0;
3434     my $files = $self->rscan_dir($dir);
3435     Archive::Tar->create_archive("$file.tar.gz", 1, @$files);
3436   }
3437 }
3438
3439 sub install_path {
3440   my $self = shift;
3441   my( $type, $value ) = ( @_, '<empty>' );
3442
3443   Carp::croak( 'Type argument missing' )
3444     unless defined( $type );
3445
3446   my $map = $self->{properties}{install_path};
3447   return $map unless @_;
3448
3449   # delete existing value if $value is literal undef()
3450   unless ( defined( $value ) ) {
3451     delete( $map->{$type} );
3452     return undef;
3453   }
3454
3455   # return existing value if no new $value is given
3456   if ( $value eq '<empty>' ) {
3457     return undef unless exists $map->{$type};
3458     return $map->{$type};
3459   }
3460
3461   # set value if $value is a valid relative path
3462   return $map->{$type} = $value;
3463 }
3464
3465 sub install_base_relpaths {
3466   # Usage: install_base_relpaths(), install_base_relpaths('lib'),
3467   #   or install_base_relpaths('lib' => $value);
3468   my $self = shift;
3469   my $map = $self->{properties}{install_base_relpaths};
3470   return $map unless @_;
3471   return $self->_relpaths($map, @_);
3472 }
3473
3474
3475 # Translated from ExtUtils::MM_Any::init_INSTALL_from_PREFIX
3476 sub prefix_relative {
3477   my ($self, $type) = @_;
3478   my $installdirs = $self->installdirs;
3479
3480   my $relpath = $self->install_sets($installdirs)->{$type};
3481
3482   return $self->_prefixify($relpath,
3483                            $self->original_prefix($installdirs),
3484                            $type,
3485                           );
3486 }
3487
3488 sub _relpaths {
3489   my $self = shift;
3490   my( $map, $type, $value ) = ( @_, '<empty>' );
3491
3492   Carp::croak( 'Type argument missing' )
3493     unless defined( $type );
3494
3495   my @value = ();
3496
3497   # delete existing value if $value is literal undef()
3498   unless ( defined( $value ) ) {
3499     delete( $map->{$type} );
3500     return undef;
3501   }
3502
3503   # return existing value if no new $value is given
3504   elsif ( $value eq '<empty>' ) {
3505     return undef unless exists $map->{$type};
3506     @value = @{ $map->{$type} };
3507   }
3508
3509   # set value if $value is a valid relative path
3510   else {
3511     Carp::croak( "Value must be a relative path" )
3512       if File::Spec::Unix->file_name_is_absolute($value);
3513
3514     @value = split( /\//, $value );
3515     $map->{$type} = \@value;
3516   }
3517
3518   return File::Spec->catdir( @value );
3519 }
3520
3521 # Defaults to use in case the config install paths cannot be prefixified.
3522 sub prefix_relpaths {
3523   # Usage: prefix_relpaths('site'), prefix_relpaths('site', 'lib'),
3524   #   or prefix_relpaths('site', 'lib' => $value);
3525   my $self = shift;
3526   my $installdirs = shift || $self->installdirs;
3527   my $map = $self->{properties}{prefix_relpaths}{$installdirs};
3528   return $map unless @_;
3529   return $self->_relpaths($map, @_);
3530 }
3531
3532
3533 # Translated from ExtUtils::MM_Unix::prefixify()
3534 sub _prefixify {
3535   my($self, $path, $sprefix, $type) = @_;
3536
3537   my $rprefix = $self->prefix;
3538   $rprefix .= '/' if $sprefix =~ m|/$|;
3539
3540   $self->log_verbose("  prefixify $path from $sprefix to $rprefix\n")
3541     if defined( $path ) && length( $path );
3542
3543   if( !defined( $path ) || ( length( $path ) == 0 ) ) {
3544     $self->log_verbose("  no path to prefixify, falling back to default.\n");
3545     return $self->_prefixify_default( $type, $rprefix );
3546   } elsif( !File::Spec->file_name_is_absolute($path) ) {
3547     $self->log_verbose("    path is relative, not prefixifying.\n");
3548   } elsif( $sprefix eq $rprefix ) {
3549     $self->log_verbose("  no new prefix.\n");
3550   } elsif( $path !~ s{^\Q$sprefix\E\b}{}s ) {
3551     $self->log_verbose("    cannot prefixify, falling back to default.\n");
3552     return $self->_prefixify_default( $type, $rprefix );
3553   }
3554
3555   $self->log_verbose("    now $path in $rprefix\n");
3556
3557   return $path;
3558 }
3559
3560 sub _prefixify_default {
3561   my $self = shift;
3562   my $type = shift;
3563   my $rprefix = shift;
3564
3565   my $default = $self->prefix_relpaths($self->installdirs, $type);
3566   if( !$default ) {
3567     $self->log_verbose("    no default install location for type '$type', using prefix '$rprefix'.\n");
3568     return $rprefix;
3569   } else {
3570     return $default;
3571   }
3572 }
3573
3574 sub install_destination {
3575   my ($self, $type) = @_;
3576
3577   return $self->install_path($type) if $self->install_path($type);
3578
3579   if ( $self->install_base ) {
3580     my $relpath = $self->install_base_relpaths($type);
3581     return $relpath ? File::Spec->catdir($self->install_base, $relpath) : undef;
3582   }
3583
3584   if ( $self->prefix ) {
3585     my $relpath = $self->prefix_relative($type);
3586     return $relpath ? File::Spec->catdir($self->prefix, $relpath) : undef;
3587   }
3588
3589   return $self->install_sets($self->installdirs)->{$type};
3590 }
3591
3592 sub install_types {
3593   my $self = shift;
3594
3595   my %types;
3596   if ( $self->install_base ) {
3597     %types = %{$self->install_base_relpaths};
3598   } elsif ( $self->prefix ) {
3599     %types = %{$self->prefix_relpaths};
3600   } else {
3601     %types = %{$self->install_sets($self->installdirs)};
3602   }
3603
3604   %types = (%types, %{$self->install_path});
3605
3606   return sort keys %types;
3607 }
3608
3609 sub install_map {
3610   my ($self, $blib) = @_;
3611   $blib ||= $self->blib;
3612
3613   my( %map, @skipping );
3614   foreach my $type ($self->install_types) {
3615     my $localdir = File::Spec->catdir( $blib, $type );
3616     next unless -e $localdir;
3617
3618     if (my $dest = $self->install_destination($type)) {
3619       $map{$localdir} = $dest;
3620     } else {
3621       push( @skipping, $type );
3622     }
3623   }
3624
3625   $self->log_warn(
3626     "WARNING: Can't figure out install path for types: @skipping\n" .
3627     "Files will not be installed.\n"
3628   ) if @skipping;
3629
3630   # Write the packlist into the same place as ExtUtils::MakeMaker.
3631   if ($self->create_packlist and my $module_name = $self->module_name) {
3632     my $archdir = $self->install_destination('arch');
3633     my @ext = split /::/, $module_name;
3634     $map{write} = File::Spec->catdir($archdir, 'auto', @ext, '.packlist');
3635   }
3636
3637   # Handle destdir
3638   if (length(my $destdir = $self->destdir || '')) {
3639     foreach (keys %map) {
3640       # Need to remove volume from $map{$_} using splitpath, or else
3641       # we'll create something crazy like C:\Foo\Bar\E:\Baz\Quux
3642       my ($volume, $path) = File::Spec->splitpath( $map{$_}, 1 );
3643       $map{$_} = File::Spec->catdir($destdir, $path);
3644     }
3645   }
3646
3647   $map{read} = '';  # To keep ExtUtils::Install quiet
3648
3649   return \%map;
3650 }
3651
3652 sub depends_on {
3653   my $self = shift;
3654   foreach my $action (@_) {
3655     $self->_call_action($action);
3656   }
3657 }
3658
3659 sub rscan_dir {
3660   my ($self, $dir, $pattern) = @_;
3661   my @result;
3662   local $_; # find() can overwrite $_, so protect ourselves
3663   my $subr = !$pattern ? sub {push @result, $File::Find::name} :
3664              !ref($pattern) || (ref $pattern eq 'Regexp') ? sub {push @result, $File::Find::name if /$pattern/} :
3665              ref($pattern) eq 'CODE' ? sub {push @result, $File::Find::name if $pattern->()} :
3666              die "Unknown pattern type";
3667
3668   File::Find::find({wanted => $subr, no_chdir => 1}, $dir);
3669   return \@result;
3670 }
3671
3672 sub delete_filetree {
3673   my $self = shift;
3674   my $deleted = 0;
3675   foreach (@_) {
3676     next unless -e $_;
3677     $self->log_info("Deleting $_\n");
3678     File::Path::rmtree($_, 0, 0);
3679     die "Couldn't remove '$_': $!\n" if -e $_;
3680     $deleted++;
3681   }
3682   return $deleted;
3683 }
3684
3685 sub autosplit_file {
3686   my ($self, $file, $to) = @_;
3687   require AutoSplit;
3688   my $dir = File::Spec->catdir($to, 'lib', 'auto');
3689   AutoSplit::autosplit($file, $dir);
3690 }
3691
3692 sub _cbuilder {
3693   # Returns a CBuilder object
3694
3695   my $self = shift;
3696   my $p = $self->{properties};
3697   return $p->{_cbuilder} if $p->{_cbuilder};
3698   return unless $self->_mb_feature('C_support');
3699
3700   require ExtUtils::CBuilder;
3701   return $p->{_cbuilder} = ExtUtils::CBuilder->new(config => $self->config);
3702 }
3703
3704 sub have_c_compiler {
3705   my ($self) = @_;
3706
3707   my $p = $self->{properties};
3708   return $p->{have_compiler} if defined $p->{have_compiler};
3709
3710   $self->log_verbose("Checking if compiler tools configured... ");
3711   my $b = $self->_cbuilder;
3712   my $have = $b && $b->have_compiler;
3713   $self->log_verbose($have ? "ok.\n" : "failed.\n");
3714   return $p->{have_compiler} = $have;
3715 }
3716
3717 sub compile_c {
3718   my ($self, $file, %args) = @_;
3719   my $b = $self->_cbuilder
3720     or die "Module::Build is not configured with C_support";
3721
3722   my $obj_file = $b->object_file($file);
3723   $self->add_to_cleanup($obj_file);
3724   return $obj_file if $self->up_to_date($file, $obj_file);
3725
3726   $b->compile(source => $file,
3727               defines => $args{defines},
3728               object_file => $obj_file,
3729               include_dirs => $self->include_dirs,
3730               extra_compiler_flags => $self->extra_compiler_flags,
3731              );
3732
3733   return $obj_file;
3734 }
3735
3736 sub link_c {
3737   my ($self, $to, $file_base) = @_;
3738   my $p = $self->{properties}; # For convenience
3739
3740   my $spec = $self->_infer_xs_spec($file_base);
3741
3742   $self->add_to_cleanup($spec->{lib_file});
3743
3744   my $objects = $p->{objects} || [];
3745
3746   return $spec->{lib_file}
3747     if $self->up_to_date([$spec->{obj_file}, @$objects],
3748                          $spec->{lib_file});
3749
3750   my $module_name = $self->module_name;
3751   $module_name  ||= $spec->{module_name};
3752
3753   my $b = $self->_cbuilder
3754     or die "Module::Build is not configured with C_support";
3755   $b->link(
3756     module_name => $module_name,
3757     objects     => [$spec->{obj_file}, @$objects],
3758     lib_file    => $spec->{lib_file},
3759     extra_linker_flags => $p->{extra_linker_flags} );
3760
3761   return $spec->{lib_file};
3762 }
3763
3764 sub compile_xs {
3765   my ($self, $file, %args) = @_;
3766
3767   $self->log_info("$file -> $args{outfile}\n");
3768
3769   if (eval {require ExtUtils::ParseXS; 1}) {
3770
3771     ExtUtils::ParseXS::process_file(
3772                                     filename => $file,
3773                                     prototypes => 0,
3774                                     output => $args{outfile},
3775                                    );
3776   } else {
3777     # Ok, I give up.  Just use backticks.
3778
3779     my $xsubpp = Module::Build::ModuleInfo->find_module_by_name('ExtUtils::xsubpp')
3780       or die "Can't find ExtUtils::xsubpp in INC (@INC)";
3781
3782     my @typemaps;
3783     push @typemaps, Module::Build::ModuleInfo->find_module_by_name('ExtUtils::typemap', \@INC);
3784     my $lib_typemap = Module::Build::ModuleInfo->find_module_by_name('typemap', ['lib']);
3785     if (defined $lib_typemap and -e $lib_typemap) {
3786       push @typemaps, 'typemap';
3787     }
3788     @typemaps = map {+'-typemap', $_} @typemaps;
3789
3790     my $cf = $self->config;
3791     my $perl = $self->{properties}{perl};
3792
3793     my @command = ($perl, "-I$cf->{installarchlib}", "-I$cf->{installprivlib}", $xsubpp, '-noprototypes',
3794                    @typemaps, $file);
3795
3796     $self->log_info("@command\n");
3797     my $fh = IO::File->new("> $args{outfile}") or die "Couldn't write $args{outfile}: $!";
3798     print {$fh} $self->_backticks(@command);
3799     close $fh;
3800   }
3801 }
3802
3803 sub split_like_shell {
3804   my ($self, $string) = @_;
3805
3806   return () unless defined($string);
3807   return @$string if UNIVERSAL::isa($string, 'ARRAY');
3808   $string =~ s/^\s+|\s+$//g;
3809   return () unless length($string);
3810
3811   return Text::ParseWords::shellwords($string);
3812 }
3813
3814 sub run_perl_script {
3815   my ($self, $script, $preargs, $postargs) = @_;
3816   foreach ($preargs, $postargs) {
3817     $_ = [ $self->split_like_shell($_) ] unless ref();
3818   }
3819   return $self->run_perl_command([@$preargs, $script, @$postargs]);
3820 }
3821
3822 sub run_perl_command {
3823   # XXX Maybe we should accept @args instead of $args?  Must resolve
3824   # this before documenting.
3825   my ($self, $args) = @_;
3826   $args = [ $self->split_like_shell($args) ] unless ref($args);
3827   $args = [ split(/\s+/, $self->_quote_args($args)) ] if $self->os_type eq 'VMS';
3828   my $perl = ref($self) ? $self->perl : $self->find_perl_interpreter;
3829
3830   # Make sure our local additions to @INC are propagated to the subprocess
3831   my $c = ref $self ? $self->config : \%Config::Config;
3832   local $ENV{PERL5LIB} = join $c->{path_sep}, $self->_added_to_INC;
3833
3834   return $self->do_system($perl, @$args);
3835 }
3836
3837 # Infer various data from the path of the input filename
3838 # that is needed to create output files.
3839 # The input filename is expected to be of the form:
3840 #   lib/Module/Name.ext or Module/Name.ext
3841 sub _infer_xs_spec {
3842   my $self = shift;
3843   my $file = shift;
3844
3845   my $cf = $self->{config};
3846
3847   my %spec;
3848
3849   my( $v, $d, $f ) = File::Spec->splitpath( $file );
3850   my @d = File::Spec->splitdir( $d );
3851   (my $file_base = $f) =~ s/\.[^.]+$//i;
3852
3853   $spec{base_name} = $file_base;
3854
3855   $spec{src_dir} = File::Spec->catpath( $v, $d, '' );
3856
3857   # the module name
3858   shift( @d ) while @d && ($d[0] eq 'lib' || $d[0] eq '');
3859   pop( @d ) while @d && $d[-1] eq '';
3860   $spec{module_name} = join( '::', (@d, $file_base) );
3861
3862   $spec{archdir} = File::Spec->catdir($self->blib, 'arch', 'auto',
3863                                       @d, $file_base);
3864
3865   $spec{bs_file} = File::Spec->catfile($spec{archdir}, "${file_base}.bs");
3866
3867   $spec{lib_file} = File::Spec->catfile($spec{archdir},
3868                                         "${file_base}.$cf->{dlext}");
3869
3870   $spec{c_file} = File::Spec->catfile( $spec{src_dir},
3871                                        "${file_base}.c" );
3872
3873   $spec{obj_file} = File::Spec->catfile( $spec{src_dir},
3874                                          "${file_base}$cf->{obj_ext}" );
3875
3876   return \%spec;
3877 }
3878
3879 sub process_xs {
3880   my ($self, $file) = @_;
3881   my $cf = $self->config; # For convenience
3882
3883   my $spec = $self->_infer_xs_spec($file);
3884
3885   # File name, minus the suffix
3886   (my $file_base = $file) =~ s/\.[^.]+$//;
3887
3888   # .xs -> .c
3889   $self->add_to_cleanup($spec->{c_file});
3890
3891   unless ($self->up_to_date($file, $spec->{c_file})) {
3892     $self->compile_xs($file, outfile => $spec->{c_file});
3893   }
3894
3895   # .c -> .o
3896   my $v = $self->dist_version;
3897   $self->compile_c($spec->{c_file},
3898                    defines => {VERSION => qq{"$v"}, XS_VERSION => qq{"$v"}});
3899
3900   # archdir
3901   File::Path::mkpath($spec->{archdir}, 0, 0777) unless -d $spec->{archdir};
3902
3903   # .xs -> .bs
3904   $self->add_to_cleanup($spec->{bs_file});
3905   unless ($self->up_to_date($file, $spec->{bs_file})) {
3906     require ExtUtils::Mkbootstrap;
3907     $self->log_info("ExtUtils::Mkbootstrap::Mkbootstrap('$spec->{bs_file}')\n");
3908     ExtUtils::Mkbootstrap::Mkbootstrap($spec->{bs_file});  # Original had $BSLOADLIBS - what's that?
3909     {my $fh = IO::File->new(">> $spec->{bs_file}")}  # create
3910     utime((time)x2, $spec->{bs_file});  # touch
3911   }
3912
3913   # .o -> .(a|bundle)
3914   $self->link_c($spec->{archdir}, $file_base);
3915 }
3916
3917 sub do_system {
3918   my ($self, @cmd) = @_;
3919   $self->log_info("@cmd\n");
3920   return !system(@cmd);
3921 }
3922
3923 sub copy_if_modified {
3924   my $self = shift;
3925   my %args = (@_ > 3
3926               ? ( @_ )
3927               : ( from => shift, to_dir => shift, flatten => shift )
3928              );
3929   $args{verbose} = !$self->quiet
3930     unless exists $args{verbose};
3931
3932   my $file = $args{from};
3933   unless (defined $file and length $file) {
3934     die "No 'from' parameter given to copy_if_modified";
3935   }
3936
3937   my $to_path;
3938   if (defined $args{to} and length $args{to}) {
3939     $to_path = $args{to};
3940   } elsif (defined $args{to_dir} and length $args{to_dir}) {
3941     $to_path = File::Spec->catfile( $args{to_dir}, $args{flatten}
3942                                     ? File::Basename::basename($file)
3943                                     : $file );
3944   } else {
3945     die "No 'to' or 'to_dir' parameter given to copy_if_modified";
3946   }
3947
3948   return if $self->up_to_date($file, $to_path); # Already fresh
3949
3950   $self->delete_filetree($to_path); # delete destination if exists
3951
3952   # Create parent directories
3953   File::Path::mkpath(File::Basename::dirname($to_path), 0, 0777);
3954
3955   $self->log_info("$file -> $to_path\n") if $args{verbose};
3956   File::Copy::copy($file, $to_path) or die "Can't copy('$file', '$to_path'): $!";
3957   # mode is read-only + (executable if source is executable)
3958   my $mode = 0444 | ( -x $file ? 0111 : 0 );
3959   chmod( $mode, $to_path );
3960
3961   return $to_path;
3962 }
3963
3964 sub up_to_date {
3965   my ($self, $source, $derived) = @_;
3966   $source  = [$source]  unless ref $source;
3967   $derived = [$derived] unless ref $derived;
3968
3969   return 0 if grep {not -e} @$derived;
3970
3971   my $most_recent_source = time / (24*60*60);
3972   foreach my $file (@$source) {
3973     unless (-e $file) {
3974       $self->log_warn("Can't find source file $file for up-to-date check");
3975       next;
3976     }
3977     $most_recent_source = -M _ if -M _ < $most_recent_source;
3978   }
3979
3980   foreach my $derived (@$derived) {
3981     return 0 if -M $derived > $most_recent_source;
3982   }
3983   return 1;
3984 }
3985
3986 sub dir_contains {
3987   my ($self, $first, $second) = @_;
3988   # File::Spec doesn't have an easy way to check whether one directory
3989   # is inside another, unfortunately.
3990
3991   ($first, $second) = map File::Spec->canonpath($_), ($first, $second);
3992   my @first_dirs = File::Spec->splitdir($first);
3993   my @second_dirs = File::Spec->splitdir($second);
3994
3995   return 0 if @second_dirs < @first_dirs;
3996
3997   my $is_same = ( File::Spec->case_tolerant
3998                   ? sub {lc(shift()) eq lc(shift())}
3999                   : sub {shift() eq shift()} );
4000
4001   while (@first_dirs) {
4002     return 0 unless $is_same->(shift @first_dirs, shift @second_dirs);
4003   }
4004
4005   return 1;
4006 }
4007
4008 1;
4009 __END__
4010
4011
4012 =head1 NAME
4013
4014 Module::Build::Base - Default methods for Module::Build
4015
4016 =head1 SYNOPSIS
4017
4018   Please see the Module::Build documentation.
4019
4020 =head1 DESCRIPTION
4021
4022 The C<Module::Build::Base> module defines the core functionality of
4023 C<Module::Build>.  Its methods may be overridden by any of the
4024 platform-dependent modules in the C<Module::Build::Platform::>
4025 namespace, but the intention here is to make this base module as
4026 platform-neutral as possible.  Nicely enough, Perl has several core
4027 tools available in the C<File::> namespace for doing this, so the task
4028 isn't very difficult.
4029
4030 Please see the C<Module::Build> documentation for more details.
4031
4032 =head1 AUTHOR
4033
4034 Ken Williams <ken@cpan.org>
4035
4036 =head1 COPYRIGHT
4037
4038 Copyright (c) 2001-2005 Ken Williams.  All rights reserved.
4039
4040 This library is free software; you can redistribute it and/or
4041 modify it under the same terms as Perl itself.
4042
4043 =head1 SEE ALSO
4044
4045 perl(1), Module::Build(3)
4046
4047 =cut