lib/Method/Generate/Constructor.pm

   1 package Method::Generate::Constructor;
   2
   3 use strictures 1;
   4 use Sub::Quote;
   5 use base qw(Class::Tiny::Object);
   6 use Sub::Defer;
   7
   8 sub register_attribute_specs {
   9   my ($self, %spec) = @_;
  10   @{$self->{attribute_specs}||={}}{keys %spec} = values %spec;
  11   $self;
  12 }
  13
  14 sub all_attribute_specs {
  15   $_[0]->{attribute_specs}
  16 }
  17
  18 sub install_delayed {
  19   my ($self) = @_;
  20   my $package = $self->{package};
  21   defer_sub "${package}::new" => sub {
  22     unquote_sub $self->generate_method(
  23       $package, 'new', $self->{attribute_specs}, { no_install => 1 }
  24     )
  25   };
  26   $self;
  27 }
  28
  29 sub generate_method {
  30   my ($self, $into, $name, $spec, $quote_opts) = @_;
  31   foreach my $no_init (grep !exists($spec->{$_}{init_arg}), keys %$spec) {
  32     $spec->{$no_init}{init_arg} = $no_init;
  33   }
  34   my $body = '    my $class = shift;'."\n";
  35   $body .= $self->_generate_args;
  36   $body .= $self->_check_required($spec);
  37   $body .= '    my $new = bless({}, $class);'."\n";
  38   $body .= $self->_assign_new($spec);
  39   $body .= '    return $new;'."\n";
  40   quote_sub
  41     "${into}::${name}" => $body,
  42     (ref($quote_opts) ? ({}, $quote_opts) : ())
  43   ;
  44 }
  45
  46 sub _generate_args {
  47   my ($self) = @_;
  48   q{    my $args = ref($_[0]) eq 'HASH' ? $_[0] : { @_ };}."\n";
  49 }
  50
  51 sub _assign_new {
  52   my ($self, $spec) = @_;
  53   my (@init, @slots);
  54   NAME: foreach my $name (keys %$spec) {
  55     my $attr_spec = $spec->{$name};
  56     push @init, do {
  57       next NAME unless defined(my $i = $attr_spec->{init_arg});
  58       $i;
  59     };
  60     push @slots, $name;
  61   }
  62   return '' unless @init;
  63   '    @{$new}{qw('.join(' ',@slots).')} = @{$args}{qw('.join(' ',@init).')};'
  64     ."\n";
  65 }
  66
  67 sub _check_required {
  68   my ($self, $spec) = @_;
  69   my @required_init =
  70     map $spec->{$_}{init_arg},
  71       grep $spec->{$_}{required},
  72         keys %$spec;
  73   return '' unless @required_init;
  74   '    if (my @missing = grep !exists $args->{$_}, qw('
  75     .join(' ',@required_init).')) {'."\n"
  76     .q{      die "Missing required arguments: ".join(', ', sort @missing);}."\n"
  77     ."    }\n";
  78 }
  79
  80 1;