lib/Method/Generate/Constructor.pm

   1 package Method::Generate::Constructor;
   2
   3 use strictures 1;
   4 use Sub::Quote;
   5 use base qw(Class::Tiny::Object);
   6 use Sub::Defer;
   7 use B 'perlstring';
   8
   9 sub register_attribute_specs {
  10   my ($self, %spec) = @_;
  11   @{$self->{attribute_specs}||={}}{keys %spec} = values %spec;
  12   $self;
  13 }
  14
  15 sub all_attribute_specs {
  16   $_[0]->{attribute_specs}
  17 }
  18
  19 sub accessor_generator {
  20   $_[0]->{accessor_generator}
  21 }
  22
  23 sub install_delayed {
  24   my ($self) = @_;
  25   my $package = $self->{package};
  26   defer_sub "${package}::new" => sub {
  27     unquote_sub $self->generate_method(
  28       $package, 'new', $self->{attribute_specs}, { no_install => 1 }
  29     )
  30   };
  31   $self;
  32 }
  33
  34 sub generate_method {
  35   my ($self, $into, $name, $spec, $quote_opts) = @_;
  36   foreach my $no_init (grep !exists($spec->{$_}{init_arg}), keys %$spec) {
  37     $spec->{$no_init}{init_arg} = $no_init;
  38   }
  39   local $self->{captures} = {};
  40   my $body = '    my $class = shift;'."\n";
  41   $body .= $self->_generate_args;
  42   $body .= $self->_check_required($spec);
  43   $body .= $self->_check_isa($spec);
  44   $body .= '    my $new = bless({}, $class);'."\n";
  45   $body .= $self->_assign_new($spec);
  46   $body .= $self->_fire_triggers($spec);
  47   $body .= '    return $new;'."\n";
  48   quote_sub
  49     "${into}::${name}" => $body,
  50     $self->{captures}, $quote_opts||{}
  51   ;
  52 }
  53
  54 sub _generate_args {
  55   my ($self) = @_;
  56   q{    my $args = ref($_[0]) eq 'HASH' ? $_[0] : { @_ };}."\n";
  57 }
  58
  59 sub _assign_new {
  60   my ($self, $spec) = @_;
  61   my (@init, @slots, %test);
  62   NAME: foreach my $name (sort keys %$spec) {
  63     my $attr_spec = $spec->{$name};
  64     next NAME unless defined(my $i = $attr_spec->{init_arg});
  65     if ($attr_spec->{lazy}) {
  66       $test{$name} = $i;
  67       next NAME;
  68     }
  69     push @init, $i;
  70     push @slots, $name;
  71   }
  72   return '' unless @init;
  73   join '', (
  74     @init
  75       ? '    @{$new}{qw('.join(' ',@slots).')}'
  76         .' = @{$args}{qw('.join(' ',@init).')};'."\n"
  77       : ''
  78   ), map {
  79     my $arg_key = perlstring($test{$_});
  80     "    \$new->{${\perlstring($_)}} = \$args->{$arg_key}\n"
  81     ."      if exists \$args->{$arg_key};\n"
  82   } sort keys %test;
  83 }
  84
  85 sub _check_required {
  86   my ($self, $spec) = @_;
  87   my @required_init =
  88     map $spec->{$_}{init_arg},
  89       grep $spec->{$_}{required},
  90         sort keys %$spec;
  91   return '' unless @required_init;
  92   '    if (my @missing = grep !exists $args->{$_}, qw('
  93     .join(' ',@required_init).')) {'."\n"
  94     .q{      die "Missing required arguments: ".join(', ', sort @missing);}."\n"
  95     ."    }\n";
  96 }
  97
  98 sub _check_isa {
  99   my ($self, $spec) = @_;
 100   my $acc = $self->accessor_generator;
 101   my $captures = $self->{captures};
 102   my $check = '';
 103   foreach my $name (sort keys %$spec) {
 104     my ($init, $isa) = @{$spec->{$name}}{qw(init_arg isa)};
 105     next unless $init and $isa;
 106     my $init_str = perlstring($init);
 107     my ($code, $add_captures) = $acc->generate_isa_check(
 108       $name, "\$args->{${init_str}}", $isa
 109     );
 110     @{$captures}{keys %$add_captures} = values %$add_captures;
 111     $check .= "    ${code} if exists \$args->{${init_str}};\n";
 112   }
 113   return $check;
 114 }
 115
 116 sub _fire_triggers {
 117   my ($self, $spec) = @_;
 118   my $acc = $self->accessor_generator;
 119   my $captures = $self->{captures};
 120   my $fire = '';
 121   foreach my $name (sort keys %$spec) {
 122     my ($init, $trigger) = @{$spec->{$name}}{qw(init_arg trigger)};
 123     next unless $init && $trigger;
 124     my ($code, $add_captures) = $acc->generate_trigger(
 125       $name, '$new', $acc->generate_simple_get('$new', $name), $trigger
 126     );
 127     @{$captures}{keys %$add_captures} = values %$add_captures;
 128     $fire .= "    ${code} if exists \$args->{${\perlstring $init}};\n";
 129   }
 130   return $fire;
 131 }
 132
 133 1;