lib/Method/Generate/Constructor.pm

   1 package Method::Generate::Constructor;
   2
   3 use strictures 1;
   4 use Sub::Quote;
   5 use base qw(Moo::Object);
   6 use Sub::Defer;
   7 use B 'perlstring';
   8
   9 sub register_attribute_specs {
  10   my ($self, %spec) = @_;
  11   @{$self->{attribute_specs}||={}}{keys %spec} = values %spec;
  12   $self;
  13 }
  14
  15 sub all_attribute_specs {
  16   $_[0]->{attribute_specs}
  17 }
  18
  19 sub accessor_generator {
  20   $_[0]->{accessor_generator}
  21 }
  22
  23 sub construction_string {
  24   my ($self) = @_;
  25   $self->{construction_string} or 'bless({}, $class);'
  26 }
  27
  28 sub install_delayed {
  29   my ($self) = @_;
  30   my $package = $self->{package};
  31   defer_sub "${package}::new" => sub {
  32     unquote_sub $self->generate_method(
  33       $package, 'new', $self->{attribute_specs}, { no_install => 1 }
  34     )
  35   };
  36   $self;
  37 }
  38
  39 sub generate_method {
  40   my ($self, $into, $name, $spec, $quote_opts) = @_;
  41   foreach my $no_init (grep !exists($spec->{$_}{init_arg}), keys %$spec) {
  42     $spec->{$no_init}{init_arg} = $no_init;
  43   }
  44   local $self->{captures} = {};
  45   my $body = '    my $class = shift;'."\n";
  46   $body .= $self->_generate_args;
  47   $body .= $self->_check_required($spec);
  48   $body .= '    my $new = '.$self->construction_string.";\n";
  49   $body .= $self->_assign_new($spec);
  50   if ($into->can('BUILD')) {
  51     require Method::Generate::BuildAll;
  52     $body .= Method::Generate::BuildAll->new->buildall_body_for(
  53       $into, '$new', '$args'
  54     );
  55   }
  56   $body .= '    return $new;'."\n";
  57   quote_sub
  58     "${into}::${name}" => $body,
  59     $self->{captures}, $quote_opts||{}
  60   ;
  61 }
  62
  63 sub _cap_call {
  64   my ($self, $code, $captures) = @_;
  65   @{$self->{captures}}{keys %$captures} = values %$captures if $captures;
  66   $code;
  67 }
  68
  69 sub _generate_args {
  70   my ($self) = @_;
  71   q{    my $args = ref($_[0]) eq 'HASH' ? $_[0] : { @_ };}."\n";
  72 }
  73
  74 sub _assign_new {
  75   my ($self, $spec) = @_;
  76   my (@init, @slots, %test);
  77   my $ag = $self->accessor_generator;
  78   NAME: foreach my $name (sort keys %$spec) {
  79     my $attr_spec = $spec->{$name};
  80     unless ($ag->is_simple_attribute($name, $attr_spec)) {
  81       next NAME unless defined($attr_spec->{init_arg})
  82                          or (($attr_spec->{default} or $attr_spec->{builder})
  83                              and not $attr_spec->{lazy});
  84       $test{$name} = $attr_spec->{init_arg};
  85       next NAME;
  86     }
  87     next NAME unless defined(my $i = $attr_spec->{init_arg});
  88     push @init, $i;
  89     push @slots, $name;
  90   }
  91   return '' unless @init or %test;
  92   join '', (
  93     @init
  94       ? '    '.$self->_cap_call($ag->generate_multi_set(
  95           '$new', [ @slots ], '@{$args}{qw('.join(' ',@init).')}'
  96         )).";\n"
  97       : ''
  98   ), map {
  99     my $arg_key = perlstring($test{$_});
 100     my $test = "exists \$args->{$arg_key}";
 101     my $source = "\$args->{$arg_key}";
 102     my $attr_spec = $spec->{$_};
 103     $self->_cap_call($ag->generate_populate_set(
 104       '$new', $_, $attr_spec, $source, $test
 105     ));
 106   } sort keys %test;
 107 }
 108
 109 sub _check_required {
 110   my ($self, $spec) = @_;
 111   my @required_init =
 112     map $spec->{$_}{init_arg},
 113       grep $spec->{$_}{required},
 114         sort keys %$spec;
 115   return '' unless @required_init;
 116   '    if (my @missing = grep !exists $args->{$_}, qw('
 117     .join(' ',@required_init).')) {'."\n"
 118     .q{      die "Missing required arguments: ".join(', ', sort @missing);}."\n"
 119     ."    }\n";
 120 }
 121
 122 sub _check_isa {
 123   my ($self, $spec) = @_;
 124   my $acc = $self->accessor_generator;
 125   my $captures = $self->{captures};
 126   my $check = '';
 127   foreach my $name (sort keys %$spec) {
 128     my ($init, $isa) = @{$spec->{$name}}{qw(init_arg isa)};
 129     next unless $init and $isa;
 130     my $init_str = perlstring($init);
 131     my ($code, $add_captures) = $acc->generate_isa_check(
 132       $name, "\$args->{${init_str}}", $isa
 133     );
 134     @{$captures}{keys %$add_captures} = values %$add_captures;
 135     $check .= "    ${code}".(
 136       (not($spec->{lazy}) and ($spec->{default} or $spec->{builder})
 137         ? ";\n"
 138         : "if exists \$args->{${init_str}};\n"
 139       )
 140     );
 141   }
 142   return $check;
 143 }
 144
 145 sub _fire_triggers {
 146   my ($self, $spec) = @_;
 147   my $acc = $self->accessor_generator;
 148   my $captures = $self->{captures};
 149   my $fire = '';
 150   foreach my $name (sort keys %$spec) {
 151     my ($init, $trigger) = @{$spec->{$name}}{qw(init_arg trigger)};
 152     next unless $init && $trigger;
 153     my ($code, $add_captures) = $acc->generate_trigger(
 154       $name, '$new', $acc->generate_simple_get('$new', $name), $trigger
 155     );
 156     @{$captures}{keys %$add_captures} = values %$add_captures;
 157     $fire .= "    ${code} if exists \$args->{${\perlstring $init}};\n";
 158   }
 159   return $fire;
 160 }
 161
 162 1;