lib/Method/Generate/Constructor.pm

   1 package Method::Generate::Constructor;
   2
   3 use strictures 1;
   4 use Sub::Quote;
   5 use base qw(Moo::Object);
   6 use Sub::Defer;
   7 use B 'perlstring';
   8
   9 sub register_attribute_specs {
  10   my ($self, @new_specs) = @_;
  11   my $specs = $self->{attribute_specs}||={};
  12   while (my ($name, $new_spec) = splice @new_specs, 0, 2) {
  13     if ($name =~ s/^\+//) {
  14       die "has '+${name}' given but no ${name} attribute already exists"
  15         unless my $old_spec = $specs->{$name};
  16       foreach my $key (keys %$old_spec) {
  17         if (!exists $new_spec->{$key}) {
  18           $new_spec->{$key} = $old_spec->{$key}
  19         }
  20         elsif ($key eq 'moosify') {
  21           $new_spec->{$key} = [map { ref $_ eq 'ARRAY' ? @$_ : $_ } ($old_spec->{$key}, $new_spec->{$key})];
  22         }
  23       }
  24     }
  25     $new_spec->{index} = scalar keys %$specs
  26       unless defined $new_spec->{index};
  27     $specs->{$name} = $new_spec;
  28   }
  29   $self;
  30 }
  31
  32 sub all_attribute_specs {
  33   $_[0]->{attribute_specs}
  34 }
  35
  36 sub accessor_generator {
  37   $_[0]->{accessor_generator}
  38 }
  39
  40 sub construction_string {
  41   my ($self) = @_;
  42   $self->{construction_string}
  43     or 'bless('
  44        .$self->accessor_generator->default_construction_string
  45        .', $class);'
  46 }
  47
  48 sub install_delayed {
  49   my ($self) = @_;
  50   my $package = $self->{package};
  51   defer_sub "${package}::new" => sub {
  52     unquote_sub $self->generate_method(
  53       $package, 'new', $self->{attribute_specs}, { no_install => 1 }
  54     )
  55   };
  56   $self;
  57 }
  58
  59 sub generate_method {
  60   my ($self, $into, $name, $spec, $quote_opts) = @_;
  61   foreach my $no_init (grep !exists($spec->{$_}{init_arg}), keys %$spec) {
  62     $spec->{$no_init}{init_arg} = $no_init;
  63   }
  64   local $self->{captures} = {};
  65   my $body = '    my $class = shift;'."\n"
  66             .'    $class = ref($class) if ref($class);'."\n";
  67   $body .= $self->_handle_subconstructor($into, $name);
  68   my $into_buildargs = $into->can('BUILDARGS');
  69   if ( $into_buildargs && $into_buildargs != \&Moo::Object::BUILDARGS ) {
  70       $body .= $self->_generate_args_via_buildargs;
  71   } else {
  72       $body .= $self->_generate_args;
  73   }
  74   $body .= $self->_check_required($spec);
  75   $body .= '    my $new = '.$self->construction_string.";\n";
  76   $body .= $self->_assign_new($spec);
  77   if ($into->can('BUILD')) {
  78     require Method::Generate::BuildAll;
  79     $body .= Method::Generate::BuildAll->new->buildall_body_for(
  80       $into, '$new', '$args'
  81     );
  82   }
  83   $body .= '    return $new;'."\n";
  84   if ($into->can('DEMOLISH')) {
  85     require Method::Generate::DemolishAll;
  86     Method::Generate::DemolishAll->new->generate_method($into);
  87   }
  88   quote_sub
  89     "${into}::${name}" => $body,
  90     $self->{captures}, $quote_opts||{}
  91   ;
  92 }
  93
  94 sub _handle_subconstructor {
  95   my ($self, $into, $name) = @_;
  96   if (my $gen = $self->{subconstructor_handler}) {
  97     '    if ($class ne '.perlstring($into).') {'."\n".
  98     $gen.
  99     '    }'."\n";
 100   } else {
 101     ''
 102   }
 103 }
 104
 105 sub _cap_call {
 106   my ($self, $code, $captures) = @_;
 107   @{$self->{captures}}{keys %$captures} = values %$captures if $captures;
 108   $code;
 109 }
 110
 111 sub _generate_args_via_buildargs {
 112   my ($self) = @_;
 113   q{    my $args = $class->BUILDARGS(@_);}."\n"
 114   .q{    die "BUILDARGS did not return a hashref" unless ref($args) eq 'HASH';}
 115   ."\n";
 116 }
 117
 118 # inlined from Moo::Object - update that first.
 119 sub _generate_args {
 120   my ($self) = @_;
 121   return <<'_EOA';
 122     my $args;
 123     if ( scalar @_ == 1 ) {
 124         unless ( defined $_[0] && ref $_[0] eq 'HASH' ) {
 125             die "Single parameters to new() must be a HASH ref"
 126                 ." data => ". $_[0] ."\n";
 127         }
 128         $args = { %{ $_[0] } };
 129     }
 130     elsif ( @_ % 2 ) {
 131         die "The new() method for $class expects a hash reference or a key/value list."
 132                 . " You passed an odd number of arguments\n";
 133     }
 134     else {
 135         $args = {@_};
 136     }
 137 _EOA
 138
 139 }
 140
 141 sub _assign_new {
 142   my ($self, $spec) = @_;
 143   my $ag = $self->accessor_generator;
 144   my %test;
 145   NAME: foreach my $name (sort keys %$spec) {
 146     my $attr_spec = $spec->{$name};
 147     next NAME unless defined($attr_spec->{init_arg})
 148                        or $ag->has_eager_default($name, $attr_spec);
 149     $test{$name} = $attr_spec->{init_arg};
 150   }
 151   join '', map {
 152     my $arg_key = perlstring($test{$_});
 153     my $test = "exists \$args->{$arg_key}";
 154     my $source = "\$args->{$arg_key}";
 155     my $attr_spec = $spec->{$_};
 156     $self->_cap_call($ag->generate_populate_set(
 157       '$new', $_, $attr_spec, $source, $test, $test{$_},
 158     ));
 159   } sort keys %test;
 160 }
 161
 162 sub _check_required {
 163   my ($self, $spec) = @_;
 164   my @required_init =
 165     map $spec->{$_}{init_arg},
 166       grep {
 167         my %s = %{$spec->{$_}}; # ignore required if default or builder set
 168         $s{required} and not($s{builder} or $s{default})
 169       } sort keys %$spec;
 170   return '' unless @required_init;
 171   '    if (my @missing = grep !exists $args->{$_}, qw('
 172     .join(' ',@required_init).')) {'."\n"
 173     .q{      die "Missing required arguments: ".join(', ', sort @missing);}."\n"
 174     ."    }\n";
 175 }
 176
 177 1;