lib/Math/BigInt.pm

   1 package Math::BigInt;
   2
   3 #
   4 # "Mike had an infinite amount to do and a negative amount of time in which
   5 # to do it." - Before and After
   6 #
   7
   8 # The following hash values are used:
   9 #   value: unsigned int with actual value (as a Math::BigInt::Calc or similiar)
  10 #   sign : +,-,NaN,+inf,-inf
  11 #   _a   : accuracy
  12 #   _p   : precision
  13 #   _f   : flags, used by MBF to flag parts of a float as untouchable
  14
  15 # Remember not to take shortcuts ala $xs = $x->{value}; $CALC->foo($xs); since
  16 # underlying lib might change the reference!
  17
  18 my $class = "Math::BigInt";
  19 require 5.005;
  20
  21 $VERSION = '1.71';
  22 use Exporter;
  23 @ISA =       qw( Exporter );
  24 @EXPORT_OK = qw( objectify bgcd blcm);
  25 # _trap_inf and _trap_nan are internal and should never be accessed from the
  26 # outside
  27 use vars qw/$round_mode $accuracy $precision $div_scale $rnd_mode
  28             $upgrade $downgrade $_trap_nan $_trap_inf/;
  29 use strict;
  30
  31 # Inside overload, the first arg is always an object. If the original code had
  32 # it reversed (like $x = 2 * $y), then the third paramater is true.
  33 # In some cases (like add, $x = $x + 2 is the same as $x = 2 + $x) this makes
  34 # no difference, but in some cases it does.
  35
  36 # For overloaded ops with only one argument we simple use $_[0]->copy() to
  37 # preserve the argument.
  38
  39 # Thus inheritance of overload operators becomes possible and transparent for
  40 # our subclasses without the need to repeat the entire overload section there.
  41
  42 use overload
  43 '='     =>      sub { $_[0]->copy(); },
  44
  45 # some shortcuts for speed (assumes that reversed order of arguments is routed
  46 # to normal '+' and we thus can always modify first arg. If this is changed,
  47 # this breaks and must be adjusted.)
  48 '+='    =>      sub { $_[0]->badd($_[1]); },
  49 '-='    =>      sub { $_[0]->bsub($_[1]); },
  50 '*='    =>      sub { $_[0]->bmul($_[1]); },
  51 '/='    =>      sub { scalar $_[0]->bdiv($_[1]); },
  52 '%='    =>      sub { $_[0]->bmod($_[1]); },
  53 '^='    =>      sub { $_[0]->bxor($_[1]); },
  54 '&='    =>      sub { $_[0]->band($_[1]); },
  55 '|='    =>      sub { $_[0]->bior($_[1]); },
  56 '**='   =>      sub { $_[0]->bpow($_[1]); },
  57
  58 # not supported by Perl yet
  59 '..'    =>      \&_pointpoint,
  60
  61 '<=>'   =>      sub { $_[2] ?
  62                       ref($_[0])->bcmp($_[1],$_[0]) :
  63                       $_[0]->bcmp($_[1])},
  64 'cmp'   =>      sub {
  65          $_[2] ?
  66                "$_[1]" cmp $_[0]->bstr() :
  67                $_[0]->bstr() cmp "$_[1]" },
  68
  69 # make cos()/sin()/exp() "work" with BigInt's or subclasses
  70 'cos'   =>      sub { cos($_[0]->numify()) },
  71 'sin'   =>      sub { sin($_[0]->numify()) },
  72 'exp'   =>      sub { exp($_[0]->numify()) },
  73 'atan2' =>      sub { atan2($_[0]->numify(),$_[1]) },
  74
  75 'log'   =>      sub { $_[0]->copy()->blog($_[1]); },
  76 'int'   =>      sub { $_[0]->copy(); },
  77 'neg'   =>      sub { $_[0]->copy()->bneg(); },
  78 'abs'   =>      sub { $_[0]->copy()->babs(); },
  79 'sqrt'  =>      sub { $_[0]->copy()->bsqrt(); },
  80 '~'     =>      sub { $_[0]->copy()->bnot(); },
  81
  82 # for sub it is a bit tricky to keep b: b-a => -a+b
  83 '-'     =>      sub { my $c = $_[0]->copy; $_[2] ?
  84                    $c->bneg()->badd($_[1]) :
  85                    $c->bsub( $_[1]) },
  86 '+'     =>      sub { $_[0]->copy()->badd($_[1]); },
  87 '*'     =>      sub { $_[0]->copy()->bmul($_[1]); },
  88
  89 '/'     =>      sub {
  90    $_[2] ? ref($_[0])->new($_[1])->bdiv($_[0]) : $_[0]->copy->bdiv($_[1]);
  91   },
  92 '%'     =>      sub {
  93    $_[2] ? ref($_[0])->new($_[1])->bmod($_[0]) : $_[0]->copy->bmod($_[1]);
  94   },
  95 '**'    =>      sub {
  96    $_[2] ? ref($_[0])->new($_[1])->bpow($_[0]) : $_[0]->copy->bpow($_[1]);
  97   },
  98 '<<'    =>      sub {
  99    $_[2] ? ref($_[0])->new($_[1])->blsft($_[0]) : $_[0]->copy->blsft($_[1]);
 100   },
 101 '>>'    =>      sub {
 102    $_[2] ? ref($_[0])->new($_[1])->brsft($_[0]) : $_[0]->copy->brsft($_[1]);
 103   },
 104 '&'     =>      sub {
 105    $_[2] ? ref($_[0])->new($_[1])->band($_[0]) : $_[0]->copy->band($_[1]);
 106   },
 107 '|'     =>      sub {
 108    $_[2] ? ref($_[0])->new($_[1])->bior($_[0]) : $_[0]->copy->bior($_[1]);
 109   },
 110 '^'     =>      sub {
 111    $_[2] ? ref($_[0])->new($_[1])->bxor($_[0]) : $_[0]->copy->bxor($_[1]);
 112   },
 113
 114 # can modify arg of ++ and --, so avoid a copy() for speed, but don't
 115 # use $_[0]->bone(), it would modify $_[0] to be 1!
 116 '++'    =>      sub { $_[0]->binc() },
 117 '--'    =>      sub { $_[0]->bdec() },
 118
 119 # if overloaded, O(1) instead of O(N) and twice as fast for small numbers
 120 'bool'  =>      sub {
 121   # this kludge is needed for perl prior 5.6.0 since returning 0 here fails :-/
 122   # v5.6.1 dumps on this: return !$_[0]->is_zero() || undef;                :-(
 123   my $t = undef;
 124   $t = 1 if !$_[0]->is_zero();
 125   $t;
 126   },
 127
 128 # the original qw() does not work with the TIESCALAR below, why?
 129 # Order of arguments unsignificant
 130 '""' => sub { $_[0]->bstr(); },
 131 '0+' => sub { $_[0]->numify(); }
 132 ;
 133
 134 ##############################################################################
 135 # global constants, flags and accessory
 136
 137 # these are public, but their usage is not recommended, use the accessor
 138 # methods instead
 139
 140 $round_mode = 'even'; # one of 'even', 'odd', '+inf', '-inf', 'zero' or 'trunc'
 141 $accuracy   = undef;
 142 $precision  = undef;
 143 $div_scale  = 40;
 144
 145 $upgrade = undef;                       # default is no upgrade
 146 $downgrade = undef;                     # default is no downgrade
 147
 148 # these are internally, and not to be used from the outside
 149
 150 sub MB_NEVER_ROUND () { 0x0001; }
 151
 152 $_trap_nan = 0;                         # are NaNs ok? set w/ config()
 153 $_trap_inf = 0;                         # are infs ok? set w/ config()
 154 my $nan = 'NaN';                        # constants for easier life
 155
 156 my $CALC = 'Math::BigInt::Calc';        # module to do the low level math
 157                                         # default is Calc.pm
 158 my $IMPORT = 0;                         # was import() called yet?
 159                                         # used to make require work
 160 my %WARN;                               # warn only once for low-level libs
 161 my %CAN;                                # cache for $CALC->can(...)
 162 my $EMU_LIB = 'Math/BigInt/CalcEmu.pm'; # emulate low-level math
 163
 164 ##############################################################################
 165 # the old code had $rnd_mode, so we need to support it, too
 166
 167 $rnd_mode   = 'even';
 168 sub TIESCALAR  { my ($class) = @_; bless \$round_mode, $class; }
 169 sub FETCH      { return $round_mode; }
 170 sub STORE      { $rnd_mode = $_[0]->round_mode($_[1]); }
 171
 172 BEGIN
 173   {
 174   # tie to enable $rnd_mode to work transparently
 175   tie $rnd_mode, 'Math::BigInt';
 176
 177   # set up some handy alias names
 178   *as_int = \&as_number;
 179   *is_pos = \&is_positive;
 180   *is_neg = \&is_negative;
 181   }
 182
 183 ##############################################################################
 184
 185 sub round_mode
 186   {
 187   no strict 'refs';
 188   # make Class->round_mode() work
 189   my $self = shift;
 190   my $class = ref($self) || $self || __PACKAGE__;
 191   if (defined $_[0])
 192     {
 193     my $m = shift;
 194     if ($m !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 195       {
 196       require Carp; Carp::croak ("Unknown round mode '$m'");
 197       }
 198     return ${"${class}::round_mode"} = $m;
 199     }
 200   ${"${class}::round_mode"};
 201   }
 202
 203 sub upgrade
 204   {
 205   no strict 'refs';
 206   # make Class->upgrade() work
 207   my $self = shift;
 208   my $class = ref($self) || $self || __PACKAGE__;
 209   # need to set new value?
 210   if (@_ > 0)
 211     {
 212     my $u = shift;
 213     return ${"${class}::upgrade"} = $u;
 214     }
 215   ${"${class}::upgrade"};
 216   }
 217
 218 sub downgrade
 219   {
 220   no strict 'refs';
 221   # make Class->downgrade() work
 222   my $self = shift;
 223   my $class = ref($self) || $self || __PACKAGE__;
 224   # need to set new value?
 225   if (@_ > 0)
 226     {
 227     my $u = shift;
 228     return ${"${class}::downgrade"} = $u;
 229     }
 230   ${"${class}::downgrade"};
 231   }
 232
 233 sub div_scale
 234   {
 235   no strict 'refs';
 236   # make Class->div_scale() work
 237   my $self = shift;
 238   my $class = ref($self) || $self || __PACKAGE__;
 239   if (defined $_[0])
 240     {
 241     if ($_[0] < 0)
 242       {
 243       require Carp; Carp::croak ('div_scale must be greater than zero');
 244       }
 245     ${"${class}::div_scale"} = shift;
 246     }
 247   ${"${class}::div_scale"};
 248   }
 249
 250 sub accuracy
 251   {
 252   # $x->accuracy($a);           ref($x) $a
 253   # $x->accuracy();             ref($x)
 254   # Class->accuracy();          class
 255   # Class->accuracy($a);        class $a
 256
 257   my $x = shift;
 258   my $class = ref($x) || $x || __PACKAGE__;
 259
 260   no strict 'refs';
 261   # need to set new value?
 262   if (@_ > 0)
 263     {
 264     my $a = shift;
 265     # convert objects to scalars to avoid deep recursion. If object doesn't
 266     # have numify(), then hopefully it will have overloading for int() and
 267     # boolean test without wandering into a deep recursion path...
 268     $a = $a->numify() if ref($a) && $a->can('numify');
 269
 270     if (defined $a)
 271       {
 272       # also croak on non-numerical
 273       if (!$a || $a <= 0)
 274         {
 275         require Carp;
 276         Carp::croak ('Argument to accuracy must be greater than zero');
 277         }
 278       if (int($a) != $a)
 279         {
 280         require Carp; Carp::croak ('Argument to accuracy must be an integer');
 281         }
 282       }
 283     if (ref($x))
 284       {
 285       # $object->accuracy() or fallback to global
 286       $x->bround($a) if $a;             # not for undef, 0
 287       $x->{_a} = $a;                    # set/overwrite, even if not rounded
 288       delete $x->{_p};                  # clear P
 289       $a = ${"${class}::accuracy"} unless defined $a;   # proper return value
 290       }
 291     else
 292       {
 293       ${"${class}::accuracy"} = $a;     # set global A
 294       ${"${class}::precision"} = undef; # clear global P
 295       }
 296     return $a;                          # shortcut
 297     }
 298
 299   my $r;
 300   # $object->accuracy() or fallback to global
 301   $r = $x->{_a} if ref($x);
 302   # but don't return global undef, when $x's accuracy is 0!
 303   $r = ${"${class}::accuracy"} if !defined $r;
 304   $r;
 305   }
 306
 307 sub precision
 308   {
 309   # $x->precision($p);          ref($x) $p
 310   # $x->precision();            ref($x)
 311   # Class->precision();         class
 312   # Class->precision($p);       class $p
 313
 314   my $x = shift;
 315   my $class = ref($x) || $x || __PACKAGE__;
 316
 317   no strict 'refs';
 318   if (@_ > 0)
 319     {
 320     my $p = shift;
 321     # convert objects to scalars to avoid deep recursion. If object doesn't
 322     # have numify(), then hopefully it will have overloading for int() and
 323     # boolean test without wandering into a deep recursion path...
 324     $p = $p->numify() if ref($p) && $p->can('numify');
 325     if ((defined $p) && (int($p) != $p))
 326       {
 327       require Carp; Carp::croak ('Argument to precision must be an integer');
 328       }
 329     if (ref($x))
 330       {
 331       # $object->precision() or fallback to global
 332       $x->bfround($p) if $p;            # not for undef, 0
 333       $x->{_p} = $p;                    # set/overwrite, even if not rounded
 334       delete $x->{_a};                  # clear A
 335       $p = ${"${class}::precision"} unless defined $p;  # proper return value
 336       }
 337     else
 338       {
 339       ${"${class}::precision"} = $p;    # set global P
 340       ${"${class}::accuracy"} = undef;  # clear global A
 341       }
 342     return $p;                          # shortcut
 343     }
 344
 345   my $r;
 346   # $object->precision() or fallback to global
 347   $r = $x->{_p} if ref($x);
 348   # but don't return global undef, when $x's precision is 0!
 349   $r = ${"${class}::precision"} if !defined $r;
 350   $r;
 351   }
 352
 353 sub config
 354   {
 355   # return (or set) configuration data as hash ref
 356   my $class = shift || 'Math::BigInt';
 357
 358   no strict 'refs';
 359   if (@_ > 0)
 360     {
 361     # try to set given options as arguments from hash
 362
 363     my $args = $_[0];
 364     if (ref($args) ne 'HASH')
 365       {
 366       $args = { @_ };
 367       }
 368     # these values can be "set"
 369     my $set_args = {};
 370     foreach my $key (
 371      qw/trap_inf trap_nan
 372         upgrade downgrade precision accuracy round_mode div_scale/
 373      )
 374       {
 375       $set_args->{$key} = $args->{$key} if exists $args->{$key};
 376       delete $args->{$key};
 377       }
 378     if (keys %$args > 0)
 379       {
 380       require Carp;
 381       Carp::croak ("Illegal key(s) '",
 382        join("','",keys %$args),"' passed to $class\->config()");
 383       }
 384     foreach my $key (keys %$set_args)
 385       {
 386       if ($key =~ /^trap_(inf|nan)\z/)
 387         {
 388         ${"${class}::_trap_$1"} = ($set_args->{"trap_$1"} ? 1 : 0);
 389         next;
 390         }
 391       # use a call instead of just setting the $variable to check argument
 392       $class->$key($set_args->{$key});
 393       }
 394     }
 395
 396   # now return actual configuration
 397
 398   my $cfg = {
 399     lib => $CALC,
 400     lib_version => ${"${CALC}::VERSION"},
 401     class => $class,
 402     trap_nan => ${"${class}::_trap_nan"},
 403     trap_inf => ${"${class}::_trap_inf"},
 404     version => ${"${class}::VERSION"},
 405     };
 406   foreach my $key (qw/
 407      upgrade downgrade precision accuracy round_mode div_scale
 408      /)
 409     {
 410     $cfg->{$key} = ${"${class}::$key"};
 411     };
 412   $cfg;
 413   }
 414
 415 sub _scale_a
 416   {
 417   # select accuracy parameter based on precedence,
 418   # used by bround() and bfround(), may return undef for scale (means no op)
 419   my ($x,$s,$m,$scale,$mode) = @_;
 420   $scale = $x->{_a} if !defined $scale;
 421   $scale = $s if (!defined $scale);
 422   $mode = $m if !defined $mode;
 423   return ($scale,$mode);
 424   }
 425
 426 sub _scale_p
 427   {
 428   # select precision parameter based on precedence,
 429   # used by bround() and bfround(), may return undef for scale (means no op)
 430   my ($x,$s,$m,$scale,$mode) = @_;
 431   $scale = $x->{_p} if !defined $scale;
 432   $scale = $s if (!defined $scale);
 433   $mode = $m if !defined $mode;
 434   return ($scale,$mode);
 435   }
 436
 437 ##############################################################################
 438 # constructors
 439
 440 sub copy
 441   {
 442   my ($c,$x);
 443   if (@_ > 1)
 444     {
 445     # if two arguments, the first one is the class to "swallow" subclasses
 446     ($c,$x) = @_;
 447     }
 448   else
 449     {
 450     $x = shift;
 451     $c = ref($x);
 452     }
 453   return unless ref($x); # only for objects
 454
 455   my $self = {}; bless $self,$c;
 456
 457   $self->{sign} = $x->{sign};
 458   $self->{value} = $CALC->_copy($x->{value});
 459   $self->{_a} = $x->{_a} if defined $x->{_a};
 460   $self->{_p} = $x->{_p} if defined $x->{_p};
 461   $self;
 462   }
 463
 464 sub new
 465   {
 466   # create a new BigInt object from a string or another BigInt object.
 467   # see hash keys documented at top
 468
 469   # the argument could be an object, so avoid ||, && etc on it, this would
 470   # cause costly overloaded code to be called. The only allowed ops are
 471   # ref() and defined.
 472
 473   my ($class,$wanted,$a,$p,$r) = @_;
 474
 475   # avoid numify-calls by not using || on $wanted!
 476   return $class->bzero($a,$p) if !defined $wanted;      # default to 0
 477   return $class->copy($wanted,$a,$p,$r)
 478    if ref($wanted) && $wanted->isa($class);             # MBI or subclass
 479
 480   $class->import() if $IMPORT == 0;             # make require work
 481
 482   my $self = bless {}, $class;
 483
 484   # shortcut for "normal" numbers
 485   if ((!ref $wanted) && ($wanted =~ /^([+-]?)[1-9][0-9]*\z/))
 486     {
 487     $self->{sign} = $1 || '+';
 488
 489     if ($wanted =~ /^[+-]/)
 490      {
 491       # remove sign without touching wanted to make it work with constants
 492       my $t = $wanted; $t =~ s/^[+-]//;
 493       $self->{value} = $CALC->_new($t);
 494       }
 495     else
 496       {
 497       $self->{value} = $CALC->_new($wanted);
 498       }
 499     no strict 'refs';
 500     if ( (defined $a) || (defined $p)
 501         || (defined ${"${class}::precision"})
 502         || (defined ${"${class}::accuracy"})
 503        )
 504       {
 505       $self->round($a,$p,$r) unless (@_ == 4 && !defined $a && !defined $p);
 506       }
 507     return $self;
 508     }
 509
 510   # handle '+inf', '-inf' first
 511   if ($wanted =~ /^[+-]?inf$/)
 512     {
 513     $self->{value} = $CALC->_zero();
 514     $self->{sign} = $wanted; $self->{sign} = '+inf' if $self->{sign} eq 'inf';
 515     return $self;
 516     }
 517   # split str in m mantissa, e exponent, i integer, f fraction, v value, s sign
 518   my ($mis,$miv,$mfv,$es,$ev) = _split($wanted);
 519   if (!ref $mis)
 520     {
 521     if ($_trap_nan)
 522       {
 523       require Carp; Carp::croak("$wanted is not a number in $class");
 524       }
 525     $self->{value} = $CALC->_zero();
 526     $self->{sign} = $nan;
 527     return $self;
 528     }
 529   if (!ref $miv)
 530     {
 531     # _from_hex or _from_bin
 532     $self->{value} = $mis->{value};
 533     $self->{sign} = $mis->{sign};
 534     return $self;       # throw away $mis
 535     }
 536   # make integer from mantissa by adjusting exp, then convert to bigint
 537   $self->{sign} = $$mis;                        # store sign
 538   $self->{value} = $CALC->_zero();              # for all the NaN cases
 539   my $e = int("$$es$$ev");                      # exponent (avoid recursion)
 540   if ($e > 0)
 541     {
 542     my $diff = $e - CORE::length($$mfv);
 543     if ($diff < 0)                              # Not integer
 544       {
 545       if ($_trap_nan)
 546         {
 547         require Carp; Carp::croak("$wanted not an integer in $class");
 548         }
 549       #print "NOI 1\n";
 550       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 551       $self->{sign} = $nan;
 552       }
 553     else                                        # diff >= 0
 554       {
 555       # adjust fraction and add it to value
 556       #print "diff > 0 $$miv\n";
 557       $$miv = $$miv . ($$mfv . '0' x $diff);
 558       }
 559     }
 560   else
 561     {
 562     if ($$mfv ne '')                            # e <= 0
 563       {
 564       # fraction and negative/zero E => NOI
 565       if ($_trap_nan)
 566         {
 567         require Carp; Carp::croak("$wanted not an integer in $class");
 568         }
 569       #print "NOI 2 \$\$mfv '$$mfv'\n";
 570       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 571       $self->{sign} = $nan;
 572       }
 573     elsif ($e < 0)
 574       {
 575       # xE-y, and empty mfv
 576       #print "xE-y\n";
 577       $e = abs($e);
 578       if ($$miv !~ s/0{$e}$//)          # can strip so many zero's?
 579         {
 580         if ($_trap_nan)
 581           {
 582           require Carp; Carp::croak("$wanted not an integer in $class");
 583           }
 584         #print "NOI 3\n";
 585         return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 586         $self->{sign} = $nan;
 587         }
 588       }
 589     }
 590   $self->{sign} = '+' if $$miv eq '0';                  # normalize -0 => +0
 591   $self->{value} = $CALC->_new($$miv) if $self->{sign} =~ /^[+-]$/;
 592   # if any of the globals is set, use them to round and store them inside $self
 593   # do not round for new($x,undef,undef) since that is used by MBF to signal
 594   # no rounding
 595   $self->round($a,$p,$r) unless @_ == 4 && !defined $a && !defined $p;
 596   $self;
 597   }
 598
 599 sub bnan
 600   {
 601   # create a bigint 'NaN', if given a BigInt, set it to 'NaN'
 602   my $self = shift;
 603   $self = $class if !defined $self;
 604   if (!ref($self))
 605     {
 606     my $c = $self; $self = {}; bless $self, $c;
 607     }
 608   no strict 'refs';
 609   if (${"${class}::_trap_nan"})
 610     {
 611     require Carp;
 612     Carp::croak ("Tried to set $self to NaN in $class\::bnan()");
 613     }
 614   $self->import() if $IMPORT == 0;              # make require work
 615   return if $self->modify('bnan');
 616   if ($self->can('_bnan'))
 617     {
 618     # use subclass to initialize
 619     $self->_bnan();
 620     }
 621   else
 622     {
 623     # otherwise do our own thing
 624     $self->{value} = $CALC->_zero();
 625     }
 626   $self->{sign} = $nan;
 627   delete $self->{_a}; delete $self->{_p};       # rounding NaN is silly
 628   $self;
 629   }
 630
 631 sub binf
 632   {
 633   # create a bigint '+-inf', if given a BigInt, set it to '+-inf'
 634   # the sign is either '+', or if given, used from there
 635   my $self = shift;
 636   my $sign = shift; $sign = '+' if !defined $sign || $sign !~ /^-(inf)?$/;
 637   $self = $class if !defined $self;
 638   if (!ref($self))
 639     {
 640     my $c = $self; $self = {}; bless $self, $c;
 641     }
 642   no strict 'refs';
 643   if (${"${class}::_trap_inf"})
 644     {
 645     require Carp;
 646     Carp::croak ("Tried to set $self to +-inf in $class\::binfn()");
 647     }
 648   $self->import() if $IMPORT == 0;              # make require work
 649   return if $self->modify('binf');
 650   if ($self->can('_binf'))
 651     {
 652     # use subclass to initialize
 653     $self->_binf();
 654     }
 655   else
 656     {
 657     # otherwise do our own thing
 658     $self->{value} = $CALC->_zero();
 659     }
 660   $sign = $sign . 'inf' if $sign !~ /inf$/;     # - => -inf
 661   $self->{sign} = $sign;
 662   ($self->{_a},$self->{_p}) = @_;               # take over requested rounding
 663   $self;
 664   }
 665
 666 sub bzero
 667   {
 668   # create a bigint '+0', if given a BigInt, set it to 0
 669   my $self = shift;
 670   $self = $class if !defined $self;
 671
 672   if (!ref($self))
 673     {
 674     my $c = $self; $self = {}; bless $self, $c;
 675     }
 676   $self->import() if $IMPORT == 0;              # make require work
 677   return if $self->modify('bzero');
 678
 679   if ($self->can('_bzero'))
 680     {
 681     # use subclass to initialize
 682     $self->_bzero();
 683     }
 684   else
 685     {
 686     # otherwise do our own thing
 687     $self->{value} = $CALC->_zero();
 688     }
 689   $self->{sign} = '+';
 690   if (@_ > 0)
 691     {
 692     if (@_ > 3)
 693       {
 694       # call like: $x->bzero($a,$p,$r,$y);
 695       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 696       }
 697     else
 698       {
 699       $self->{_a} = $_[0]
 700        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 701       $self->{_p} = $_[1]
 702        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 703       }
 704     }
 705   $self;
 706   }
 707
 708 sub bone
 709   {
 710   # create a bigint '+1' (or -1 if given sign '-'),
 711   # if given a BigInt, set it to +1 or -1, respecively
 712   my $self = shift;
 713   my $sign = shift; $sign = '+' if !defined $sign || $sign ne '-';
 714   $self = $class if !defined $self;
 715
 716   if (!ref($self))
 717     {
 718     my $c = $self; $self = {}; bless $self, $c;
 719     }
 720   $self->import() if $IMPORT == 0;              # make require work
 721   return if $self->modify('bone');
 722
 723   if ($self->can('_bone'))
 724     {
 725     # use subclass to initialize
 726     $self->_bone();
 727     }
 728   else
 729     {
 730     # otherwise do our own thing
 731     $self->{value} = $CALC->_one();
 732     }
 733   $self->{sign} = $sign;
 734   if (@_ > 0)
 735     {
 736     if (@_ > 3)
 737       {
 738       # call like: $x->bone($sign,$a,$p,$r,$y);
 739       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 740       }
 741     else
 742       {
 743       # call like: $x->bone($sign,$a,$p,$r);
 744       $self->{_a} = $_[0]
 745        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 746       $self->{_p} = $_[1]
 747        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 748       }
 749     }
 750   $self;
 751   }
 752
 753 ##############################################################################
 754 # string conversation
 755
 756 sub bsstr
 757   {
 758   # (ref to BFLOAT or num_str ) return num_str
 759   # Convert number from internal format to scientific string format.
 760   # internal format is always normalized (no leading zeros, "-0E0" => "+0E0")
 761   my $x = shift; $class = ref($x) || $x; $x = $class->new(shift) if !ref($x);
 762   # my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 763
 764   if ($x->{sign} !~ /^[+-]$/)
 765     {
 766     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 767     return 'inf';                                       # +inf
 768     }
 769   my ($m,$e) = $x->parts();
 770   #$m->bstr() . 'e+' . $e->bstr();      # e can only be positive in BigInt
 771   # 'e+' because E can only be positive in BigInt
 772   $m->bstr() . 'e+' . $CALC->_str($e->{value});
 773   }
 774
 775 sub bstr
 776   {
 777   # make a string from bigint object
 778   my $x = shift; $class = ref($x) || $x; $x = $class->new(shift) if !ref($x);
 779   # my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 780
 781   if ($x->{sign} !~ /^[+-]$/)
 782     {
 783     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 784     return 'inf';                                       # +inf
 785     }
 786   my $es = ''; $es = $x->{sign} if $x->{sign} eq '-';
 787   $es.$CALC->_str($x->{value});
 788   }
 789
 790 sub numify
 791   {
 792   # Make a "normal" scalar from a BigInt object
 793   my $x = shift; $x = $class->new($x) unless ref $x;
 794
 795   return $x->bstr() if $x->{sign} !~ /^[+-]$/;
 796   my $num = $CALC->_num($x->{value});
 797   return -$num if $x->{sign} eq '-';
 798   $num;
 799   }
 800
 801 ##############################################################################
 802 # public stuff (usually prefixed with "b")
 803
 804 sub sign
 805   {
 806   # return the sign of the number: +/-/-inf/+inf/NaN
 807   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 808
 809   $x->{sign};
 810   }
 811
 812 sub _find_round_parameters
 813   {
 814   # After any operation or when calling round(), the result is rounded by
 815   # regarding the A & P from arguments, local parameters, or globals.
 816
 817   # !!!!!!! If you change this, remember to change round(), too! !!!!!!!!!!
 818
 819   # This procedure finds the round parameters, but it is for speed reasons
 820   # duplicated in round. Otherwise, it is tested by the testsuite and used
 821   # by fdiv().
 822
 823   # returns ($self) or ($self,$a,$p,$r) - sets $self to NaN of both A and P
 824   # were requested/defined (locally or globally or both)
 825
 826   my ($self,$a,$p,$r,@args) = @_;
 827   # $a accuracy, if given by caller
 828   # $p precision, if given by caller
 829   # $r round_mode, if given by caller
 830   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 831
 832   # leave bigfloat parts alone
 833   return ($self) if exists $self->{_f} && ($self->{_f} & MB_NEVER_ROUND) != 0;
 834
 835   my $c = ref($self);                           # find out class of argument(s)
 836   no strict 'refs';
 837
 838   # now pick $a or $p, but only if we have got "arguments"
 839   if (!defined $a)
 840     {
 841     foreach ($self,@args)
 842       {
 843       # take the defined one, or if both defined, the one that is smaller
 844       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 845       }
 846     }
 847   if (!defined $p)
 848     {
 849     # even if $a is defined, take $p, to signal error for both defined
 850     foreach ($self,@args)
 851       {
 852       # take the defined one, or if both defined, the one that is bigger
 853       # -2 > -3, and 3 > 2
 854       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 855       }
 856     }
 857   # if still none defined, use globals (#2)
 858   $a = ${"$c\::accuracy"} unless defined $a;
 859   $p = ${"$c\::precision"} unless defined $p;
 860
 861   # A == 0 is useless, so undef it to signal no rounding
 862   $a = undef if defined $a && $a == 0;
 863
 864   # no rounding today?
 865   return ($self) unless defined $a || defined $p;               # early out
 866
 867   # set A and set P is an fatal error
 868   return ($self->bnan()) if defined $a && defined $p;           # error
 869
 870   $r = ${"$c\::round_mode"} unless defined $r;
 871   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 872     {
 873     require Carp; Carp::croak ("Unknown round mode '$r'");
 874     }
 875
 876   ($self,$a,$p,$r);
 877   }
 878
 879 sub round
 880   {
 881   # Round $self according to given parameters, or given second argument's
 882   # parameters or global defaults
 883
 884   # for speed reasons, _find_round_parameters is embeded here:
 885
 886   my ($self,$a,$p,$r,@args) = @_;
 887   # $a accuracy, if given by caller
 888   # $p precision, if given by caller
 889   # $r round_mode, if given by caller
 890   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 891
 892   # leave bigfloat parts alone
 893   return ($self) if exists $self->{_f} && ($self->{_f} & MB_NEVER_ROUND) != 0;
 894
 895   my $c = ref($self);                           # find out class of argument(s)
 896   no strict 'refs';
 897
 898   # now pick $a or $p, but only if we have got "arguments"
 899   if (!defined $a)
 900     {
 901     foreach ($self,@args)
 902       {
 903       # take the defined one, or if both defined, the one that is smaller
 904       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 905       }
 906     }
 907   if (!defined $p)
 908     {
 909     # even if $a is defined, take $p, to signal error for both defined
 910     foreach ($self,@args)
 911       {
 912       # take the defined one, or if both defined, the one that is bigger
 913       # -2 > -3, and 3 > 2
 914       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 915       }
 916     }
 917   # if still none defined, use globals (#2)
 918   $a = ${"$c\::accuracy"} unless defined $a;
 919   $p = ${"$c\::precision"} unless defined $p;
 920
 921   # A == 0 is useless, so undef it to signal no rounding
 922   $a = undef if defined $a && $a == 0;
 923
 924   # no rounding today?
 925   return $self unless defined $a || defined $p;         # early out
 926
 927   # set A and set P is an fatal error
 928   return $self->bnan() if defined $a && defined $p;
 929
 930   $r = ${"$c\::round_mode"} unless defined $r;
 931   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 932     {
 933     require Carp; Carp::croak ("Unknown round mode '$r'");
 934     }
 935
 936   # now round, by calling either fround or ffround:
 937   if (defined $a)
 938     {
 939     $self->bround($a,$r) if !defined $self->{_a} || $self->{_a} >= $a;
 940     }
 941   else # both can't be undefined due to early out
 942     {
 943     $self->bfround($p,$r) if !defined $self->{_p} || $self->{_p} <= $p;
 944     }
 945   $self->bnorm();                       # after round, normalize
 946   }
 947
 948 sub bnorm
 949   {
 950   # (numstr or BINT) return BINT
 951   # Normalize number -- no-op here
 952   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 953   $x;
 954   }
 955
 956 sub babs
 957   {
 958   # (BINT or num_str) return BINT
 959   # make number absolute, or return absolute BINT from string
 960   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 961
 962   return $x if $x->modify('babs');
 963   # post-normalized abs for internal use (does nothing for NaN)
 964   $x->{sign} =~ s/^-/+/;
 965   $x;
 966   }
 967
 968 sub bneg
 969   {
 970   # (BINT or num_str) return BINT
 971   # negate number or make a negated number from string
 972   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 973
 974   return $x if $x->modify('bneg');
 975
 976   # for +0 dont negate (to have always normalized)
 977   $x->{sign} =~ tr/+-/-+/ if !$x->is_zero();    # does nothing for NaN
 978   $x;
 979   }
 980
 981 sub bcmp
 982   {
 983   # Compares 2 values.  Returns one of undef, <0, =0, >0. (suitable for sort)
 984   # (BINT or num_str, BINT or num_str) return cond_code
 985
 986   # set up parameters
 987   my ($self,$x,$y) = (ref($_[0]),@_);
 988
 989   # objectify is costly, so avoid it
 990   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
 991     {
 992     ($self,$x,$y) = objectify(2,@_);
 993     }
 994
 995   return $upgrade->bcmp($x,$y) if defined $upgrade &&
 996     ((!$x->isa($self)) || (!$y->isa($self)));
 997
 998   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
 999     {
1000     # handle +-inf and NaN
1001     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1002     return 0 if $x->{sign} eq $y->{sign} && $x->{sign} =~ /^[+-]inf$/;
1003     return +1 if $x->{sign} eq '+inf';
1004     return -1 if $x->{sign} eq '-inf';
1005     return -1 if $y->{sign} eq '+inf';
1006     return +1;
1007     }
1008   # check sign for speed first
1009   return 1 if $x->{sign} eq '+' && $y->{sign} eq '-';   # does also 0 <=> -y
1010   return -1 if $x->{sign} eq '-' && $y->{sign} eq '+';  # does also -x <=> 0
1011
1012   # have same sign, so compare absolute values. Don't make tests for zero here
1013   # because it's actually slower than testin in Calc (especially w/ Pari et al)
1014
1015   # post-normalized compare for internal use (honors signs)
1016   if ($x->{sign} eq '+')
1017     {
1018     # $x and $y both > 0
1019     return $CALC->_acmp($x->{value},$y->{value});
1020     }
1021
1022   # $x && $y both < 0
1023   $CALC->_acmp($y->{value},$x->{value});        # swaped acmp (lib returns 0,1,-1)
1024   }
1025
1026 sub bacmp
1027   {
1028   # Compares 2 values, ignoring their signs.
1029   # Returns one of undef, <0, =0, >0. (suitable for sort)
1030   # (BINT, BINT) return cond_code
1031
1032   # set up parameters
1033   my ($self,$x,$y) = (ref($_[0]),@_);
1034   # objectify is costly, so avoid it
1035   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1036     {
1037     ($self,$x,$y) = objectify(2,@_);
1038     }
1039
1040   return $upgrade->bacmp($x,$y) if defined $upgrade &&
1041     ((!$x->isa($self)) || (!$y->isa($self)));
1042
1043   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1044     {
1045     # handle +-inf and NaN
1046     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1047     return 0 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} =~ /^[+-]inf$/;
1048     return 1 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} !~ /^[+-]inf$/;
1049     return -1;
1050     }
1051   $CALC->_acmp($x->{value},$y->{value});        # lib does only 0,1,-1
1052   }
1053
1054 sub badd
1055   {
1056   # add second arg (BINT or string) to first (BINT) (modifies first)
1057   # return result as BINT
1058
1059   # set up parameters
1060   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1061   # objectify is costly, so avoid it
1062   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1063     {
1064     ($self,$x,$y,@r) = objectify(2,@_);
1065     }
1066
1067   return $x if $x->modify('badd');
1068   return $upgrade->badd($upgrade->new($x),$upgrade->new($y),@r) if defined $upgrade &&
1069     ((!$x->isa($self)) || (!$y->isa($self)));
1070
1071   $r[3] = $y;                           # no push!
1072   # inf and NaN handling
1073   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1074     {
1075     # NaN first
1076     return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1077     # inf handling
1078     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1079       {
1080       # +inf++inf or -inf+-inf => same, rest is NaN
1081       return $x if $x->{sign} eq $y->{sign};
1082       return $x->bnan();
1083       }
1084     # +-inf + something => +inf
1085     # something +-inf => +-inf
1086     $x->{sign} = $y->{sign}, return $x if $y->{sign} =~ /^[+-]inf$/;
1087     return $x;
1088     }
1089
1090   my ($sx, $sy) = ( $x->{sign}, $y->{sign} );           # get signs
1091
1092   if ($sx eq $sy)
1093     {
1094     $x->{value} = $CALC->_add($x->{value},$y->{value}); # same sign, abs add
1095     }
1096   else
1097     {
1098     my $a = $CALC->_acmp ($y->{value},$x->{value});     # absolute compare
1099     if ($a > 0)
1100       {
1101       $x->{value} = $CALC->_sub($y->{value},$x->{value},1); # abs sub w/ swap
1102       $x->{sign} = $sy;
1103       }
1104     elsif ($a == 0)
1105       {
1106       # speedup, if equal, set result to 0
1107       $x->{value} = $CALC->_zero();
1108       $x->{sign} = '+';
1109       }
1110     else # a < 0
1111       {
1112       $x->{value} = $CALC->_sub($x->{value}, $y->{value}); # abs sub
1113       }
1114     }
1115   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1116   $x;
1117   }
1118
1119 sub bsub
1120   {
1121   # (BINT or num_str, BINT or num_str) return BINT
1122   # subtract second arg from first, modify first
1123
1124   # set up parameters
1125   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1126   # objectify is costly, so avoid it
1127   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1128     {
1129     ($self,$x,$y,@r) = objectify(2,@_);
1130     }
1131
1132   return $x if $x->modify('bsub');
1133
1134   return $upgrade->new($x)->bsub($upgrade->new($y),@r) if defined $upgrade &&
1135    ((!$x->isa($self)) || (!$y->isa($self)));
1136
1137   if ($y->is_zero())
1138     {
1139     $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1140     return $x;
1141     }
1142
1143   require Scalar::Util;
1144   if (Scalar::Util::refaddr($x) == Scalar::Util::refaddr($y))
1145     {
1146     # if we get the same variable twice, the result must be zero (the code
1147     # below fails in that case)
1148     return $x->bzero(@r) if $x->{sign} =~ /^[+-]$/;
1149     return $x->bnan();          # NaN, -inf, +inf
1150     }
1151   $y->{sign} =~ tr/+\-/-+/;     # does nothing for NaN
1152   $x->badd($y,@r);              # badd does not leave internal zeros
1153   $y->{sign} =~ tr/+\-/-+/;     # refix $y (does nothing for NaN)
1154   $x;                           # already rounded by badd() or no round necc.
1155   }
1156
1157 sub binc
1158   {
1159   # increment arg by one
1160   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1161   return $x if $x->modify('binc');
1162
1163   if ($x->{sign} eq '+')
1164     {
1165     $x->{value} = $CALC->_inc($x->{value});
1166     $x->round($a,$p,$r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1167     return $x;
1168     }
1169   elsif ($x->{sign} eq '-')
1170     {
1171     $x->{value} = $CALC->_dec($x->{value});
1172     $x->{sign} = '+' if $CALC->_is_zero($x->{value}); # -1 +1 => -0 => +0
1173     $x->round($a,$p,$r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1174     return $x;
1175     }
1176   # inf, nan handling etc
1177   $x->badd($self->bone(),$a,$p,$r);             # badd does round
1178   }
1179
1180 sub bdec
1181   {
1182   # decrement arg by one
1183   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1184   return $x if $x->modify('bdec');
1185
1186   if ($x->{sign} eq '-')
1187     {
1188     # < 0
1189     $x->{value} = $CALC->_inc($x->{value});
1190     }
1191   else
1192     {
1193     return $x->badd($self->bone('-'),@r) unless $x->{sign} eq '+'; # inf/NaN
1194     # >= 0
1195     if ($CALC->_is_zero($x->{value}))
1196       {
1197       # == 0
1198       $x->{value} = $CALC->_one(); $x->{sign} = '-';            # 0 => -1
1199       }
1200     else
1201       {
1202       # > 0
1203       $x->{value} = $CALC->_dec($x->{value});
1204       }
1205     }
1206   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1207   $x;
1208   }
1209
1210 sub blog
1211   {
1212   # calculate $x = $a ** $base + $b and return $a (e.g. the log() to base
1213   # $base of $x)
1214
1215   # set up parameters
1216   my ($self,$x,$base,@r) = (ref($_[0]),@_);
1217   # objectify is costly, so avoid it
1218   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1219     {
1220     ($self,$x,$base,@r) = objectify(1,$class,@_);
1221     }
1222
1223   return $x if $x->modify('blog');
1224
1225   # inf, -inf, NaN, <0 => NaN
1226   return $x->bnan()
1227    if $x->{sign} ne '+' || (defined $base && $base->{sign} ne '+');
1228
1229   return $upgrade->blog($upgrade->new($x),$base,@r) if
1230     defined $upgrade;
1231
1232   my ($rc,$exact) = $CALC->_log_int($x->{value},$base->{value});
1233   return $x->bnan() unless defined $rc;         # not possible to take log?
1234   $x->{value} = $rc;
1235   $x->round(@r);
1236   }
1237
1238 sub blcm
1239   {
1240   # (BINT or num_str, BINT or num_str) return BINT
1241   # does not modify arguments, but returns new object
1242   # Lowest Common Multiplicator
1243
1244   my $y = shift; my ($x);
1245   if (ref($y))
1246     {
1247     $x = $y->copy();
1248     }
1249   else
1250     {
1251     $x = __PACKAGE__->new($y);
1252     }
1253   my $self = ref($x);
1254   while (@_)
1255     {
1256     my $y = shift; $y = $self->new($y) if !ref ($y);
1257     $x = __lcm($x,$y);
1258     }
1259   $x;
1260   }
1261
1262 sub bgcd
1263   {
1264   # (BINT or num_str, BINT or num_str) return BINT
1265   # does not modify arguments, but returns new object
1266   # GCD -- Euclids algorithm, variant C (Knuth Vol 3, pg 341 ff)
1267
1268   my $y = shift;
1269   $y = __PACKAGE__->new($y) if !ref($y);
1270   my $self = ref($y);
1271   my $x = $y->copy()->babs();                   # keep arguments
1272   return $x->bnan() if $x->{sign} !~ /^[+-]$/;  # x NaN?
1273
1274   while (@_)
1275     {
1276     $y = shift; $y = $self->new($y) if !ref($y);
1277     next if $y->is_zero();
1278     return $x->bnan() if $y->{sign} !~ /^[+-]$/;        # y NaN?
1279     $x->{value} = $CALC->_gcd($x->{value},$y->{value}); last if $x->is_one();
1280     }
1281   $x;
1282   }
1283
1284 sub bnot
1285   {
1286   # (num_str or BINT) return BINT
1287   # represent ~x as twos-complement number
1288   # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1289   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1290
1291   return $x if $x->modify('bnot');
1292   $x->binc()->bneg();                   # binc already does round
1293   }
1294
1295 ##############################################################################
1296 # is_foo test routines
1297 # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1298
1299 sub is_zero
1300   {
1301   # return true if arg (BINT or num_str) is zero (array '+', '0')
1302   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1303
1304   return 0 if $x->{sign} !~ /^\+$/;                     # -, NaN & +-inf aren't
1305   $CALC->_is_zero($x->{value});
1306   }
1307
1308 sub is_nan
1309   {
1310   # return true if arg (BINT or num_str) is NaN
1311   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1312
1313   $x->{sign} eq $nan ? 1 : 0;
1314   }
1315
1316 sub is_inf
1317   {
1318   # return true if arg (BINT or num_str) is +-inf
1319   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1320
1321   if (defined $sign)
1322     {
1323     $sign = '[+-]inf' if $sign eq '';   # +- doesn't matter, only that's inf
1324     $sign = "[$1]inf" if $sign =~ /^([+-])(inf)?$/;     # extract '+' or '-'
1325     return $x->{sign} =~ /^$sign$/ ? 1 : 0;
1326     }
1327   $x->{sign} =~ /^[+-]inf$/ ? 1 : 0;            # only +-inf is infinity
1328   }
1329
1330 sub is_one
1331   {
1332   # return true if arg (BINT or num_str) is +1, or -1 if sign is given
1333   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1334
1335   $sign = '+' if !defined $sign || $sign ne '-';
1336
1337   return 0 if $x->{sign} ne $sign;      # -1 != +1, NaN, +-inf aren't either
1338   $CALC->_is_one($x->{value});
1339   }
1340
1341 sub is_odd
1342   {
1343   # return true when arg (BINT or num_str) is odd, false for even
1344   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1345
1346   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1347   $CALC->_is_odd($x->{value});
1348   }
1349
1350 sub is_even
1351   {
1352   # return true when arg (BINT or num_str) is even, false for odd
1353   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1354
1355   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1356   $CALC->_is_even($x->{value});
1357   }
1358
1359 sub is_positive
1360   {
1361   # return true when arg (BINT or num_str) is positive (>= 0)
1362   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1363
1364   $x->{sign} =~ /^\+/ ? 1 : 0;          # +inf is also positive, but NaN not
1365   }
1366
1367 sub is_negative
1368   {
1369   # return true when arg (BINT or num_str) is negative (< 0)
1370   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1371
1372   $x->{sign} =~ /^-/ ? 1 : 0;           # -inf is also negative, but NaN not
1373   }
1374
1375 sub is_int
1376   {
1377   # return true when arg (BINT or num_str) is an integer
1378   # always true for BigInt, but different for BigFloats
1379   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1380
1381   $x->{sign} =~ /^[+-]$/ ? 1 : 0;               # inf/-inf/NaN aren't
1382   }
1383
1384 ###############################################################################
1385
1386 sub bmul
1387   {
1388   # multiply two numbers -- stolen from Knuth Vol 2 pg 233
1389   # (BINT or num_str, BINT or num_str) return BINT
1390
1391   # set up parameters
1392   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1393   # objectify is costly, so avoid it
1394   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1395     {
1396     ($self,$x,$y,@r) = objectify(2,@_);
1397     }
1398
1399   return $x if $x->modify('bmul');
1400
1401   return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1402
1403   # inf handling
1404   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1405     {
1406     return $x->bnan() if $x->is_zero() || $y->is_zero();
1407     # result will always be +-inf:
1408     # +inf * +/+inf => +inf, -inf * -/-inf => +inf
1409     # +inf * -/-inf => -inf, -inf * +/+inf => -inf
1410     return $x->binf() if ($x->{sign} =~ /^\+/ && $y->{sign} =~ /^\+/);
1411     return $x->binf() if ($x->{sign} =~ /^-/ && $y->{sign} =~ /^-/);
1412     return $x->binf('-');
1413     }
1414
1415   return $upgrade->bmul($x,$upgrade->new($y),@r)
1416    if defined $upgrade && !$y->isa($self);
1417
1418   $r[3] = $y;                           # no push here
1419
1420   $x->{sign} = $x->{sign} eq $y->{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 => +
1421
1422   $x->{value} = $CALC->_mul($x->{value},$y->{value});   # do actual math
1423   $x->{sign} = '+' if $CALC->_is_zero($x->{value});     # no -0
1424
1425   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1426   $x;
1427   }
1428
1429 sub _div_inf
1430   {
1431   # helper function that handles +-inf cases for bdiv()/bmod() to reuse code
1432   my ($self,$x,$y) = @_;
1433
1434   # NaN if x == NaN or y == NaN or x==y==0
1435   return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan()
1436    if (($x->is_nan() || $y->is_nan())   ||
1437        ($x->is_zero() && $y->is_zero()));
1438
1439   # +-inf / +-inf == NaN, reminder also NaN
1440   if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1441     {
1442     return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan();
1443     }
1444   # x / +-inf => 0, remainder x (works even if x == 0)
1445   if ($y->{sign} =~ /^[+-]inf$/)
1446     {
1447     my $t = $x->copy();         # bzero clobbers up $x
1448     return wantarray ? ($x->bzero(),$t) : $x->bzero()
1449     }
1450
1451   # 5 / 0 => +inf, -6 / 0 => -inf
1452   # +inf / 0 = inf, inf,  and -inf / 0 => -inf, -inf
1453   # exception:   -8 / 0 has remainder -8, not 8
1454   # exception: -inf / 0 has remainder -inf, not inf
1455   if ($y->is_zero())
1456     {
1457     # +-inf / 0 => special case for -inf
1458     return wantarray ?  ($x,$x->copy()) : $x if $x->is_inf();
1459     if (!$x->is_zero() && !$x->is_inf())
1460       {
1461       my $t = $x->copy();               # binf clobbers up $x
1462       return wantarray ?
1463        ($x->binf($x->{sign}),$t) : $x->binf($x->{sign})
1464       }
1465     }
1466
1467   # last case: +-inf / ordinary number
1468   my $sign = '+inf';
1469   $sign = '-inf' if substr($x->{sign},0,1) ne $y->{sign};
1470   $x->{sign} = $sign;
1471   return wantarray ? ($x,$self->bzero()) : $x;
1472   }
1473
1474 sub bdiv
1475   {
1476   # (dividend: BINT or num_str, divisor: BINT or num_str) return
1477   # (BINT,BINT) (quo,rem) or BINT (only rem)
1478
1479   # set up parameters
1480   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1481   # objectify is costly, so avoid it
1482   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1483     {
1484     ($self,$x,$y,@r) = objectify(2,@_);
1485     }
1486
1487   return $x if $x->modify('bdiv');
1488
1489   return $self->_div_inf($x,$y)
1490    if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero());
1491
1492   return $upgrade->bdiv($upgrade->new($x),$upgrade->new($y),@r)
1493    if defined $upgrade;
1494
1495   $r[3] = $y;                                   # no push!
1496
1497   # calc new sign and in case $y == +/- 1, return $x
1498   my $xsign = $x->{sign};                               # keep
1499   $x->{sign} = ($x->{sign} ne $y->{sign} ? '-' : '+');
1500
1501   if (wantarray)
1502     {
1503     my $rem = $self->bzero();
1504     ($x->{value},$rem->{value}) = $CALC->_div($x->{value},$y->{value});
1505     $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1506     $rem->{_a} = $x->{_a};
1507     $rem->{_p} = $x->{_p};
1508     $x->round(@r) if !exists $x->{_f} || ($x->{_f} & MB_NEVER_ROUND) == 0;
1509     if (! $CALC->_is_zero($rem->{value}))
1510       {
1511       $rem->{sign} = $y->{sign};
1512       $rem = $y->copy()->bsub($rem) if $xsign ne $y->{sign}; # one of them '-'
1513       }
1514     else
1515       {
1516       $rem->{sign} = '+';                       # dont leave -0
1517       }
1518     $rem->round(@r) if !exists $rem->{_f} || ($rem->{_f} & MB_NEVER_ROUND) == 0;
1519     return ($x,$rem);
1520     }
1521
1522   $x->{value} = $CALC->_div($x->{value},$y->{value});
1523   $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1524
1525   $x->round(@r) if !exists $x->{_f} || ($x->{_f} & MB_NEVER_ROUND) == 0;
1526   $x;
1527   }
1528
1529 ###############################################################################
1530 # modulus functions
1531
1532 sub bmod
1533   {
1534   # modulus (or remainder)
1535   # (BINT or num_str, BINT or num_str) return BINT
1536
1537   # set up parameters
1538   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1539   # objectify is costly, so avoid it
1540   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1541     {
1542     ($self,$x,$y,@r) = objectify(2,@_);
1543     }
1544
1545   return $x if $x->modify('bmod');
1546   $r[3] = $y;                                   # no push!
1547   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero())
1548     {
1549     my ($d,$r) = $self->_div_inf($x,$y);
1550     $x->{sign} = $r->{sign};
1551     $x->{value} = $r->{value};
1552     return $x->round(@r);
1553     }
1554
1555   # calc new sign and in case $y == +/- 1, return $x
1556   $x->{value} = $CALC->_mod($x->{value},$y->{value});
1557   if (!$CALC->_is_zero($x->{value}))
1558     {
1559     my $xsign = $x->{sign};
1560     $x->{sign} = $y->{sign};
1561     if ($xsign ne $y->{sign})
1562       {
1563       my $t = $CALC->_copy($x->{value});                # copy $x
1564       $x->{value} = $CALC->_sub($y->{value},$t,1);      # $y-$x
1565       }
1566     }
1567    else
1568     {
1569     $x->{sign} = '+';                           # dont leave -0
1570     }
1571   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1572   $x;
1573   }
1574
1575 sub bmodinv
1576   {
1577   # Modular inverse.  given a number which is (hopefully) relatively
1578   # prime to the modulus, calculate its inverse using Euclid's
1579   # alogrithm.  If the number is not relatively prime to the modulus
1580   # (i.e. their gcd is not one) then NaN is returned.
1581
1582   # set up parameters
1583   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1584   # objectify is costly, so avoid it
1585   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1586     {
1587     ($self,$x,$y,@r) = objectify(2,@_);
1588     }
1589
1590   return $x if $x->modify('bmodinv');
1591
1592   return $x->bnan()
1593         if ($y->{sign} ne '+'                           # -, NaN, +inf, -inf
1594          || $x->is_zero()                               # or num == 0
1595          || $x->{sign} !~ /^[+-]$/                      # or num NaN, inf, -inf
1596         );
1597
1598   # put least residue into $x if $x was negative, and thus make it positive
1599   $x->bmod($y) if $x->{sign} eq '-';
1600
1601   my $sign;
1602   ($x->{value},$sign) = $CALC->_modinv($x->{value},$y->{value});
1603   return $x->bnan() if !defined $x->{value};            # in case no GCD found
1604   return $x if !defined $sign;                  # already real result
1605   $x->{sign} = $sign;                           # flip/flop see below
1606   $x->bmod($y);                                 # calc real result
1607   $x;
1608   }
1609
1610 sub bmodpow
1611   {
1612   # takes a very large number to a very large exponent in a given very
1613   # large modulus, quickly, thanks to binary exponentation.  supports
1614   # negative exponents.
1615   my ($self,$num,$exp,$mod,@r) = objectify(3,@_);
1616
1617   return $num if $num->modify('bmodpow');
1618
1619   # check modulus for valid values
1620   return $num->bnan() if ($mod->{sign} ne '+'           # NaN, - , -inf, +inf
1621                        || $mod->is_zero());
1622
1623   # check exponent for valid values
1624   if ($exp->{sign} =~ /\w/)
1625     {
1626     # i.e., if it's NaN, +inf, or -inf...
1627     return $num->bnan();
1628     }
1629
1630   $num->bmodinv ($mod) if ($exp->{sign} eq '-');
1631
1632   # check num for valid values (also NaN if there was no inverse but $exp < 0)
1633   return $num->bnan() if $num->{sign} !~ /^[+-]$/;
1634
1635   # $mod is positive, sign on $exp is ignored, result also positive
1636   $num->{value} = $CALC->_modpow($num->{value},$exp->{value},$mod->{value});
1637   $num;
1638   }
1639
1640 ###############################################################################
1641
1642 sub bfac
1643   {
1644   # (BINT or num_str, BINT or num_str) return BINT
1645   # compute factorial number from $x, modify $x in place
1646   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1647
1648   return $x if $x->modify('bfac');
1649
1650   return $x if $x->{sign} eq '+inf';            # inf => inf
1651   return $x->bnan() if $x->{sign} ne '+';       # NaN, <0 etc => NaN
1652
1653   $x->{value} = $CALC->_fac($x->{value});
1654   $x->round(@r);
1655   }
1656
1657 sub bpow
1658   {
1659   # (BINT or num_str, BINT or num_str) return BINT
1660   # compute power of two numbers -- stolen from Knuth Vol 2 pg 233
1661   # modifies first argument
1662
1663   # set up parameters
1664   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1665   # objectify is costly, so avoid it
1666   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1667     {
1668     ($self,$x,$y,@r) = objectify(2,@_);
1669     }
1670
1671   return $x if $x->modify('bpow');
1672
1673   return $upgrade->bpow($upgrade->new($x),$y,@r)
1674    if defined $upgrade && !$y->isa($self);
1675
1676   $r[3] = $y;                                   # no push!
1677   return $x if $x->{sign} =~ /^[+-]inf$/;       # -inf/+inf ** x
1678   return $x->bnan() if $x->{sign} eq $nan || $y->{sign} eq $nan;
1679
1680   # cases 0 ** Y, X ** 0, X ** 1, 1 ** Y are handled by Calc or Emu
1681
1682   my $new_sign = '+';
1683   $new_sign = $y->is_odd() ? '-' : '+' if ($x->{sign} ne '+');
1684
1685   # 0 ** -7 => ( 1 / (0 ** 7)) => 1 / 0 => +inf
1686   return $x->binf()
1687     if $y->{sign} eq '-' && $x->{sign} eq '+' && $CALC->_is_zero($x->{value});
1688   # 1 ** -y => 1 / (1 ** |y|)
1689   # so do test for negative $y after above's clause
1690   return $x->bnan() if $y->{sign} eq '-' && !$CALC->_is_one($x->{value});
1691
1692   $x->{value} = $CALC->_pow($x->{value},$y->{value});
1693   $x->{sign} = $new_sign;
1694   $x->{sign} = '+' if $CALC->_is_zero($y->{value});
1695   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1696   $x;
1697   }
1698
1699 sub blsft
1700   {
1701   # (BINT or num_str, BINT or num_str) return BINT
1702   # compute x << y, base n, y >= 0
1703
1704   # set up parameters
1705   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1706   # objectify is costly, so avoid it
1707   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1708     {
1709     ($self,$x,$y,$n,@r) = objectify(2,@_);
1710     }
1711
1712   return $x if $x->modify('blsft');
1713   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1714   return $x->round(@r) if $y->is_zero();
1715
1716   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1717
1718   $x->{value} = $CALC->_lsft($x->{value},$y->{value},$n);
1719   $x->round(@r);
1720   }
1721
1722 sub brsft
1723   {
1724   # (BINT or num_str, BINT or num_str) return BINT
1725   # compute x >> y, base n, y >= 0
1726
1727   # set up parameters
1728   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1729   # objectify is costly, so avoid it
1730   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1731     {
1732     ($self,$x,$y,$n,@r) = objectify(2,@_);
1733     }
1734
1735   return $x if $x->modify('brsft');
1736   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1737   return $x->round(@r) if $y->is_zero();
1738   return $x->bzero(@r) if $x->is_zero();                # 0 => 0
1739
1740   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1741
1742    # this only works for negative numbers when shifting in base 2
1743   if (($x->{sign} eq '-') && ($n == 2))
1744     {
1745     return $x->round(@r) if $x->is_one('-');    # -1 => -1
1746     if (!$y->is_one())
1747       {
1748       # although this is O(N*N) in calc (as_bin!) it is O(N) in Pari et al
1749       # but perhaps there is a better emulation for two's complement shift...
1750       # if $y != 1, we must simulate it by doing:
1751       # convert to bin, flip all bits, shift, and be done
1752       $x->binc();                       # -3 => -2
1753       my $bin = $x->as_bin();
1754       $bin =~ s/^-0b//;                 # strip '-0b' prefix
1755       $bin =~ tr/10/01/;                # flip bits
1756       # now shift
1757       if (CORE::length($bin) <= $y)
1758         {
1759         $bin = '0';                     # shifting to far right creates -1
1760                                         # 0, because later increment makes
1761                                         # that 1, attached '-' makes it '-1'
1762                                         # because -1 >> x == -1 !
1763         }
1764       else
1765         {
1766         $bin =~ s/.{$y}$//;             # cut off at the right side
1767         $bin = '1' . $bin;              # extend left side by one dummy '1'
1768         $bin =~ tr/10/01/;              # flip bits back
1769         }
1770       my $res = $self->new('0b'.$bin);  # add prefix and convert back
1771       $res->binc();                     # remember to increment
1772       $x->{value} = $res->{value};      # take over value
1773       return $x->round(@r);             # we are done now, magic, isn't?
1774       }
1775     # x < 0, n == 2, y == 1
1776     $x->bdec();                         # n == 2, but $y == 1: this fixes it
1777     }
1778
1779   $x->{value} = $CALC->_rsft($x->{value},$y->{value},$n);
1780   $x->round(@r);
1781   }
1782
1783 sub band
1784   {
1785   #(BINT or num_str, BINT or num_str) return BINT
1786   # compute x & y
1787
1788   # set up parameters
1789   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1790   # objectify is costly, so avoid it
1791   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1792     {
1793     ($self,$x,$y,@r) = objectify(2,@_);
1794     }
1795
1796   return $x if $x->modify('band');
1797
1798   $r[3] = $y;                           # no push!
1799
1800   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1801
1802   my $sx = $x->{sign} eq '+' ? 1 : -1;
1803   my $sy = $y->{sign} eq '+' ? 1 : -1;
1804
1805   if ($sx == 1 && $sy == 1)
1806     {
1807     $x->{value} = $CALC->_and($x->{value},$y->{value});
1808     return $x->round(@r);
1809     }
1810
1811   if ($CAN{signed_and})
1812     {
1813     $x->{value} = $CALC->_signed_and($x->{value},$y->{value},$sx,$sy);
1814     return $x->round(@r);
1815     }
1816
1817   require $EMU_LIB;
1818   __emu_band($self,$x,$y,$sx,$sy,@r);
1819   }
1820
1821 sub bior
1822   {
1823   #(BINT or num_str, BINT or num_str) return BINT
1824   # compute x | y
1825
1826   # set up parameters
1827   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1828   # objectify is costly, so avoid it
1829   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1830     {
1831     ($self,$x,$y,@r) = objectify(2,@_);
1832     }
1833
1834   return $x if $x->modify('bior');
1835   $r[3] = $y;                           # no push!
1836
1837   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1838
1839   my $sx = $x->{sign} eq '+' ? 1 : -1;
1840   my $sy = $y->{sign} eq '+' ? 1 : -1;
1841
1842   # the sign of X follows the sign of X, e.g. sign of Y irrelevant for bior()
1843
1844   # don't use lib for negative values
1845   if ($sx == 1 && $sy == 1)
1846     {
1847     $x->{value} = $CALC->_or($x->{value},$y->{value});
1848     return $x->round(@r);
1849     }
1850
1851   # if lib can do negative values, let it handle this
1852   if ($CAN{signed_or})
1853     {
1854     $x->{value} = $CALC->_signed_or($x->{value},$y->{value},$sx,$sy);
1855     return $x->round(@r);
1856     }
1857
1858   require $EMU_LIB;
1859   __emu_bior($self,$x,$y,$sx,$sy,@r);
1860   }
1861
1862 sub bxor
1863   {
1864   #(BINT or num_str, BINT or num_str) return BINT
1865   # compute x ^ y
1866
1867   # set up parameters
1868   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1869   # objectify is costly, so avoid it
1870   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1871     {
1872     ($self,$x,$y,@r) = objectify(2,@_);
1873     }
1874
1875   return $x if $x->modify('bxor');
1876   $r[3] = $y;                           # no push!
1877
1878   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1879
1880   my $sx = $x->{sign} eq '+' ? 1 : -1;
1881   my $sy = $y->{sign} eq '+' ? 1 : -1;
1882
1883   # don't use lib for negative values
1884   if ($sx == 1 && $sy == 1)
1885     {
1886     $x->{value} = $CALC->_xor($x->{value},$y->{value});
1887     return $x->round(@r);
1888     }
1889
1890   # if lib can do negative values, let it handle this
1891   if ($CAN{signed_xor})
1892     {
1893     $x->{value} = $CALC->_signed_xor($x->{value},$y->{value},$sx,$sy);
1894     return $x->round(@r);
1895     }
1896
1897   require $EMU_LIB;
1898   __emu_bxor($self,$x,$y,$sx,$sy,@r);
1899   }
1900
1901 sub length
1902   {
1903   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1904
1905   my $e = $CALC->_len($x->{value});
1906   wantarray ? ($e,0) : $e;
1907   }
1908
1909 sub digit
1910   {
1911   # return the nth decimal digit, negative values count backward, 0 is right
1912   my ($self,$x,$n) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1913
1914   $n = $n->numify() if ref($n);
1915   $CALC->_digit($x->{value},$n||0);
1916   }
1917
1918 sub _trailing_zeros
1919   {
1920   # return the amount of trailing zeros in $x (as scalar)
1921   my $x = shift;
1922   $x = $class->new($x) unless ref $x;
1923
1924   return 0 if $x->{sign} !~ /^[+-]$/;   # NaN, inf, -inf etc
1925
1926   $CALC->_zeros($x->{value});           # must handle odd values, 0 etc
1927   }
1928
1929 sub bsqrt
1930   {
1931   # calculate square root of $x
1932   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1933
1934   return $x if $x->modify('bsqrt');
1935
1936   return $x->bnan() if $x->{sign} !~ /^\+/;     # -x or -inf or NaN => NaN
1937   return $x if $x->{sign} eq '+inf';            # sqrt(+inf) == inf
1938
1939   return $upgrade->bsqrt($x,@r) if defined $upgrade;
1940
1941   $x->{value} = $CALC->_sqrt($x->{value});
1942   $x->round(@r);
1943   }
1944
1945 sub broot
1946   {
1947   # calculate $y'th root of $x
1948
1949   # set up parameters
1950   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1951
1952   $y = $self->new(2) unless defined $y;
1953
1954   # objectify is costly, so avoid it
1955   if ((!ref($x)) || (ref($x) ne ref($y)))
1956     {
1957     ($self,$x,$y,@r) = objectify(2,$self || $class,@_);
1958     }
1959
1960   return $x if $x->modify('broot');
1961
1962   # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
1963   return $x->bnan() if $x->{sign} !~ /^\+/ || $y->is_zero() ||
1964          $y->{sign} !~ /^\+$/;
1965
1966   return $x->round(@r)
1967     if $x->is_zero() || $x->is_one() || $x->is_inf() || $y->is_one();
1968
1969   return $upgrade->new($x)->broot($upgrade->new($y),@r) if defined $upgrade;
1970
1971   $x->{value} = $CALC->_root($x->{value},$y->{value});
1972   $x->round(@r);
1973   }
1974
1975 sub exponent
1976   {
1977   # return a copy of the exponent (here always 0, NaN or 1 for $m == 0)
1978   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
1979
1980   if ($x->{sign} !~ /^[+-]$/)
1981     {
1982     my $s = $x->{sign}; $s =~ s/^[+-]//;  # NaN, -inf,+inf => NaN or inf
1983     return $self->new($s);
1984     }
1985   return $self->bone() if $x->is_zero();
1986
1987   $self->new($x->_trailing_zeros());
1988   }
1989
1990 sub mantissa
1991   {
1992   # return the mantissa (compatible to Math::BigFloat, e.g. reduced)
1993   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
1994
1995   if ($x->{sign} !~ /^[+-]$/)
1996     {
1997     # for NaN, +inf, -inf: keep the sign
1998     return $self->new($x->{sign});
1999     }
2000   my $m = $x->copy(); delete $m->{_p}; delete $m->{_a};
2001   # that's a bit inefficient:
2002   my $zeros = $m->_trailing_zeros();
2003   $m->brsft($zeros,10) if $zeros != 0;
2004   $m;
2005   }
2006
2007 sub parts
2008   {
2009   # return a copy of both the exponent and the mantissa
2010   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2011
2012   ($x->mantissa(),$x->exponent());
2013   }
2014
2015 ##############################################################################
2016 # rounding functions
2017
2018 sub bfround
2019   {
2020   # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
2021   # $n == 0 || $n == 1 => round to integer
2022   my $x = shift; my $self = ref($x) || $x; $x = $self->new($x) unless ref $x;
2023
2024   my ($scale,$mode) = $x->_scale_p($x->precision(),$x->round_mode(),@_);
2025
2026   return $x if !defined $scale || $x->modify('bfround');        # no-op
2027
2028   # no-op for BigInts if $n <= 0
2029   $x->bround( $x->length()-$scale, $mode) if $scale > 0;
2030
2031   delete $x->{_a};      # delete to save memory
2032   $x->{_p} = $scale;    # store new _p
2033   $x;
2034   }
2035
2036 sub _scan_for_nonzero
2037   {
2038   # internal, used by bround() to scan for non-zeros after a '5'
2039   my ($x,$pad,$xs,$len) = @_;
2040
2041   return 0 if $len == 1;                # "5" is trailed by invisible zeros
2042   my $follow = $pad - 1;
2043   return 0 if $follow > $len || $follow < 1;
2044
2045   # use the string form to check whether only '0's follow or not
2046   substr ($xs,-$follow) =~ /[^0]/ ? 1 : 0;
2047   }
2048
2049 sub fround
2050   {
2051   # Exists to make life easier for switch between MBF and MBI (should we
2052   # autoload fxxx() like MBF does for bxxx()?)
2053   my $x = shift;
2054   $x->bround(@_);
2055   }
2056
2057 sub bround
2058   {
2059   # accuracy: +$n preserve $n digits from left,
2060   #           -$n preserve $n digits from right (f.i. for 0.1234 style in MBF)
2061   # no-op for $n == 0
2062   # and overwrite the rest with 0's, return normalized number
2063   # do not return $x->bnorm(), but $x
2064
2065   my $x = shift; $x = $class->new($x) unless ref $x;
2066   my ($scale,$mode) = $x->_scale_a($x->accuracy(),$x->round_mode(),@_);
2067   return $x if !defined $scale;                 # no-op
2068   return $x if $x->modify('bround');
2069
2070   if ($x->is_zero() || $scale == 0)
2071     {
2072     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2073     return $x;
2074     }
2075   return $x if $x->{sign} !~ /^[+-]$/;          # inf, NaN
2076
2077   # we have fewer digits than we want to scale to
2078   my $len = $x->length();
2079   # convert $scale to a scalar in case it is an object (put's a limit on the
2080   # number length, but this would already limited by memory constraints), makes
2081   # it faster
2082   $scale = $scale->numify() if ref ($scale);
2083
2084   # scale < 0, but > -len (not >=!)
2085   if (($scale < 0 && $scale < -$len-1) || ($scale >= $len))
2086     {
2087     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2088     return $x;
2089     }
2090
2091   # count of 0's to pad, from left (+) or right (-): 9 - +6 => 3, or |-6| => 6
2092   my ($pad,$digit_round,$digit_after);
2093   $pad = $len - $scale;
2094   $pad = abs($scale-1) if $scale < 0;
2095
2096   # do not use digit(), it is very costly for binary => decimal
2097   # getting the entire string is also costly, but we need to do it only once
2098   my $xs = $CALC->_str($x->{value});
2099   my $pl = -$pad-1;
2100
2101   # pad:   123: 0 => -1, at 1 => -2, at 2 => -3, at 3 => -4
2102   # pad+1: 123: 0 => 0,  at 1 => -1, at 2 => -2, at 3 => -3
2103   $digit_round = '0'; $digit_round = substr($xs,$pl,1) if $pad <= $len;
2104   $pl++; $pl ++ if $pad >= $len;
2105   $digit_after = '0'; $digit_after = substr($xs,$pl,1) if $pad > 0;
2106
2107   # in case of 01234 we round down, for 6789 up, and only in case 5 we look
2108   # closer at the remaining digits of the original $x, remember decision
2109   my $round_up = 1;                                     # default round up
2110   $round_up -- if
2111     ($mode eq 'trunc')                          ||      # trunc by round down
2112     ($digit_after =~ /[01234]/)                 ||      # round down anyway,
2113                                                         # 6789 => round up
2114     ($digit_after eq '5')                       &&      # not 5000...0000
2115     ($x->_scan_for_nonzero($pad,$xs,$len) == 0)         &&
2116     (
2117      ($mode eq 'even') && ($digit_round =~ /[24680]/) ||
2118      ($mode eq 'odd')  && ($digit_round =~ /[13579]/) ||
2119      ($mode eq '+inf') && ($x->{sign} eq '-')   ||
2120      ($mode eq '-inf') && ($x->{sign} eq '+')   ||
2121      ($mode eq 'zero')          # round down if zero, sign adjusted below
2122     );
2123   my $put_back = 0;                                     # not yet modified
2124
2125   if (($pad > 0) && ($pad <= $len))
2126     {
2127     substr($xs,-$pad,$pad) = '0' x $pad;                # replace with '00...'
2128     $put_back = 1;                                      # need to put back
2129     }
2130   elsif ($pad > $len)
2131     {
2132     $x->bzero();                                        # round to '0'
2133     }
2134
2135   if ($round_up)                                        # what gave test above?
2136     {
2137     $put_back = 1;                                      # need to put back
2138     $pad = $len, $xs = '0' x $pad if $scale < 0;        # tlr: whack 0.51=>1.0
2139
2140     # we modify directly the string variant instead of creating a number and
2141     # adding it, since that is faster (we already have the string)
2142     my $c = 0; $pad ++;                         # for $pad == $len case
2143     while ($pad <= $len)
2144       {
2145       $c = substr($xs,-$pad,1) + 1; $c = '0' if $c eq '10';
2146       substr($xs,-$pad,1) = $c; $pad++;
2147       last if $c != 0;                          # no overflow => early out
2148       }
2149     $xs = '1'.$xs if $c == 0;
2150
2151     }
2152   $x->{value} = $CALC->_new($xs) if $put_back == 1;     # put back, if needed
2153
2154   $x->{_a} = $scale if $scale >= 0;
2155   if ($scale < 0)
2156     {
2157     $x->{_a} = $len+$scale;
2158     $x->{_a} = 0 if $scale < -$len;
2159     }
2160   $x;
2161   }
2162
2163 sub bfloor
2164   {
2165   # return integer less or equal then number; no-op since it's already integer
2166   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2167
2168   $x->round(@r);
2169   }
2170
2171 sub bceil
2172   {
2173   # return integer greater or equal then number; no-op since it's already int
2174   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2175
2176   $x->round(@r);
2177   }
2178
2179 sub as_number
2180   {
2181   # An object might be asked to return itself as bigint on certain overloaded
2182   # operations, this does exactly this, so that sub classes can simple inherit
2183   # it or override with their own integer conversion routine.
2184   $_[0]->copy();
2185   }
2186
2187 sub as_hex
2188   {
2189   # return as hex string, with prefixed 0x
2190   my $x = shift; $x = $class->new($x) if !ref($x);
2191
2192   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2193
2194   my $s = '';
2195   $s = $x->{sign} if $x->{sign} eq '-';
2196   $s . $CALC->_as_hex($x->{value});
2197   }
2198
2199 sub as_bin
2200   {
2201   # return as binary string, with prefixed 0b
2202   my $x = shift; $x = $class->new($x) if !ref($x);
2203
2204   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2205
2206   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2207   return $s . $CALC->_as_bin($x->{value});
2208   }
2209
2210 ##############################################################################
2211 # private stuff (internal use only)
2212
2213 sub objectify
2214   {
2215   # check for strings, if yes, return objects instead
2216
2217   # the first argument is number of args objectify() should look at it will
2218   # return $count+1 elements, the first will be a classname. This is because
2219   # overloaded '""' calls bstr($object,undef,undef) and this would result in
2220   # useless objects beeing created and thrown away. So we cannot simple loop
2221   # over @_. If the given count is 0, all arguments will be used.
2222
2223   # If the second arg is a ref, use it as class.
2224   # If not, try to use it as classname, unless undef, then use $class
2225   # (aka Math::BigInt). The latter shouldn't happen,though.
2226
2227   # caller:                        gives us:
2228   # $x->badd(1);                => ref x, scalar y
2229   # Class->badd(1,2);           => classname x (scalar), scalar x, scalar y
2230   # Class->badd( Class->(1),2); => classname x (scalar), ref x, scalar y
2231   # Math::BigInt::badd(1,2);    => scalar x, scalar y
2232   # In the last case we check number of arguments to turn it silently into
2233   # $class,1,2. (We can not take '1' as class ;o)
2234   # badd($class,1) is not supported (it should, eventually, try to add undef)
2235   # currently it tries 'Math::BigInt' + 1, which will not work.
2236
2237   # some shortcut for the common cases
2238   # $x->unary_op();
2239   return (ref($_[1]),$_[1]) if (@_ == 2) && ($_[0]||0 == 1) && ref($_[1]);
2240
2241   my $count = abs(shift || 0);
2242
2243   my (@a,$k,$d);                # resulting array, temp, and downgrade
2244   if (ref $_[0])
2245     {
2246     # okay, got object as first
2247     $a[0] = ref $_[0];
2248     }
2249   else
2250     {
2251     # nope, got 1,2 (Class->xxx(1) => Class,1 and not supported)
2252     $a[0] = $class;
2253     $a[0] = shift if $_[0] =~ /^[A-Z].*::/;     # classname as first?
2254     }
2255
2256   no strict 'refs';
2257   # disable downgrading, because Math::BigFLoat->foo('1.0','2.0') needs floats
2258   if (defined ${"$a[0]::downgrade"})
2259     {
2260     $d = ${"$a[0]::downgrade"};
2261     ${"$a[0]::downgrade"} = undef;
2262     }
2263
2264   my $up = ${"$a[0]::upgrade"};
2265   #print "Now in objectify, my class is today $a[0], count = $count\n";
2266   if ($count == 0)
2267     {
2268     while (@_)
2269       {
2270       $k = shift;
2271       if (!ref($k))
2272         {
2273         $k = $a[0]->new($k);
2274         }
2275       elsif (!defined $up && ref($k) ne $a[0])
2276         {
2277         # foreign object, try to convert to integer
2278         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2279         }
2280       push @a,$k;
2281       }
2282     }
2283   else
2284     {
2285     while ($count > 0)
2286       {
2287       $count--;
2288       $k = shift;
2289       if (!ref($k))
2290         {
2291         $k = $a[0]->new($k);
2292         }
2293       elsif (!defined $up && ref($k) ne $a[0])
2294         {
2295         # foreign object, try to convert to integer
2296         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2297         }
2298       push @a,$k;
2299       }
2300     push @a,@_;         # return other params, too
2301     }
2302   if (! wantarray)
2303     {
2304     require Carp; Carp::croak ("$class objectify needs list context");
2305     }
2306   ${"$a[0]::downgrade"} = $d;
2307   @a;
2308   }
2309
2310 sub import
2311   {
2312   my $self = shift;
2313
2314   $IMPORT++;                            # remember we did import()
2315   my @a; my $l = scalar @_;
2316   for ( my $i = 0; $i < $l ; $i++ )
2317     {
2318     if ($_[$i] eq ':constant')
2319       {
2320       # this causes overlord er load to step in
2321       overload::constant
2322         integer => sub { $self->new(shift) },
2323         binary => sub { $self->new(shift) };
2324       }
2325     elsif ($_[$i] eq 'upgrade')
2326       {
2327       # this causes upgrading
2328       $upgrade = $_[$i+1];              # or undef to disable
2329       $i++;
2330       }
2331     elsif ($_[$i] =~ /^lib$/i)
2332       {
2333       # this causes a different low lib to take care...
2334       $CALC = $_[$i+1] || '';
2335       $i++;
2336       }
2337     else
2338       {
2339       push @a, $_[$i];
2340       }
2341     }
2342   # any non :constant stuff is handled by our parent, Exporter
2343   # even if @_ is empty, to give it a chance
2344   $self->SUPER::import(@a);                     # need it for subclasses
2345   $self->export_to_level(1,$self,@a);           # need it for MBF
2346
2347   # try to load core math lib
2348   my @c = split /\s*,\s*/,$CALC;
2349   push @c,'Calc';                               # if all fail, try this
2350   $CALC = '';                                   # signal error
2351   foreach my $lib (@c)
2352     {
2353     next if ($lib || '') eq '';
2354     $lib = 'Math::BigInt::'.$lib if $lib !~ /^Math::BigInt/i;
2355     $lib =~ s/\.pm$//;
2356     if ($] < 5.006)
2357       {
2358       # Perl < 5.6.0 dies with "out of memory!" when eval() and ':constant' is
2359       # used in the same script, or eval inside import().
2360       my @parts = split /::/, $lib;             # Math::BigInt => Math BigInt
2361       my $file = pop @parts; $file .= '.pm';    # BigInt => BigInt.pm
2362       require File::Spec;
2363       $file = File::Spec->catfile (@parts, $file);
2364       eval { require "$file"; $lib->import( @c ); }
2365       }
2366     else
2367       {
2368       eval "use $lib qw/@c/;";
2369       }
2370     if ($@ eq '')
2371       {
2372       my $ok = 1;
2373       # loaded it ok, see if the api_version() is high enough
2374       if ($lib->can('api_version') && $lib->api_version() >= 1.0)
2375         {
2376         $ok = 0;
2377         # api_version matches, check if it really provides anything we need
2378         for my $method (qw/
2379                 one two ten
2380                 str num
2381                 add mul div sub dec inc
2382                 acmp len digit is_one is_zero is_even is_odd
2383                 is_two is_ten
2384                 new copy check from_hex from_bin as_hex as_bin zeros
2385                 rsft lsft xor and or
2386                 mod sqrt root fac pow modinv modpow log_int gcd
2387          /)
2388           {
2389           if (!$lib->can("_$method"))
2390             {
2391             if (($WARN{$lib}||0) < 2)
2392               {
2393               require Carp;
2394               Carp::carp ("$lib is missing method '_$method'");
2395               $WARN{$lib} = 1;          # still warn about the lib
2396               }
2397             $ok++; last;
2398             }
2399           }
2400         }
2401       if ($ok == 0)
2402         {
2403         $CALC = $lib;
2404         last;                   # found a usable one, break
2405         }
2406       else
2407         {
2408         if (($WARN{$lib}||0) < 2)
2409           {
2410           my $ver = eval "\$$lib\::VERSION";
2411           require Carp;
2412           Carp::carp ("Cannot load outdated $lib v$ver, please upgrade");
2413           $WARN{$lib} = 2;              # never warn again
2414           }
2415         }
2416       }
2417     }
2418   if ($CALC eq '')
2419     {
2420     require Carp;
2421     Carp::croak ("Couldn't load any math lib, not even 'Calc.pm'");
2422     }
2423   _fill_can_cache();            # for emulating lower math lib functions
2424   }
2425
2426 sub _fill_can_cache
2427   {
2428   # fill $CAN with the results of $CALC->can(...)
2429
2430   %CAN = ();
2431   for my $method (qw/ signed_and or signed_or xor signed_xor /)
2432     {
2433     $CAN{$method} = $CALC->can("_$method") ? 1 : 0;
2434     }
2435   }
2436
2437 sub __from_hex
2438   {
2439   # convert a (ref to) big hex string to BigInt, return undef for error
2440   my $hs = shift;
2441
2442   my $x = Math::BigInt->bzero();
2443
2444   # strip underscores
2445   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2446   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2447
2448   return $x->bnan() if $hs !~ /^[\-\+]?0x[0-9A-Fa-f]+$/;
2449
2450   my $sign = '+'; $sign = '-' if $hs =~ /^-/;
2451
2452   $hs =~ s/^[+-]//;                                             # strip sign
2453   $x->{value} = $CALC->_from_hex($hs);
2454   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2455   $x;
2456   }
2457
2458 sub __from_bin
2459   {
2460   # convert a (ref to) big binary string to BigInt, return undef for error
2461   my $bs = shift;
2462
2463   my $x = Math::BigInt->bzero();
2464   # strip underscores
2465   $bs =~ s/([01])_([01])/$1$2/g;
2466   $bs =~ s/([01])_([01])/$1$2/g;
2467   return $x->bnan() if $bs !~ /^[+-]?0b[01]+$/;
2468
2469   my $sign = '+'; $sign = '-' if $bs =~ /^\-/;
2470   $bs =~ s/^[+-]//;                                             # strip sign
2471
2472   $x->{value} = $CALC->_from_bin($bs);
2473   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2474   $x;
2475   }
2476
2477 sub _split
2478   {
2479   # (ref to num_str) return num_str
2480   # internal, take apart a string and return the pieces
2481   # strip leading/trailing whitespace, leading zeros, underscore and reject
2482   # invalid input
2483   my $x = shift;
2484
2485   # strip white space at front, also extranous leading zeros
2486   $x =~ s/^\s*([-]?)0*([0-9])/$1$2/g;   # will not strip '  .2'
2487   $x =~ s/^\s+//;                       # but this will
2488   $x =~ s/\s+$//g;                      # strip white space at end
2489
2490   # shortcut, if nothing to split, return early
2491   if ($x =~ /^[+-]?\d+\z/)
2492     {
2493     $x =~ s/^([+-])0*([0-9])/$2/; my $sign = $1 || '+';
2494     return (\$sign, \$x, \'', \'', \0);
2495     }
2496
2497   # invalid starting char?
2498   return if $x !~ /^[+-]?(\.?[0-9]|0b[0-1]|0x[0-9a-fA-F])/;
2499
2500   return __from_hex($x) if $x =~ /^[\-\+]?0x/;  # hex string
2501   return __from_bin($x) if $x =~ /^[\-\+]?0b/;  # binary string
2502
2503   # strip underscores between digits
2504   $x =~ s/(\d)_(\d)/$1$2/g;
2505   $x =~ s/(\d)_(\d)/$1$2/g;             # do twice for 1_2_3
2506
2507   # some possible inputs:
2508   # 2.1234 # 0.12        # 1          # 1E1 # 2.134E1 # 434E-10 # 1.02009E-2
2509   # .2     # 1_2_3.4_5_6 # 1.4E1_2_3  # 1e3 # +.2     # 0e999
2510
2511   my ($m,$e,$last) = split /[Ee]/,$x;
2512   return if defined $last;              # last defined => 1e2E3 or others
2513   $e = '0' if !defined $e || $e eq "";
2514
2515   # sign,value for exponent,mantint,mantfrac
2516   my ($es,$ev,$mis,$miv,$mfv);
2517   # valid exponent?
2518   if ($e =~ /^([+-]?)0*(\d+)$/) # strip leading zeros
2519     {
2520     $es = $1; $ev = $2;
2521     # valid mantissa?
2522     return if $m eq '.' || $m eq '';
2523     my ($mi,$mf,$lastf) = split /\./,$m;
2524     return if defined $lastf;           # lastf defined => 1.2.3 or others
2525     $mi = '0' if !defined $mi;
2526     $mi .= '0' if $mi =~ /^[\-\+]?$/;
2527     $mf = '0' if !defined $mf || $mf eq '';
2528     if ($mi =~ /^([+-]?)0*(\d+)$/) # strip leading zeros
2529       {
2530       $mis = $1||'+'; $miv = $2;
2531       return unless ($mf =~ /^(\d*?)0*$/);      # strip trailing zeros
2532       $mfv = $1;
2533       # handle the 0e999 case here
2534       $ev = 0 if $miv eq '0' && $mfv eq '';
2535       return (\$mis,\$miv,\$mfv,\$es,\$ev);
2536       }
2537     }
2538   return; # NaN, not a number
2539   }
2540
2541 ##############################################################################
2542 # internal calculation routines (others are in Math::BigInt::Calc etc)
2543
2544 sub __lcm
2545   {
2546   # (BINT or num_str, BINT or num_str) return BINT
2547   # does modify first argument
2548   # LCM
2549
2550   my $x = shift; my $ty = shift;
2551   return $x->bnan() if ($x->{sign} eq $nan) || ($ty->{sign} eq $nan);
2552   $x * $ty / bgcd($x,$ty);
2553   }
2554
2555 ###############################################################################
2556 # this method return 0 if the object can be modified, or 1 for not
2557 # We use a fast constant sub() here, to avoid costly calls. Subclasses
2558 # may override it with special code (f.i. Math::BigInt::Constant does so)
2559
2560 sub modify () { 0; }
2561
2562 1;
2563 __END__
2564
2565 =head1 NAME
2566
2567 Math::BigInt - Arbitrary size integer math package
2568
2569 =head1 SYNOPSIS
2570
2571   use Math::BigInt;
2572
2573   # or make it faster: install (optional) Math::BigInt::GMP
2574   # and always use (it will fall back to pure Perl if the
2575   # GMP library is not installed):
2576
2577   use Math::BigInt lib => 'GMP';
2578
2579   my $str = '1234567890';
2580   my @values = (64,74,18);
2581   my $n = 1; my $sign = '-';
2582
2583   # Number creation
2584   $x = Math::BigInt->new($str);         # defaults to 0
2585   $y = $x->copy();                      # make a true copy
2586   $nan  = Math::BigInt->bnan();         # create a NotANumber
2587   $zero = Math::BigInt->bzero();        # create a +0
2588   $inf = Math::BigInt->binf();          # create a +inf
2589   $inf = Math::BigInt->binf('-');       # create a -inf
2590   $one = Math::BigInt->bone();          # create a +1
2591   $one = Math::BigInt->bone('-');       # create a -1
2592
2593   # Testing (don't modify their arguments)
2594   # (return true if the condition is met, otherwise false)
2595
2596   $x->is_zero();        # if $x is +0
2597   $x->is_nan();         # if $x is NaN
2598   $x->is_one();         # if $x is +1
2599   $x->is_one('-');      # if $x is -1
2600   $x->is_odd();         # if $x is odd
2601   $x->is_even();        # if $x is even
2602   $x->is_pos();         # if $x >= 0
2603   $x->is_neg();         # if $x <  0
2604   $x->is_inf($sign);    # if $x is +inf, or -inf (sign is default '+')
2605   $x->is_int();         # if $x is an integer (not a float)
2606
2607   # comparing and digit/sign extration
2608   $x->bcmp($y);         # compare numbers (undef,<0,=0,>0)
2609   $x->bacmp($y);        # compare absolutely (undef,<0,=0,>0)
2610   $x->sign();           # return the sign, either +,- or NaN
2611   $x->digit($n);        # return the nth digit, counting from right
2612   $x->digit(-$n);       # return the nth digit, counting from left
2613
2614   # The following all modify their first argument. If you want to preserve
2615   # $x, use $z = $x->copy()->bXXX($y); See under L<CAVEATS> for why this is
2616   # neccessary when mixing $a = $b assigments with non-overloaded math.
2617
2618   $x->bzero();          # set $x to 0
2619   $x->bnan();           # set $x to NaN
2620   $x->bone();           # set $x to +1
2621   $x->bone('-');        # set $x to -1
2622   $x->binf();           # set $x to inf
2623   $x->binf('-');        # set $x to -inf
2624
2625   $x->bneg();           # negation
2626   $x->babs();           # absolute value
2627   $x->bnorm();          # normalize (no-op in BigInt)
2628   $x->bnot();           # two's complement (bit wise not)
2629   $x->binc();           # increment $x by 1
2630   $x->bdec();           # decrement $x by 1
2631
2632   $x->badd($y);         # addition (add $y to $x)
2633   $x->bsub($y);         # subtraction (subtract $y from $x)
2634   $x->bmul($y);         # multiplication (multiply $x by $y)
2635   $x->bdiv($y);         # divide, set $x to quotient
2636                         # return (quo,rem) or quo if scalar
2637
2638   $x->bmod($y);            # modulus (x % y)
2639   $x->bmodpow($exp,$mod);  # modular exponentation (($num**$exp) % $mod))
2640   $x->bmodinv($mod);       # the inverse of $x in the given modulus $mod
2641
2642   $x->bpow($y);            # power of arguments (x ** y)
2643   $x->blsft($y);           # left shift
2644   $x->brsft($y);           # right shift
2645   $x->blsft($y,$n);        # left shift, by base $n (like 10)
2646   $x->brsft($y,$n);        # right shift, by base $n (like 10)
2647
2648   $x->band($y);            # bitwise and
2649   $x->bior($y);            # bitwise inclusive or
2650   $x->bxor($y);            # bitwise exclusive or
2651   $x->bnot();              # bitwise not (two's complement)
2652
2653   $x->bsqrt();             # calculate square-root
2654   $x->broot($y);           # $y'th root of $x (e.g. $y == 3 => cubic root)
2655   $x->bfac();              # factorial of $x (1*2*3*4*..$x)
2656
2657   $x->round($A,$P,$mode);  # round to accuracy or precision using mode $mode
2658   $x->bround($n);          # accuracy: preserve $n digits
2659   $x->bfround($n);         # round to $nth digit, no-op for BigInts
2660
2661   # The following do not modify their arguments in BigInt (are no-ops),
2662   # but do so in BigFloat:
2663
2664   $x->bfloor();            # return integer less or equal than $x
2665   $x->bceil();             # return integer greater or equal than $x
2666
2667   # The following do not modify their arguments:
2668
2669   # greatest common divisor (no OO style)
2670   my $gcd = Math::BigInt::bgcd(@values);
2671   # lowest common multiplicator (no OO style)
2672   my $lcm = Math::BigInt::blcm(@values);
2673
2674   $x->length();            # return number of digits in number
2675   ($xl,$f) = $x->length(); # length of number and length of fraction part,
2676                            # latter is always 0 digits long for BigInt's
2677
2678   $x->exponent();          # return exponent as BigInt
2679   $x->mantissa();          # return (signed) mantissa as BigInt
2680   $x->parts();             # return (mantissa,exponent) as BigInt
2681   $x->copy();              # make a true copy of $x (unlike $y = $x;)
2682   $x->as_int();            # return as BigInt (in BigInt: same as copy())
2683   $x->numify();            # return as scalar (might overflow!)
2684
2685   # conversation to string (do not modify their argument)
2686   $x->bstr();              # normalized string
2687   $x->bsstr();             # normalized string in scientific notation
2688   $x->as_hex();            # as signed hexadecimal string with prefixed 0x
2689   $x->as_bin();            # as signed binary string with prefixed 0b
2690
2691
2692   # precision and accuracy (see section about rounding for more)
2693   $x->precision();         # return P of $x (or global, if P of $x undef)
2694   $x->precision($n);       # set P of $x to $n
2695   $x->accuracy();          # return A of $x (or global, if A of $x undef)
2696   $x->accuracy($n);        # set A $x to $n
2697
2698   # Global methods
2699   Math::BigInt->precision(); # get/set global P for all BigInt objects
2700   Math::BigInt->accuracy();  # get/set global A for all BigInt objects
2701   Math::BigInt->config();    # return hash containing configuration
2702
2703 =head1 DESCRIPTION
2704
2705 All operators (inlcuding basic math operations) are overloaded if you
2706 declare your big integers as
2707
2708   $i = new Math::BigInt '123_456_789_123_456_789';
2709
2710 Operations with overloaded operators preserve the arguments which is
2711 exactly what you expect.
2712
2713 =over 2
2714
2715 =item Input
2716
2717 Input values to these routines may be any string, that looks like a number
2718 and results in an integer, including hexadecimal and binary numbers.
2719
2720 Scalars holding numbers may also be passed, but note that non-integer numbers
2721 may already have lost precision due to the conversation to float. Quote
2722 your input if you want BigInt to see all the digits:
2723
2724         $x = Math::BigInt->new(12345678890123456789);   # bad
2725         $x = Math::BigInt->new('12345678901234567890'); # good
2726
2727 You can include one underscore between any two digits.
2728
2729 This means integer values like 1.01E2 or even 1000E-2 are also accepted.
2730 Non-integer values result in NaN.
2731
2732 Currently, Math::BigInt::new() defaults to 0, while Math::BigInt::new('')
2733 results in 'NaN'. This might change in the future, so use always the following
2734 explicit forms to get a zero or NaN:
2735
2736         $zero = Math::BigInt->bzero();
2737         $nan = Math::BigInt->bnan();
2738
2739 C<bnorm()> on a BigInt object is now effectively a no-op, since the numbers
2740 are always stored in normalized form. If passed a string, creates a BigInt
2741 object from the input.
2742
2743 =item Output
2744
2745 Output values are BigInt objects (normalized), except for bstr(), which
2746 returns a string in normalized form.
2747 Some routines (C<is_odd()>, C<is_even()>, C<is_zero()>, C<is_one()>,
2748 C<is_nan()>) return true or false, while others (C<bcmp()>, C<bacmp()>)
2749 return either undef, <0, 0 or >0 and are suited for sort.
2750
2751 =back
2752
2753 =head1 METHODS
2754
2755 Each of the methods below (except config(), accuracy() and precision())
2756 accepts three additional parameters. These arguments $A, $P and $R are
2757 accuracy, precision and round_mode. Please see the section about
2758 L<ACCURACY and PRECISION> for more information.
2759
2760 =head2 config
2761
2762         use Data::Dumper;
2763
2764         print Dumper ( Math::BigInt->config() );
2765         print Math::BigInt->config()->{lib},"\n";
2766
2767 Returns a hash containing the configuration, e.g. the version number, lib
2768 loaded etc. The following hash keys are currently filled in with the
2769 appropriate information.
2770
2771         key             Description
2772                         Example
2773         ============================================================
2774         lib             Name of the low-level math library
2775                         Math::BigInt::Calc
2776         lib_version     Version of low-level math library (see 'lib')
2777                         0.30
2778         class           The class name of config() you just called
2779                         Math::BigInt
2780         upgrade         To which class math operations might be upgraded
2781                         Math::BigFloat
2782         downgrade       To which class math operations might be downgraded
2783                         undef
2784         precision       Global precision
2785                         undef
2786         accuracy        Global accuracy
2787                         undef
2788         round_mode      Global round mode
2789                         even
2790         version         version number of the class you used
2791                         1.61
2792         div_scale       Fallback acccuracy for div
2793                         40
2794         trap_nan        If true, traps creation of NaN via croak()
2795                         1
2796         trap_inf        If true, traps creation of +inf/-inf via croak()
2797                         1
2798
2799 The following values can be set by passing C<config()> a reference to a hash:
2800
2801         trap_inf trap_nan
2802         upgrade downgrade precision accuracy round_mode div_scale
2803
2804 Example:
2805
2806         $new_cfg = Math::BigInt->config( { trap_inf => 1, precision => 5 } );
2807
2808 =head2 accuracy
2809
2810         $x->accuracy(5);                # local for $x
2811         CLASS->accuracy(5);             # global for all members of CLASS
2812         $A = $x->accuracy();            # read out
2813         $A = CLASS->accuracy();         # read out
2814
2815 Set or get the global or local accuracy, aka how many significant digits the
2816 results have.
2817
2818 Please see the section about L<ACCURACY AND PRECISION> for further details.
2819
2820 Value must be greater than zero. Pass an undef value to disable it:
2821
2822         $x->accuracy(undef);
2823         Math::BigInt->accuracy(undef);
2824
2825 Returns the current accuracy. For C<$x->accuracy()> it will return either the
2826 local accuracy, or if not defined, the global. This means the return value
2827 represents the accuracy that will be in effect for $x:
2828
2829         $y = Math::BigInt->new(1234567);        # unrounded
2830         print Math::BigInt->accuracy(4),"\n";   # set 4, print 4
2831         $x = Math::BigInt->new(123456);         # will be automatically rounded
2832         print "$x $y\n";                        # '123500 1234567'
2833         print $x->accuracy(),"\n";              # will be 4
2834         print $y->accuracy(),"\n";              # also 4, since global is 4
2835         print Math::BigInt->accuracy(5),"\n";   # set to 5, print 5
2836         print $x->accuracy(),"\n";              # still 4
2837         print $y->accuracy(),"\n";              # 5, since global is 5
2838
2839 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
2840 globals separated from Math::BigInt, but it is possible to subclass
2841 Math::BigInt and make the globals of the subclass aliases to the ones from
2842 Math::BigInt.
2843
2844 =head2 precision
2845
2846         $x->precision(-2);              # local for $x, round right of the dot
2847         $x->precision(2);               # ditto, but round left of the dot
2848         CLASS->accuracy(5);             # global for all members of CLASS
2849         CLASS->precision(-5);           # ditto
2850         $P = CLASS->precision();        # read out
2851         $P = $x->precision();           # read out
2852
2853 Set or get the global or local precision, aka how many digits the result has
2854 after the dot (or where to round it when passing a positive number). In
2855 Math::BigInt, passing a negative number precision has no effect since no
2856 numbers have digits after the dot.
2857
2858 Please see the section about L<ACCURACY AND PRECISION> for further details.
2859
2860 Value must be greater than zero. Pass an undef value to disable it:
2861
2862         $x->precision(undef);
2863         Math::BigInt->precision(undef);
2864
2865 Returns the current precision. For C<$x->precision()> it will return either the
2866 local precision of $x, or if not defined, the global. This means the return
2867 value represents the accuracy that will be in effect for $x:
2868
2869         $y = Math::BigInt->new(1234567);        # unrounded
2870         print Math::BigInt->precision(4),"\n";  # set 4, print 4
2871         $x = Math::BigInt->new(123456);         # will be automatically rounded
2872
2873 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
2874 globals separated from Math::BigInt, but it is possible to subclass
2875 Math::BigInt and make the globals of the subclass aliases to the ones from
2876 Math::BigInt.
2877
2878 =head2 brsft
2879
2880         $x->brsft($y,$n);
2881
2882 Shifts $x right by $y in base $n. Default is base 2, used are usually 10 and
2883 2, but others work, too.
2884
2885 Right shifting usually amounts to dividing $x by $n ** $y and truncating the
2886 result:
2887
2888
2889         $x = Math::BigInt->new(10);
2890         $x->brsft(1);                   # same as $x >> 1: 5
2891         $x = Math::BigInt->new(1234);
2892         $x->brsft(2,10);                # result 12
2893
2894 There is one exception, and that is base 2 with negative $x:
2895
2896
2897         $x = Math::BigInt->new(-5);
2898         print $x->brsft(1);
2899
2900 This will print -3, not -2 (as it would if you divide -5 by 2 and truncate the
2901 result).
2902
2903 =head2 new
2904
2905         $x = Math::BigInt->new($str,$A,$P,$R);
2906
2907 Creates a new BigInt object from a scalar or another BigInt object. The
2908 input is accepted as decimal, hex (with leading '0x') or binary (with leading
2909 '0b').
2910
2911 See L<Input> for more info on accepted input formats.
2912
2913 =head2 bnan
2914
2915         $x = Math::BigInt->bnan();
2916
2917 Creates a new BigInt object representing NaN (Not A Number).
2918 If used on an object, it will set it to NaN:
2919
2920         $x->bnan();
2921
2922 =head2 bzero
2923
2924         $x = Math::BigInt->bzero();
2925
2926 Creates a new BigInt object representing zero.
2927 If used on an object, it will set it to zero:
2928
2929         $x->bzero();
2930
2931 =head2 binf
2932
2933         $x = Math::BigInt->binf($sign);
2934
2935 Creates a new BigInt object representing infinity. The optional argument is
2936 either '-' or '+', indicating whether you want infinity or minus infinity.
2937 If used on an object, it will set it to infinity:
2938
2939         $x->binf();
2940         $x->binf('-');
2941
2942 =head2 bone
2943
2944         $x = Math::BigInt->binf($sign);
2945
2946 Creates a new BigInt object representing one. The optional argument is
2947 either '-' or '+', indicating whether you want one or minus one.
2948 If used on an object, it will set it to one:
2949
2950         $x->bone();             # +1
2951         $x->bone('-');          # -1
2952
2953 =head2 is_one()/is_zero()/is_nan()/is_inf()
2954
2955
2956         $x->is_zero();                  # true if arg is +0
2957         $x->is_nan();                   # true if arg is NaN
2958         $x->is_one();                   # true if arg is +1
2959         $x->is_one('-');                # true if arg is -1
2960         $x->is_inf();                   # true if +inf
2961         $x->is_inf('-');                # true if -inf (sign is default '+')
2962
2963 These methods all test the BigInt for beeing one specific value and return
2964 true or false depending on the input. These are faster than doing something
2965 like:
2966
2967         if ($x == 0)
2968
2969 =head2 is_pos()/is_neg()
2970
2971         $x->is_pos();                   # true if >= 0
2972         $x->is_neg();                   # true if <  0
2973
2974 The methods return true if the argument is positive or negative, respectively.
2975 C<NaN> is neither positive nor negative, while C<+inf> counts as positive, and
2976 C<-inf> is negative. A C<zero> is positive.
2977
2978 These methods are only testing the sign, and not the value.
2979
2980 C<is_positive()> and C<is_negative()> are aliase to C<is_pos()> and
2981 C<is_neg()>, respectively. C<is_positive()> and C<is_negative()> were
2982 introduced in v1.36, while C<is_pos()> and C<is_neg()> were only introduced
2983 in v1.68.
2984
2985 =head2 is_odd()/is_even()/is_int()
2986
2987         $x->is_odd();                   # true if odd, false for even
2988         $x->is_even();                  # true if even, false for odd
2989         $x->is_int();                   # true if $x is an integer
2990
2991 The return true when the argument satisfies the condition. C<NaN>, C<+inf>,
2992 C<-inf> are not integers and are neither odd nor even.
2993
2994 In BigInt, all numbers except C<NaN>, C<+inf> and C<-inf> are integers.
2995
2996 =head2 bcmp
2997
2998         $x->bcmp($y);
2999
3000 Compares $x with $y and takes the sign into account.
3001 Returns -1, 0, 1 or undef.
3002
3003 =head2 bacmp
3004
3005         $x->bacmp($y);
3006
3007 Compares $x with $y while ignoring their. Returns -1, 0, 1 or undef.
3008
3009 =head2 sign
3010
3011         $x->sign();
3012
3013 Return the sign, of $x, meaning either C<+>, C<->, C<-inf>, C<+inf> or NaN.
3014
3015 =head2 digit
3016
3017         $x->digit($n);          # return the nth digit, counting from right
3018
3019 If C<$n> is negative, returns the digit counting from left.
3020
3021 =head2 bneg
3022
3023         $x->bneg();
3024
3025 Negate the number, e.g. change the sign between '+' and '-', or between '+inf'
3026 and '-inf', respectively. Does nothing for NaN or zero.
3027
3028 =head2 babs
3029
3030         $x->babs();
3031
3032 Set the number to it's absolute value, e.g. change the sign from '-' to '+'
3033 and from '-inf' to '+inf', respectively. Does nothing for NaN or positive
3034 numbers.
3035
3036 =head2 bnorm
3037
3038         $x->bnorm();                    # normalize (no-op)
3039
3040 =head2 bnot
3041
3042         $x->bnot();
3043
3044 Two's complement (bit wise not). This is equivalent to
3045
3046         $x->binc()->bneg();
3047
3048 but faster.
3049
3050 =head2 binc
3051
3052         $x->binc();                     # increment x by 1
3053
3054 =head2 bdec
3055
3056         $x->bdec();                     # decrement x by 1
3057
3058 =head2 badd
3059
3060         $x->badd($y);                   # addition (add $y to $x)
3061
3062 =head2 bsub
3063
3064         $x->bsub($y);                   # subtraction (subtract $y from $x)
3065
3066 =head2 bmul
3067
3068         $x->bmul($y);                   # multiplication (multiply $x by $y)
3069
3070 =head2 bdiv
3071
3072         $x->bdiv($y);                   # divide, set $x to quotient
3073                                         # return (quo,rem) or quo if scalar
3074
3075 =head2 bmod
3076
3077         $x->bmod($y);                   # modulus (x % y)
3078
3079 =head2 bmodinv
3080
3081         num->bmodinv($mod);             # modular inverse
3082
3083 Returns the inverse of C<$num> in the given modulus C<$mod>.  'C<NaN>' is
3084 returned unless C<$num> is relatively prime to C<$mod>, i.e. unless
3085 C<bgcd($num, $mod)==1>.
3086
3087 =head2 bmodpow
3088
3089         $num->bmodpow($exp,$mod);       # modular exponentation
3090                                         # ($num**$exp % $mod)
3091
3092 Returns the value of C<$num> taken to the power C<$exp> in the modulus
3093 C<$mod> using binary exponentation.  C<bmodpow> is far superior to
3094 writing
3095
3096         $num ** $exp % $mod
3097
3098 because it is much faster - it reduces internal variables into
3099 the modulus whenever possible, so it operates on smaller numbers.
3100
3101 C<bmodpow> also supports negative exponents.
3102
3103         bmodpow($num, -1, $mod)
3104
3105 is exactly equivalent to
3106
3107         bmodinv($num, $mod)
3108
3109 =head2 bpow
3110
3111         $x->bpow($y);                   # power of arguments (x ** y)
3112
3113 =head2 blsft
3114
3115         $x->blsft($y);          # left shift
3116         $x->blsft($y,$n);       # left shift, in base $n (like 10)
3117
3118 =head2 brsft
3119
3120         $x->brsft($y);          # right shift
3121         $x->brsft($y,$n);       # right shift, in base $n (like 10)
3122
3123 =head2 band
3124
3125         $x->band($y);                   # bitwise and
3126
3127 =head2 bior
3128
3129         $x->bior($y);                   # bitwise inclusive or
3130
3131 =head2 bxor
3132
3133         $x->bxor($y);                   # bitwise exclusive or
3134
3135 =head2 bnot
3136
3137         $x->bnot();                     # bitwise not (two's complement)
3138
3139 =head2 bsqrt
3140
3141         $x->bsqrt();                    # calculate square-root
3142
3143 =head2 bfac
3144
3145         $x->bfac();                     # factorial of $x (1*2*3*4*..$x)
3146
3147 =head2 round
3148
3149         $x->round($A,$P,$round_mode);
3150
3151 Round $x to accuracy C<$A> or precision C<$P> using the round mode
3152 C<$round_mode>.
3153
3154 =head2 bround
3155
3156         $x->bround($N);               # accuracy: preserve $N digits
3157
3158 =head2 bfround
3159
3160         $x->bfround($N);              # round to $Nth digit, no-op for BigInts
3161
3162 =head2 bfloor
3163
3164         $x->bfloor();
3165
3166 Set $x to the integer less or equal than $x. This is a no-op in BigInt, but
3167 does change $x in BigFloat.
3168
3169 =head2 bceil
3170
3171         $x->bceil();
3172
3173 Set $x to the integer greater or equal than $x. This is a no-op in BigInt, but
3174 does change $x in BigFloat.
3175
3176 =head2 bgcd
3177
3178         bgcd(@values);          # greatest common divisor (no OO style)
3179
3180 =head2 blcm
3181
3182         blcm(@values);          # lowest common multiplicator (no OO style)
3183
3184 head2 length
3185
3186         $x->length();
3187         ($xl,$fl) = $x->length();
3188
3189 Returns the number of digits in the decimal representation of the number.
3190 In list context, returns the length of the integer and fraction part. For
3191 BigInt's, the length of the fraction part will always be 0.
3192
3193 =head2 exponent
3194
3195         $x->exponent();
3196
3197 Return the exponent of $x as BigInt.
3198
3199 =head2 mantissa
3200
3201         $x->mantissa();
3202
3203 Return the signed mantissa of $x as BigInt.
3204
3205 =head2 parts
3206
3207         $x->parts();            # return (mantissa,exponent) as BigInt
3208
3209 =head2 copy
3210
3211         $x->copy();             # make a true copy of $x (unlike $y = $x;)
3212
3213 =head2 as_int
3214
3215         $x->as_int();
3216
3217 Returns $x as a BigInt (truncated towards zero). In BigInt this is the same as
3218 C<copy()>.
3219
3220 C<as_number()> is an alias to this method. C<as_number> was introduced in
3221 v1.22, while C<as_int()> was only introduced in v1.68.
3222
3223 =head2 bstr
3224
3225         $x->bstr();
3226
3227 Returns a normalized string represantation of C<$x>.
3228
3229 =head2 bsstr
3230
3231         $x->bsstr();            # normalized string in scientific notation
3232
3233 =head2 as_hex
3234
3235         $x->as_hex();           # as signed hexadecimal string with prefixed 0x
3236
3237 =head2 as_bin
3238
3239         $x->as_bin();           # as signed binary string with prefixed 0b
3240
3241 =head1 ACCURACY and PRECISION
3242
3243 Since version v1.33, Math::BigInt and Math::BigFloat have full support for
3244 accuracy and precision based rounding, both automatically after every
3245 operation, as well as manually.
3246
3247 This section describes the accuracy/precision handling in Math::Big* as it
3248 used to be and as it is now, complete with an explanation of all terms and
3249 abbreviations.
3250
3251 Not yet implemented things (but with correct description) are marked with '!',
3252 things that need to be answered are marked with '?'.
3253
3254 In the next paragraph follows a short description of terms used here (because
3255 these may differ from terms used by others people or documentation).
3256
3257 During the rest of this document, the shortcuts A (for accuracy), P (for
3258 precision), F (fallback) and R (rounding mode) will be used.
3259
3260 =head2 Precision P
3261
3262 A fixed number of digits before (positive) or after (negative)
3263 the decimal point. For example, 123.45 has a precision of -2. 0 means an
3264 integer like 123 (or 120). A precision of 2 means two digits to the left
3265 of the decimal point are zero, so 123 with P = 1 becomes 120. Note that
3266 numbers with zeros before the decimal point may have different precisions,
3267 because 1200 can have p = 0, 1 or 2 (depending on what the inital value
3268 was). It could also have p < 0, when the digits after the decimal point
3269 are zero.
3270
3271 The string output (of floating point numbers) will be padded with zeros:
3272
3273         Initial value   P       A       Result          String
3274         ------------------------------------------------------------
3275         1234.01         -3              1000            1000
3276         1234            -2              1200            1200
3277         1234.5          -1              1230            1230
3278         1234.001        1               1234            1234.0
3279         1234.01         0               1234            1234
3280         1234.01         2               1234.01         1234.01
3281         1234.01         5               1234.01         1234.01000
3282
3283 For BigInts, no padding occurs.
3284
3285 =head2 Accuracy A
3286
3287 Number of significant digits. Leading zeros are not counted. A
3288 number may have an accuracy greater than the non-zero digits
3289 when there are zeros in it or trailing zeros. For example, 123.456 has
3290 A of 6, 10203 has 5, 123.0506 has 7, 123.450000 has 8 and 0.000123 has 3.
3291
3292 The string output (of floating point numbers) will be padded with zeros:
3293
3294         Initial value   P       A       Result          String
3295         ------------------------------------------------------------
3296         1234.01                 3       1230            1230
3297         1234.01                 6       1234.01         1234.01
3298         1234.1                  8       1234.1          1234.1000
3299
3300 For BigInts, no padding occurs.
3301
3302 =head2 Fallback F
3303
3304 When both A and P are undefined, this is used as a fallback accuracy when
3305 dividing numbers.
3306
3307 =head2 Rounding mode R
3308
3309 When rounding a number, different 'styles' or 'kinds'
3310 of rounding are possible. (Note that random rounding, as in
3311 Math::Round, is not implemented.)
3312
3313 =over 2
3314
3315 =item 'trunc'
3316
3317 truncation invariably removes all digits following the
3318 rounding place, replacing them with zeros. Thus, 987.65 rounded
3319 to tens (P=1) becomes 980, and rounded to the fourth sigdig
3320 becomes 987.6 (A=4). 123.456 rounded to the second place after the
3321 decimal point (P=-2) becomes 123.46.
3322
3323 All other implemented styles of rounding attempt to round to the
3324 "nearest digit." If the digit D immediately to the right of the
3325 rounding place (skipping the decimal point) is greater than 5, the
3326 number is incremented at the rounding place (possibly causing a
3327 cascade of incrementation): e.g. when rounding to units, 0.9 rounds
3328 to 1, and -19.9 rounds to -20. If D < 5, the number is similarly
3329 truncated at the rounding place: e.g. when rounding to units, 0.4
3330 rounds to 0, and -19.4 rounds to -19.
3331
3332 However the results of other styles of rounding differ if the
3333 digit immediately to the right of the rounding place (skipping the
3334 decimal point) is 5 and if there are no digits, or no digits other
3335 than 0, after that 5. In such cases:
3336
3337 =item 'even'
3338
3339 rounds the digit at the rounding place to 0, 2, 4, 6, or 8
3340 if it is not already. E.g., when rounding to the first sigdig, 0.45
3341 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.
3342
3343 =item 'odd'
3344
3345 rounds the digit at the rounding place to 1, 3, 5, 7, or 9 if
3346 it is not already. E.g., when rounding to the first sigdig, 0.45
3347 becomes 0.5, -0.55 becomes -0.5, but 0.5501 becomes 0.6.
3348
3349 =item '+inf'
3350
3351 round to plus infinity, i.e. always round up. E.g., when
3352 rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5,
3353 and 0.4501 also becomes 0.5.
3354
3355 =item '-inf'
3356
3357 round to minus infinity, i.e. always round down. E.g., when
3358 rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6,
3359 but 0.4501 becomes 0.5.
3360
3361 =item 'zero'
3362
3363 round to zero, i.e. positive numbers down, negative ones up.
3364 E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55
3365 becomes -0.5, but 0.4501 becomes 0.5.
3366
3367 =back
3368
3369 The handling of A & P in MBI/MBF (the old core code shipped with Perl
3370 versions <= 5.7.2) is like this:
3371
3372 =over 2
3373
3374 =item Precision
3375
3376   * ffround($p) is able to round to $p number of digits after the decimal
3377     point
3378   * otherwise P is unused
3379
3380 =item Accuracy (significant digits)
3381
3382   * fround($a) rounds to $a significant digits
3383   * only fdiv() and fsqrt() take A as (optional) paramater
3384     + other operations simply create the same number (fneg etc), or more (fmul)
3385       of digits
3386     + rounding/truncating is only done when explicitly calling one of fround
3387       or ffround, and never for BigInt (not implemented)
3388   * fsqrt() simply hands its accuracy argument over to fdiv.
3389   * the documentation and the comment in the code indicate two different ways
3390     on how fdiv() determines the maximum number of digits it should calculate,
3391     and the actual code does yet another thing
3392     POD:
3393       max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
3394     Comment:
3395       result has at most max(scale, length(dividend), length(divisor)) digits
3396     Actual code:
3397       scale = max(scale, length(dividend)-1,length(divisor)-1);
3398       scale += length(divisior) - length(dividend);
3399     So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10+9-3).
3400     Actually, the 'difference' added to the scale is calculated from the
3401     number of "significant digits" in dividend and divisor, which is derived
3402     by looking at the length of the mantissa. Which is wrong, since it includes
3403     the + sign (oops) and actually gets 2 for '+100' and 4 for '+101'. Oops
3404     again. Thus 124/3 with div_scale=1 will get you '41.3' based on the strange
3405     assumption that 124 has 3 significant digits, while 120/7 will get you
3406     '17', not '17.1' since 120 is thought to have 2 significant digits.
3407     The rounding after the division then uses the remainder and $y to determine
3408     wether it must round up or down.
3409  ?  I have no idea which is the right way. That's why I used a slightly more
3410  ?  simple scheme and tweaked the few failing testcases to match it.
3411
3412 =back
3413
3414 This is how it works now:
3415
3416 =over 2
3417
3418 =item Setting/Accessing
3419
3420   * You can set the A global via C<< Math::BigInt->accuracy() >> or
3421     C<< Math::BigFloat->accuracy() >> or whatever class you are using.
3422   * You can also set P globally by using C<< Math::SomeClass->precision() >>
3423     likewise.
3424   * Globals are classwide, and not inherited by subclasses.
3425   * to undefine A, use C<< Math::SomeCLass->accuracy(undef); >>
3426   * to undefine P, use C<< Math::SomeClass->precision(undef); >>
3427   * Setting C<< Math::SomeClass->accuracy() >> clears automatically
3428     C<< Math::SomeClass->precision() >>, and vice versa.
3429   * To be valid, A must be > 0, P can have any value.
3430   * If P is negative, this means round to the P'th place to the right of the
3431     decimal point; positive values mean to the left of the decimal point.
3432     P of 0 means round to integer.
3433   * to find out the current global A, use C<< Math::SomeClass->accuracy() >>
3434   * to find out the current global P, use C<< Math::SomeClass->precision() >>
3435   * use C<< $x->accuracy() >> respective C<< $x->precision() >> for the local
3436     setting of C<< $x >>.
3437   * Please note that C<< $x->accuracy() >> respecive C<< $x->precision() >>
3438     return eventually defined global A or P, when C<< $x >>'s A or P is not
3439     set.
3440
3441 =item Creating numbers
3442
3443   * When you create a number, you can give it's desired A or P via:
3444     $x = Math::BigInt->new($number,$A,$P);
3445   * Only one of A or P can be defined, otherwise the result is NaN
3446   * If no A or P is give ($x = Math::BigInt->new($number) form), then the
3447     globals (if set) will be used. Thus changing the global defaults later on
3448     will not change the A or P of previously created numbers (i.e., A and P of
3449     $x will be what was in effect when $x was created)
3450   * If given undef for A and P, B<no> rounding will occur, and the globals will
3451     B<not> be used. This is used by subclasses to create numbers without
3452     suffering rounding in the parent. Thus a subclass is able to have it's own
3453     globals enforced upon creation of a number by using
3454     C<< $x = Math::BigInt->new($number,undef,undef) >>:
3455
3456         use Math::BigInt::SomeSubclass;
3457         use Math::BigInt;
3458
3459         Math::BigInt->accuracy(2);
3460         Math::BigInt::SomeSubClass->accuracy(3);
3461         $x = Math::BigInt::SomeSubClass->new(1234);
3462
3463     $x is now 1230, and not 1200. A subclass might choose to implement
3464     this otherwise, e.g. falling back to the parent's A and P.
3465
3466 =item Usage
3467
3468   * If A or P are enabled/defined, they are used to round the result of each
3469     operation according to the rules below
3470   * Negative P is ignored in Math::BigInt, since BigInts never have digits
3471     after the decimal point
3472   * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
3473     Math::BigInt as globals does not tamper with the parts of a BigFloat.
3474     A flag is used to mark all Math::BigFloat numbers as 'never round'.
3475
3476 =item Precedence
3477
3478   * It only makes sense that a number has only one of A or P at a time.
3479     If you set either A or P on one object, or globally, the other one will
3480     be automatically cleared.
3481   * If two objects are involved in an operation, and one of them has A in
3482     effect, and the other P, this results in an error (NaN).
3483   * A takes precendence over P (Hint: A comes before P).
3484     If neither of them is defined, nothing is used, i.e. the result will have
3485     as many digits as it can (with an exception for fdiv/fsqrt) and will not
3486     be rounded.
3487   * There is another setting for fdiv() (and thus for fsqrt()). If neither of
3488     A or P is defined, fdiv() will use a fallback (F) of $div_scale digits.
3489     If either the dividend's or the divisor's mantissa has more digits than
3490     the value of F, the higher value will be used instead of F.
3491     This is to limit the digits (A) of the result (just consider what would
3492     happen with unlimited A and P in the case of 1/3 :-)
3493   * fdiv will calculate (at least) 4 more digits than required (determined by
3494     A, P or F), and, if F is not used, round the result
3495     (this will still fail in the case of a result like 0.12345000000001 with A
3496     or P of 5, but this can not be helped - or can it?)
3497   * Thus you can have the math done by on Math::Big* class in two modi:
3498     + never round (this is the default):
3499       This is done by setting A and P to undef. No math operation
3500       will round the result, with fdiv() and fsqrt() as exceptions to guard
3501       against overflows. You must explicitely call bround(), bfround() or
3502       round() (the latter with parameters).
3503       Note: Once you have rounded a number, the settings will 'stick' on it
3504       and 'infect' all other numbers engaged in math operations with it, since
3505       local settings have the highest precedence. So, to get SaferRound[tm],
3506       use a copy() before rounding like this:
3507
3508         $x = Math::BigFloat->new(12.34);
3509         $y = Math::BigFloat->new(98.76);
3510         $z = $x * $y;                           # 1218.6984
3511         print $x->copy()->fround(3);            # 12.3 (but A is now 3!)
3512         $z = $x * $y;                           # still 1218.6984, without
3513                                                 # copy would have been 1210!
3514
3515     + round after each op:
3516       After each single operation (except for testing like is_zero()), the
3517       method round() is called and the result is rounded appropriately. By
3518       setting proper values for A and P, you can have all-the-same-A or
3519       all-the-same-P modes. For example, Math::Currency might set A to undef,
3520       and P to -2, globally.
3521
3522  ?Maybe an extra option that forbids local A & P settings would be in order,
3523  ?so that intermediate rounding does not 'poison' further math?
3524
3525 =item Overriding globals
3526
3527   * you will be able to give A, P and R as an argument to all the calculation
3528     routines; the second parameter is A, the third one is P, and the fourth is
3529     R (shift right by one for binary operations like badd). P is used only if
3530     the first parameter (A) is undefined. These three parameters override the
3531     globals in the order detailed as follows, i.e. the first defined value
3532     wins:
3533     (local: per object, global: global default, parameter: argument to sub)
3534       + parameter A
3535       + parameter P
3536       + local A (if defined on both of the operands: smaller one is taken)
3537       + local P (if defined on both of the operands: bigger one is taken)
3538       + global A
3539       + global P
3540       + global F
3541   * fsqrt() will hand its arguments to fdiv(), as it used to, only now for two
3542     arguments (A and P) instead of one
3543
3544 =item Local settings
3545
3546   * You can set A or P locally by using C<< $x->accuracy() >> or
3547     C<< $x->precision() >>
3548     and thus force different A and P for different objects/numbers.
3549   * Setting A or P this way immediately rounds $x to the new value.
3550   * C<< $x->accuracy() >> clears C<< $x->precision() >>, and vice versa.
3551
3552 =item Rounding
3553
3554   * the rounding routines will use the respective global or local settings.
3555     fround()/bround() is for accuracy rounding, while ffround()/bfround()
3556     is for precision
3557   * the two rounding functions take as the second parameter one of the
3558     following rounding modes (R):
3559     'even', 'odd', '+inf', '-inf', 'zero', 'trunc'
3560   * you can set/get the global R by using C<< Math::SomeClass->round_mode() >>
3561     or by setting C<< $Math::SomeClass::round_mode >>
3562   * after each operation, C<< $result->round() >> is called, and the result may
3563     eventually be rounded (that is, if A or P were set either locally,
3564     globally or as parameter to the operation)
3565   * to manually round a number, call C<< $x->round($A,$P,$round_mode); >>
3566     this will round the number by using the appropriate rounding function
3567     and then normalize it.
3568   * rounding modifies the local settings of the number:
3569
3570         $x = Math::BigFloat->new(123.456);
3571         $x->accuracy(5);
3572         $x->bround(4);
3573
3574     Here 4 takes precedence over 5, so 123.5 is the result and $x->accuracy()
3575     will be 4 from now on.
3576
3577 =item Default values
3578
3579   * R: 'even'
3580   * F: 40
3581   * A: undef
3582   * P: undef
3583
3584 =item Remarks
3585
3586   * The defaults are set up so that the new code gives the same results as
3587     the old code (except in a few cases on fdiv):
3588     + Both A and P are undefined and thus will not be used for rounding
3589       after each operation.
3590     + round() is thus a no-op, unless given extra parameters A and P
3591
3592 =back
3593
3594 =head1 INTERNALS
3595
3596 The actual numbers are stored as unsigned big integers (with seperate sign).
3597 You should neither care about nor depend on the internal representation; it
3598 might change without notice. Use only method calls like C<< $x->sign(); >>
3599 instead relying on the internal hash keys like in C<< $x->{sign}; >>.
3600
3601 =head2 MATH LIBRARY
3602
3603 Math with the numbers is done (by default) by a module called
3604 C<Math::BigInt::Calc>. This is equivalent to saying:
3605
3606         use Math::BigInt lib => 'Calc';
3607
3608 You can change this by using:
3609
3610         use Math::BigInt lib => 'BitVect';
3611
3612 The following would first try to find Math::BigInt::Foo, then
3613 Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:
3614
3615         use Math::BigInt lib => 'Foo,Math::BigInt::Bar';
3616
3617 Since Math::BigInt::GMP is in almost all cases faster than Calc (especially in
3618 cases involving really big numbers, where it is B<much> faster), and there is
3619 no penalty if Math::BigInt::GMP is not installed, it is a good idea to always
3620 use the following:
3621
3622         use Math::BigInt lib => 'GMP';
3623
3624 Different low-level libraries use different formats to store the
3625 numbers. You should not depend on the number having a specific format.
3626
3627 See the respective math library module documentation for further details.
3628
3629 =head2 SIGN
3630
3631 The sign is either '+', '-', 'NaN', '+inf' or '-inf' and stored seperately.
3632
3633 A sign of 'NaN' is used to represent the result when input arguments are not
3634 numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively
3635 minus infinity. You will get '+inf' when dividing a positive number by 0, and
3636 '-inf' when dividing any negative number by 0.
3637
3638 =head2 mantissa(), exponent() and parts()
3639
3640 C<mantissa()> and C<exponent()> return the said parts of the BigInt such
3641 that:
3642
3643         $m = $x->mantissa();
3644         $e = $x->exponent();
3645         $y = $m * ( 10 ** $e );
3646         print "ok\n" if $x == $y;
3647
3648 C<< ($m,$e) = $x->parts() >> is just a shortcut that gives you both of them
3649 in one go. Both the returned mantissa and exponent have a sign.
3650
3651 Currently, for BigInts C<$e> is always 0, except for NaN, +inf and -inf,
3652 where it is C<NaN>; and for C<$x == 0>, where it is C<1> (to be compatible
3653 with Math::BigFloat's internal representation of a zero as C<0E1>).
3654
3655 C<$m> is currently just a copy of the original number. The relation between
3656 C<$e> and C<$m> will stay always the same, though their real values might
3657 change.
3658
3659 =head1 EXAMPLES
3660
3661   use Math::BigInt;
3662
3663   sub bint { Math::BigInt->new(shift); }
3664
3665   $x = Math::BigInt->bstr("1234")       # string "1234"
3666   $x = "$x";                            # same as bstr()
3667   $x = Math::BigInt->bneg("1234");      # BigInt "-1234"
3668   $x = Math::BigInt->babs("-12345");    # BigInt "12345"
3669   $x = Math::BigInt->bnorm("-0 00");    # BigInt "0"
3670   $x = bint(1) + bint(2);               # BigInt "3"
3671   $x = bint(1) + "2";                   # ditto (auto-BigIntify of "2")
3672   $x = bint(1);                         # BigInt "1"
3673   $x = $x + 5 / 2;                      # BigInt "3"
3674   $x = $x ** 3;                         # BigInt "27"
3675   $x *= 2;                              # BigInt "54"
3676   $x = Math::BigInt->new(0);            # BigInt "0"
3677   $x--;                                 # BigInt "-1"
3678   $x = Math::BigInt->badd(4,5)          # BigInt "9"
3679   print $x->bsstr();                    # 9e+0
3680
3681 Examples for rounding:
3682
3683   use Math::BigFloat;
3684   use Test;
3685
3686   $x = Math::BigFloat->new(123.4567);
3687   $y = Math::BigFloat->new(123.456789);
3688   Math::BigFloat->accuracy(4);          # no more A than 4
3689
3690   ok ($x->copy()->fround(),123.4);      # even rounding
3691   print $x->copy()->fround(),"\n";      # 123.4
3692   Math::BigFloat->round_mode('odd');    # round to odd
3693   print $x->copy()->fround(),"\n";      # 123.5
3694   Math::BigFloat->accuracy(5);          # no more A than 5
3695   Math::BigFloat->round_mode('odd');    # round to odd
3696   print $x->copy()->fround(),"\n";      # 123.46
3697   $y = $x->copy()->fround(4),"\n";      # A = 4: 123.4
3698   print "$y, ",$y->accuracy(),"\n";     # 123.4, 4
3699
3700   Math::BigFloat->accuracy(undef);      # A not important now
3701   Math::BigFloat->precision(2);         # P important
3702   print $x->copy()->bnorm(),"\n";       # 123.46
3703   print $x->copy()->fround(),"\n";      # 123.46
3704
3705 Examples for converting:
3706
3707   my $x = Math::BigInt->new('0b1'.'01' x 123);
3708   print "bin: ",$x->as_bin()," hex:",$x->as_hex()," dec: ",$x,"\n";
3709
3710 =head1 Autocreating constants
3711
3712 After C<use Math::BigInt ':constant'> all the B<integer> decimal, hexadecimal
3713 and binary constants in the given scope are converted to C<Math::BigInt>.
3714 This conversion happens at compile time.
3715
3716 In particular,
3717
3718   perl -MMath::BigInt=:constant -e 'print 2**100,"\n"'
3719
3720 prints the integer value of C<2**100>. Note that without conversion of
3721 constants the expression 2**100 will be calculated as perl scalar.
3722
3723 Please note that strings and floating point constants are not affected,
3724 so that
3725
3726         use Math::BigInt qw/:constant/;
3727
3728         $x = 1234567890123456789012345678901234567890
3729                 + 123456789123456789;
3730         $y = '1234567890123456789012345678901234567890'
3731                 + '123456789123456789';
3732
3733 do not work. You need an explicit Math::BigInt->new() around one of the
3734 operands. You should also quote large constants to protect loss of precision:
3735
3736         use Math::BigInt;
3737
3738         $x = Math::BigInt->new('1234567889123456789123456789123456789');
3739
3740 Without the quotes Perl would convert the large number to a floating point
3741 constant at compile time and then hand the result to BigInt, which results in
3742 an truncated result or a NaN.
3743
3744 This also applies to integers that look like floating point constants:
3745
3746         use Math::BigInt ':constant';
3747
3748         print ref(123e2),"\n";
3749         print ref(123.2e2),"\n";
3750
3751 will print nothing but newlines. Use either L<bignum> or L<Math::BigFloat>
3752 to get this to work.
3753
3754 =head1 PERFORMANCE
3755
3756 Using the form $x += $y; etc over $x = $x + $y is faster, since a copy of $x
3757 must be made in the second case. For long numbers, the copy can eat up to 20%
3758 of the work (in the case of addition/subtraction, less for
3759 multiplication/division). If $y is very small compared to $x, the form
3760 $x += $y is MUCH faster than $x = $x + $y since making the copy of $x takes
3761 more time then the actual addition.
3762
3763 With a technique called copy-on-write, the cost of copying with overload could
3764 be minimized or even completely avoided. A test implementation of COW did show
3765 performance gains for overloaded math, but introduced a performance loss due
3766 to a constant overhead for all other operatons. So Math::BigInt does currently
3767 not COW.
3768
3769 The rewritten version of this module (vs. v0.01) is slower on certain
3770 operations, like C<new()>, C<bstr()> and C<numify()>. The reason are that it
3771 does now more work and handles much more cases. The time spent in these
3772 operations is usually gained in the other math operations so that code on
3773 the average should get (much) faster. If they don't, please contact the author.
3774
3775 Some operations may be slower for small numbers, but are significantly faster
3776 for big numbers. Other operations are now constant (O(1), like C<bneg()>,
3777 C<babs()> etc), instead of O(N) and thus nearly always take much less time.
3778 These optimizations were done on purpose.
3779
3780 If you find the Calc module to slow, try to install any of the replacement
3781 modules and see if they help you.
3782
3783 =head2 Alternative math libraries
3784
3785 You can use an alternative library to drive Math::BigInt via:
3786
3787         use Math::BigInt lib => 'Module';
3788
3789 See L<MATH LIBRARY> for more information.
3790
3791 For more benchmark results see L<http://bloodgate.com/perl/benchmarks.html>.
3792
3793 =head2 SUBCLASSING
3794
3795 =head1 Subclassing Math::BigInt
3796
3797 The basic design of Math::BigInt allows simple subclasses with very little
3798 work, as long as a few simple rules are followed:
3799
3800 =over 2
3801
3802 =item *
3803
3804 The public API must remain consistent, i.e. if a sub-class is overloading
3805 addition, the sub-class must use the same name, in this case badd(). The
3806 reason for this is that Math::BigInt is optimized to call the object methods
3807 directly.
3808
3809 =item *
3810
3811 The private object hash keys like C<$x->{sign}> may not be changed, but
3812 additional keys can be added, like C<$x->{_custom}>.
3813
3814 =item *
3815
3816 Accessor functions are available for all existing object hash keys and should
3817 be used instead of directly accessing the internal hash keys. The reason for
3818 this is that Math::BigInt itself has a pluggable interface which permits it
3819 to support different storage methods.
3820
3821 =back
3822
3823 More complex sub-classes may have to replicate more of the logic internal of
3824 Math::BigInt if they need to change more basic behaviors. A subclass that
3825 needs to merely change the output only needs to overload C<bstr()>.
3826
3827 All other object methods and overloaded functions can be directly inherited
3828 from the parent class.
3829
3830 At the very minimum, any subclass will need to provide it's own C<new()> and can
3831 store additional hash keys in the object. There are also some package globals
3832 that must be defined, e.g.:
3833
3834   # Globals
3835   $accuracy = undef;
3836   $precision = -2;       # round to 2 decimal places
3837   $round_mode = 'even';
3838   $div_scale = 40;
3839
3840 Additionally, you might want to provide the following two globals to allow
3841 auto-upgrading and auto-downgrading to work correctly:
3842
3843   $upgrade = undef;
3844   $downgrade = undef;
3845
3846 This allows Math::BigInt to correctly retrieve package globals from the
3847 subclass, like C<$SubClass::precision>.  See t/Math/BigInt/Subclass.pm or
3848 t/Math/BigFloat/SubClass.pm completely functional subclass examples.
3849
3850 Don't forget to
3851
3852         use overload;
3853
3854 in your subclass to automatically inherit the overloading from the parent. If
3855 you like, you can change part of the overloading, look at Math::String for an
3856 example.
3857
3858 =head1 UPGRADING
3859
3860 When used like this:
3861
3862         use Math::BigInt upgrade => 'Foo::Bar';
3863
3864 certain operations will 'upgrade' their calculation and thus the result to
3865 the class Foo::Bar. Usually this is used in conjunction with Math::BigFloat:
3866
3867         use Math::BigInt upgrade => 'Math::BigFloat';
3868
3869 As a shortcut, you can use the module C<bignum>:
3870
3871         use bignum;
3872
3873 Also good for oneliners:
3874
3875         perl -Mbignum -le 'print 2 ** 255'
3876
3877 This makes it possible to mix arguments of different classes (as in 2.5 + 2)
3878 as well es preserve accuracy (as in sqrt(3)).
3879
3880 Beware: This feature is not fully implemented yet.
3881
3882 =head2 Auto-upgrade
3883
3884 The following methods upgrade themselves unconditionally; that is if upgrade
3885 is in effect, they will always hand up their work:
3886
3887 =over 2
3888
3889 =item bsqrt()
3890
3891 =item div()
3892
3893 =item blog()
3894
3895 =back
3896
3897 Beware: This list is not complete.
3898
3899 All other methods upgrade themselves only when one (or all) of their
3900 arguments are of the class mentioned in $upgrade (This might change in later
3901 versions to a more sophisticated scheme):
3902
3903 =head1 BUGS
3904
3905 =over 2
3906
3907 =item broot() does not work
3908
3909 The broot() function in BigInt may only work for small values. This will be
3910 fixed in a later version.
3911
3912 =item Out of Memory!
3913
3914 Under Perl prior to 5.6.0 having an C<use Math::BigInt ':constant';> and
3915 C<eval()> in your code will crash with "Out of memory". This is probably an
3916 overload/exporter bug. You can workaround by not having C<eval()>
3917 and ':constant' at the same time or upgrade your Perl to a newer version.
3918
3919 =item Fails to load Calc on Perl prior 5.6.0
3920
3921 Since eval(' use ...') can not be used in conjunction with ':constant', BigInt
3922 will fall back to eval { require ... } when loading the math lib on Perls
3923 prior to 5.6.0. This simple replaces '::' with '/' and thus might fail on
3924 filesystems using a different seperator.
3925
3926 =back
3927
3928 =head1 CAVEATS
3929
3930 Some things might not work as you expect them. Below is documented what is
3931 known to be troublesome:
3932
3933 =over 1
3934
3935 =item bstr(), bsstr() and 'cmp'
3936
3937 Both C<bstr()> and C<bsstr()> as well as automated stringify via overload now
3938 drop the leading '+'. The old code would return '+3', the new returns '3'.
3939 This is to be consistent with Perl and to make C<cmp> (especially with
3940 overloading) to work as you expect. It also solves problems with C<Test.pm>,
3941 because it's C<ok()> uses 'eq' internally.
3942
3943 Mark Biggar said, when asked about to drop the '+' altogether, or make only
3944 C<cmp> work:
3945
3946         I agree (with the first alternative), don't add the '+' on positive
3947         numbers.  It's not as important anymore with the new internal
3948         form for numbers.  It made doing things like abs and neg easier,
3949         but those have to be done differently now anyway.
3950
3951 So, the following examples will now work all as expected:
3952
3953         use Test;
3954         BEGIN { plan tests => 1 }
3955         use Math::BigInt;
3956
3957         my $x = new Math::BigInt 3*3;
3958         my $y = new Math::BigInt 3*3;
3959
3960         ok ($x,3*3);
3961         print "$x eq 9" if $x eq $y;
3962         print "$x eq 9" if $x eq '9';
3963         print "$x eq 9" if $x eq 3*3;
3964
3965 Additionally, the following still works:
3966
3967         print "$x == 9" if $x == $y;
3968         print "$x == 9" if $x == 9;
3969         print "$x == 9" if $x == 3*3;
3970
3971 There is now a C<bsstr()> method to get the string in scientific notation aka
3972 C<1e+2> instead of C<100>. Be advised that overloaded 'eq' always uses bstr()
3973 for comparisation, but Perl will represent some numbers as 100 and others
3974 as 1e+308. If in doubt, convert both arguments to Math::BigInt before
3975 comparing them as strings:
3976
3977         use Test;
3978         BEGIN { plan tests => 3 }
3979         use Math::BigInt;
3980
3981         $x = Math::BigInt->new('1e56'); $y = 1e56;
3982         ok ($x,$y);                     # will fail
3983         ok ($x->bsstr(),$y);            # okay
3984         $y = Math::BigInt->new($y);
3985         ok ($x,$y);                     # okay
3986
3987 Alternatively, simple use C<< <=> >> for comparisations, this will get it
3988 always right. There is not yet a way to get a number automatically represented
3989 as a string that matches exactly the way Perl represents it.
3990
3991 =item int()
3992
3993 C<int()> will return (at least for Perl v5.7.1 and up) another BigInt, not a
3994 Perl scalar:
3995
3996         $x = Math::BigInt->new(123);
3997         $y = int($x);                           # BigInt 123
3998         $x = Math::BigFloat->new(123.45);
3999         $y = int($x);                           # BigInt 123
4000
4001 In all Perl versions you can use C<as_number()> for the same effect:
4002
4003         $x = Math::BigFloat->new(123.45);
4004         $y = $x->as_number();                   # BigInt 123
4005
4006 This also works for other subclasses, like Math::String.
4007
4008 It is yet unlcear whether overloaded int() should return a scalar or a BigInt.
4009
4010 =item length
4011
4012 The following will probably not do what you expect:
4013
4014         $c = Math::BigInt->new(123);
4015         print $c->length(),"\n";                # prints 30
4016
4017 It prints both the number of digits in the number and in the fraction part
4018 since print calls C<length()> in list context. Use something like:
4019
4020         print scalar $c->length(),"\n";         # prints 3
4021
4022 =item bdiv
4023
4024 The following will probably not do what you expect:
4025
4026         print $c->bdiv(10000),"\n";
4027
4028 It prints both quotient and remainder since print calls C<bdiv()> in list
4029 context. Also, C<bdiv()> will modify $c, so be carefull. You probably want
4030 to use
4031
4032         print $c / 10000,"\n";
4033         print scalar $c->bdiv(10000),"\n";  # or if you want to modify $c
4034
4035 instead.
4036
4037 The quotient is always the greatest integer less than or equal to the
4038 real-valued quotient of the two operands, and the remainder (when it is
4039 nonzero) always has the same sign as the second operand; so, for
4040 example,
4041
4042           1 / 4  => ( 0, 1)
4043           1 / -4 => (-1,-3)
4044          -3 / 4  => (-1, 1)
4045          -3 / -4 => ( 0,-3)
4046         -11 / 2  => (-5,1)
4047          11 /-2  => (-5,-1)
4048
4049 As a consequence, the behavior of the operator % agrees with the
4050 behavior of Perl's built-in % operator (as documented in the perlop
4051 manpage), and the equation
4052
4053         $x == ($x / $y) * $y + ($x % $y)
4054
4055 holds true for any $x and $y, which justifies calling the two return
4056 values of bdiv() the quotient and remainder. The only exception to this rule
4057 are when $y == 0 and $x is negative, then the remainder will also be
4058 negative. See below under "infinity handling" for the reasoning behing this.
4059
4060 Perl's 'use integer;' changes the behaviour of % and / for scalars, but will
4061 not change BigInt's way to do things. This is because under 'use integer' Perl
4062 will do what the underlying C thinks is right and this is different for each
4063 system. If you need BigInt's behaving exactly like Perl's 'use integer', bug
4064 the author to implement it ;)
4065
4066 =item infinity handling
4067
4068 Here are some examples that explain the reasons why certain results occur while
4069 handling infinity:
4070
4071 The following table shows the result of the division and the remainder, so that
4072 the equation above holds true. Some "ordinary" cases are strewn in to show more
4073 clearly the reasoning:
4074
4075         A /  B  =   C,     R so that C *    B +    R =    A
4076      =========================================================
4077         5 /   8 =   0,     5         0 *    8 +    5 =    5
4078         0 /   8 =   0,     0         0 *    8 +    0 =    0
4079         0 / inf =   0,     0         0 *  inf +    0 =    0
4080         0 /-inf =   0,     0         0 * -inf +    0 =    0
4081         5 / inf =   0,     5         0 *  inf +    5 =    5
4082         5 /-inf =   0,     5         0 * -inf +    5 =    5
4083         -5/ inf =   0,    -5         0 *  inf +   -5 =   -5
4084         -5/-inf =   0,    -5         0 * -inf +   -5 =   -5
4085        inf/   5 =  inf,    0       inf *    5 +    0 =  inf
4086       -inf/   5 = -inf,    0      -inf *    5 +    0 = -inf
4087        inf/  -5 = -inf,    0      -inf *   -5 +    0 =  inf
4088       -inf/  -5 =  inf,    0       inf *   -5 +    0 = -inf
4089          5/   5 =    1,    0         1 *    5 +    0 =    5
4090         -5/  -5 =    1,    0         1 *   -5 +    0 =   -5
4091        inf/ inf =    1,    0         1 *  inf +    0 =  inf
4092       -inf/-inf =    1,    0         1 * -inf +    0 = -inf
4093        inf/-inf =   -1,    0        -1 * -inf +    0 =  inf
4094       -inf/ inf =   -1,    0         1 * -inf +    0 = -inf
4095          8/   0 =  inf,    8       inf *    0 +    8 =    8
4096        inf/   0 =  inf,  inf       inf *    0 +  inf =  inf
4097          0/   0 =  NaN
4098
4099 These cases below violate the "remainder has the sign of the second of the two
4100 arguments", since they wouldn't match up otherwise.
4101
4102         A /  B  =   C,     R so that C *    B +    R =    A
4103      ========================================================
4104       -inf/   0 = -inf, -inf      -inf *    0 +  inf = -inf
4105         -8/   0 = -inf,   -8      -inf *    0 +    8 = -8
4106
4107 =item Modifying and =
4108
4109 Beware of:
4110
4111         $x = Math::BigFloat->new(5);
4112         $y = $x;
4113
4114 It will not do what you think, e.g. making a copy of $x. Instead it just makes
4115 a second reference to the B<same> object and stores it in $y. Thus anything
4116 that modifies $x (except overloaded operators) will modify $y, and vice versa.
4117 Or in other words, C<=> is only safe if you modify your BigInts only via
4118 overloaded math. As soon as you use a method call it breaks:
4119
4120         $x->bmul(2);
4121         print "$x, $y\n";       # prints '10, 10'
4122
4123 If you want a true copy of $x, use:
4124
4125         $y = $x->copy();
4126
4127 You can also chain the calls like this, this will make first a copy and then
4128 multiply it by 2:
4129
4130         $y = $x->copy()->bmul(2);
4131
4132 See also the documentation for overload.pm regarding C<=>.
4133
4134 =item bpow
4135
4136 C<bpow()> (and the rounding functions) now modifies the first argument and
4137 returns it, unlike the old code which left it alone and only returned the
4138 result. This is to be consistent with C<badd()> etc. The first three will
4139 modify $x, the last one won't:
4140
4141         print bpow($x,$i),"\n";         # modify $x
4142         print $x->bpow($i),"\n";        # ditto
4143         print $x **= $i,"\n";           # the same
4144         print $x ** $i,"\n";            # leave $x alone
4145
4146 The form C<$x **= $y> is faster than C<$x = $x ** $y;>, though.
4147
4148 =item Overloading -$x
4149
4150 The following:
4151
4152         $x = -$x;
4153
4154 is slower than
4155
4156         $x->bneg();
4157
4158 since overload calls C<sub($x,0,1);> instead of C<neg($x)>. The first variant
4159 needs to preserve $x since it does not know that it later will get overwritten.
4160 This makes a copy of $x and takes O(N), but $x->bneg() is O(1).
4161
4162 With Copy-On-Write, this issue would be gone, but C-o-W is not implemented
4163 since it is slower for all other things.
4164
4165 =item Mixing different object types
4166
4167 In Perl you will get a floating point value if you do one of the following:
4168
4169         $float = 5.0 + 2;
4170         $float = 2 + 5.0;
4171         $float = 5 / 2;
4172
4173 With overloaded math, only the first two variants will result in a BigFloat:
4174
4175         use Math::BigInt;
4176         use Math::BigFloat;
4177
4178         $mbf = Math::BigFloat->new(5);
4179         $mbi2 = Math::BigInteger->new(5);
4180         $mbi = Math::BigInteger->new(2);
4181
4182                                         # what actually gets called:
4183         $float = $mbf + $mbi;           # $mbf->badd()
4184         $float = $mbf / $mbi;           # $mbf->bdiv()
4185         $integer = $mbi + $mbf;         # $mbi->badd()
4186         $integer = $mbi2 / $mbi;        # $mbi2->bdiv()
4187         $integer = $mbi2 / $mbf;        # $mbi2->bdiv()
4188
4189 This is because math with overloaded operators follows the first (dominating)
4190 operand, and the operation of that is called and returns thus the result. So,
4191 Math::BigInt::bdiv() will always return a Math::BigInt, regardless whether
4192 the result should be a Math::BigFloat or the second operant is one.
4193
4194 To get a Math::BigFloat you either need to call the operation manually,
4195 make sure the operands are already of the proper type or casted to that type
4196 via Math::BigFloat->new():
4197
4198         $float = Math::BigFloat->new($mbi2) / $mbi;     # = 2.5
4199
4200 Beware of simple "casting" the entire expression, this would only convert
4201 the already computed result:
4202
4203         $float = Math::BigFloat->new($mbi2 / $mbi);     # = 2.0 thus wrong!
4204
4205 Beware also of the order of more complicated expressions like:
4206
4207         $integer = ($mbi2 + $mbi) / $mbf;               # int / float => int
4208         $integer = $mbi2 / Math::BigFloat->new($mbi);   # ditto
4209
4210 If in doubt, break the expression into simpler terms, or cast all operands
4211 to the desired resulting type.
4212
4213 Scalar values are a bit different, since:
4214
4215         $float = 2 + $mbf;
4216         $float = $mbf + 2;
4217
4218 will both result in the proper type due to the way the overloaded math works.
4219
4220 This section also applies to other overloaded math packages, like Math::String.
4221
4222 One solution to you problem might be autoupgrading|upgrading. See the
4223 pragmas L<bignum>, L<bigint> and L<bigrat> for an easy way to do this.
4224
4225 =item bsqrt()
4226
4227 C<bsqrt()> works only good if the result is a big integer, e.g. the square
4228 root of 144 is 12, but from 12 the square root is 3, regardless of rounding
4229 mode. The reason is that the result is always truncated to an integer.
4230
4231 If you want a better approximation of the square root, then use:
4232
4233         $x = Math::BigFloat->new(12);
4234         Math::BigFloat->precision(0);
4235         Math::BigFloat->round_mode('even');
4236         print $x->copy->bsqrt(),"\n";           # 4
4237
4238         Math::BigFloat->precision(2);
4239         print $x->bsqrt(),"\n";                 # 3.46
4240         print $x->bsqrt(3),"\n";                # 3.464
4241
4242 =item brsft()
4243
4244 For negative numbers in base see also L<brsft|brsft>.
4245
4246 =back
4247
4248 =head1 LICENSE
4249
4250 This program is free software; you may redistribute it and/or modify it under
4251 the same terms as Perl itself.
4252
4253 =head1 SEE ALSO
4254
4255 L<Math::BigFloat>, L<Math::BigRat> and L<Math::Big> as well as
4256 L<Math::BigInt::BitVect>, L<Math::BigInt::Pari> and  L<Math::BigInt::GMP>.
4257
4258 The pragmas L<bignum>, L<bigint> and L<bigrat> also might be of interest
4259 because they solve the autoupgrading/downgrading issue, at least partly.
4260
4261 The package at
4262 L<http://search.cpan.org/search?mode=module&query=Math%3A%3ABigInt> contains
4263 more documentation including a full version history, testcases, empty
4264 subclass files and benchmarks.
4265
4266 =head1 AUTHORS
4267
4268 Original code by Mark Biggar, overloaded interface by Ilya Zakharevich.
4269 Completely rewritten by Tels http://bloodgate.com in late 2000, 2001 - 2003
4270 and still at it in 2004.
4271
4272 Many people contributed in one or more ways to the final beast, see the file
4273 CREDITS for an (uncomplete) list. If you miss your name, please drop me a
4274 mail. Thank you!
4275
4276 =cut