lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Class::Tiny::_Utils;
   5 use base qw(Class::Tiny::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8
   9 sub generate_method {
  10   my ($self, $into, $name, $spec, $quote_opts) = @_;
  11   die "Must have an is" unless my $is = $spec->{is};
  12   local $self->{captures} = {};
  13   my $body = do {
  14     if ($is eq 'ro') {
  15       $self->_generate_get($name)
  16     } elsif ($is eq 'rw') {
  17       $self->_generate_getset($name, $spec)
  18     } else {
  19       die "Unknown is ${is}";
  20     }
  21   };
  22   quote_sub
  23     "${into}::${name}" => '    '.$body."\n",
  24     $self->{captures}, $quote_opts||{}
  25   ;
  26 }
  27
  28 sub _generate_get {
  29   my ($self, $name) = @_;
  30   $self->_generate_simple_get('$_[0]', $name);
  31 }
  32
  33 sub generate_simple_get {
  34   shift->_generate_simple_get(@_);
  35 }
  36
  37 sub _generate_simple_get {
  38   my ($self, $me, $name) = @_;
  39   my $name_str = perlstring $name;
  40   "${me}->{${name_str}}";
  41 }
  42
  43 sub _generate_set {
  44   my ($self, $name, $value, $spec) = @_;
  45   my $simple = $self->_generate_simple_set($name, $value);
  46   if (my $trigger = $spec->{trigger}) {
  47     my $value = '$value';
  48     my $fire = $self->_generate_trigger($name, '$_[0]', '$value', $trigger);
  49     return 'do { '
  50       .'my $value = '.$simple.'; '.$fire.'; '
  51       .'$value }'
  52     ;
  53   }
  54   return $simple;
  55 }
  56
  57 sub generate_trigger {
  58   my $self = shift;
  59   local $self->{captures} = {};
  60   my $code = $self->_generate_trigger(@_);
  61   return ($code, $self->{captures});
  62 }
  63
  64 sub _generate_trigger {
  65   my ($self, $name, $obj, $value, $trigger) = @_;
  66   if (my $quoted = quoted_from_sub($trigger)) {
  67     die "Captures? ARGH!" if $quoted->[2];
  68     my $code = $quoted->[1];
  69     return 'do { local @_ = ('.join(', ', $obj, $value).'); '.$code.' }';
  70   }
  71   my $cap_name = qq{\$trigger_for_${name}};
  72   $self->{captures}->{$cap_name} = \$trigger;
  73   return "${cap_name}->(${obj}, ${value})";
  74 }
  75
  76 sub _generate_simple_set {
  77   my ($self, $name, $value) = @_;
  78   my $name_str = perlstring $name;
  79   "\$_[0]->{${name_str}} = ${value}";
  80 }
  81
  82 sub _generate_getset {
  83   my ($self, $name, $spec) = @_;
  84   q{(@_ > 1 ? }.$self->_generate_set($name, q{$_[1]}, $spec)
  85     .' : '.$self->_generate_get($name).')';
  86 }
  87
  88 1;