lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 use Module::Runtime qw(use_module);
  11 BEGIN {
  12   our $CAN_HAZ_XS =
  13     !$ENV{MOO_XS_DISABLE}
  14       &&
  15     _maybe_load_module('Class::XSAccessor')
  16       &&
  17     (eval { Class::XSAccessor->VERSION('1.07') })
  18   ;
  19 }
  20
  21 sub _check_overwrite
  22 {
  23   my ($pkg, $method, $type) = @_;
  24   *{_getglob("${pkg}::${method}")}{CODE} and
  25     die "You cannot overwrite a locally defined method ($method) with a @{[ $type || 'accessor' ]}";
  26 }
  27
  28 sub generate_method {
  29   my ($self, $into, $name, $spec, $quote_opts) = @_;
  30   $name =~ s/^\+//;
  31   die "Must have an is" unless my $is = $spec->{is};
  32   if ($is eq 'ro') {
  33     $spec->{reader} = $name unless exists $spec->{reader};
  34   } elsif ($is eq 'rw') {
  35     $spec->{accessor} = $name unless exists $spec->{accessor}
  36       or ( $spec->{reader} and $spec->{writer} );
  37   } elsif ($is eq 'lazy') {
  38     $spec->{reader} = $name unless exists $spec->{reader};
  39     $spec->{lazy} = 1;
  40     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  41   } elsif ($is eq 'rwp') {
  42     $spec->{reader} = $name unless exists $spec->{reader};
  43     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  44   } elsif ($is ne 'bare') {
  45     die "Unknown is ${is}";
  46   }
  47   if (exists $spec->{builder}) {
  48     if(ref $spec->{builder}) {
  49       die "Invalid builder for $into->$name - not a method name, coderef or"
  50         . " code-convertible object"
  51         unless ref $spec->{builder} eq 'CODE'
  52         or (blessed($spec->{builder}) and eval { \&{$spec->{builder}} });
  53       $spec->{builder_sub} = $spec->{builder};
  54       $spec->{builder} = 1;
  55     }
  56     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  57     die "Invalid builder for $into->$name - not a valid method name"
  58       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  59   }
  60   if (($spec->{predicate}||0) eq 1) {
  61     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  62   }
  63   if (($spec->{clearer}||0) eq 1) {
  64     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  65   }
  66   if (($spec->{trigger}||0) eq 1) {
  67     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  68   }
  69
  70   if (exists $spec->{coerce}) {
  71     my $value = $spec->{coerce};
  72     my $invalid = "Invalid coerce '" . overload::StrVal($value)
  73       . "' for $into->$name - not a coderef";
  74     die "$invalid or code-convertible object"
  75       unless ref $value and (ref $value eq 'CODE' or blessed($value));
  76     die "$invalid and could not be converted to a coderef: $@"
  77       if !eval { \&$value };
  78   }
  79
  80   if (exists $spec->{default}) {
  81     my $value = $spec->{default};
  82     if (!defined $value || ref $value) {
  83       my $invalid = "Invalid default '" . overload::StrVal($value)
  84         . "' for $into->$name - not a coderef or non-ref";
  85       die "$invalid or code-convertible object"
  86         unless ref $value and (ref $value eq 'CODE' or blessed($value));
  87       die "$invalid and could not be converted to a coderef: $@"
  88         if !eval { \&$value };
  89     }
  90   }
  91
  92
  93   my %methods;
  94   if (my $reader = $spec->{reader}) {
  95     _check_overwrite($into, $reader, 'reader');
  96     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  97       $methods{$reader} = $self->_generate_xs(
  98         getters => $into, $reader, $name, $spec
  99       );
 100     } else {
 101       $self->{captures} = {};
 102       $methods{$reader} =
 103         quote_sub "${into}::${reader}"
 104           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
 105              .$self->_generate_get($name, $spec)
 106           => delete $self->{captures}
 107         ;
 108     }
 109   }
 110   if (my $accessor = $spec->{accessor}) {
 111     _check_overwrite($into, $accessor, 'accessor');
 112     if (
 113       our $CAN_HAZ_XS
 114       && $self->is_simple_get($name, $spec)
 115       && $self->is_simple_set($name, $spec)
 116     ) {
 117       $methods{$accessor} = $self->_generate_xs(
 118         accessors => $into, $accessor, $name, $spec
 119       );
 120     } else {
 121       $self->{captures} = {};
 122       $methods{$accessor} =
 123         quote_sub "${into}::${accessor}"
 124           => $self->_generate_getset($name, $spec)
 125           => delete $self->{captures}
 126         ;
 127     }
 128   }
 129   if (my $writer = $spec->{writer}) {
 130     _check_overwrite($into, $writer, 'writer');
 131     if (
 132       our $CAN_HAZ_XS
 133       && $self->is_simple_set($name, $spec)
 134     ) {
 135       $methods{$writer} = $self->_generate_xs(
 136         setters => $into, $writer, $name, $spec
 137       );
 138     } else {
 139       $self->{captures} = {};
 140       $methods{$writer} =
 141         quote_sub "${into}::${writer}"
 142           => $self->_generate_set($name, $spec)
 143           => delete $self->{captures}
 144         ;
 145     }
 146   }
 147   if (my $pred = $spec->{predicate}) {
 148     _check_overwrite($into, $pred, 'predicate');
 149     $methods{$pred} =
 150       quote_sub "${into}::${pred}" =>
 151         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 152       ;
 153   }
 154   if (my $pred = $spec->{builder_sub}) {
 155     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 156   }
 157   if (my $cl = $spec->{clearer}) {
 158     _check_overwrite($into, $cl, 'clearer');
 159     $methods{$cl} =
 160       quote_sub "${into}::${cl}" =>
 161         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 162       ;
 163   }
 164   if (my $hspec = $spec->{handles}) {
 165     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 166     my @specs = do {
 167       if (ref($hspec) eq 'ARRAY') {
 168         map [ $_ => $_ ], @$hspec;
 169       } elsif (ref($hspec) eq 'HASH') {
 170         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 171           keys %$hspec;
 172       } elsif (!ref($hspec)) {
 173         map [ $_ => $_ ], use_module('Role::Tiny')->methods_provided_by(use_module($hspec))
 174       } else {
 175         die "You gave me a handles of ${hspec} and I have no idea why";
 176       }
 177     };
 178     foreach my $spec (@specs) {
 179       my ($proxy, $target, @args) = @$spec;
 180       _check_overwrite($into, $proxy, 'delegation');
 181       $self->{captures} = {};
 182       $methods{$proxy} =
 183         quote_sub "${into}::${proxy}" =>
 184           $self->_generate_delegation($asserter, $target, \@args),
 185           delete $self->{captures}
 186         ;
 187     }
 188   }
 189   if (my $asserter = $spec->{asserter}) {
 190     $self->{captures} = {};
 191
 192     my $code = "do {\n"
 193                ."  my \$val = ".$self->_generate_get($name, $spec).";\n"
 194                ."  unless (".$self->_generate_simple_has('$_[0]', $name).") {\n"
 195                .qq!    die "Attempted to access '${name}' but it is not set";\n!
 196                ."  }\n"
 197                ."  \$val;\n"
 198                ."}\n";
 199
 200     $methods{$asserter} =
 201       quote_sub "${into}::${asserter}" => $code,
 202         delete $self->{captures}
 203       ;
 204   }
 205   \%methods;
 206 }
 207
 208 sub is_simple_attribute {
 209   my ($self, $name, $spec) = @_;
 210   # clearer doesn't have to be listed because it doesn't
 211   # affect whether defined/exists makes a difference
 212   !grep $spec->{$_},
 213     qw(lazy default builder coerce isa trigger predicate weak_ref);
 214 }
 215
 216 sub is_simple_get {
 217   my ($self, $name, $spec) = @_;
 218   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 219 }
 220
 221 sub is_simple_set {
 222   my ($self, $name, $spec) = @_;
 223   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 224 }
 225
 226 sub has_eager_default {
 227   my ($self, $name, $spec) = @_;
 228   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 229 }
 230
 231 sub _generate_get {
 232   my ($self, $name, $spec) = @_;
 233   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 234   if ($self->is_simple_get($name, $spec)) {
 235     $simple;
 236   } else {
 237     'do { '.$self->_generate_use_default(
 238       '$_[0]', $name, $spec,
 239       $self->_generate_simple_has('$_[0]', $name, $spec),
 240     ).'; '
 241     .($spec->{isa}
 242       ?($self->_generate_isa_check($name, $simple, $spec->{isa}).'; ')
 243       :''
 244     )
 245     .$simple.' }';
 246   }
 247 }
 248
 249 sub _generate_simple_has {
 250   my ($self, $me, $name) = @_;
 251   "exists ${me}->{${\perlstring $name}}";
 252 }
 253
 254 sub _generate_simple_clear {
 255   my ($self, $me, $name) = @_;
 256   "    delete ${me}->{${\perlstring $name}}\n"
 257 }
 258
 259 sub generate_get_default {
 260   my $self = shift;
 261   $self->{captures} = {};
 262   my $code = $self->_generate_get_default(@_);
 263   ($code, delete $self->{captures});
 264 }
 265
 266 sub _generate_use_default {
 267   my ($self, $me, $name, $spec, $test) = @_;
 268   my $get_value = $self->_generate_get_default($me, $name, $spec);
 269   if ($spec->{coerce}) {
 270     $get_value = $self->_generate_coerce(
 271       $name, $get_value,
 272       $spec->{coerce}
 273     )
 274   }
 275   $self->_generate_simple_set(
 276     $me, $name, $spec, $get_value
 277   ).' unless '.$test;
 278 }
 279
 280 sub _generate_get_default {
 281   my ($self, $me, $name, $spec) = @_;
 282   if (exists $spec->{default}) {
 283     ref $spec->{default}
 284       ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 285       : perlstring $spec->{default};
 286   }
 287   else {
 288     "${me}->${\$spec->{builder}}"
 289   }
 290 }
 291
 292 sub generate_simple_get {
 293   my ($self, @args) = @_;
 294   $self->_generate_simple_get(@args);
 295 }
 296
 297 sub _generate_simple_get {
 298   my ($self, $me, $name) = @_;
 299   my $name_str = perlstring $name;
 300   "${me}->{${name_str}}";
 301 }
 302
 303 sub _generate_set {
 304   my ($self, $name, $spec) = @_;
 305   if ($self->is_simple_set($name, $spec)) {
 306     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 307   } else {
 308     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 309     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 310     my $code = "do { my (\$self, \$value) = \@_;\n";
 311     if ($coerce) {
 312       $code .=
 313         "        \$value = "
 314         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 315     }
 316     if ($isa_check) {
 317       $code .=
 318         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 319     }
 320     if ($trigger) {
 321       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 322       $code .=
 323         "        ".$simple.";\n        ".$fire.";\n"
 324         ."        \$value;\n";
 325     } else {
 326       $code .= "        ".$simple.";\n";
 327     }
 328     $code .= "      }";
 329     $code;
 330   }
 331 }
 332
 333 sub generate_coerce {
 334   my $self = shift;
 335   $self->{captures} = {};
 336   my $code = $self->_generate_coerce(@_);
 337   ($code, delete $self->{captures});
 338 }
 339
 340 sub _attr_desc {
 341   my ($name, $init_arg) = @_;
 342   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 343   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 344 }
 345
 346 sub _generate_coerce {
 347   my ($self, $name, $value, $coerce, $init_arg) = @_;
 348   $self->_generate_die_prefix(
 349     "coercion for ${\_attr_desc($name, $init_arg)} failed: ",
 350     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 351   );
 352 }
 353
 354 sub generate_trigger {
 355   my $self = shift;
 356   $self->{captures} = {};
 357   my $code = $self->_generate_trigger(@_);
 358   ($code, delete $self->{captures});
 359 }
 360
 361 sub _generate_trigger {
 362   my ($self, $name, $obj, $value, $trigger) = @_;
 363   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 364 }
 365
 366 sub generate_isa_check {
 367   my ($self, @args) = @_;
 368   $self->{captures} = {};
 369   my $code = $self->_generate_isa_check(@args);
 370   ($code, delete $self->{captures});
 371 }
 372
 373 sub _generate_die_prefix {
 374   my ($self, $prefix, $inside) = @_;
 375   "do {\n"
 376   .'  my $sig_die = $SIG{__DIE__} || sub { die $_[0] };'."\n"
 377   .'  local $SIG{__DIE__} = sub {'."\n"
 378   .'    $sig_die->(ref($_[0]) ? $_[0] : '.perlstring($prefix).'.$_[0]);'."\n"
 379   .'  };'."\n"
 380   .$inside
 381   ."}\n"
 382 }
 383
 384 sub _generate_isa_check {
 385   my ($self, $name, $value, $check, $init_arg) = @_;
 386   $self->_generate_die_prefix(
 387     "isa check for ${\_attr_desc($name, $init_arg)} failed: ",
 388     $self->_generate_call_code($name, 'isa_check', $value, $check)
 389   );
 390 }
 391
 392 sub _generate_call_code {
 393   my ($self, $name, $type, $values, $sub) = @_;
 394   if (my $quoted = quoted_from_sub($sub)) {
 395     my $code = $quoted->[1];
 396     if (my $captures = $quoted->[2]) {
 397       my $cap_name = qq{\$${type}_captures_for_${name}};
 398       $self->{captures}->{$cap_name} = \$captures;
 399       Sub::Quote::inlinify(
 400         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), 1
 401       );
 402     } else {
 403       Sub::Quote::inlinify($code, $values, undef, 1);
 404     }
 405   } else {
 406     my $cap_name = qq{\$${type}_for_${name}};
 407     $self->{captures}->{$cap_name} = \$sub;
 408     "${cap_name}->(${values})";
 409   }
 410 }
 411
 412 sub generate_populate_set {
 413   my $self = shift;
 414   $self->{captures} = {};
 415   my $code = $self->_generate_populate_set(@_);
 416   ($code, delete $self->{captures});
 417 }
 418
 419 sub _generate_populate_set {
 420   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 421   if ($self->has_eager_default($name, $spec)) {
 422     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 423     my $get_default = $self->_generate_get_default(
 424                         '$new', $_, $spec
 425                       );
 426     my $get_value =
 427       defined($spec->{init_arg})
 428         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 429             .$get_default
 430             ."\n${get_indent})"
 431         : $get_default;
 432     if ($spec->{coerce}) {
 433       $get_value = $self->_generate_coerce(
 434         $name, $get_value,
 435         $spec->{coerce}, $init_arg
 436       )
 437     }
 438     ($spec->{isa}
 439       ? "    {\n      my \$value = ".$get_value.";\n      "
 440         .$self->_generate_isa_check(
 441           $name, '$value', $spec->{isa}, $init_arg
 442         ).";\n"
 443         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 444         ."    }\n"
 445       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 446     )
 447     .($spec->{trigger}
 448       ? '    '
 449         .$self->_generate_trigger(
 450           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 451           $spec->{trigger}
 452         )." if ${test};\n"
 453       : ''
 454     );
 455   } else {
 456     "    if (${test}) {\n"
 457       .($spec->{coerce}
 458         ? "      $source = "
 459           .$self->_generate_coerce(
 460             $name, $source,
 461             $spec->{coerce}, $init_arg
 462           ).";\n"
 463         : ""
 464       )
 465       .($spec->{isa}
 466         ? "      "
 467           .$self->_generate_isa_check(
 468             $name, $source, $spec->{isa}, $init_arg
 469           ).";\n"
 470         : ""
 471       )
 472       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 473       .($spec->{trigger}
 474         ? "      "
 475           .$self->_generate_trigger(
 476             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 477             $spec->{trigger}
 478           ).";\n"
 479         : ""
 480       )
 481       ."    }\n";
 482   }
 483 }
 484
 485 sub _generate_core_set {
 486   my ($self, $me, $name, $spec, $value) = @_;
 487   my $name_str = perlstring $name;
 488   "${me}->{${name_str}} = ${value}";
 489 }
 490
 491 sub _generate_simple_set {
 492   my ($self, $me, $name, $spec, $value) = @_;
 493   my $name_str = perlstring $name;
 494
 495   if ($spec->{weak_ref}) {
 496     $value = '$preserve = '.$value;
 497     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 498     require Scalar::Util;
 499
 500     # Perl < 5.8.3 can't weaken refs to readonly vars
 501     # (e.g. string constants). This *can* be solved by:
 502     #
 503     #Internals::SetReadWrite($foo);
 504     #Scalar::Util::weaken ($foo);
 505     #Internals::SetReadOnly($foo);
 506     #
 507     # but requires XS and is just too damn crazy
 508     # so simply throw a better exception
 509     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple}); no warnings 'void'; \$preserve";
 510     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 511
 512       my \$preserve;
 513       eval { Scalar::Util::weaken($simple); 1 }
 514         ? do { no warnings 'void'; \$preserve; }
 515         : do {
 516           if( \$@ =~ /Modification of a read-only value attempted/) {
 517             require Carp;
 518             Carp::croak( sprintf (
 519               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 520               $name_str,
 521             ) );
 522           } else {
 523             die \$@;
 524           }
 525         }
 526 EOC
 527   } else {
 528     $self->_generate_core_set($me, $name, $spec, $value);
 529   }
 530 }
 531
 532 sub _generate_getset {
 533   my ($self, $name, $spec) = @_;
 534   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 535     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 536 }
 537
 538 sub _generate_delegation {
 539   my ($self, $asserter, $target, $args) = @_;
 540   my $arg_string = do {
 541     if (@$args) {
 542       # I could, I reckon, linearise out non-refs here using perlstring
 543       # plus something to check for numbers but I'm unsure if it's worth it
 544       $self->{captures}{'@curries'} = $args;
 545       '@curries, @_';
 546     } else {
 547       '@_';
 548     }
 549   };
 550   "shift->${asserter}->${target}(${arg_string});";
 551 }
 552
 553 sub _generate_xs {
 554   my ($self, $type, $into, $name, $slot) = @_;
 555   Class::XSAccessor->import(
 556     class => $into,
 557     $type => { $name => $slot },
 558     replace => 1,
 559   );
 560   $into->can($name);
 561 }
 562
 563 sub default_construction_string { '{}' }
 564
 565 1;