lib/Method/Generate/Constructor.pm

   1 package Method::Generate::Constructor;
   2
   3 use strictures 1;
   4 use Sub::Quote;
   5 use base qw(Moo::Object);
   6 use Sub::Defer;
   7 use B 'perlstring';
   8
   9 sub register_attribute_specs {
  10   my ($self, @new_specs) = @_;
  11   my $specs = $self->{attribute_specs}||={};
  12   while (my ($name, $new_spec) = splice @new_specs, 0, 2) {
  13     if ($name =~ s/^\+//) {
  14       die "has '+${name}' given but no ${name} attribute already exists"
  15         unless my $old_spec = $specs->{$name};
  16       foreach my $key (keys %$old_spec) {
  17         if (!exists $new_spec->{$key}) {
  18           $new_spec->{$key} = $old_spec->{$key}
  19             unless $key eq 'handles';
  20         }
  21         elsif ($key eq 'moosify') {
  22           $new_spec->{$key} = [
  23             map { ref $_ eq 'ARRAY' ? @$_ : $_ }
  24               ($old_spec->{$key}, $new_spec->{$key})
  25           ];
  26         }
  27       }
  28     }
  29     $new_spec->{index} = scalar keys %$specs
  30       unless defined $new_spec->{index};
  31     $specs->{$name} = $new_spec;
  32   }
  33   $self;
  34 }
  35
  36 sub all_attribute_specs {
  37   $_[0]->{attribute_specs}
  38 }
  39
  40 sub accessor_generator {
  41   $_[0]->{accessor_generator}
  42 }
  43
  44 sub construction_string {
  45   my ($self) = @_;
  46   $self->{construction_string}
  47     or 'bless('
  48        .$self->accessor_generator->default_construction_string
  49        .', $class);'
  50 }
  51
  52 sub install_delayed {
  53   my ($self) = @_;
  54   my $package = $self->{package};
  55   defer_sub "${package}::new" => sub {
  56     unquote_sub $self->generate_method(
  57       $package, 'new', $self->{attribute_specs}, { no_install => 1 }
  58     )
  59   };
  60   $self;
  61 }
  62
  63 sub generate_method {
  64   my ($self, $into, $name, $spec, $quote_opts) = @_;
  65   foreach my $no_init (grep !exists($spec->{$_}{init_arg}), keys %$spec) {
  66     $spec->{$no_init}{init_arg} = $no_init;
  67   }
  68   local $self->{captures} = {};
  69   my $body = '    my $class = shift;'."\n"
  70             .'    $class = ref($class) if ref($class);'."\n";
  71   $body .= $self->_handle_subconstructor($into, $name);
  72   my $into_buildargs = $into->can('BUILDARGS');
  73   if ( $into_buildargs && $into_buildargs != \&Moo::Object::BUILDARGS ) {
  74       $body .= $self->_generate_args_via_buildargs;
  75   } else {
  76       $body .= $self->_generate_args;
  77   }
  78   $body .= $self->_check_required($spec);
  79   $body .= '    my $new = '.$self->construction_string.";\n";
  80   $body .= $self->_assign_new($spec);
  81   if ($into->can('BUILD')) {
  82     require Method::Generate::BuildAll;
  83     $body .= Method::Generate::BuildAll->new->buildall_body_for(
  84       $into, '$new', '$args'
  85     );
  86   }
  87   $body .= '    return $new;'."\n";
  88   if ($into->can('DEMOLISH')) {
  89     require Method::Generate::DemolishAll;
  90     Method::Generate::DemolishAll->new->generate_method($into);
  91   }
  92   quote_sub
  93     "${into}::${name}" => $body,
  94     $self->{captures}, $quote_opts||{}
  95   ;
  96 }
  97
  98 sub _handle_subconstructor {
  99   my ($self, $into, $name) = @_;
 100   if (my $gen = $self->{subconstructor_handler}) {
 101     '    if ($class ne '.perlstring($into).') {'."\n".
 102     $gen.
 103     '    }'."\n";
 104   } else {
 105     ''
 106   }
 107 }
 108
 109 sub _cap_call {
 110   my ($self, $code, $captures) = @_;
 111   @{$self->{captures}}{keys %$captures} = values %$captures if $captures;
 112   $code;
 113 }
 114
 115 sub _generate_args_via_buildargs {
 116   my ($self) = @_;
 117   q{    my $args = $class->BUILDARGS(@_);}."\n"
 118   .q{    die "BUILDARGS did not return a hashref" unless ref($args) eq 'HASH';}
 119   ."\n";
 120 }
 121
 122 # inlined from Moo::Object - update that first.
 123 sub _generate_args {
 124   my ($self) = @_;
 125   return <<'_EOA';
 126     my $args;
 127     if ( scalar @_ == 1 ) {
 128         unless ( defined $_[0] && ref $_[0] eq 'HASH' ) {
 129             die "Single parameters to new() must be a HASH ref"
 130                 ." data => ". $_[0] ."\n";
 131         }
 132         $args = { %{ $_[0] } };
 133     }
 134     elsif ( @_ % 2 ) {
 135         die "The new() method for $class expects a hash reference or a key/value list."
 136                 . " You passed an odd number of arguments\n";
 137     }
 138     else {
 139         $args = {@_};
 140     }
 141 _EOA
 142
 143 }
 144
 145 sub _assign_new {
 146   my ($self, $spec) = @_;
 147   my $ag = $self->accessor_generator;
 148   my %test;
 149   NAME: foreach my $name (sort keys %$spec) {
 150     my $attr_spec = $spec->{$name};
 151     next NAME unless defined($attr_spec->{init_arg})
 152                        or $ag->has_eager_default($name, $attr_spec);
 153     $test{$name} = $attr_spec->{init_arg};
 154   }
 155   join '', map {
 156     my $arg_key = perlstring($test{$_});
 157     my $test = "exists \$args->{$arg_key}";
 158     my $source = "\$args->{$arg_key}";
 159     my $attr_spec = $spec->{$_};
 160     $self->_cap_call($ag->generate_populate_set(
 161       '$new', $_, $attr_spec, $source, $test, $test{$_},
 162     ));
 163   } sort keys %test;
 164 }
 165
 166 sub _check_required {
 167   my ($self, $spec) = @_;
 168   my @required_init =
 169     map $spec->{$_}{init_arg},
 170       grep {
 171         my %s = %{$spec->{$_}}; # ignore required if default or builder set
 172         $s{required} and not($s{builder} or $s{default})
 173       } sort keys %$spec;
 174   return '' unless @required_init;
 175   '    if (my @missing = grep !exists $args->{$_}, qw('
 176     .join(' ',@required_init).')) {'."\n"
 177     .q{      die "Missing required arguments: ".join(', ', sort @missing);}."\n"
 178     ."    }\n";
 179 }
 180
 181 1;