lib/Math/BigInt.pm

   1 package Math::BigInt;
   2
   3 #
   4 # "Mike had an infinite amount to do and a negative amount of time in which
   5 # to do it." - Before and After
   6 #
   7
   8 # The following hash values are used:
   9 #   value: unsigned int with actual value (as a Math::BigInt::Calc or similiar)
  10 #   sign : +,-,NaN,+inf,-inf
  11 #   _a   : accuracy
  12 #   _p   : precision
  13 #   _f   : flags, used by MBF to flag parts of a float as untouchable
  14
  15 # Remember not to take shortcuts ala $xs = $x->{value}; $CALC->foo($xs); since
  16 # underlying lib might change the reference!
  17
  18 my $class = "Math::BigInt";
  19 use 5.006002;
  20
  21 $VERSION = '1.87';
  22
  23 @ISA = qw(Exporter);
  24 @EXPORT_OK = qw(objectify bgcd blcm);
  25
  26 # _trap_inf and _trap_nan are internal and should never be accessed from the
  27 # outside
  28 use vars qw/$round_mode $accuracy $precision $div_scale $rnd_mode
  29             $upgrade $downgrade $_trap_nan $_trap_inf/;
  30 use strict;
  31
  32 # Inside overload, the first arg is always an object. If the original code had
  33 # it reversed (like $x = 2 * $y), then the third paramater is true.
  34 # In some cases (like add, $x = $x + 2 is the same as $x = 2 + $x) this makes
  35 # no difference, but in some cases it does.
  36
  37 # For overloaded ops with only one argument we simple use $_[0]->copy() to
  38 # preserve the argument.
  39
  40 # Thus inheritance of overload operators becomes possible and transparent for
  41 # our subclasses without the need to repeat the entire overload section there.
  42
  43 use overload
  44 '='     =>      sub { $_[0]->copy(); },
  45
  46 # some shortcuts for speed (assumes that reversed order of arguments is routed
  47 # to normal '+' and we thus can always modify first arg. If this is changed,
  48 # this breaks and must be adjusted.)
  49 '+='    =>      sub { $_[0]->badd($_[1]); },
  50 '-='    =>      sub { $_[0]->bsub($_[1]); },
  51 '*='    =>      sub { $_[0]->bmul($_[1]); },
  52 '/='    =>      sub { scalar $_[0]->bdiv($_[1]); },
  53 '%='    =>      sub { $_[0]->bmod($_[1]); },
  54 '^='    =>      sub { $_[0]->bxor($_[1]); },
  55 '&='    =>      sub { $_[0]->band($_[1]); },
  56 '|='    =>      sub { $_[0]->bior($_[1]); },
  57
  58 '**='   =>      sub { $_[0]->bpow($_[1]); },
  59 '<<='   =>      sub { $_[0]->blsft($_[1]); },
  60 '>>='   =>      sub { $_[0]->brsft($_[1]); },
  61
  62 # not supported by Perl yet
  63 '..'    =>      \&_pointpoint,
  64
  65 '<=>'   =>      sub { my $rc = $_[2] ?
  66                       ref($_[0])->bcmp($_[1],$_[0]) :
  67                       $_[0]->bcmp($_[1]);
  68                       $rc = 1 unless defined $rc;
  69                       $rc <=> 0;
  70                 },
  71 # we need '>=' to get things like "1 >= NaN" right:
  72 '>='    =>      sub { my $rc = $_[2] ?
  73                       ref($_[0])->bcmp($_[1],$_[0]) :
  74                       $_[0]->bcmp($_[1]);
  75                       # if there was a NaN involved, return false
  76                       return '' unless defined $rc;
  77                       $rc >= 0;
  78                 },
  79 'cmp'   =>      sub {
  80          $_[2] ?
  81                "$_[1]" cmp $_[0]->bstr() :
  82                $_[0]->bstr() cmp "$_[1]" },
  83
  84 # make cos()/sin()/atan2() "work" with BigInt's or subclasses
  85 'cos'   =>      sub { cos($_[0]->numify()) },
  86 'sin'   =>      sub { sin($_[0]->numify()) },
  87 'atan2' =>      sub { $_[2] ?
  88                         atan2($_[1],$_[0]->numify()) :
  89                         atan2($_[0]->numify(),$_[1]) },
  90
  91 # are not yet overloadable
  92 #'hex'  =>      sub { print "hex"; $_[0]; },
  93 #'oct'  =>      sub { print "oct"; $_[0]; },
  94
  95 # log(N) is log(N, e), where e is Euler's number
  96 'log'   =>      sub { $_[0]->copy()->blog($_[1], undef); },
  97 'exp'   =>      sub { $_[0]->copy()->bexp($_[1]); },
  98 'int'   =>      sub { $_[0]->copy(); },
  99 'neg'   =>      sub { $_[0]->copy()->bneg(); },
 100 'abs'   =>      sub { $_[0]->copy()->babs(); },
 101 'sqrt'  =>      sub { $_[0]->copy()->bsqrt(); },
 102 '~'     =>      sub { $_[0]->copy()->bnot(); },
 103
 104 # for subtract it's a bit tricky to not modify b: b-a => -a+b
 105 '-'     =>      sub { my $c = $_[0]->copy; $_[2] ?
 106                         $c->bneg()->badd( $_[1]) :
 107                         $c->bsub( $_[1]) },
 108 '+'     =>      sub { $_[0]->copy()->badd($_[1]); },
 109 '*'     =>      sub { $_[0]->copy()->bmul($_[1]); },
 110
 111 '/'     =>      sub {
 112    $_[2] ? ref($_[0])->new($_[1])->bdiv($_[0]) : $_[0]->copy->bdiv($_[1]);
 113   },
 114 '%'     =>      sub {
 115    $_[2] ? ref($_[0])->new($_[1])->bmod($_[0]) : $_[0]->copy->bmod($_[1]);
 116   },
 117 '**'    =>      sub {
 118    $_[2] ? ref($_[0])->new($_[1])->bpow($_[0]) : $_[0]->copy->bpow($_[1]);
 119   },
 120 '<<'    =>      sub {
 121    $_[2] ? ref($_[0])->new($_[1])->blsft($_[0]) : $_[0]->copy->blsft($_[1]);
 122   },
 123 '>>'    =>      sub {
 124    $_[2] ? ref($_[0])->new($_[1])->brsft($_[0]) : $_[0]->copy->brsft($_[1]);
 125   },
 126 '&'     =>      sub {
 127    $_[2] ? ref($_[0])->new($_[1])->band($_[0]) : $_[0]->copy->band($_[1]);
 128   },
 129 '|'     =>      sub {
 130    $_[2] ? ref($_[0])->new($_[1])->bior($_[0]) : $_[0]->copy->bior($_[1]);
 131   },
 132 '^'     =>      sub {
 133    $_[2] ? ref($_[0])->new($_[1])->bxor($_[0]) : $_[0]->copy->bxor($_[1]);
 134   },
 135
 136 # can modify arg of ++ and --, so avoid a copy() for speed, but don't
 137 # use $_[0]->bone(), it would modify $_[0] to be 1!
 138 '++'    =>      sub { $_[0]->binc() },
 139 '--'    =>      sub { $_[0]->bdec() },
 140
 141 # if overloaded, O(1) instead of O(N) and twice as fast for small numbers
 142 'bool'  =>      sub {
 143   # this kludge is needed for perl prior 5.6.0 since returning 0 here fails :-/
 144   # v5.6.1 dumps on this: return !$_[0]->is_zero() || undef;                :-(
 145   my $t = undef;
 146   $t = 1 if !$_[0]->is_zero();
 147   $t;
 148   },
 149
 150 # the original qw() does not work with the TIESCALAR below, why?
 151 # Order of arguments unsignificant
 152 '""' => sub { $_[0]->bstr(); },
 153 '0+' => sub { $_[0]->numify(); }
 154 ;
 155
 156 ##############################################################################
 157 # global constants, flags and accessory
 158
 159 # These vars are public, but their direct usage is not recommended, use the
 160 # accessor methods instead
 161
 162 $round_mode = 'even'; # one of 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'
 163 $accuracy   = undef;
 164 $precision  = undef;
 165 $div_scale  = 40;
 166
 167 $upgrade = undef;                       # default is no upgrade
 168 $downgrade = undef;                     # default is no downgrade
 169
 170 # These are internally, and not to be used from the outside at all
 171
 172 $_trap_nan = 0;                         # are NaNs ok? set w/ config()
 173 $_trap_inf = 0;                         # are infs ok? set w/ config()
 174 my $nan = 'NaN';                        # constants for easier life
 175
 176 my $CALC = 'Math::BigInt::FastCalc';    # module to do the low level math
 177                                         # default is FastCalc.pm
 178 my $IMPORT = 0;                         # was import() called yet?
 179                                         # used to make require work
 180 my %WARN;                               # warn only once for low-level libs
 181 my %CAN;                                # cache for $CALC->can(...)
 182 my %CALLBACKS;                          # callbacks to notify on lib loads
 183 my $EMU_LIB = 'Math/BigInt/CalcEmu.pm'; # emulate low-level math
 184
 185 ##############################################################################
 186 # the old code had $rnd_mode, so we need to support it, too
 187
 188 $rnd_mode   = 'even';
 189 sub TIESCALAR  { my ($class) = @_; bless \$round_mode, $class; }
 190 sub FETCH      { return $round_mode; }
 191 sub STORE      { $rnd_mode = $_[0]->round_mode($_[1]); }
 192
 193 BEGIN
 194   {
 195   # tie to enable $rnd_mode to work transparently
 196   tie $rnd_mode, 'Math::BigInt';
 197
 198   # set up some handy alias names
 199   *as_int = \&as_number;
 200   *is_pos = \&is_positive;
 201   *is_neg = \&is_negative;
 202   }
 203
 204 ##############################################################################
 205
 206 sub round_mode
 207   {
 208   no strict 'refs';
 209   # make Class->round_mode() work
 210   my $self = shift;
 211   my $class = ref($self) || $self || __PACKAGE__;
 212   if (defined $_[0])
 213     {
 214     my $m = shift;
 215     if ($m !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
 216       {
 217       require Carp; Carp::croak ("Unknown round mode '$m'");
 218       }
 219     return ${"${class}::round_mode"} = $m;
 220     }
 221   ${"${class}::round_mode"};
 222   }
 223
 224 sub upgrade
 225   {
 226   no strict 'refs';
 227   # make Class->upgrade() work
 228   my $self = shift;
 229   my $class = ref($self) || $self || __PACKAGE__;
 230   # need to set new value?
 231   if (@_ > 0)
 232     {
 233     return ${"${class}::upgrade"} = $_[0];
 234     }
 235   ${"${class}::upgrade"};
 236   }
 237
 238 sub downgrade
 239   {
 240   no strict 'refs';
 241   # make Class->downgrade() work
 242   my $self = shift;
 243   my $class = ref($self) || $self || __PACKAGE__;
 244   # need to set new value?
 245   if (@_ > 0)
 246     {
 247     return ${"${class}::downgrade"} = $_[0];
 248     }
 249   ${"${class}::downgrade"};
 250   }
 251
 252 sub div_scale
 253   {
 254   no strict 'refs';
 255   # make Class->div_scale() work
 256   my $self = shift;
 257   my $class = ref($self) || $self || __PACKAGE__;
 258   if (defined $_[0])
 259     {
 260     if ($_[0] < 0)
 261       {
 262       require Carp; Carp::croak ('div_scale must be greater than zero');
 263       }
 264     ${"${class}::div_scale"} = $_[0];
 265     }
 266   ${"${class}::div_scale"};
 267   }
 268
 269 sub accuracy
 270   {
 271   # $x->accuracy($a);           ref($x) $a
 272   # $x->accuracy();             ref($x)
 273   # Class->accuracy();          class
 274   # Class->accuracy($a);        class $a
 275
 276   my $x = shift;
 277   my $class = ref($x) || $x || __PACKAGE__;
 278
 279   no strict 'refs';
 280   # need to set new value?
 281   if (@_ > 0)
 282     {
 283     my $a = shift;
 284     # convert objects to scalars to avoid deep recursion. If object doesn't
 285     # have numify(), then hopefully it will have overloading for int() and
 286     # boolean test without wandering into a deep recursion path...
 287     $a = $a->numify() if ref($a) && $a->can('numify');
 288
 289     if (defined $a)
 290       {
 291       # also croak on non-numerical
 292       if (!$a || $a <= 0)
 293         {
 294         require Carp;
 295         Carp::croak ('Argument to accuracy must be greater than zero');
 296         }
 297       if (int($a) != $a)
 298         {
 299         require Carp; Carp::croak ('Argument to accuracy must be an integer');
 300         }
 301       }
 302     if (ref($x))
 303       {
 304       # $object->accuracy() or fallback to global
 305       $x->bround($a) if $a;             # not for undef, 0
 306       $x->{_a} = $a;                    # set/overwrite, even if not rounded
 307       delete $x->{_p};                  # clear P
 308       $a = ${"${class}::accuracy"} unless defined $a;   # proper return value
 309       }
 310     else
 311       {
 312       ${"${class}::accuracy"} = $a;     # set global A
 313       ${"${class}::precision"} = undef; # clear global P
 314       }
 315     return $a;                          # shortcut
 316     }
 317
 318   my $a;
 319   # $object->accuracy() or fallback to global
 320   $a = $x->{_a} if ref($x);
 321   # but don't return global undef, when $x's accuracy is 0!
 322   $a = ${"${class}::accuracy"} if !defined $a;
 323   $a;
 324   }
 325
 326 sub precision
 327   {
 328   # $x->precision($p);          ref($x) $p
 329   # $x->precision();            ref($x)
 330   # Class->precision();         class
 331   # Class->precision($p);       class $p
 332
 333   my $x = shift;
 334   my $class = ref($x) || $x || __PACKAGE__;
 335
 336   no strict 'refs';
 337   if (@_ > 0)
 338     {
 339     my $p = shift;
 340     # convert objects to scalars to avoid deep recursion. If object doesn't
 341     # have numify(), then hopefully it will have overloading for int() and
 342     # boolean test without wandering into a deep recursion path...
 343     $p = $p->numify() if ref($p) && $p->can('numify');
 344     if ((defined $p) && (int($p) != $p))
 345       {
 346       require Carp; Carp::croak ('Argument to precision must be an integer');
 347       }
 348     if (ref($x))
 349       {
 350       # $object->precision() or fallback to global
 351       $x->bfround($p) if $p;            # not for undef, 0
 352       $x->{_p} = $p;                    # set/overwrite, even if not rounded
 353       delete $x->{_a};                  # clear A
 354       $p = ${"${class}::precision"} unless defined $p;  # proper return value
 355       }
 356     else
 357       {
 358       ${"${class}::precision"} = $p;    # set global P
 359       ${"${class}::accuracy"} = undef;  # clear global A
 360       }
 361     return $p;                          # shortcut
 362     }
 363
 364   my $p;
 365   # $object->precision() or fallback to global
 366   $p = $x->{_p} if ref($x);
 367   # but don't return global undef, when $x's precision is 0!
 368   $p = ${"${class}::precision"} if !defined $p;
 369   $p;
 370   }
 371
 372 sub config
 373   {
 374   # return (or set) configuration data as hash ref
 375   my $class = shift || 'Math::BigInt';
 376
 377   no strict 'refs';
 378   if (@_ > 1 || (@_ == 1 && (ref($_[0]) eq 'HASH')))
 379     {
 380     # try to set given options as arguments from hash
 381
 382     my $args = $_[0];
 383     if (ref($args) ne 'HASH')
 384       {
 385       $args = { @_ };
 386       }
 387     # these values can be "set"
 388     my $set_args = {};
 389     foreach my $key (
 390      qw/trap_inf trap_nan
 391         upgrade downgrade precision accuracy round_mode div_scale/
 392      )
 393       {
 394       $set_args->{$key} = $args->{$key} if exists $args->{$key};
 395       delete $args->{$key};
 396       }
 397     if (keys %$args > 0)
 398       {
 399       require Carp;
 400       Carp::croak ("Illegal key(s) '",
 401        join("','",keys %$args),"' passed to $class\->config()");
 402       }
 403     foreach my $key (keys %$set_args)
 404       {
 405       if ($key =~ /^trap_(inf|nan)\z/)
 406         {
 407         ${"${class}::_trap_$1"} = ($set_args->{"trap_$1"} ? 1 : 0);
 408         next;
 409         }
 410       # use a call instead of just setting the $variable to check argument
 411       $class->$key($set_args->{$key});
 412       }
 413     }
 414
 415   # now return actual configuration
 416
 417   my $cfg = {
 418     lib => $CALC,
 419     lib_version => ${"${CALC}::VERSION"},
 420     class => $class,
 421     trap_nan => ${"${class}::_trap_nan"},
 422     trap_inf => ${"${class}::_trap_inf"},
 423     version => ${"${class}::VERSION"},
 424     };
 425   foreach my $key (qw/
 426      upgrade downgrade precision accuracy round_mode div_scale
 427      /)
 428     {
 429     $cfg->{$key} = ${"${class}::$key"};
 430     };
 431   if (@_ == 1 && (ref($_[0]) ne 'HASH'))
 432     {
 433     # calls of the style config('lib') return just this value
 434     return $cfg->{$_[0]};
 435     }
 436   $cfg;
 437   }
 438
 439 sub _scale_a
 440   {
 441   # select accuracy parameter based on precedence,
 442   # used by bround() and bfround(), may return undef for scale (means no op)
 443   my ($x,$scale,$mode) = @_;
 444
 445   $scale = $x->{_a} unless defined $scale;
 446
 447   no strict 'refs';
 448   my $class = ref($x);
 449
 450   $scale = ${ $class . '::accuracy' } unless defined $scale;
 451   $mode = ${ $class . '::round_mode' } unless defined $mode;
 452
 453   ($scale,$mode);
 454   }
 455
 456 sub _scale_p
 457   {
 458   # select precision parameter based on precedence,
 459   # used by bround() and bfround(), may return undef for scale (means no op)
 460   my ($x,$scale,$mode) = @_;
 461
 462   $scale = $x->{_p} unless defined $scale;
 463
 464   no strict 'refs';
 465   my $class = ref($x);
 466
 467   $scale = ${ $class . '::precision' } unless defined $scale;
 468   $mode = ${ $class . '::round_mode' } unless defined $mode;
 469
 470   ($scale,$mode);
 471   }
 472
 473 ##############################################################################
 474 # constructors
 475
 476 sub copy
 477   {
 478   my ($c,$x);
 479   if (@_ > 1)
 480     {
 481     # if two arguments, the first one is the class to "swallow" subclasses
 482     ($c,$x) = @_;
 483     }
 484   else
 485     {
 486     $x = shift;
 487     $c = ref($x);
 488     }
 489   return unless ref($x); # only for objects
 490
 491   my $self = bless {}, $c;
 492
 493   $self->{sign} = $x->{sign};
 494   $self->{value} = $CALC->_copy($x->{value});
 495   $self->{_a} = $x->{_a} if defined $x->{_a};
 496   $self->{_p} = $x->{_p} if defined $x->{_p};
 497   $self;
 498   }
 499
 500 sub new
 501   {
 502   # create a new BigInt object from a string or another BigInt object.
 503   # see hash keys documented at top
 504
 505   # the argument could be an object, so avoid ||, && etc on it, this would
 506   # cause costly overloaded code to be called. The only allowed ops are
 507   # ref() and defined.
 508
 509   my ($class,$wanted,$a,$p,$r) = @_;
 510
 511   # avoid numify-calls by not using || on $wanted!
 512   return $class->bzero($a,$p) if !defined $wanted;      # default to 0
 513   return $class->copy($wanted,$a,$p,$r)
 514    if ref($wanted) && $wanted->isa($class);             # MBI or subclass
 515
 516   $class->import() if $IMPORT == 0;             # make require work
 517
 518   my $self = bless {}, $class;
 519
 520   # shortcut for "normal" numbers
 521   if ((!ref $wanted) && ($wanted =~ /^([+-]?)[1-9][0-9]*\z/))
 522     {
 523     $self->{sign} = $1 || '+';
 524
 525     if ($wanted =~ /^[+-]/)
 526      {
 527       # remove sign without touching wanted to make it work with constants
 528       my $t = $wanted; $t =~ s/^[+-]//;
 529       $self->{value} = $CALC->_new($t);
 530       }
 531     else
 532       {
 533       $self->{value} = $CALC->_new($wanted);
 534       }
 535     no strict 'refs';
 536     if ( (defined $a) || (defined $p)
 537         || (defined ${"${class}::precision"})
 538         || (defined ${"${class}::accuracy"})
 539        )
 540       {
 541       $self->round($a,$p,$r) unless (@_ == 4 && !defined $a && !defined $p);
 542       }
 543     return $self;
 544     }
 545
 546   # handle '+inf', '-inf' first
 547   if ($wanted =~ /^[+-]?inf\z/)
 548     {
 549     $self->{sign} = $wanted;            # set a default sign for bstr()
 550     return $self->binf($wanted);
 551     }
 552   # split str in m mantissa, e exponent, i integer, f fraction, v value, s sign
 553   my ($mis,$miv,$mfv,$es,$ev) = _split($wanted);
 554   if (!ref $mis)
 555     {
 556     if ($_trap_nan)
 557       {
 558       require Carp; Carp::croak("$wanted is not a number in $class");
 559       }
 560     $self->{value} = $CALC->_zero();
 561     $self->{sign} = $nan;
 562     return $self;
 563     }
 564   if (!ref $miv)
 565     {
 566     # _from_hex or _from_bin
 567     $self->{value} = $mis->{value};
 568     $self->{sign} = $mis->{sign};
 569     return $self;       # throw away $mis
 570     }
 571   # make integer from mantissa by adjusting exp, then convert to bigint
 572   $self->{sign} = $$mis;                        # store sign
 573   $self->{value} = $CALC->_zero();              # for all the NaN cases
 574   my $e = int("$$es$$ev");                      # exponent (avoid recursion)
 575   if ($e > 0)
 576     {
 577     my $diff = $e - CORE::length($$mfv);
 578     if ($diff < 0)                              # Not integer
 579       {
 580       if ($_trap_nan)
 581         {
 582         require Carp; Carp::croak("$wanted not an integer in $class");
 583         }
 584       #print "NOI 1\n";
 585       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 586       $self->{sign} = $nan;
 587       }
 588     else                                        # diff >= 0
 589       {
 590       # adjust fraction and add it to value
 591       #print "diff > 0 $$miv\n";
 592       $$miv = $$miv . ($$mfv . '0' x $diff);
 593       }
 594     }
 595   else
 596     {
 597     if ($$mfv ne '')                            # e <= 0
 598       {
 599       # fraction and negative/zero E => NOI
 600       if ($_trap_nan)
 601         {
 602         require Carp; Carp::croak("$wanted not an integer in $class");
 603         }
 604       #print "NOI 2 \$\$mfv '$$mfv'\n";
 605       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 606       $self->{sign} = $nan;
 607       }
 608     elsif ($e < 0)
 609       {
 610       # xE-y, and empty mfv
 611       #print "xE-y\n";
 612       $e = abs($e);
 613       if ($$miv !~ s/0{$e}$//)          # can strip so many zero's?
 614         {
 615         if ($_trap_nan)
 616           {
 617           require Carp; Carp::croak("$wanted not an integer in $class");
 618           }
 619         #print "NOI 3\n";
 620         return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 621         $self->{sign} = $nan;
 622         }
 623       }
 624     }
 625   $self->{sign} = '+' if $$miv eq '0';                  # normalize -0 => +0
 626   $self->{value} = $CALC->_new($$miv) if $self->{sign} =~ /^[+-]$/;
 627   # if any of the globals is set, use them to round and store them inside $self
 628   # do not round for new($x,undef,undef) since that is used by MBF to signal
 629   # no rounding
 630   $self->round($a,$p,$r) unless @_ == 4 && !defined $a && !defined $p;
 631   $self;
 632   }
 633
 634 sub bnan
 635   {
 636   # create a bigint 'NaN', if given a BigInt, set it to 'NaN'
 637   my $self = shift;
 638   $self = $class if !defined $self;
 639   if (!ref($self))
 640     {
 641     my $c = $self; $self = {}; bless $self, $c;
 642     }
 643   no strict 'refs';
 644   if (${"${class}::_trap_nan"})
 645     {
 646     require Carp;
 647     Carp::croak ("Tried to set $self to NaN in $class\::bnan()");
 648     }
 649   $self->import() if $IMPORT == 0;              # make require work
 650   return if $self->modify('bnan');
 651   if ($self->can('_bnan'))
 652     {
 653     # use subclass to initialize
 654     $self->_bnan();
 655     }
 656   else
 657     {
 658     # otherwise do our own thing
 659     $self->{value} = $CALC->_zero();
 660     }
 661   $self->{sign} = $nan;
 662   delete $self->{_a}; delete $self->{_p};       # rounding NaN is silly
 663   $self;
 664   }
 665
 666 sub binf
 667   {
 668   # create a bigint '+-inf', if given a BigInt, set it to '+-inf'
 669   # the sign is either '+', or if given, used from there
 670   my $self = shift;
 671   my $sign = shift; $sign = '+' if !defined $sign || $sign !~ /^-(inf)?$/;
 672   $self = $class if !defined $self;
 673   if (!ref($self))
 674     {
 675     my $c = $self; $self = {}; bless $self, $c;
 676     }
 677   no strict 'refs';
 678   if (${"${class}::_trap_inf"})
 679     {
 680     require Carp;
 681     Carp::croak ("Tried to set $self to +-inf in $class\::binf()");
 682     }
 683   $self->import() if $IMPORT == 0;              # make require work
 684   return if $self->modify('binf');
 685   if ($self->can('_binf'))
 686     {
 687     # use subclass to initialize
 688     $self->_binf();
 689     }
 690   else
 691     {
 692     # otherwise do our own thing
 693     $self->{value} = $CALC->_zero();
 694     }
 695   $sign = $sign . 'inf' if $sign !~ /inf$/;     # - => -inf
 696   $self->{sign} = $sign;
 697   ($self->{_a},$self->{_p}) = @_;               # take over requested rounding
 698   $self;
 699   }
 700
 701 sub bzero
 702   {
 703   # create a bigint '+0', if given a BigInt, set it to 0
 704   my $self = shift;
 705   $self = __PACKAGE__ if !defined $self;
 706
 707   if (!ref($self))
 708     {
 709     my $c = $self; $self = {}; bless $self, $c;
 710     }
 711   $self->import() if $IMPORT == 0;              # make require work
 712   return if $self->modify('bzero');
 713
 714   if ($self->can('_bzero'))
 715     {
 716     # use subclass to initialize
 717     $self->_bzero();
 718     }
 719   else
 720     {
 721     # otherwise do our own thing
 722     $self->{value} = $CALC->_zero();
 723     }
 724   $self->{sign} = '+';
 725   if (@_ > 0)
 726     {
 727     if (@_ > 3)
 728       {
 729       # call like: $x->bzero($a,$p,$r,$y);
 730       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 731       }
 732     else
 733       {
 734       $self->{_a} = $_[0]
 735        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 736       $self->{_p} = $_[1]
 737        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 738       }
 739     }
 740   $self;
 741   }
 742
 743 sub bone
 744   {
 745   # create a bigint '+1' (or -1 if given sign '-'),
 746   # if given a BigInt, set it to +1 or -1, respectively
 747   my $self = shift;
 748   my $sign = shift; $sign = '+' if !defined $sign || $sign ne '-';
 749   $self = $class if !defined $self;
 750
 751   if (!ref($self))
 752     {
 753     my $c = $self; $self = {}; bless $self, $c;
 754     }
 755   $self->import() if $IMPORT == 0;              # make require work
 756   return if $self->modify('bone');
 757
 758   if ($self->can('_bone'))
 759     {
 760     # use subclass to initialize
 761     $self->_bone();
 762     }
 763   else
 764     {
 765     # otherwise do our own thing
 766     $self->{value} = $CALC->_one();
 767     }
 768   $self->{sign} = $sign;
 769   if (@_ > 0)
 770     {
 771     if (@_ > 3)
 772       {
 773       # call like: $x->bone($sign,$a,$p,$r,$y);
 774       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 775       }
 776     else
 777       {
 778       # call like: $x->bone($sign,$a,$p,$r);
 779       $self->{_a} = $_[0]
 780        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 781       $self->{_p} = $_[1]
 782        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 783       }
 784     }
 785   $self;
 786   }
 787
 788 ##############################################################################
 789 # string conversation
 790
 791 sub bsstr
 792   {
 793   # (ref to BFLOAT or num_str ) return num_str
 794   # Convert number from internal format to scientific string format.
 795   # internal format is always normalized (no leading zeros, "-0E0" => "+0E0")
 796   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 797
 798   if ($x->{sign} !~ /^[+-]$/)
 799     {
 800     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 801     return 'inf';                                       # +inf
 802     }
 803   my ($m,$e) = $x->parts();
 804   #$m->bstr() . 'e+' . $e->bstr();      # e can only be positive in BigInt
 805   # 'e+' because E can only be positive in BigInt
 806   $m->bstr() . 'e+' . $CALC->_str($e->{value});
 807   }
 808
 809 sub bstr
 810   {
 811   # make a string from bigint object
 812   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 813
 814   if ($x->{sign} !~ /^[+-]$/)
 815     {
 816     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 817     return 'inf';                                       # +inf
 818     }
 819   my $es = ''; $es = $x->{sign} if $x->{sign} eq '-';
 820   $es.$CALC->_str($x->{value});
 821   }
 822
 823 sub numify
 824   {
 825   # Make a "normal" scalar from a BigInt object
 826   my $x = shift; $x = $class->new($x) unless ref $x;
 827
 828   return $x->bstr() if $x->{sign} !~ /^[+-]$/;
 829   my $num = $CALC->_num($x->{value});
 830   return -$num if $x->{sign} eq '-';
 831   $num;
 832   }
 833
 834 ##############################################################################
 835 # public stuff (usually prefixed with "b")
 836
 837 sub sign
 838   {
 839   # return the sign of the number: +/-/-inf/+inf/NaN
 840   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 841
 842   $x->{sign};
 843   }
 844
 845 sub _find_round_parameters
 846   {
 847   # After any operation or when calling round(), the result is rounded by
 848   # regarding the A & P from arguments, local parameters, or globals.
 849
 850   # !!!!!!! If you change this, remember to change round(), too! !!!!!!!!!!
 851
 852   # This procedure finds the round parameters, but it is for speed reasons
 853   # duplicated in round. Otherwise, it is tested by the testsuite and used
 854   # by fdiv().
 855
 856   # returns ($self) or ($self,$a,$p,$r) - sets $self to NaN of both A and P
 857   # were requested/defined (locally or globally or both)
 858
 859   my ($self,$a,$p,$r,@args) = @_;
 860   # $a accuracy, if given by caller
 861   # $p precision, if given by caller
 862   # $r round_mode, if given by caller
 863   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 864
 865   my $c = ref($self);                           # find out class of argument(s)
 866   no strict 'refs';
 867
 868   # now pick $a or $p, but only if we have got "arguments"
 869   if (!defined $a)
 870     {
 871     foreach ($self,@args)
 872       {
 873       # take the defined one, or if both defined, the one that is smaller
 874       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 875       }
 876     }
 877   if (!defined $p)
 878     {
 879     # even if $a is defined, take $p, to signal error for both defined
 880     foreach ($self,@args)
 881       {
 882       # take the defined one, or if both defined, the one that is bigger
 883       # -2 > -3, and 3 > 2
 884       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 885       }
 886     }
 887   # if still none defined, use globals (#2)
 888   $a = ${"$c\::accuracy"} unless defined $a;
 889   $p = ${"$c\::precision"} unless defined $p;
 890
 891   # A == 0 is useless, so undef it to signal no rounding
 892   $a = undef if defined $a && $a == 0;
 893
 894   # no rounding today?
 895   return ($self) unless defined $a || defined $p;               # early out
 896
 897   # set A and set P is an fatal error
 898   return ($self->bnan()) if defined $a && defined $p;           # error
 899
 900   $r = ${"$c\::round_mode"} unless defined $r;
 901   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
 902     {
 903     require Carp; Carp::croak ("Unknown round mode '$r'");
 904     }
 905
 906   ($self,$a,$p,$r);
 907   }
 908
 909 sub round
 910   {
 911   # Round $self according to given parameters, or given second argument's
 912   # parameters or global defaults
 913
 914   # for speed reasons, _find_round_parameters is embeded here:
 915
 916   my ($self,$a,$p,$r,@args) = @_;
 917   # $a accuracy, if given by caller
 918   # $p precision, if given by caller
 919   # $r round_mode, if given by caller
 920   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 921
 922   my $c = ref($self);                           # find out class of argument(s)
 923   no strict 'refs';
 924
 925   # now pick $a or $p, but only if we have got "arguments"
 926   if (!defined $a)
 927     {
 928     foreach ($self,@args)
 929       {
 930       # take the defined one, or if both defined, the one that is smaller
 931       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 932       }
 933     }
 934   if (!defined $p)
 935     {
 936     # even if $a is defined, take $p, to signal error for both defined
 937     foreach ($self,@args)
 938       {
 939       # take the defined one, or if both defined, the one that is bigger
 940       # -2 > -3, and 3 > 2
 941       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 942       }
 943     }
 944   # if still none defined, use globals (#2)
 945   $a = ${"$c\::accuracy"} unless defined $a;
 946   $p = ${"$c\::precision"} unless defined $p;
 947
 948   # A == 0 is useless, so undef it to signal no rounding
 949   $a = undef if defined $a && $a == 0;
 950
 951   # no rounding today?
 952   return $self unless defined $a || defined $p;         # early out
 953
 954   # set A and set P is an fatal error
 955   return $self->bnan() if defined $a && defined $p;
 956
 957   $r = ${"$c\::round_mode"} unless defined $r;
 958   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
 959     {
 960     require Carp; Carp::croak ("Unknown round mode '$r'");
 961     }
 962
 963   # now round, by calling either fround or ffround:
 964   if (defined $a)
 965     {
 966     $self->bround($a,$r) if !defined $self->{_a} || $self->{_a} >= $a;
 967     }
 968   else # both can't be undefined due to early out
 969     {
 970     $self->bfround($p,$r) if !defined $self->{_p} || $self->{_p} <= $p;
 971     }
 972   # bround() or bfround() already callled bnorm() if nec.
 973   $self;
 974   }
 975
 976 sub bnorm
 977   {
 978   # (numstr or BINT) return BINT
 979   # Normalize number -- no-op here
 980   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 981   $x;
 982   }
 983
 984 sub babs
 985   {
 986   # (BINT or num_str) return BINT
 987   # make number absolute, or return absolute BINT from string
 988   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 989
 990   return $x if $x->modify('babs');
 991   # post-normalized abs for internal use (does nothing for NaN)
 992   $x->{sign} =~ s/^-/+/;
 993   $x;
 994   }
 995
 996 sub bneg
 997   {
 998   # (BINT or num_str) return BINT
 999   # negate number or make a negated number from string
1000   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1001
1002   return $x if $x->modify('bneg');
1003
1004   # for +0 dont negate (to have always normalized +0). Does nothing for 'NaN'
1005   $x->{sign} =~ tr/+-/-+/ unless ($x->{sign} eq '+' && $CALC->_is_zero($x->{value}));
1006   $x;
1007   }
1008
1009 sub bcmp
1010   {
1011   # Compares 2 values.  Returns one of undef, <0, =0, >0. (suitable for sort)
1012   # (BINT or num_str, BINT or num_str) return cond_code
1013
1014   # set up parameters
1015   my ($self,$x,$y) = (ref($_[0]),@_);
1016
1017   # objectify is costly, so avoid it
1018   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1019     {
1020     ($self,$x,$y) = objectify(2,@_);
1021     }
1022
1023   return $upgrade->bcmp($x,$y) if defined $upgrade &&
1024     ((!$x->isa($self)) || (!$y->isa($self)));
1025
1026   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1027     {
1028     # handle +-inf and NaN
1029     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1030     return 0 if $x->{sign} eq $y->{sign} && $x->{sign} =~ /^[+-]inf$/;
1031     return +1 if $x->{sign} eq '+inf';
1032     return -1 if $x->{sign} eq '-inf';
1033     return -1 if $y->{sign} eq '+inf';
1034     return +1;
1035     }
1036   # check sign for speed first
1037   return 1 if $x->{sign} eq '+' && $y->{sign} eq '-';   # does also 0 <=> -y
1038   return -1 if $x->{sign} eq '-' && $y->{sign} eq '+';  # does also -x <=> 0
1039
1040   # have same sign, so compare absolute values. Don't make tests for zero here
1041   # because it's actually slower than testin in Calc (especially w/ Pari et al)
1042
1043   # post-normalized compare for internal use (honors signs)
1044   if ($x->{sign} eq '+')
1045     {
1046     # $x and $y both > 0
1047     return $CALC->_acmp($x->{value},$y->{value});
1048     }
1049
1050   # $x && $y both < 0
1051   $CALC->_acmp($y->{value},$x->{value});        # swaped acmp (lib returns 0,1,-1)
1052   }
1053
1054 sub bacmp
1055   {
1056   # Compares 2 values, ignoring their signs.
1057   # Returns one of undef, <0, =0, >0. (suitable for sort)
1058   # (BINT, BINT) return cond_code
1059
1060   # set up parameters
1061   my ($self,$x,$y) = (ref($_[0]),@_);
1062   # objectify is costly, so avoid it
1063   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1064     {
1065     ($self,$x,$y) = objectify(2,@_);
1066     }
1067
1068   return $upgrade->bacmp($x,$y) if defined $upgrade &&
1069     ((!$x->isa($self)) || (!$y->isa($self)));
1070
1071   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1072     {
1073     # handle +-inf and NaN
1074     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1075     return 0 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} =~ /^[+-]inf$/;
1076     return 1 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} !~ /^[+-]inf$/;
1077     return -1;
1078     }
1079   $CALC->_acmp($x->{value},$y->{value});        # lib does only 0,1,-1
1080   }
1081
1082 sub badd
1083   {
1084   # add second arg (BINT or string) to first (BINT) (modifies first)
1085   # return result as BINT
1086
1087   # set up parameters
1088   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1089   # objectify is costly, so avoid it
1090   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1091     {
1092     ($self,$x,$y,@r) = objectify(2,@_);
1093     }
1094
1095   return $x if $x->modify('badd');
1096   return $upgrade->badd($upgrade->new($x),$upgrade->new($y),@r) if defined $upgrade &&
1097     ((!$x->isa($self)) || (!$y->isa($self)));
1098
1099   $r[3] = $y;                           # no push!
1100   # inf and NaN handling
1101   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1102     {
1103     # NaN first
1104     return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1105     # inf handling
1106     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1107       {
1108       # +inf++inf or -inf+-inf => same, rest is NaN
1109       return $x if $x->{sign} eq $y->{sign};
1110       return $x->bnan();
1111       }
1112     # +-inf + something => +inf
1113     # something +-inf => +-inf
1114     $x->{sign} = $y->{sign}, return $x if $y->{sign} =~ /^[+-]inf$/;
1115     return $x;
1116     }
1117
1118   my ($sx, $sy) = ( $x->{sign}, $y->{sign} );           # get signs
1119
1120   if ($sx eq $sy)
1121     {
1122     $x->{value} = $CALC->_add($x->{value},$y->{value}); # same sign, abs add
1123     }
1124   else
1125     {
1126     my $a = $CALC->_acmp ($y->{value},$x->{value});     # absolute compare
1127     if ($a > 0)
1128       {
1129       $x->{value} = $CALC->_sub($y->{value},$x->{value},1); # abs sub w/ swap
1130       $x->{sign} = $sy;
1131       }
1132     elsif ($a == 0)
1133       {
1134       # speedup, if equal, set result to 0
1135       $x->{value} = $CALC->_zero();
1136       $x->{sign} = '+';
1137       }
1138     else # a < 0
1139       {
1140       $x->{value} = $CALC->_sub($x->{value}, $y->{value}); # abs sub
1141       }
1142     }
1143   $x->round(@r);
1144   }
1145
1146 sub bsub
1147   {
1148   # (BINT or num_str, BINT or num_str) return BINT
1149   # subtract second arg from first, modify first
1150
1151   # set up parameters
1152   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1153
1154   # objectify is costly, so avoid it
1155   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1156     {
1157     ($self,$x,$y,@r) = objectify(2,@_);
1158     }
1159
1160   return $x if $x->modify('bsub');
1161
1162   return $upgrade->new($x)->bsub($upgrade->new($y),@r) if defined $upgrade &&
1163    ((!$x->isa($self)) || (!$y->isa($self)));
1164
1165   return $x->round(@r) if $y->is_zero();
1166
1167   # To correctly handle the lone special case $x->bsub($x), we note the sign
1168   # of $x, then flip the sign from $y, and if the sign of $x did change, too,
1169   # then we caught the special case:
1170   my $xsign = $x->{sign};
1171   $y->{sign} =~ tr/+\-/-+/;     # does nothing for NaN
1172   if ($xsign ne $x->{sign})
1173     {
1174     # special case of $x->bsub($x) results in 0
1175     return $x->bzero(@r) if $xsign =~ /^[+-]$/;
1176     return $x->bnan();          # NaN, -inf, +inf
1177     }
1178   $x->badd($y,@r);              # badd does not leave internal zeros
1179   $y->{sign} =~ tr/+\-/-+/;     # refix $y (does nothing for NaN)
1180   $x;                           # already rounded by badd() or no round nec.
1181   }
1182
1183 sub binc
1184   {
1185   # increment arg by one
1186   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1187   return $x if $x->modify('binc');
1188
1189   if ($x->{sign} eq '+')
1190     {
1191     $x->{value} = $CALC->_inc($x->{value});
1192     return $x->round($a,$p,$r);
1193     }
1194   elsif ($x->{sign} eq '-')
1195     {
1196     $x->{value} = $CALC->_dec($x->{value});
1197     $x->{sign} = '+' if $CALC->_is_zero($x->{value}); # -1 +1 => -0 => +0
1198     return $x->round($a,$p,$r);
1199     }
1200   # inf, nan handling etc
1201   $x->badd($self->bone(),$a,$p,$r);             # badd does round
1202   }
1203
1204 sub bdec
1205   {
1206   # decrement arg by one
1207   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1208   return $x if $x->modify('bdec');
1209
1210   if ($x->{sign} eq '-')
1211     {
1212     # x already < 0
1213     $x->{value} = $CALC->_inc($x->{value});
1214     }
1215   else
1216     {
1217     return $x->badd($self->bone('-'),@r) unless $x->{sign} eq '+';      # inf or NaN
1218     # >= 0
1219     if ($CALC->_is_zero($x->{value}))
1220       {
1221       # == 0
1222       $x->{value} = $CALC->_one(); $x->{sign} = '-';            # 0 => -1
1223       }
1224     else
1225       {
1226       # > 0
1227       $x->{value} = $CALC->_dec($x->{value});
1228       }
1229     }
1230   $x->round(@r);
1231   }
1232
1233 sub blog
1234   {
1235   # calculate $x = $a ** $base + $b and return $a (e.g. the log() to base
1236   # $base of $x)
1237
1238   # set up parameters
1239   my ($self,$x,$base,@r) = (undef,@_);
1240   # objectify is costly, so avoid it
1241   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1242     {
1243     ($self,$x,$base,@r) = objectify(1,ref($x),@_);
1244     }
1245
1246   return $x if $x->modify('blog');
1247
1248   $base = $self->new($base) if defined $base && !ref $base;
1249
1250   # inf, -inf, NaN, <0 => NaN
1251   return $x->bnan()
1252    if $x->{sign} ne '+' || (defined $base && $base->{sign} ne '+');
1253
1254   return $upgrade->blog($upgrade->new($x),$base,@r) if
1255     defined $upgrade;
1256
1257   # fix for bug #24969:
1258   # the default base is e (Euler's number) which is not an integer
1259   if (!defined $base)
1260     {
1261     require Math::BigFloat;
1262     my $u = Math::BigFloat->blog(Math::BigFloat->new($x))->as_int();
1263     # modify $x in place
1264     $x->{value} = $u->{value};
1265     $x->{sign} = $u->{sign};
1266     return $x;
1267     }
1268
1269   my ($rc,$exact) = $CALC->_log_int($x->{value},$base->{value});
1270   return $x->bnan() unless defined $rc;         # not possible to take log?
1271   $x->{value} = $rc;
1272   $x->round(@r);
1273   }
1274
1275 sub bnok
1276   {
1277   # Calculate n over k (binomial coefficient or "choose" function) as integer.
1278   # set up parameters
1279   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1280
1281   # objectify is costly, so avoid it
1282   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1283     {
1284     ($self,$x,$y,@r) = objectify(2,@_);
1285     }
1286
1287   return $x if $x->modify('bnok');
1288   return $x->bnan() if $x->{sign} eq 'NaN' || $y->{sign} eq 'NaN';
1289   return $x->binf() if $x->{sign} eq '+inf';
1290
1291   # k > n or k < 0 => 0
1292   my $cmp = $x->bacmp($y);
1293   return $x->bzero() if $cmp < 0 || $y->{sign} =~ /^-/;
1294   # k == n => 1
1295   return $x->bone(@r) if $cmp == 0;
1296
1297   if ($CALC->can('_nok'))
1298     {
1299     $x->{value} = $CALC->_nok($x->{value},$y->{value});
1300     }
1301   else
1302     {
1303     # ( 7 )    7!          7*6*5 * 4*3*2*1   7 * 6 * 5
1304     # ( - ) = --------- =  --------------- = ---------
1305     # ( 3 )   3! (7-3)!    3*2*1 * 4*3*2*1   3 * 2 * 1
1306
1307     # compute n - k + 2 (so we start with 5 in the example above)
1308     my $z = $x - $y;
1309     if (!$z->is_one())
1310       {
1311       $z->binc();
1312       my $r = $z->copy(); $z->binc();
1313       my $d = $self->new(2);
1314       while ($z->bacmp($x) <= 0)                # f < x ?
1315         {
1316         $r->bmul($z); $r->bdiv($d);
1317         $z->binc(); $d->binc();
1318         }
1319       $x->{value} = $r->{value}; $x->{sign} = '+';
1320       }
1321     else { $x->bone(); }
1322     }
1323   $x->round(@r);
1324   }
1325
1326 sub bexp
1327   {
1328   # Calculate e ** $x (Euler's number to the power of X), truncated to
1329   # an integer value.
1330   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1331   return $x if $x->modify('bexp');
1332
1333   # inf, -inf, NaN, <0 => NaN
1334   return $x->bnan() if $x->{sign} eq 'NaN';
1335   return $x->bone() if $x->is_zero();
1336   return $x if $x->{sign} eq '+inf';
1337   return $x->bzero() if $x->{sign} eq '-inf';
1338
1339   my $u;
1340   {
1341     # run through Math::BigFloat unless told otherwise
1342     require Math::BigFloat unless defined $upgrade;
1343     local $upgrade = 'Math::BigFloat' unless defined $upgrade;
1344     # calculate result, truncate it to integer
1345     $u = $upgrade->bexp($upgrade->new($x),@r);
1346   }
1347
1348   if (!defined $upgrade)
1349     {
1350     $u = $u->as_int();
1351     # modify $x in place
1352     $x->{value} = $u->{value};
1353     $x->round(@r);
1354     }
1355   else { $x = $u; }
1356   }
1357
1358 sub blcm
1359   {
1360   # (BINT or num_str, BINT or num_str) return BINT
1361   # does not modify arguments, but returns new object
1362   # Lowest Common Multiplicator
1363
1364   my $y = shift; my ($x);
1365   if (ref($y))
1366     {
1367     $x = $y->copy();
1368     }
1369   else
1370     {
1371     $x = $class->new($y);
1372     }
1373   my $self = ref($x);
1374   while (@_)
1375     {
1376     my $y = shift; $y = $self->new($y) if !ref ($y);
1377     $x = __lcm($x,$y);
1378     }
1379   $x;
1380   }
1381
1382 sub bgcd
1383   {
1384   # (BINT or num_str, BINT or num_str) return BINT
1385   # does not modify arguments, but returns new object
1386   # GCD -- Euclids algorithm, variant C (Knuth Vol 3, pg 341 ff)
1387
1388   my $y = shift;
1389   $y = $class->new($y) if !ref($y);
1390   my $self = ref($y);
1391   my $x = $y->copy()->babs();                   # keep arguments
1392   return $x->bnan() if $x->{sign} !~ /^[+-]$/;  # x NaN?
1393
1394   while (@_)
1395     {
1396     $y = shift; $y = $self->new($y) if !ref($y);
1397     return $x->bnan() if $y->{sign} !~ /^[+-]$/;        # y NaN?
1398     $x->{value} = $CALC->_gcd($x->{value},$y->{value});
1399     last if $CALC->_is_one($x->{value});
1400     }
1401   $x;
1402   }
1403
1404 sub bnot
1405   {
1406   # (num_str or BINT) return BINT
1407   # represent ~x as twos-complement number
1408   # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1409   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1410
1411   return $x if $x->modify('bnot');
1412   $x->binc()->bneg();                   # binc already does round
1413   }
1414
1415 ##############################################################################
1416 # is_foo test routines
1417 # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1418
1419 sub is_zero
1420   {
1421   # return true if arg (BINT or num_str) is zero (array '+', '0')
1422   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1423
1424   return 0 if $x->{sign} !~ /^\+$/;                     # -, NaN & +-inf aren't
1425   $CALC->_is_zero($x->{value});
1426   }
1427
1428 sub is_nan
1429   {
1430   # return true if arg (BINT or num_str) is NaN
1431   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1432
1433   $x->{sign} eq $nan ? 1 : 0;
1434   }
1435
1436 sub is_inf
1437   {
1438   # return true if arg (BINT or num_str) is +-inf
1439   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1440
1441   if (defined $sign)
1442     {
1443     $sign = '[+-]inf' if $sign eq '';   # +- doesn't matter, only that's inf
1444     $sign = "[$1]inf" if $sign =~ /^([+-])(inf)?$/;     # extract '+' or '-'
1445     return $x->{sign} =~ /^$sign$/ ? 1 : 0;
1446     }
1447   $x->{sign} =~ /^[+-]inf$/ ? 1 : 0;            # only +-inf is infinity
1448   }
1449
1450 sub is_one
1451   {
1452   # return true if arg (BINT or num_str) is +1, or -1 if sign is given
1453   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1454
1455   $sign = '+' if !defined $sign || $sign ne '-';
1456
1457   return 0 if $x->{sign} ne $sign;      # -1 != +1, NaN, +-inf aren't either
1458   $CALC->_is_one($x->{value});
1459   }
1460
1461 sub is_odd
1462   {
1463   # return true when arg (BINT or num_str) is odd, false for even
1464   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1465
1466   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1467   $CALC->_is_odd($x->{value});
1468   }
1469
1470 sub is_even
1471   {
1472   # return true when arg (BINT or num_str) is even, false for odd
1473   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1474
1475   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1476   $CALC->_is_even($x->{value});
1477   }
1478
1479 sub is_positive
1480   {
1481   # return true when arg (BINT or num_str) is positive (>= 0)
1482   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1483
1484   return 1 if $x->{sign} eq '+inf';                     # +inf is positive
1485
1486   # 0+ is neither positive nor negative
1487   ($x->{sign} eq '+' && !$x->is_zero()) ? 1 : 0;
1488   }
1489
1490 sub is_negative
1491   {
1492   # return true when arg (BINT or num_str) is negative (< 0)
1493   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1494
1495   $x->{sign} =~ /^-/ ? 1 : 0;           # -inf is negative, but NaN is not
1496   }
1497
1498 sub is_int
1499   {
1500   # return true when arg (BINT or num_str) is an integer
1501   # always true for BigInt, but different for BigFloats
1502   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1503
1504   $x->{sign} =~ /^[+-]$/ ? 1 : 0;               # inf/-inf/NaN aren't
1505   }
1506
1507 ###############################################################################
1508
1509 sub bmul
1510   {
1511   # multiply two numbers -- stolen from Knuth Vol 2 pg 233
1512   # (BINT or num_str, BINT or num_str) return BINT
1513
1514   # set up parameters
1515   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1516   # objectify is costly, so avoid it
1517   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1518     {
1519     ($self,$x,$y,@r) = objectify(2,@_);
1520     }
1521
1522   return $x if $x->modify('bmul');
1523
1524   return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1525
1526   # inf handling
1527   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1528     {
1529     return $x->bnan() if $x->is_zero() || $y->is_zero();
1530     # result will always be +-inf:
1531     # +inf * +/+inf => +inf, -inf * -/-inf => +inf
1532     # +inf * -/-inf => -inf, -inf * +/+inf => -inf
1533     return $x->binf() if ($x->{sign} =~ /^\+/ && $y->{sign} =~ /^\+/);
1534     return $x->binf() if ($x->{sign} =~ /^-/ && $y->{sign} =~ /^-/);
1535     return $x->binf('-');
1536     }
1537
1538   return $upgrade->bmul($x,$upgrade->new($y),@r)
1539    if defined $upgrade && !$y->isa($self);
1540
1541   $r[3] = $y;                           # no push here
1542
1543   $x->{sign} = $x->{sign} eq $y->{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 => +
1544
1545   $x->{value} = $CALC->_mul($x->{value},$y->{value});   # do actual math
1546   $x->{sign} = '+' if $CALC->_is_zero($x->{value});     # no -0
1547
1548   $x->round(@r);
1549   }
1550
1551 sub _div_inf
1552   {
1553   # helper function that handles +-inf cases for bdiv()/bmod() to reuse code
1554   my ($self,$x,$y) = @_;
1555
1556   # NaN if x == NaN or y == NaN or x==y==0
1557   return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan()
1558    if (($x->is_nan() || $y->is_nan())   ||
1559        ($x->is_zero() && $y->is_zero()));
1560
1561   # +-inf / +-inf == NaN, reminder also NaN
1562   if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1563     {
1564     return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan();
1565     }
1566   # x / +-inf => 0, remainder x (works even if x == 0)
1567   if ($y->{sign} =~ /^[+-]inf$/)
1568     {
1569     my $t = $x->copy();         # bzero clobbers up $x
1570     return wantarray ? ($x->bzero(),$t) : $x->bzero()
1571     }
1572
1573   # 5 / 0 => +inf, -6 / 0 => -inf
1574   # +inf / 0 = inf, inf,  and -inf / 0 => -inf, -inf
1575   # exception:   -8 / 0 has remainder -8, not 8
1576   # exception: -inf / 0 has remainder -inf, not inf
1577   if ($y->is_zero())
1578     {
1579     # +-inf / 0 => special case for -inf
1580     return wantarray ?  ($x,$x->copy()) : $x if $x->is_inf();
1581     if (!$x->is_zero() && !$x->is_inf())
1582       {
1583       my $t = $x->copy();               # binf clobbers up $x
1584       return wantarray ?
1585        ($x->binf($x->{sign}),$t) : $x->binf($x->{sign})
1586       }
1587     }
1588
1589   # last case: +-inf / ordinary number
1590   my $sign = '+inf';
1591   $sign = '-inf' if substr($x->{sign},0,1) ne $y->{sign};
1592   $x->{sign} = $sign;
1593   return wantarray ? ($x,$self->bzero()) : $x;
1594   }
1595
1596 sub bdiv
1597   {
1598   # (dividend: BINT or num_str, divisor: BINT or num_str) return
1599   # (BINT,BINT) (quo,rem) or BINT (only rem)
1600
1601   # set up parameters
1602   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1603   # objectify is costly, so avoid it
1604   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1605     {
1606     ($self,$x,$y,@r) = objectify(2,@_);
1607     }
1608
1609   return $x if $x->modify('bdiv');
1610
1611   return $self->_div_inf($x,$y)
1612    if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero());
1613
1614   return $upgrade->bdiv($upgrade->new($x),$upgrade->new($y),@r)
1615    if defined $upgrade;
1616
1617   $r[3] = $y;                                   # no push!
1618
1619   # calc new sign and in case $y == +/- 1, return $x
1620   my $xsign = $x->{sign};                               # keep
1621   $x->{sign} = ($x->{sign} ne $y->{sign} ? '-' : '+');
1622
1623   if (wantarray)
1624     {
1625     my $rem = $self->bzero();
1626     ($x->{value},$rem->{value}) = $CALC->_div($x->{value},$y->{value});
1627     $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1628     $rem->{_a} = $x->{_a};
1629     $rem->{_p} = $x->{_p};
1630     $x->round(@r);
1631     if (! $CALC->_is_zero($rem->{value}))
1632       {
1633       $rem->{sign} = $y->{sign};
1634       $rem = $y->copy()->bsub($rem) if $xsign ne $y->{sign}; # one of them '-'
1635       }
1636     else
1637       {
1638       $rem->{sign} = '+';                       # dont leave -0
1639       }
1640     $rem->round(@r);
1641     return ($x,$rem);
1642     }
1643
1644   $x->{value} = $CALC->_div($x->{value},$y->{value});
1645   $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1646
1647   $x->round(@r);
1648   }
1649
1650 ###############################################################################
1651 # modulus functions
1652
1653 sub bmod
1654   {
1655   # modulus (or remainder)
1656   # (BINT or num_str, BINT or num_str) return BINT
1657
1658   # set up parameters
1659   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1660   # objectify is costly, so avoid it
1661   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1662     {
1663     ($self,$x,$y,@r) = objectify(2,@_);
1664     }
1665
1666   return $x if $x->modify('bmod');
1667   $r[3] = $y;                                   # no push!
1668   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero())
1669     {
1670     my ($d,$r) = $self->_div_inf($x,$y);
1671     $x->{sign} = $r->{sign};
1672     $x->{value} = $r->{value};
1673     return $x->round(@r);
1674     }
1675
1676   # calc new sign and in case $y == +/- 1, return $x
1677   $x->{value} = $CALC->_mod($x->{value},$y->{value});
1678   if (!$CALC->_is_zero($x->{value}))
1679     {
1680     $x->{value} = $CALC->_sub($y->{value},$x->{value},1)        # $y-$x
1681       if ($x->{sign} ne $y->{sign});
1682     $x->{sign} = $y->{sign};
1683     }
1684    else
1685     {
1686     $x->{sign} = '+';                           # dont leave -0
1687     }
1688   $x->round(@r);
1689   }
1690
1691 sub bmodinv
1692   {
1693   # Modular inverse.  given a number which is (hopefully) relatively
1694   # prime to the modulus, calculate its inverse using Euclid's
1695   # alogrithm.  If the number is not relatively prime to the modulus
1696   # (i.e. their gcd is not one) then NaN is returned.
1697
1698   # set up parameters
1699   my ($self,$x,$y,@r) = (undef,@_);
1700   # objectify is costly, so avoid it
1701   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1702     {
1703     ($self,$x,$y,@r) = objectify(2,@_);
1704     }
1705
1706   return $x if $x->modify('bmodinv');
1707
1708   return $x->bnan()
1709         if ($y->{sign} ne '+'                           # -, NaN, +inf, -inf
1710          || $x->is_zero()                               # or num == 0
1711          || $x->{sign} !~ /^[+-]$/                      # or num NaN, inf, -inf
1712         );
1713
1714   # put least residue into $x if $x was negative, and thus make it positive
1715   $x->bmod($y) if $x->{sign} eq '-';
1716
1717   my $sign;
1718   ($x->{value},$sign) = $CALC->_modinv($x->{value},$y->{value});
1719   return $x->bnan() if !defined $x->{value};            # in case no GCD found
1720   return $x if !defined $sign;                  # already real result
1721   $x->{sign} = $sign;                           # flip/flop see below
1722   $x->bmod($y);                                 # calc real result
1723   $x;
1724   }
1725
1726 sub bmodpow
1727   {
1728   # takes a very large number to a very large exponent in a given very
1729   # large modulus, quickly, thanks to binary exponentation.  supports
1730   # negative exponents.
1731   my ($self,$num,$exp,$mod,@r) = objectify(3,@_);
1732
1733   return $num if $num->modify('bmodpow');
1734
1735   # check modulus for valid values
1736   return $num->bnan() if ($mod->{sign} ne '+'           # NaN, - , -inf, +inf
1737                        || $mod->is_zero());
1738
1739   # check exponent for valid values
1740   if ($exp->{sign} =~ /\w/)
1741     {
1742     # i.e., if it's NaN, +inf, or -inf...
1743     return $num->bnan();
1744     }
1745
1746   $num->bmodinv ($mod) if ($exp->{sign} eq '-');
1747
1748   # check num for valid values (also NaN if there was no inverse but $exp < 0)
1749   return $num->bnan() if $num->{sign} !~ /^[+-]$/;
1750
1751   # $mod is positive, sign on $exp is ignored, result also positive
1752   $num->{value} = $CALC->_modpow($num->{value},$exp->{value},$mod->{value});
1753   $num;
1754   }
1755
1756 ###############################################################################
1757
1758 sub bfac
1759   {
1760   # (BINT or num_str, BINT or num_str) return BINT
1761   # compute factorial number from $x, modify $x in place
1762   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1763
1764   return $x if $x->modify('bfac') || $x->{sign} eq '+inf';      # inf => inf
1765   return $x->bnan() if $x->{sign} ne '+';                       # NaN, <0 etc => NaN
1766
1767   $x->{value} = $CALC->_fac($x->{value});
1768   $x->round(@r);
1769   }
1770
1771 sub bpow
1772   {
1773   # (BINT or num_str, BINT or num_str) return BINT
1774   # compute power of two numbers -- stolen from Knuth Vol 2 pg 233
1775   # modifies first argument
1776
1777   # set up parameters
1778   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1779   # objectify is costly, so avoid it
1780   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1781     {
1782     ($self,$x,$y,@r) = objectify(2,@_);
1783     }
1784
1785   return $x if $x->modify('bpow');
1786
1787   return $x->bnan() if $x->{sign} eq $nan || $y->{sign} eq $nan;
1788
1789   # inf handling
1790   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1791     {
1792     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1793       {
1794       # +-inf ** +-inf
1795       return $x->bnan();
1796       }
1797     # +-inf ** Y
1798     if ($x->{sign} =~ /^[+-]inf/)
1799       {
1800       # +inf ** 0 => NaN
1801       return $x->bnan() if $y->is_zero();
1802       # -inf ** -1 => 1/inf => 0
1803       return $x->bzero() if $y->is_one('-') && $x->is_negative();
1804
1805       # +inf ** Y => inf
1806       return $x if $x->{sign} eq '+inf';
1807
1808       # -inf ** Y => -inf if Y is odd
1809       return $x if $y->is_odd();
1810       return $x->babs();
1811       }
1812     # X ** +-inf
1813
1814     # 1 ** +inf => 1
1815     return $x if $x->is_one();
1816
1817     # 0 ** inf => 0
1818     return $x if $x->is_zero() && $y->{sign} =~ /^[+]/;
1819
1820     # 0 ** -inf => inf
1821     return $x->binf() if $x->is_zero();
1822
1823     # -1 ** -inf => NaN
1824     return $x->bnan() if $x->is_one('-') && $y->{sign} =~ /^[-]/;
1825
1826     # -X ** -inf => 0
1827     return $x->bzero() if $x->{sign} eq '-' && $y->{sign} =~ /^[-]/;
1828
1829     # -1 ** inf => NaN
1830     return $x->bnan() if $x->{sign} eq '-';
1831
1832     # X ** inf => inf
1833     return $x->binf() if $y->{sign} =~ /^[+]/;
1834     # X ** -inf => 0
1835     return $x->bzero();
1836     }
1837
1838   return $upgrade->bpow($upgrade->new($x),$y,@r)
1839    if defined $upgrade && (!$y->isa($self) || $y->{sign} eq '-');
1840
1841   $r[3] = $y;                                   # no push!
1842
1843   # cases 0 ** Y, X ** 0, X ** 1, 1 ** Y are handled by Calc or Emu
1844
1845   my $new_sign = '+';
1846   $new_sign = $y->is_odd() ? '-' : '+' if ($x->{sign} ne '+');
1847
1848   # 0 ** -7 => ( 1 / (0 ** 7)) => 1 / 0 => +inf
1849   return $x->binf()
1850     if $y->{sign} eq '-' && $x->{sign} eq '+' && $CALC->_is_zero($x->{value});
1851   # 1 ** -y => 1 / (1 ** |y|)
1852   # so do test for negative $y after above's clause
1853   return $x->bnan() if $y->{sign} eq '-' && !$CALC->_is_one($x->{value});
1854
1855   $x->{value} = $CALC->_pow($x->{value},$y->{value});
1856   $x->{sign} = $new_sign;
1857   $x->{sign} = '+' if $CALC->_is_zero($y->{value});
1858   $x->round(@r);
1859   }
1860
1861 sub blsft
1862   {
1863   # (BINT or num_str, BINT or num_str) return BINT
1864   # compute x << y, base n, y >= 0
1865
1866   # set up parameters
1867   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1868   # objectify is costly, so avoid it
1869   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1870     {
1871     ($self,$x,$y,$n,@r) = objectify(2,@_);
1872     }
1873
1874   return $x if $x->modify('blsft');
1875   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1876   return $x->round(@r) if $y->is_zero();
1877
1878   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1879
1880   $x->{value} = $CALC->_lsft($x->{value},$y->{value},$n);
1881   $x->round(@r);
1882   }
1883
1884 sub brsft
1885   {
1886   # (BINT or num_str, BINT or num_str) return BINT
1887   # compute x >> y, base n, y >= 0
1888
1889   # set up parameters
1890   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1891   # objectify is costly, so avoid it
1892   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1893     {
1894     ($self,$x,$y,$n,@r) = objectify(2,@_);
1895     }
1896
1897   return $x if $x->modify('brsft');
1898   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1899   return $x->round(@r) if $y->is_zero();
1900   return $x->bzero(@r) if $x->is_zero();                # 0 => 0
1901
1902   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1903
1904    # this only works for negative numbers when shifting in base 2
1905   if (($x->{sign} eq '-') && ($n == 2))
1906     {
1907     return $x->round(@r) if $x->is_one('-');    # -1 => -1
1908     if (!$y->is_one())
1909       {
1910       # although this is O(N*N) in calc (as_bin!) it is O(N) in Pari et al
1911       # but perhaps there is a better emulation for two's complement shift...
1912       # if $y != 1, we must simulate it by doing:
1913       # convert to bin, flip all bits, shift, and be done
1914       $x->binc();                       # -3 => -2
1915       my $bin = $x->as_bin();
1916       $bin =~ s/^-0b//;                 # strip '-0b' prefix
1917       $bin =~ tr/10/01/;                # flip bits
1918       # now shift
1919       if ($y >= CORE::length($bin))
1920         {
1921         $bin = '0';                     # shifting to far right creates -1
1922                                         # 0, because later increment makes
1923                                         # that 1, attached '-' makes it '-1'
1924                                         # because -1 >> x == -1 !
1925         }
1926       else
1927         {
1928         $bin =~ s/.{$y}$//;             # cut off at the right side
1929         $bin = '1' . $bin;              # extend left side by one dummy '1'
1930         $bin =~ tr/10/01/;              # flip bits back
1931         }
1932       my $res = $self->new('0b'.$bin);  # add prefix and convert back
1933       $res->binc();                     # remember to increment
1934       $x->{value} = $res->{value};      # take over value
1935       return $x->round(@r);             # we are done now, magic, isn't?
1936       }
1937     # x < 0, n == 2, y == 1
1938     $x->bdec();                         # n == 2, but $y == 1: this fixes it
1939     }
1940
1941   $x->{value} = $CALC->_rsft($x->{value},$y->{value},$n);
1942   $x->round(@r);
1943   }
1944
1945 sub band
1946   {
1947   #(BINT or num_str, BINT or num_str) return BINT
1948   # compute x & y
1949
1950   # set up parameters
1951   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1952   # objectify is costly, so avoid it
1953   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1954     {
1955     ($self,$x,$y,@r) = objectify(2,@_);
1956     }
1957
1958   return $x if $x->modify('band');
1959
1960   $r[3] = $y;                           # no push!
1961
1962   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1963
1964   my $sx = $x->{sign} eq '+' ? 1 : -1;
1965   my $sy = $y->{sign} eq '+' ? 1 : -1;
1966
1967   if ($sx == 1 && $sy == 1)
1968     {
1969     $x->{value} = $CALC->_and($x->{value},$y->{value});
1970     return $x->round(@r);
1971     }
1972
1973   if ($CAN{signed_and})
1974     {
1975     $x->{value} = $CALC->_signed_and($x->{value},$y->{value},$sx,$sy);
1976     return $x->round(@r);
1977     }
1978
1979   require $EMU_LIB;
1980   __emu_band($self,$x,$y,$sx,$sy,@r);
1981   }
1982
1983 sub bior
1984   {
1985   #(BINT or num_str, BINT or num_str) return BINT
1986   # compute x | y
1987
1988   # set up parameters
1989   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1990   # objectify is costly, so avoid it
1991   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1992     {
1993     ($self,$x,$y,@r) = objectify(2,@_);
1994     }
1995
1996   return $x if $x->modify('bior');
1997   $r[3] = $y;                           # no push!
1998
1999   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2000
2001   my $sx = $x->{sign} eq '+' ? 1 : -1;
2002   my $sy = $y->{sign} eq '+' ? 1 : -1;
2003
2004   # the sign of X follows the sign of X, e.g. sign of Y irrelevant for bior()
2005
2006   # don't use lib for negative values
2007   if ($sx == 1 && $sy == 1)
2008     {
2009     $x->{value} = $CALC->_or($x->{value},$y->{value});
2010     return $x->round(@r);
2011     }
2012
2013   # if lib can do negative values, let it handle this
2014   if ($CAN{signed_or})
2015     {
2016     $x->{value} = $CALC->_signed_or($x->{value},$y->{value},$sx,$sy);
2017     return $x->round(@r);
2018     }
2019
2020   require $EMU_LIB;
2021   __emu_bior($self,$x,$y,$sx,$sy,@r);
2022   }
2023
2024 sub bxor
2025   {
2026   #(BINT or num_str, BINT or num_str) return BINT
2027   # compute x ^ y
2028
2029   # set up parameters
2030   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2031   # objectify is costly, so avoid it
2032   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
2033     {
2034     ($self,$x,$y,@r) = objectify(2,@_);
2035     }
2036
2037   return $x if $x->modify('bxor');
2038   $r[3] = $y;                           # no push!
2039
2040   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2041
2042   my $sx = $x->{sign} eq '+' ? 1 : -1;
2043   my $sy = $y->{sign} eq '+' ? 1 : -1;
2044
2045   # don't use lib for negative values
2046   if ($sx == 1 && $sy == 1)
2047     {
2048     $x->{value} = $CALC->_xor($x->{value},$y->{value});
2049     return $x->round(@r);
2050     }
2051
2052   # if lib can do negative values, let it handle this
2053   if ($CAN{signed_xor})
2054     {
2055     $x->{value} = $CALC->_signed_xor($x->{value},$y->{value},$sx,$sy);
2056     return $x->round(@r);
2057     }
2058
2059   require $EMU_LIB;
2060   __emu_bxor($self,$x,$y,$sx,$sy,@r);
2061   }
2062
2063 sub length
2064   {
2065   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2066
2067   my $e = $CALC->_len($x->{value});
2068   wantarray ? ($e,0) : $e;
2069   }
2070
2071 sub digit
2072   {
2073   # return the nth decimal digit, negative values count backward, 0 is right
2074   my ($self,$x,$n) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2075
2076   $n = $n->numify() if ref($n);
2077   $CALC->_digit($x->{value},$n||0);
2078   }
2079
2080 sub _trailing_zeros
2081   {
2082   # return the amount of trailing zeros in $x (as scalar)
2083   my $x = shift;
2084   $x = $class->new($x) unless ref $x;
2085
2086   return 0 if $x->{sign} !~ /^[+-]$/;   # NaN, inf, -inf etc
2087
2088   $CALC->_zeros($x->{value});           # must handle odd values, 0 etc
2089   }
2090
2091 sub bsqrt
2092   {
2093   # calculate square root of $x
2094   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2095
2096   return $x if $x->modify('bsqrt');
2097
2098   return $x->bnan() if $x->{sign} !~ /^\+/;     # -x or -inf or NaN => NaN
2099   return $x if $x->{sign} eq '+inf';            # sqrt(+inf) == inf
2100
2101   return $upgrade->bsqrt($x,@r) if defined $upgrade;
2102
2103   $x->{value} = $CALC->_sqrt($x->{value});
2104   $x->round(@r);
2105   }
2106
2107 sub broot
2108   {
2109   # calculate $y'th root of $x
2110
2111   # set up parameters
2112   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2113
2114   $y = $self->new(2) unless defined $y;
2115
2116   # objectify is costly, so avoid it
2117   if ((!ref($x)) || (ref($x) ne ref($y)))
2118     {
2119     ($self,$x,$y,@r) = objectify(2,$self || $class,@_);
2120     }
2121
2122   return $x if $x->modify('broot');
2123
2124   # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
2125   return $x->bnan() if $x->{sign} !~ /^\+/ || $y->is_zero() ||
2126          $y->{sign} !~ /^\+$/;
2127
2128   return $x->round(@r)
2129     if $x->is_zero() || $x->is_one() || $x->is_inf() || $y->is_one();
2130
2131   return $upgrade->new($x)->broot($upgrade->new($y),@r) if defined $upgrade;
2132
2133   $x->{value} = $CALC->_root($x->{value},$y->{value});
2134   $x->round(@r);
2135   }
2136
2137 sub exponent
2138   {
2139   # return a copy of the exponent (here always 0, NaN or 1 for $m == 0)
2140   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2141
2142   if ($x->{sign} !~ /^[+-]$/)
2143     {
2144     my $s = $x->{sign}; $s =~ s/^[+-]//;  # NaN, -inf,+inf => NaN or inf
2145     return $self->new($s);
2146     }
2147   return $self->bone() if $x->is_zero();
2148
2149   # 12300 => 2 trailing zeros => exponent is 2
2150   $self->new( $CALC->_zeros($x->{value}) );
2151   }
2152
2153 sub mantissa
2154   {
2155   # return the mantissa (compatible to Math::BigFloat, e.g. reduced)
2156   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2157
2158   if ($x->{sign} !~ /^[+-]$/)
2159     {
2160     # for NaN, +inf, -inf: keep the sign
2161     return $self->new($x->{sign});
2162     }
2163   my $m = $x->copy(); delete $m->{_p}; delete $m->{_a};
2164
2165   # that's a bit inefficient:
2166   my $zeros = $CALC->_zeros($m->{value});
2167   $m->brsft($zeros,10) if $zeros != 0;
2168   $m;
2169   }
2170
2171 sub parts
2172   {
2173   # return a copy of both the exponent and the mantissa
2174   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2175
2176   ($x->mantissa(),$x->exponent());
2177   }
2178
2179 ##############################################################################
2180 # rounding functions
2181
2182 sub bfround
2183   {
2184   # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
2185   # $n == 0 || $n == 1 => round to integer
2186   my $x = shift; my $self = ref($x) || $x; $x = $self->new($x) unless ref $x;
2187
2188   my ($scale,$mode) = $x->_scale_p(@_);
2189
2190   return $x if !defined $scale || $x->modify('bfround');        # no-op
2191
2192   # no-op for BigInts if $n <= 0
2193   $x->bround( $x->length()-$scale, $mode) if $scale > 0;
2194
2195   delete $x->{_a};      # delete to save memory
2196   $x->{_p} = $scale;    # store new _p
2197   $x;
2198   }
2199
2200 sub _scan_for_nonzero
2201   {
2202   # internal, used by bround() to scan for non-zeros after a '5'
2203   my ($x,$pad,$xs,$len) = @_;
2204
2205   return 0 if $len == 1;                # "5" is trailed by invisible zeros
2206   my $follow = $pad - 1;
2207   return 0 if $follow > $len || $follow < 1;
2208
2209   # use the string form to check whether only '0's follow or not
2210   substr ($xs,-$follow) =~ /[^0]/ ? 1 : 0;
2211   }
2212
2213 sub fround
2214   {
2215   # Exists to make life easier for switch between MBF and MBI (should we
2216   # autoload fxxx() like MBF does for bxxx()?)
2217   my $x = shift; $x = $class->new($x) unless ref $x;
2218   $x->bround(@_);
2219   }
2220
2221 sub bround
2222   {
2223   # accuracy: +$n preserve $n digits from left,
2224   #           -$n preserve $n digits from right (f.i. for 0.1234 style in MBF)
2225   # no-op for $n == 0
2226   # and overwrite the rest with 0's, return normalized number
2227   # do not return $x->bnorm(), but $x
2228
2229   my $x = shift; $x = $class->new($x) unless ref $x;
2230   my ($scale,$mode) = $x->_scale_a(@_);
2231   return $x if !defined $scale || $x->modify('bround'); # no-op
2232
2233   if ($x->is_zero() || $scale == 0)
2234     {
2235     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2236     return $x;
2237     }
2238   return $x if $x->{sign} !~ /^[+-]$/;          # inf, NaN
2239
2240   # we have fewer digits than we want to scale to
2241   my $len = $x->length();
2242   # convert $scale to a scalar in case it is an object (put's a limit on the
2243   # number length, but this would already limited by memory constraints), makes
2244   # it faster
2245   $scale = $scale->numify() if ref ($scale);
2246
2247   # scale < 0, but > -len (not >=!)
2248   if (($scale < 0 && $scale < -$len-1) || ($scale >= $len))
2249     {
2250     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2251     return $x;
2252     }
2253
2254   # count of 0's to pad, from left (+) or right (-): 9 - +6 => 3, or |-6| => 6
2255   my ($pad,$digit_round,$digit_after);
2256   $pad = $len - $scale;
2257   $pad = abs($scale-1) if $scale < 0;
2258
2259   # do not use digit(), it is very costly for binary => decimal
2260   # getting the entire string is also costly, but we need to do it only once
2261   my $xs = $CALC->_str($x->{value});
2262   my $pl = -$pad-1;
2263
2264   # pad:   123: 0 => -1, at 1 => -2, at 2 => -3, at 3 => -4
2265   # pad+1: 123: 0 => 0,  at 1 => -1, at 2 => -2, at 3 => -3
2266   $digit_round = '0'; $digit_round = substr($xs,$pl,1) if $pad <= $len;
2267   $pl++; $pl ++ if $pad >= $len;
2268   $digit_after = '0'; $digit_after = substr($xs,$pl,1) if $pad > 0;
2269
2270   # in case of 01234 we round down, for 6789 up, and only in case 5 we look
2271   # closer at the remaining digits of the original $x, remember decision
2272   my $round_up = 1;                                     # default round up
2273   $round_up -- if
2274     ($mode eq 'trunc')                          ||      # trunc by round down
2275     ($digit_after =~ /[01234]/)                 ||      # round down anyway,
2276                                                         # 6789 => round up
2277     ($digit_after eq '5')                       &&      # not 5000...0000
2278     ($x->_scan_for_nonzero($pad,$xs,$len) == 0)         &&
2279     (
2280      ($mode eq 'even') && ($digit_round =~ /[24680]/) ||
2281      ($mode eq 'odd')  && ($digit_round =~ /[13579]/) ||
2282      ($mode eq '+inf') && ($x->{sign} eq '-')   ||
2283      ($mode eq '-inf') && ($x->{sign} eq '+')   ||
2284      ($mode eq 'zero')          # round down if zero, sign adjusted below
2285     );
2286   my $put_back = 0;                                     # not yet modified
2287
2288   if (($pad > 0) && ($pad <= $len))
2289     {
2290     substr($xs,-$pad,$pad) = '0' x $pad;                # replace with '00...'
2291     $put_back = 1;                                      # need to put back
2292     }
2293   elsif ($pad > $len)
2294     {
2295     $x->bzero();                                        # round to '0'
2296     }
2297
2298   if ($round_up)                                        # what gave test above?
2299     {
2300     $put_back = 1;                                      # need to put back
2301     $pad = $len, $xs = '0' x $pad if $scale < 0;        # tlr: whack 0.51=>1.0
2302
2303     # we modify directly the string variant instead of creating a number and
2304     # adding it, since that is faster (we already have the string)
2305     my $c = 0; $pad ++;                         # for $pad == $len case
2306     while ($pad <= $len)
2307       {
2308       $c = substr($xs,-$pad,1) + 1; $c = '0' if $c eq '10';
2309       substr($xs,-$pad,1) = $c; $pad++;
2310       last if $c != 0;                          # no overflow => early out
2311       }
2312     $xs = '1'.$xs if $c == 0;
2313
2314     }
2315   $x->{value} = $CALC->_new($xs) if $put_back == 1;     # put back, if needed
2316
2317   $x->{_a} = $scale if $scale >= 0;
2318   if ($scale < 0)
2319     {
2320     $x->{_a} = $len+$scale;
2321     $x->{_a} = 0 if $scale < -$len;
2322     }
2323   $x;
2324   }
2325
2326 sub bfloor
2327   {
2328   # return integer less or equal then number; no-op since it's already integer
2329   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2330
2331   $x->round(@r);
2332   }
2333
2334 sub bceil
2335   {
2336   # return integer greater or equal then number; no-op since it's already int
2337   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2338
2339   $x->round(@r);
2340   }
2341
2342 sub as_number
2343   {
2344   # An object might be asked to return itself as bigint on certain overloaded
2345   # operations. This does exactly this, so that sub classes can simple inherit
2346   # it or override with their own integer conversion routine.
2347   $_[0]->copy();
2348   }
2349
2350 sub as_hex
2351   {
2352   # return as hex string, with prefixed 0x
2353   my $x = shift; $x = $class->new($x) if !ref($x);
2354
2355   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2356
2357   my $s = '';
2358   $s = $x->{sign} if $x->{sign} eq '-';
2359   $s . $CALC->_as_hex($x->{value});
2360   }
2361
2362 sub as_bin
2363   {
2364   # return as binary string, with prefixed 0b
2365   my $x = shift; $x = $class->new($x) if !ref($x);
2366
2367   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2368
2369   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2370   return $s . $CALC->_as_bin($x->{value});
2371   }
2372
2373 sub as_oct
2374   {
2375   # return as octal string, with prefixed 0
2376   my $x = shift; $x = $class->new($x) if !ref($x);
2377
2378   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2379
2380   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2381   return $s . $CALC->_as_oct($x->{value});
2382   }
2383
2384 ##############################################################################
2385 # private stuff (internal use only)
2386
2387 sub objectify
2388   {
2389   # check for strings, if yes, return objects instead
2390
2391   # the first argument is number of args objectify() should look at it will
2392   # return $count+1 elements, the first will be a classname. This is because
2393   # overloaded '""' calls bstr($object,undef,undef) and this would result in
2394   # useless objects being created and thrown away. So we cannot simple loop
2395   # over @_. If the given count is 0, all arguments will be used.
2396
2397   # If the second arg is a ref, use it as class.
2398   # If not, try to use it as classname, unless undef, then use $class
2399   # (aka Math::BigInt). The latter shouldn't happen,though.
2400
2401   # caller:                        gives us:
2402   # $x->badd(1);                => ref x, scalar y
2403   # Class->badd(1,2);           => classname x (scalar), scalar x, scalar y
2404   # Class->badd( Class->(1),2); => classname x (scalar), ref x, scalar y
2405   # Math::BigInt::badd(1,2);    => scalar x, scalar y
2406   # In the last case we check number of arguments to turn it silently into
2407   # $class,1,2. (We can not take '1' as class ;o)
2408   # badd($class,1) is not supported (it should, eventually, try to add undef)
2409   # currently it tries 'Math::BigInt' + 1, which will not work.
2410
2411   # some shortcut for the common cases
2412   # $x->unary_op();
2413   return (ref($_[1]),$_[1]) if (@_ == 2) && ($_[0]||0 == 1) && ref($_[1]);
2414
2415   my $count = abs(shift || 0);
2416
2417   my (@a,$k,$d);                # resulting array, temp, and downgrade
2418   if (ref $_[0])
2419     {
2420     # okay, got object as first
2421     $a[0] = ref $_[0];
2422     }
2423   else
2424     {
2425     # nope, got 1,2 (Class->xxx(1) => Class,1 and not supported)
2426     $a[0] = $class;
2427     $a[0] = shift if $_[0] =~ /^[A-Z].*::/;     # classname as first?
2428     }
2429
2430   no strict 'refs';
2431   # disable downgrading, because Math::BigFLoat->foo('1.0','2.0') needs floats
2432   if (defined ${"$a[0]::downgrade"})
2433     {
2434     $d = ${"$a[0]::downgrade"};
2435     ${"$a[0]::downgrade"} = undef;
2436     }
2437
2438   my $up = ${"$a[0]::upgrade"};
2439   # print STDERR "# Now in objectify, my class is today $a[0], count = $count\n";
2440   if ($count == 0)
2441     {
2442     while (@_)
2443       {
2444       $k = shift;
2445       if (!ref($k))
2446         {
2447         $k = $a[0]->new($k);
2448         }
2449       elsif (!defined $up && ref($k) ne $a[0])
2450         {
2451         # foreign object, try to convert to integer
2452         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2453         }
2454       push @a,$k;
2455       }
2456     }
2457   else
2458     {
2459     while ($count > 0)
2460       {
2461       $count--;
2462       $k = shift;
2463       if (!ref($k))
2464         {
2465         $k = $a[0]->new($k);
2466         }
2467       elsif (!defined $up && ref($k) ne $a[0])
2468         {
2469         # foreign object, try to convert to integer
2470         $k->can('as_number') ? $k = $k->as_number() : $k = $a[0]->new($k);
2471         }
2472       push @a,$k;
2473       }
2474     push @a,@_;         # return other params, too
2475     }
2476   if (! wantarray)
2477     {
2478     require Carp; Carp::croak ("$class objectify needs list context");
2479     }
2480   ${"$a[0]::downgrade"} = $d;
2481   @a;
2482   }
2483
2484 sub _register_callback
2485   {
2486   my ($class,$callback) = @_;
2487
2488   if (ref($callback) ne 'CODE')
2489     {
2490     require Carp;
2491     Carp::croak ("$callback is not a coderef");
2492     }
2493   $CALLBACKS{$class} = $callback;
2494   }
2495
2496 sub import
2497   {
2498   my $self = shift;
2499
2500   $IMPORT++;                            # remember we did import()
2501   my @a; my $l = scalar @_;
2502   my $warn_or_die = 0;                  # 0 - no warn, 1 - warn, 2 - die
2503   for ( my $i = 0; $i < $l ; $i++ )
2504     {
2505     if ($_[$i] eq ':constant')
2506       {
2507       # this causes overlord er load to step in
2508       overload::constant
2509         integer => sub { $self->new(shift) },
2510         binary => sub { $self->new(shift) };
2511       }
2512     elsif ($_[$i] eq 'upgrade')
2513       {
2514       # this causes upgrading
2515       $upgrade = $_[$i+1];              # or undef to disable
2516       $i++;
2517       }
2518     elsif ($_[$i] =~ /^(lib|try|only)\z/)
2519       {
2520       # this causes a different low lib to take care...
2521       $CALC = $_[$i+1] || '';
2522       # lib => 1 (warn on fallback), try => 0 (no warn), only => 2 (die on fallback)
2523       $warn_or_die = 1 if $_[$i] eq 'lib';
2524       $warn_or_die = 2 if $_[$i] eq 'only';
2525       $i++;
2526       }
2527     else
2528       {
2529       push @a, $_[$i];
2530       }
2531     }
2532   # any non :constant stuff is handled by our parent, Exporter
2533   if (@a > 0)
2534     {
2535     require Exporter;
2536
2537     $self->SUPER::import(@a);                   # need it for subclasses
2538     $self->export_to_level(1,$self,@a);         # need it for MBF
2539     }
2540
2541   # try to load core math lib
2542   my @c = split /\s*,\s*/,$CALC;
2543   foreach (@c)
2544     {
2545     $_ =~ tr/a-zA-Z0-9://cd;                    # limit to sane characters
2546     }
2547   push @c, \'FastCalc', \'Calc'                 # if all fail, try these
2548     if $warn_or_die < 2;                        # but not for "only"
2549   $CALC = '';                                   # signal error
2550   foreach my $l (@c)
2551     {
2552     # fallback libraries are "marked" as \'string', extract string if nec.
2553     my $lib = $l; $lib = $$l if ref($l);
2554
2555     next if ($lib || '') eq '';
2556     $lib = 'Math::BigInt::'.$lib if $lib !~ /^Math::BigInt/i;
2557     $lib =~ s/\.pm$//;
2558     if ($] < 5.006)
2559       {
2560       # Perl < 5.6.0 dies with "out of memory!" when eval("") and ':constant' is
2561       # used in the same script, or eval("") inside import().
2562       my @parts = split /::/, $lib;             # Math::BigInt => Math BigInt
2563       my $file = pop @parts; $file .= '.pm';    # BigInt => BigInt.pm
2564       require File::Spec;
2565       $file = File::Spec->catfile (@parts, $file);
2566       eval { require "$file"; $lib->import( @c ); }
2567       }
2568     else
2569       {
2570       eval "use $lib qw/@c/;";
2571       }
2572     if ($@ eq '')
2573       {
2574       my $ok = 1;
2575       # loaded it ok, see if the api_version() is high enough
2576       if ($lib->can('api_version') && $lib->api_version() >= 1.0)
2577         {
2578         $ok = 0;
2579         # api_version matches, check if it really provides anything we need
2580         for my $method (qw/
2581                 one two ten
2582                 str num
2583                 add mul div sub dec inc
2584                 acmp len digit is_one is_zero is_even is_odd
2585                 is_two is_ten
2586                 zeros new copy check
2587                 from_hex from_oct from_bin as_hex as_bin as_oct
2588                 rsft lsft xor and or
2589                 mod sqrt root fac pow modinv modpow log_int gcd
2590          /)
2591           {
2592           if (!$lib->can("_$method"))
2593             {
2594             if (($WARN{$lib}||0) < 2)
2595               {
2596               require Carp;
2597               Carp::carp ("$lib is missing method '_$method'");
2598               $WARN{$lib} = 1;          # still warn about the lib
2599               }
2600             $ok++; last;
2601             }
2602           }
2603         }
2604       if ($ok == 0)
2605         {
2606         $CALC = $lib;
2607         if ($warn_or_die > 0 && ref($l))
2608           {
2609           require Carp;
2610           my $msg = "Math::BigInt: couldn't load specified math lib(s), fallback to $lib";
2611           Carp::carp ($msg) if $warn_or_die == 1;
2612           Carp::croak ($msg) if $warn_or_die == 2;
2613           }
2614         last;                   # found a usable one, break
2615         }
2616       else
2617         {
2618         if (($WARN{$lib}||0) < 2)
2619           {
2620           my $ver = eval "\$$lib\::VERSION" || 'unknown';
2621           require Carp;
2622           Carp::carp ("Cannot load outdated $lib v$ver, please upgrade");
2623           $WARN{$lib} = 2;              # never warn again
2624           }
2625         }
2626       }
2627     }
2628   if ($CALC eq '')
2629     {
2630     require Carp;
2631     if ($warn_or_die == 2)
2632       {
2633       Carp::croak ("Couldn't load specified math lib(s) and fallback disallowed");
2634       }
2635     else
2636       {
2637       Carp::croak ("Couldn't load any math lib(s), not even fallback to Calc.pm");
2638       }
2639     }
2640
2641   # notify callbacks
2642   foreach my $class (keys %CALLBACKS)
2643     {
2644     &{$CALLBACKS{$class}}($CALC);
2645     }
2646
2647   # Fill $CAN with the results of $CALC->can(...) for emulating lower math lib
2648   # functions
2649
2650   %CAN = ();
2651   for my $method (qw/ signed_and signed_or signed_xor /)
2652     {
2653     $CAN{$method} = $CALC->can("_$method") ? 1 : 0;
2654     }
2655
2656   # import done
2657   }
2658
2659 sub from_hex
2660   {
2661   # create a bigint from a hexadecimal string
2662   my ($self, $hs) = @_;
2663
2664   my $rc = $self->__from_hex($hs);
2665
2666   return $self->bnan() unless defined $rc;
2667
2668   $rc;
2669   }
2670
2671 sub from_bin
2672   {
2673   # create a bigint from a hexadecimal string
2674   my ($self, $bs) = @_;
2675
2676   my $rc = $self->__from_bin($bs);
2677
2678   return $self->bnan() unless defined $rc;
2679
2680   $rc;
2681   }
2682
2683 sub from_oct
2684   {
2685   # create a bigint from a hexadecimal string
2686   my ($self, $os) = @_;
2687
2688   my $x = $self->bzero();
2689
2690   # strip underscores
2691   $os =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2692   $os =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2693
2694   return $x->bnan() if $os !~ /^[\-\+]?0[0-9]+$/;
2695
2696   my $sign = '+'; $sign = '-' if $os =~ /^-/;
2697
2698   $os =~ s/^[+-]//;                                             # strip sign
2699   $x->{value} = $CALC->_from_oct($os);
2700   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2701   $x;
2702   }
2703
2704 sub __from_hex
2705   {
2706   # internal
2707   # convert a (ref to) big hex string to BigInt, return undef for error
2708   my $hs = shift;
2709
2710   my $x = Math::BigInt->bzero();
2711
2712   # strip underscores
2713   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2714   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2715
2716   return $x->bnan() if $hs !~ /^[\-\+]?0x[0-9A-Fa-f]+$/;
2717
2718   my $sign = '+'; $sign = '-' if $hs =~ /^-/;
2719
2720   $hs =~ s/^[+-]//;                                             # strip sign
2721   $x->{value} = $CALC->_from_hex($hs);
2722   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2723   $x;
2724   }
2725
2726 sub __from_bin
2727   {
2728   # internal
2729   # convert a (ref to) big binary string to BigInt, return undef for error
2730   my $bs = shift;
2731
2732   my $x = Math::BigInt->bzero();
2733
2734   # strip underscores
2735   $bs =~ s/([01])_([01])/$1$2/g;
2736   $bs =~ s/([01])_([01])/$1$2/g;
2737   return $x->bnan() if $bs !~ /^[+-]?0b[01]+$/;
2738
2739   my $sign = '+'; $sign = '-' if $bs =~ /^\-/;
2740   $bs =~ s/^[+-]//;                                             # strip sign
2741
2742   $x->{value} = $CALC->_from_bin($bs);
2743   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2744   $x;
2745   }
2746
2747 sub _split
2748   {
2749   # input: num_str; output: undef for invalid or
2750   # (\$mantissa_sign,\$mantissa_value,\$mantissa_fraction,\$exp_sign,\$exp_value)
2751   # Internal, take apart a string and return the pieces.
2752   # Strip leading/trailing whitespace, leading zeros, underscore and reject
2753   # invalid input.
2754   my $x = shift;
2755
2756   # strip white space at front, also extranous leading zeros
2757   $x =~ s/^\s*([-]?)0*([0-9])/$1$2/g;   # will not strip '  .2'
2758   $x =~ s/^\s+//;                       # but this will
2759   $x =~ s/\s+$//g;                      # strip white space at end
2760
2761   # shortcut, if nothing to split, return early
2762   if ($x =~ /^[+-]?[0-9]+\z/)
2763     {
2764     $x =~ s/^([+-])0*([0-9])/$2/; my $sign = $1 || '+';
2765     return (\$sign, \$x, \'', \'', \0);
2766     }
2767
2768   # invalid starting char?
2769   return if $x !~ /^[+-]?(\.?[0-9]|0b[0-1]|0x[0-9a-fA-F])/;
2770
2771   return __from_hex($x) if $x =~ /^[\-\+]?0x/;          # hex string
2772   return __from_bin($x) if $x =~ /^[\-\+]?0b/;          # binary string
2773
2774   # strip underscores between digits
2775   $x =~ s/([0-9])_([0-9])/$1$2/g;
2776   $x =~ s/([0-9])_([0-9])/$1$2/g;               # do twice for 1_2_3
2777
2778   # some possible inputs:
2779   # 2.1234 # 0.12        # 1          # 1E1 # 2.134E1 # 434E-10 # 1.02009E-2
2780   # .2     # 1_2_3.4_5_6 # 1.4E1_2_3  # 1e3 # +.2     # 0e999
2781
2782   my ($m,$e,$last) = split /[Ee]/,$x;
2783   return if defined $last;              # last defined => 1e2E3 or others
2784   $e = '0' if !defined $e || $e eq "";
2785
2786   # sign,value for exponent,mantint,mantfrac
2787   my ($es,$ev,$mis,$miv,$mfv);
2788   # valid exponent?
2789   if ($e =~ /^([+-]?)0*([0-9]+)$/)      # strip leading zeros
2790     {
2791     $es = $1; $ev = $2;
2792     # valid mantissa?
2793     return if $m eq '.' || $m eq '';
2794     my ($mi,$mf,$lastf) = split /\./,$m;
2795     return if defined $lastf;           # lastf defined => 1.2.3 or others
2796     $mi = '0' if !defined $mi;
2797     $mi .= '0' if $mi =~ /^[\-\+]?$/;
2798     $mf = '0' if !defined $mf || $mf eq '';
2799     if ($mi =~ /^([+-]?)0*([0-9]+)$/)           # strip leading zeros
2800       {
2801       $mis = $1||'+'; $miv = $2;
2802       return unless ($mf =~ /^([0-9]*?)0*$/);   # strip trailing zeros
2803       $mfv = $1;
2804       # handle the 0e999 case here
2805       $ev = 0 if $miv eq '0' && $mfv eq '';
2806       return (\$mis,\$miv,\$mfv,\$es,\$ev);
2807       }
2808     }
2809   return; # NaN, not a number
2810   }
2811
2812 ##############################################################################
2813 # internal calculation routines (others are in Math::BigInt::Calc etc)
2814
2815 sub __lcm
2816   {
2817   # (BINT or num_str, BINT or num_str) return BINT
2818   # does modify first argument
2819   # LCM
2820
2821   my ($x,$ty) = @_;
2822   return $x->bnan() if ($x->{sign} eq $nan) || ($ty->{sign} eq $nan);
2823   my $method = ref($x) . '::bgcd';
2824   no strict 'refs';
2825   $x * $ty / &$method($x,$ty);
2826   }
2827
2828 ###############################################################################
2829 # this method returns 0 if the object can be modified, or 1 if not.
2830 # We use a fast constant sub() here, to avoid costly calls. Subclasses
2831 # may override it with special code (f.i. Math::BigInt::Constant does so)
2832
2833 sub modify () { 0; }
2834
2835 1;
2836 __END__
2837
2838 =pod
2839
2840 =head1 NAME
2841
2842 Math::BigInt - Arbitrary size integer/float math package
2843
2844 =head1 SYNOPSIS
2845
2846   use Math::BigInt;
2847
2848   # or make it faster: install (optional) Math::BigInt::GMP
2849   # and always use (it will fall back to pure Perl if the
2850   # GMP library is not installed):
2851
2852   # will warn if Math::BigInt::GMP cannot be found
2853   use Math::BigInt lib => 'GMP';
2854
2855   # to supress the warning use this:
2856   # use Math::BigInt try => 'GMP';
2857
2858   my $str = '1234567890';
2859   my @values = (64,74,18);
2860   my $n = 1; my $sign = '-';
2861
2862   # Number creation
2863   $x = Math::BigInt->new($str);         # defaults to 0
2864   $y = $x->copy();                      # make a true copy
2865   $nan  = Math::BigInt->bnan();         # create a NotANumber
2866   $zero = Math::BigInt->bzero();        # create a +0
2867   $inf = Math::BigInt->binf();          # create a +inf
2868   $inf = Math::BigInt->binf('-');       # create a -inf
2869   $one = Math::BigInt->bone();          # create a +1
2870   $one = Math::BigInt->bone('-');       # create a -1
2871
2872   $h = Math::BigInt->new('0x123');      # from hexadecimal
2873   $b = Math::BigInt->new('0b101');      # from binary
2874   $o = Math::BigInt->from_oct('0101');  # from octal
2875
2876   # Testing (don't modify their arguments)
2877   # (return true if the condition is met, otherwise false)
2878
2879   $x->is_zero();        # if $x is +0
2880   $x->is_nan();         # if $x is NaN
2881   $x->is_one();         # if $x is +1
2882   $x->is_one('-');      # if $x is -1
2883   $x->is_odd();         # if $x is odd
2884   $x->is_even();        # if $x is even
2885   $x->is_pos();         # if $x >= 0
2886   $x->is_neg();         # if $x <  0
2887   $x->is_inf($sign);    # if $x is +inf, or -inf (sign is default '+')
2888   $x->is_int();         # if $x is an integer (not a float)
2889
2890   # comparing and digit/sign extraction
2891   $x->bcmp($y);         # compare numbers (undef,<0,=0,>0)
2892   $x->bacmp($y);        # compare absolutely (undef,<0,=0,>0)
2893   $x->sign();           # return the sign, either +,- or NaN
2894   $x->digit($n);        # return the nth digit, counting from right
2895   $x->digit(-$n);       # return the nth digit, counting from left
2896
2897   # The following all modify their first argument. If you want to preserve
2898   # $x, use $z = $x->copy()->bXXX($y); See under L<CAVEATS> for why this is
2899   # necessary when mixing $a = $b assignments with non-overloaded math.
2900
2901   $x->bzero();          # set $x to 0
2902   $x->bnan();           # set $x to NaN
2903   $x->bone();           # set $x to +1
2904   $x->bone('-');        # set $x to -1
2905   $x->binf();           # set $x to inf
2906   $x->binf('-');        # set $x to -inf
2907
2908   $x->bneg();           # negation
2909   $x->babs();           # absolute value
2910   $x->bnorm();          # normalize (no-op in BigInt)
2911   $x->bnot();           # two's complement (bit wise not)
2912   $x->binc();           # increment $x by 1
2913   $x->bdec();           # decrement $x by 1
2914
2915   $x->badd($y);         # addition (add $y to $x)
2916   $x->bsub($y);         # subtraction (subtract $y from $x)
2917   $x->bmul($y);         # multiplication (multiply $x by $y)
2918   $x->bdiv($y);         # divide, set $x to quotient
2919                         # return (quo,rem) or quo if scalar
2920
2921   $x->bmod($y);            # modulus (x % y)
2922   $x->bmodpow($exp,$mod);  # modular exponentation (($num**$exp) % $mod))
2923   $x->bmodinv($mod);       # the inverse of $x in the given modulus $mod
2924
2925   $x->bpow($y);            # power of arguments (x ** y)
2926   $x->blsft($y);           # left shift in base 2
2927   $x->brsft($y);           # right shift in base 2
2928                            # returns (quo,rem) or quo if in scalar context
2929   $x->blsft($y,$n);        # left shift by $y places in base $n
2930   $x->brsft($y,$n);        # right shift by $y places in base $n
2931                            # returns (quo,rem) or quo if in scalar context
2932
2933   $x->band($y);            # bitwise and
2934   $x->bior($y);            # bitwise inclusive or
2935   $x->bxor($y);            # bitwise exclusive or
2936   $x->bnot();              # bitwise not (two's complement)
2937
2938   $x->bsqrt();             # calculate square-root
2939   $x->broot($y);           # $y'th root of $x (e.g. $y == 3 => cubic root)
2940   $x->bfac();              # factorial of $x (1*2*3*4*..$x)
2941
2942   $x->bnok($y);            # x over y (binomial coefficient n over k)
2943
2944   $x->blog();              # logarithm of $x to base e (Euler's number)
2945   $x->blog($base);         # logarithm of $x to base $base (f.i. 2)
2946   $x->bexp();              # calculate e ** $x where e is Euler's number
2947
2948   $x->round($A,$P,$mode);  # round to accuracy or precision using mode $mode
2949   $x->bround($n);          # accuracy: preserve $n digits
2950   $x->bfround($n);         # round to $nth digit, no-op for BigInts
2951
2952   # The following do not modify their arguments in BigInt (are no-ops),
2953   # but do so in BigFloat:
2954
2955   $x->bfloor();            # return integer less or equal than $x
2956   $x->bceil();             # return integer greater or equal than $x
2957
2958   # The following do not modify their arguments:
2959
2960   # greatest common divisor (no OO style)
2961   my $gcd = Math::BigInt::bgcd(@values);
2962   # lowest common multiplicator (no OO style)
2963   my $lcm = Math::BigInt::blcm(@values);
2964
2965   $x->length();            # return number of digits in number
2966   ($xl,$f) = $x->length(); # length of number and length of fraction part,
2967                            # latter is always 0 digits long for BigInts
2968
2969   $x->exponent();          # return exponent as BigInt
2970   $x->mantissa();          # return (signed) mantissa as BigInt
2971   $x->parts();             # return (mantissa,exponent) as BigInt
2972   $x->copy();              # make a true copy of $x (unlike $y = $x;)
2973   $x->as_int();            # return as BigInt (in BigInt: same as copy())
2974   $x->numify();            # return as scalar (might overflow!)
2975
2976   # conversation to string (do not modify their argument)
2977   $x->bstr();              # normalized string (e.g. '3')
2978   $x->bsstr();             # norm. string in scientific notation (e.g. '3E0')
2979   $x->as_hex();            # as signed hexadecimal string with prefixed 0x
2980   $x->as_bin();            # as signed binary string with prefixed 0b
2981   $x->as_oct();            # as signed octal string with prefixed 0
2982
2983
2984   # precision and accuracy (see section about rounding for more)
2985   $x->precision();         # return P of $x (or global, if P of $x undef)
2986   $x->precision($n);       # set P of $x to $n
2987   $x->accuracy();          # return A of $x (or global, if A of $x undef)
2988   $x->accuracy($n);        # set A $x to $n
2989
2990   # Global methods
2991   Math::BigInt->precision();    # get/set global P for all BigInt objects
2992   Math::BigInt->accuracy();     # get/set global A for all BigInt objects
2993   Math::BigInt->round_mode();   # get/set global round mode, one of
2994                                 # 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'
2995   Math::BigInt->config();       # return hash containing configuration
2996
2997 =head1 DESCRIPTION
2998
2999 All operators (including basic math operations) are overloaded if you
3000 declare your big integers as
3001
3002   $i = new Math::BigInt '123_456_789_123_456_789';
3003
3004 Operations with overloaded operators preserve the arguments which is
3005 exactly what you expect.
3006
3007 =over 2
3008
3009 =item Input
3010
3011 Input values to these routines may be any string, that looks like a number
3012 and results in an integer, including hexadecimal and binary numbers.
3013
3014 Scalars holding numbers may also be passed, but note that non-integer numbers
3015 may already have lost precision due to the conversation to float. Quote
3016 your input if you want BigInt to see all the digits:
3017
3018         $x = Math::BigInt->new(12345678890123456789);   # bad
3019         $x = Math::BigInt->new('12345678901234567890'); # good
3020
3021 You can include one underscore between any two digits.
3022
3023 This means integer values like 1.01E2 or even 1000E-2 are also accepted.
3024 Non-integer values result in NaN.
3025
3026 Hexadecimal (prefixed with "0x") and binary numbers (prefixed with "0b")
3027 are accepted, too. Please note that octal numbers are not recognized
3028 by new(), so the following will print "123":
3029
3030         perl -MMath::BigInt -le 'print Math::BigInt->new("0123")'
3031
3032 To convert an octal number, use from_oct();
3033
3034         perl -MMath::BigInt -le 'print Math::BigInt->from_oct("0123")'
3035
3036 Currently, Math::BigInt::new() defaults to 0, while Math::BigInt::new('')
3037 results in 'NaN'. This might change in the future, so use always the following
3038 explicit forms to get a zero or NaN:
3039
3040         $zero = Math::BigInt->bzero();
3041         $nan = Math::BigInt->bnan();
3042
3043 C<bnorm()> on a BigInt object is now effectively a no-op, since the numbers
3044 are always stored in normalized form. If passed a string, creates a BigInt
3045 object from the input.
3046
3047 =item Output
3048
3049 Output values are BigInt objects (normalized), except for the methods which
3050 return a string (see L<SYNOPSIS>).
3051
3052 Some routines (C<is_odd()>, C<is_even()>, C<is_zero()>, C<is_one()>,
3053 C<is_nan()>, etc.) return true or false, while others (C<bcmp()>, C<bacmp()>)
3054 return either undef (if NaN is involved), <0, 0 or >0 and are suited for sort.
3055
3056 =back
3057
3058 =head1 METHODS
3059
3060 Each of the methods below (except config(), accuracy() and precision())
3061 accepts three additional parameters. These arguments C<$A>, C<$P> and C<$R>
3062 are C<accuracy>, C<precision> and C<round_mode>. Please see the section about
3063 L<ACCURACY and PRECISION> for more information.
3064
3065 =head2 config()
3066
3067         use Data::Dumper;
3068
3069         print Dumper ( Math::BigInt->config() );
3070         print Math::BigInt->config()->{lib},"\n";
3071
3072 Returns a hash containing the configuration, e.g. the version number, lib
3073 loaded etc. The following hash keys are currently filled in with the
3074 appropriate information.
3075
3076         key             Description
3077                         Example
3078         ============================================================
3079         lib             Name of the low-level math library
3080                         Math::BigInt::Calc
3081         lib_version     Version of low-level math library (see 'lib')
3082                         0.30
3083         class           The class name of config() you just called
3084                         Math::BigInt
3085         upgrade         To which class math operations might be upgraded
3086                         Math::BigFloat
3087         downgrade       To which class math operations might be downgraded
3088                         undef
3089         precision       Global precision
3090                         undef
3091         accuracy        Global accuracy
3092                         undef
3093         round_mode      Global round mode
3094                         even
3095         version         version number of the class you used
3096                         1.61
3097         div_scale       Fallback accuracy for div
3098                         40
3099         trap_nan        If true, traps creation of NaN via croak()
3100                         1
3101         trap_inf        If true, traps creation of +inf/-inf via croak()
3102                         1
3103
3104 The following values can be set by passing C<config()> a reference to a hash:
3105
3106         trap_inf trap_nan
3107         upgrade downgrade precision accuracy round_mode div_scale
3108
3109 Example:
3110
3111         $new_cfg = Math::BigInt->config( { trap_inf => 1, precision => 5 } );
3112
3113 =head2 accuracy()
3114
3115         $x->accuracy(5);                # local for $x
3116         CLASS->accuracy(5);             # global for all members of CLASS
3117                                         # Note: This also applies to new()!
3118
3119         $A = $x->accuracy();            # read out accuracy that affects $x
3120         $A = CLASS->accuracy();         # read out global accuracy
3121
3122 Set or get the global or local accuracy, aka how many significant digits the
3123 results have. If you set a global accuracy, then this also applies to new()!
3124
3125 Warning! The accuracy I<sticks>, e.g. once you created a number under the
3126 influence of C<< CLASS->accuracy($A) >>, all results from math operations with
3127 that number will also be rounded.
3128
3129 In most cases, you should probably round the results explicitly using one of
3130 L<round()>, L<bround()> or L<bfround()> or by passing the desired accuracy
3131 to the math operation as additional parameter:
3132
3133         my $x = Math::BigInt->new(30000);
3134         my $y = Math::BigInt->new(7);
3135         print scalar $x->copy()->bdiv($y, 2);           # print 4300
3136         print scalar $x->copy()->bdiv($y)->bround(2);   # print 4300
3137
3138 Please see the section about L<ACCURACY AND PRECISION> for further details.
3139
3140 Value must be greater than zero. Pass an undef value to disable it:
3141
3142         $x->accuracy(undef);
3143         Math::BigInt->accuracy(undef);
3144
3145 Returns the current accuracy. For C<$x->accuracy()> it will return either the
3146 local accuracy, or if not defined, the global. This means the return value
3147 represents the accuracy that will be in effect for $x:
3148
3149         $y = Math::BigInt->new(1234567);        # unrounded
3150         print Math::BigInt->accuracy(4),"\n";   # set 4, print 4
3151         $x = Math::BigInt->new(123456);         # $x will be automatically rounded!
3152         print "$x $y\n";                        # '123500 1234567'
3153         print $x->accuracy(),"\n";              # will be 4
3154         print $y->accuracy(),"\n";              # also 4, since global is 4
3155         print Math::BigInt->accuracy(5),"\n";   # set to 5, print 5
3156         print $x->accuracy(),"\n";              # still 4
3157         print $y->accuracy(),"\n";              # 5, since global is 5
3158
3159 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
3160 globals separated from Math::BigInt, but it is possible to subclass
3161 Math::BigInt and make the globals of the subclass aliases to the ones from
3162 Math::BigInt.
3163
3164 =head2 precision()
3165
3166         $x->precision(-2);      # local for $x, round at the second digit right of the dot
3167         $x->precision(2);       # ditto, round at the second digit left of the dot
3168
3169         CLASS->precision(5);    # Global for all members of CLASS
3170                                 # This also applies to new()!
3171         CLASS->precision(-5);   # ditto
3172
3173         $P = CLASS->precision();        # read out global precision
3174         $P = $x->precision();           # read out precision that affects $x
3175
3176 Note: You probably want to use L<accuracy()> instead. With L<accuracy> you
3177 set the number of digits each result should have, with L<precision> you
3178 set the place where to round!
3179
3180 C<precision()> sets or gets the global or local precision, aka at which digit
3181 before or after the dot to round all results. A set global precision also
3182 applies to all newly created numbers!
3183
3184 In Math::BigInt, passing a negative number precision has no effect since no
3185 numbers have digits after the dot. In L<Math::BigFloat>, it will round all
3186 results to P digits after the dot.
3187
3188 Please see the section about L<ACCURACY AND PRECISION> for further details.
3189
3190 Pass an undef value to disable it:
3191
3192         $x->precision(undef);
3193         Math::BigInt->precision(undef);
3194
3195 Returns the current precision. For C<$x->precision()> it will return either the
3196 local precision of $x, or if not defined, the global. This means the return
3197 value represents the prevision that will be in effect for $x:
3198
3199         $y = Math::BigInt->new(1234567);        # unrounded
3200         print Math::BigInt->precision(4),"\n";  # set 4, print 4
3201         $x = Math::BigInt->new(123456);         # will be automatically rounded
3202         print $x;                               # print "120000"!
3203
3204 Note: Works also for subclasses like L<Math::BigFloat>. Each class has its
3205 own globals separated from Math::BigInt, but it is possible to subclass
3206 Math::BigInt and make the globals of the subclass aliases to the ones from
3207 Math::BigInt.
3208
3209 =head2 brsft()
3210
3211         $x->brsft($y,$n);
3212
3213 Shifts $x right by $y in base $n. Default is base 2, used are usually 10 and
3214 2, but others work, too.
3215
3216 Right shifting usually amounts to dividing $x by $n ** $y and truncating the
3217 result:
3218
3219
3220         $x = Math::BigInt->new(10);
3221         $x->brsft(1);                   # same as $x >> 1: 5
3222         $x = Math::BigInt->new(1234);
3223         $x->brsft(2,10);                # result 12
3224
3225 There is one exception, and that is base 2 with negative $x:
3226
3227
3228         $x = Math::BigInt->new(-5);
3229         print $x->brsft(1);
3230
3231 This will print -3, not -2 (as it would if you divide -5 by 2 and truncate the
3232 result).
3233
3234 =head2 new()
3235
3236         $x = Math::BigInt->new($str,$A,$P,$R);
3237
3238 Creates a new BigInt object from a scalar or another BigInt object. The
3239 input is accepted as decimal, hex (with leading '0x') or binary (with leading
3240 '0b').
3241
3242 See L<Input> for more info on accepted input formats.
3243
3244 =head2 from_oct()
3245
3246         $x = Math::BigIn->from_oct("0775");     # input is octal
3247
3248 =head2 from_hex()
3249
3250         $x = Math::BigIn->from_hex("0xcafe");   # input is hexadecimal
3251
3252 =head2 from_bin()
3253
3254         $x = Math::BigIn->from_oct("0x10011");  # input is binary
3255
3256 =head2 bnan()
3257
3258         $x = Math::BigInt->bnan();
3259
3260 Creates a new BigInt object representing NaN (Not A Number).
3261 If used on an object, it will set it to NaN:
3262
3263         $x->bnan();
3264
3265 =head2 bzero()
3266
3267         $x = Math::BigInt->bzero();
3268
3269 Creates a new BigInt object representing zero.
3270 If used on an object, it will set it to zero:
3271
3272         $x->bzero();
3273
3274 =head2 binf()
3275
3276         $x = Math::BigInt->binf($sign);
3277
3278 Creates a new BigInt object representing infinity. The optional argument is
3279 either '-' or '+', indicating whether you want infinity or minus infinity.
3280 If used on an object, it will set it to infinity:
3281
3282         $x->binf();
3283         $x->binf('-');
3284
3285 =head2 bone()
3286
3287         $x = Math::BigInt->binf($sign);
3288
3289 Creates a new BigInt object representing one. The optional argument is
3290 either '-' or '+', indicating whether you want one or minus one.
3291 If used on an object, it will set it to one:
3292
3293         $x->bone();             # +1
3294         $x->bone('-');          # -1
3295
3296 =head2 is_one()/is_zero()/is_nan()/is_inf()
3297
3298
3299         $x->is_zero();                  # true if arg is +0
3300         $x->is_nan();                   # true if arg is NaN
3301         $x->is_one();                   # true if arg is +1
3302         $x->is_one('-');                # true if arg is -1
3303         $x->is_inf();                   # true if +inf
3304         $x->is_inf('-');                # true if -inf (sign is default '+')
3305
3306 These methods all test the BigInt for being one specific value and return
3307 true or false depending on the input. These are faster than doing something
3308 like:
3309
3310         if ($x == 0)
3311
3312 =head2 is_pos()/is_neg()/is_positive()/is_negative()
3313
3314         $x->is_pos();                   # true if > 0
3315         $x->is_neg();                   # true if < 0
3316
3317 The methods return true if the argument is positive or negative, respectively.
3318 C<NaN> is neither positive nor negative, while C<+inf> counts as positive, and
3319 C<-inf> is negative. A C<zero> is neither positive nor negative.
3320
3321 These methods are only testing the sign, and not the value.
3322
3323 C<is_positive()> and C<is_negative()> are aliases to C<is_pos()> and
3324 C<is_neg()>, respectively. C<is_positive()> and C<is_negative()> were
3325 introduced in v1.36, while C<is_pos()> and C<is_neg()> were only introduced
3326 in v1.68.
3327
3328 =head2 is_odd()/is_even()/is_int()
3329
3330         $x->is_odd();                   # true if odd, false for even
3331         $x->is_even();                  # true if even, false for odd
3332         $x->is_int();                   # true if $x is an integer
3333
3334 The return true when the argument satisfies the condition. C<NaN>, C<+inf>,
3335 C<-inf> are not integers and are neither odd nor even.
3336
3337 In BigInt, all numbers except C<NaN>, C<+inf> and C<-inf> are integers.
3338
3339 =head2 bcmp()
3340
3341         $x->bcmp($y);
3342
3343 Compares $x with $y and takes the sign into account.
3344 Returns -1, 0, 1 or undef.
3345
3346 =head2 bacmp()
3347
3348         $x->bacmp($y);
3349
3350 Compares $x with $y while ignoring their. Returns -1, 0, 1 or undef.
3351
3352 =head2 sign()
3353
3354         $x->sign();
3355
3356 Return the sign, of $x, meaning either C<+>, C<->, C<-inf>, C<+inf> or NaN.
3357
3358 If you want $x to have a certain sign, use one of the following methods:
3359
3360         $x->babs();             # '+'
3361         $x->babs()->bneg();     # '-'
3362         $x->bnan();             # 'NaN'
3363         $x->binf();             # '+inf'
3364         $x->binf('-');          # '-inf'
3365
3366 =head2 digit()
3367
3368         $x->digit($n);          # return the nth digit, counting from right
3369
3370 If C<$n> is negative, returns the digit counting from left.
3371
3372 =head2 bneg()
3373
3374         $x->bneg();
3375
3376 Negate the number, e.g. change the sign between '+' and '-', or between '+inf'
3377 and '-inf', respectively. Does nothing for NaN or zero.
3378
3379 =head2 babs()
3380
3381         $x->babs();
3382
3383 Set the number to it's absolute value, e.g. change the sign from '-' to '+'
3384 and from '-inf' to '+inf', respectively. Does nothing for NaN or positive
3385 numbers.
3386
3387 =head2 bnorm()
3388
3389         $x->bnorm();                    # normalize (no-op)
3390
3391 =head2 bnot()
3392
3393         $x->bnot();
3394
3395 Two's complement (bit wise not). This is equivalent to
3396
3397         $x->binc()->bneg();
3398
3399 but faster.
3400
3401 =head2 binc()
3402
3403         $x->binc();                     # increment x by 1
3404
3405 =head2 bdec()
3406
3407         $x->bdec();                     # decrement x by 1
3408
3409 =head2 badd()
3410
3411         $x->badd($y);                   # addition (add $y to $x)
3412
3413 =head2 bsub()
3414
3415         $x->bsub($y);                   # subtraction (subtract $y from $x)
3416
3417 =head2 bmul()
3418
3419         $x->bmul($y);                   # multiplication (multiply $x by $y)
3420
3421 =head2 bdiv()
3422
3423         $x->bdiv($y);                   # divide, set $x to quotient
3424                                         # return (quo,rem) or quo if scalar
3425
3426 =head2 bmod()
3427
3428         $x->bmod($y);                   # modulus (x % y)
3429
3430 =head2 bmodinv()
3431
3432         num->bmodinv($mod);             # modular inverse
3433
3434 Returns the inverse of C<$num> in the given modulus C<$mod>.  'C<NaN>' is
3435 returned unless C<$num> is relatively prime to C<$mod>, i.e. unless
3436 C<bgcd($num, $mod)==1>.
3437
3438 =head2 bmodpow()
3439
3440         $num->bmodpow($exp,$mod);       # modular exponentation
3441                                         # ($num**$exp % $mod)
3442
3443 Returns the value of C<$num> taken to the power C<$exp> in the modulus
3444 C<$mod> using binary exponentation.  C<bmodpow> is far superior to
3445 writing
3446
3447         $num ** $exp % $mod
3448
3449 because it is much faster - it reduces internal variables into
3450 the modulus whenever possible, so it operates on smaller numbers.
3451
3452 C<bmodpow> also supports negative exponents.
3453
3454         bmodpow($num, -1, $mod)
3455
3456 is exactly equivalent to
3457
3458         bmodinv($num, $mod)
3459
3460 =head2 bpow()
3461
3462         $x->bpow($y);                   # power of arguments (x ** y)
3463
3464 =head2 blog()
3465
3466         $x->blog($base, $accuracy);     # logarithm of x to the base $base
3467
3468 If C<$base> is not defined, Euler's number (e) is used:
3469
3470         print $x->blog(undef, 100);     # log(x) to 100 digits
3471
3472 =head2 bexp()
3473
3474         $x->bexp($accuracy);            # calculate e ** X
3475
3476 Calculates the expression C<e ** $x> where C<e> is Euler's number.
3477
3478 This method was added in v1.82 of Math::BigInt (April 2007).
3479
3480 See also L<blog()>.
3481
3482 =head2 bnok()
3483
3484         $x->bnok($y);              # x over y (binomial coefficient n over k)
3485
3486 Calculates the binomial coefficient n over k, also called the "choose"
3487 function. The result is equivalent to:
3488
3489         ( n )      n!
3490         | - |  = -------
3491         ( k )    k!(n-k)!
3492
3493 This method was added in v1.84 of Math::BigInt (April 2007).
3494
3495 =head2 blsft()
3496
3497         $x->blsft($y);          # left shift in base 2
3498         $x->blsft($y,$n);       # left shift, in base $n (like 10)
3499
3500 =head2 brsft()
3501
3502         $x->brsft($y);          # right shift in base 2
3503         $x->brsft($y,$n);       # right shift, in base $n (like 10)
3504
3505 =head2 band()
3506
3507         $x->band($y);                   # bitwise and
3508
3509 =head2 bior()
3510
3511         $x->bior($y);                   # bitwise inclusive or
3512
3513 =head2 bxor()
3514
3515         $x->bxor($y);                   # bitwise exclusive or
3516
3517 =head2 bnot()
3518
3519         $x->bnot();                     # bitwise not (two's complement)
3520
3521 =head2 bsqrt()
3522
3523         $x->bsqrt();                    # calculate square-root
3524
3525 =head2 bfac()
3526
3527         $x->bfac();                     # factorial of $x (1*2*3*4*..$x)
3528
3529 =head2 round()
3530
3531         $x->round($A,$P,$round_mode);
3532
3533 Round $x to accuracy C<$A> or precision C<$P> using the round mode
3534 C<$round_mode>.
3535
3536 =head2 bround()
3537
3538         $x->bround($N);               # accuracy: preserve $N digits
3539
3540 =head2 bfround()
3541
3542         $x->bfround($N);              # round to $Nth digit, no-op for BigInts
3543
3544 =head2 bfloor()
3545
3546         $x->bfloor();
3547
3548 Set $x to the integer less or equal than $x. This is a no-op in BigInt, but
3549 does change $x in BigFloat.
3550
3551 =head2 bceil()
3552
3553         $x->bceil();
3554
3555 Set $x to the integer greater or equal than $x. This is a no-op in BigInt, but
3556 does change $x in BigFloat.
3557
3558 =head2 bgcd()
3559
3560         bgcd(@values);          # greatest common divisor (no OO style)
3561
3562 =head2 blcm()
3563
3564         blcm(@values);          # lowest common multiplicator (no OO style)
3565
3566 head2 length()
3567
3568         $x->length();
3569         ($xl,$fl) = $x->length();
3570
3571 Returns the number of digits in the decimal representation of the number.
3572 In list context, returns the length of the integer and fraction part. For
3573 BigInt's, the length of the fraction part will always be 0.
3574
3575 =head2 exponent()
3576
3577         $x->exponent();
3578
3579 Return the exponent of $x as BigInt.
3580
3581 =head2 mantissa()
3582
3583         $x->mantissa();
3584
3585 Return the signed mantissa of $x as BigInt.
3586
3587 =head2 parts()
3588
3589         $x->parts();            # return (mantissa,exponent) as BigInt
3590
3591 =head2 copy()
3592
3593         $x->copy();             # make a true copy of $x (unlike $y = $x;)
3594
3595 =head2 as_int()/as_number()
3596
3597         $x->as_int();
3598
3599 Returns $x as a BigInt (truncated towards zero). In BigInt this is the same as
3600 C<copy()>.
3601
3602 C<as_number()> is an alias to this method. C<as_number> was introduced in
3603 v1.22, while C<as_int()> was only introduced in v1.68.
3604
3605 =head2 bstr()
3606
3607         $x->bstr();
3608
3609 Returns a normalized string representation of C<$x>.
3610
3611 =head2 bsstr()
3612
3613         $x->bsstr();            # normalized string in scientific notation
3614
3615 =head2 as_hex()
3616
3617         $x->as_hex();           # as signed hexadecimal string with prefixed 0x
3618
3619 =head2 as_bin()
3620
3621         $x->as_bin();           # as signed binary string with prefixed 0b
3622
3623 =head2 as_oct()
3624
3625         $x->as_oct();           # as signed octal string with prefixed 0
3626
3627 =head2 numify()
3628
3629         print $x->numify();
3630
3631 This returns a normal Perl scalar from $x. It is used automatically
3632 whenever a scalar is needed, for instance in array index operations.
3633
3634 This loses precision, to avoid this use L<as_int()> instead.
3635
3636 =head2 modify()
3637
3638         $x->modify('bpowd');
3639
3640 This method returns 0 if the object can be modified with the given
3641 peration, or 1 if not.
3642
3643 This is used for instance by L<Math::BigInt::Constant>.
3644
3645 =head2 upgrade()/downgrade()
3646
3647 Set/get the class for downgrade/upgrade operations. Thuis is used
3648 for instance by L<bignum>. The defaults are '', thus the following
3649 operation will create a BigInt, not a BigFloat:
3650
3651         my $i = Math::BigInt->new(123);
3652         my $f = Math::BigFloat->new('123.1');
3653
3654         print $i + $f,"\n";                     # print 246
3655
3656 =head2 div_scale()
3657
3658 Set/get the number of digits for the default precision in divide
3659 operations.
3660
3661 =head2 round_mode()
3662
3663 Set/get the current round mode.
3664
3665 =head1 ACCURACY and PRECISION
3666
3667 Since version v1.33, Math::BigInt and Math::BigFloat have full support for
3668 accuracy and precision based rounding, both automatically after every
3669 operation, as well as manually.
3670
3671 This section describes the accuracy/precision handling in Math::Big* as it
3672 used to be and as it is now, complete with an explanation of all terms and
3673 abbreviations.
3674
3675 Not yet implemented things (but with correct description) are marked with '!',
3676 things that need to be answered are marked with '?'.
3677
3678 In the next paragraph follows a short description of terms used here (because
3679 these may differ from terms used by others people or documentation).
3680
3681 During the rest of this document, the shortcuts A (for accuracy), P (for
3682 precision), F (fallback) and R (rounding mode) will be used.
3683
3684 =head2 Precision P
3685
3686 A fixed number of digits before (positive) or after (negative)
3687 the decimal point. For example, 123.45 has a precision of -2. 0 means an
3688 integer like 123 (or 120). A precision of 2 means two digits to the left
3689 of the decimal point are zero, so 123 with P = 1 becomes 120. Note that
3690 numbers with zeros before the decimal point may have different precisions,
3691 because 1200 can have p = 0, 1 or 2 (depending on what the inital value
3692 was). It could also have p < 0, when the digits after the decimal point
3693 are zero.
3694
3695 The string output (of floating point numbers) will be padded with zeros:
3696
3697         Initial value   P       A       Result          String
3698         ------------------------------------------------------------
3699         1234.01         -3              1000            1000
3700         1234            -2              1200            1200
3701         1234.5          -1              1230            1230
3702         1234.001        1               1234            1234.0
3703         1234.01         0               1234            1234
3704         1234.01         2               1234.01         1234.01
3705         1234.01         5               1234.01         1234.01000
3706
3707 For BigInts, no padding occurs.
3708
3709 =head2 Accuracy A
3710
3711 Number of significant digits. Leading zeros are not counted. A
3712 number may have an accuracy greater than the non-zero digits
3713 when there are zeros in it or trailing zeros. For example, 123.456 has
3714 A of 6, 10203 has 5, 123.0506 has 7, 123.450000 has 8 and 0.000123 has 3.
3715
3716 The string output (of floating point numbers) will be padded with zeros:
3717
3718         Initial value   P       A       Result          String
3719         ------------------------------------------------------------
3720         1234.01                 3       1230            1230
3721         1234.01                 6       1234.01         1234.01
3722         1234.1                  8       1234.1          1234.1000
3723
3724 For BigInts, no padding occurs.
3725
3726 =head2 Fallback F
3727
3728 When both A and P are undefined, this is used as a fallback accuracy when
3729 dividing numbers.
3730
3731 =head2 Rounding mode R
3732
3733 When rounding a number, different 'styles' or 'kinds'
3734 of rounding are possible. (Note that random rounding, as in
3735 Math::Round, is not implemented.)
3736
3737 =over 2
3738
3739 =item 'trunc'
3740
3741 truncation invariably removes all digits following the
3742 rounding place, replacing them with zeros. Thus, 987.65 rounded
3743 to tens (P=1) becomes 980, and rounded to the fourth sigdig
3744 becomes 987.6 (A=4). 123.456 rounded to the second place after the
3745 decimal point (P=-2) becomes 123.46.
3746
3747 All other implemented styles of rounding attempt to round to the
3748 "nearest digit." If the digit D immediately to the right of the
3749 rounding place (skipping the decimal point) is greater than 5, the
3750 number is incremented at the rounding place (possibly causing a
3751 cascade of incrementation): e.g. when rounding to units, 0.9 rounds
3752 to 1, and -19.9 rounds to -20. If D < 5, the number is similarly
3753 truncated at the rounding place: e.g. when rounding to units, 0.4
3754 rounds to 0, and -19.4 rounds to -19.
3755
3756 However the results of other styles of rounding differ if the
3757 digit immediately to the right of the rounding place (skipping the
3758 decimal point) is 5 and if there are no digits, or no digits other
3759 than 0, after that 5. In such cases:
3760
3761 =item 'even'
3762
3763 rounds the digit at the rounding place to 0, 2, 4, 6, or 8
3764 if it is not already. E.g., when rounding to the first sigdig, 0.45
3765 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.
3766
3767 =item 'odd'
3768
3769 rounds the digit at the rounding place to 1, 3, 5, 7, or 9 if
3770 it is not already. E.g., when rounding to the first sigdig, 0.45
3771 becomes 0.5, -0.55 becomes -0.5, but 0.5501 becomes 0.6.
3772
3773 =item '+inf'
3774
3775 round to plus infinity, i.e. always round up. E.g., when
3776 rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5,
3777 and 0.4501 also becomes 0.5.
3778
3779 =item '-inf'
3780
3781 round to minus infinity, i.e. always round down. E.g., when
3782 rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6,
3783 but 0.4501 becomes 0.5.
3784
3785 =item 'zero'
3786
3787 round to zero, i.e. positive numbers down, negative ones up.
3788 E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55
3789 becomes -0.5, but 0.4501 becomes 0.5.
3790
3791 =item 'common'
3792
3793 round up if the digit immediately to the right of the rounding place
3794 is 5 or greater, otherwise round down. E.g., 0.15 becomes 0.2 and
3795 0.149 becomes 0.1.
3796
3797 =back
3798
3799 The handling of A & P in MBI/MBF (the old core code shipped with Perl
3800 versions <= 5.7.2) is like this:
3801
3802 =over 2
3803
3804 =item Precision
3805
3806   * ffround($p) is able to round to $p number of digits after the decimal
3807     point
3808   * otherwise P is unused
3809
3810 =item Accuracy (significant digits)
3811
3812   * fround($a) rounds to $a significant digits
3813   * only fdiv() and fsqrt() take A as (optional) paramater
3814     + other operations simply create the same number (fneg etc), or more (fmul)
3815       of digits
3816     + rounding/truncating is only done when explicitly calling one of fround
3817       or ffround, and never for BigInt (not implemented)
3818   * fsqrt() simply hands its accuracy argument over to fdiv.
3819   * the documentation and the comment in the code indicate two different ways
3820     on how fdiv() determines the maximum number of digits it should calculate,
3821     and the actual code does yet another thing
3822     POD:
3823       max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
3824     Comment:
3825       result has at most max(scale, length(dividend), length(divisor)) digits
3826     Actual code:
3827       scale = max(scale, length(dividend)-1,length(divisor)-1);
3828       scale += length(divisor) - length(dividend);
3829     So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10+9-3).
3830     Actually, the 'difference' added to the scale is calculated from the
3831     number of "significant digits" in dividend and divisor, which is derived
3832     by looking at the length of the mantissa. Which is wrong, since it includes
3833     the + sign (oops) and actually gets 2 for '+100' and 4 for '+101'. Oops
3834     again. Thus 124/3 with div_scale=1 will get you '41.3' based on the strange
3835     assumption that 124 has 3 significant digits, while 120/7 will get you
3836     '17', not '17.1' since 120 is thought to have 2 significant digits.
3837     The rounding after the division then uses the remainder and $y to determine
3838     wether it must round up or down.
3839  ?  I have no idea which is the right way. That's why I used a slightly more
3840  ?  simple scheme and tweaked the few failing testcases to match it.
3841
3842 =back
3843
3844 This is how it works now:
3845
3846 =over 2
3847
3848 =item Setting/Accessing
3849
3850   * You can set the A global via C<< Math::BigInt->accuracy() >> or
3851     C<< Math::BigFloat->accuracy() >> or whatever class you are using.
3852   * You can also set P globally by using C<< Math::SomeClass->precision() >>
3853     likewise.
3854   * Globals are classwide, and not inherited by subclasses.
3855   * to undefine A, use C<< Math::SomeCLass->accuracy(undef); >>
3856   * to undefine P, use C<< Math::SomeClass->precision(undef); >>
3857   * Setting C<< Math::SomeClass->accuracy() >> clears automatically
3858     C<< Math::SomeClass->precision() >>, and vice versa.
3859   * To be valid, A must be > 0, P can have any value.
3860   * If P is negative, this means round to the P'th place to the right of the
3861     decimal point; positive values mean to the left of the decimal point.
3862     P of 0 means round to integer.
3863   * to find out the current global A, use C<< Math::SomeClass->accuracy() >>
3864   * to find out the current global P, use C<< Math::SomeClass->precision() >>
3865   * use C<< $x->accuracy() >> respective C<< $x->precision() >> for the local
3866     setting of C<< $x >>.
3867   * Please note that C<< $x->accuracy() >> respective C<< $x->precision() >>
3868     return eventually defined global A or P, when C<< $x >>'s A or P is not
3869     set.
3870
3871 =item Creating numbers
3872
3873   * When you create a number, you can give it's desired A or P via:
3874     $x = Math::BigInt->new($number,$A,$P);
3875   * Only one of A or P can be defined, otherwise the result is NaN
3876   * If no A or P is give ($x = Math::BigInt->new($number) form), then the
3877     globals (if set) will be used. Thus changing the global defaults later on
3878     will not change the A or P of previously created numbers (i.e., A and P of
3879     $x will be what was in effect when $x was created)
3880   * If given undef for A and P, B<no> rounding will occur, and the globals will
3881     B<not> be used. This is used by subclasses to create numbers without
3882     suffering rounding in the parent. Thus a subclass is able to have it's own
3883     globals enforced upon creation of a number by using
3884     C<< $x = Math::BigInt->new($number,undef,undef) >>:
3885
3886         use Math::BigInt::SomeSubclass;
3887         use Math::BigInt;
3888
3889         Math::BigInt->accuracy(2);
3890         Math::BigInt::SomeSubClass->accuracy(3);
3891         $x = Math::BigInt::SomeSubClass->new(1234);
3892
3893     $x is now 1230, and not 1200. A subclass might choose to implement
3894     this otherwise, e.g. falling back to the parent's A and P.
3895
3896 =item Usage
3897
3898   * If A or P are enabled/defined, they are used to round the result of each
3899     operation according to the rules below
3900   * Negative P is ignored in Math::BigInt, since BigInts never have digits
3901     after the decimal point
3902   * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
3903     Math::BigInt as globals does not tamper with the parts of a BigFloat.
3904     A flag is used to mark all Math::BigFloat numbers as 'never round'.
3905
3906 =item Precedence
3907
3908   * It only makes sense that a number has only one of A or P at a time.
3909     If you set either A or P on one object, or globally, the other one will
3910     be automatically cleared.
3911   * If two objects are involved in an operation, and one of them has A in
3912     effect, and the other P, this results in an error (NaN).
3913   * A takes precedence over P (Hint: A comes before P).
3914     If neither of them is defined, nothing is used, i.e. the result will have
3915     as many digits as it can (with an exception for fdiv/fsqrt) and will not
3916     be rounded.
3917   * There is another setting for fdiv() (and thus for fsqrt()). If neither of
3918     A or P is defined, fdiv() will use a fallback (F) of $div_scale digits.
3919     If either the dividend's or the divisor's mantissa has more digits than
3920     the value of F, the higher value will be used instead of F.
3921     This is to limit the digits (A) of the result (just consider what would
3922     happen with unlimited A and P in the case of 1/3 :-)
3923   * fdiv will calculate (at least) 4 more digits than required (determined by
3924     A, P or F), and, if F is not used, round the result
3925     (this will still fail in the case of a result like 0.12345000000001 with A
3926     or P of 5, but this can not be helped - or can it?)
3927   * Thus you can have the math done by on Math::Big* class in two modi:
3928     + never round (this is the default):
3929       This is done by setting A and P to undef. No math operation
3930       will round the result, with fdiv() and fsqrt() as exceptions to guard
3931       against overflows. You must explicitly call bround(), bfround() or
3932       round() (the latter with parameters).
3933       Note: Once you have rounded a number, the settings will 'stick' on it
3934       and 'infect' all other numbers engaged in math operations with it, since
3935       local settings have the highest precedence. So, to get SaferRound[tm],
3936       use a copy() before rounding like this:
3937
3938         $x = Math::BigFloat->new(12.34);
3939         $y = Math::BigFloat->new(98.76);
3940         $z = $x * $y;                           # 1218.6984
3941         print $x->copy()->fround(3);            # 12.3 (but A is now 3!)
3942         $z = $x * $y;                           # still 1218.6984, without
3943                                                 # copy would have been 1210!
3944
3945     + round after each op:
3946       After each single operation (except for testing like is_zero()), the
3947       method round() is called and the result is rounded appropriately. By
3948       setting proper values for A and P, you can have all-the-same-A or
3949       all-the-same-P modes. For example, Math::Currency might set A to undef,
3950       and P to -2, globally.
3951
3952  ?Maybe an extra option that forbids local A & P settings would be in order,
3953  ?so that intermediate rounding does not 'poison' further math?
3954
3955 =item Overriding globals
3956
3957   * you will be able to give A, P and R as an argument to all the calculation
3958     routines; the second parameter is A, the third one is P, and the fourth is
3959     R (shift right by one for binary operations like badd). P is used only if
3960     the first parameter (A) is undefined. These three parameters override the
3961     globals in the order detailed as follows, i.e. the first defined value
3962     wins:
3963     (local: per object, global: global default, parameter: argument to sub)
3964       + parameter A
3965       + parameter P
3966       + local A (if defined on both of the operands: smaller one is taken)
3967       + local P (if defined on both of the operands: bigger one is taken)
3968       + global A
3969       + global P
3970       + global F
3971   * fsqrt() will hand its arguments to fdiv(), as it used to, only now for two
3972     arguments (A and P) instead of one
3973
3974 =item Local settings
3975
3976   * You can set A or P locally by using C<< $x->accuracy() >> or
3977     C<< $x->precision() >>
3978     and thus force different A and P for different objects/numbers.
3979   * Setting A or P this way immediately rounds $x to the new value.
3980   * C<< $x->accuracy() >> clears C<< $x->precision() >>, and vice versa.
3981
3982 =item Rounding
3983
3984   * the rounding routines will use the respective global or local settings.
3985     fround()/bround() is for accuracy rounding, while ffround()/bfround()
3986     is for precision
3987   * the two rounding functions take as the second parameter one of the
3988     following rounding modes (R):
3989     'even', 'odd', '+inf', '-inf', 'zero', 'trunc', 'common'
3990   * you can set/get the global R by using C<< Math::SomeClass->round_mode() >>
3991     or by setting C<< $Math::SomeClass::round_mode >>
3992   * after each operation, C<< $result->round() >> is called, and the result may
3993     eventually be rounded (that is, if A or P were set either locally,
3994     globally or as parameter to the operation)
3995   * to manually round a number, call C<< $x->round($A,$P,$round_mode); >>
3996     this will round the number by using the appropriate rounding function
3997     and then normalize it.
3998   * rounding modifies the local settings of the number:
3999
4000         $x = Math::BigFloat->new(123.456);
4001         $x->accuracy(5);
4002         $x->bround(4);
4003
4004     Here 4 takes precedence over 5, so 123.5 is the result and $x->accuracy()
4005     will be 4 from now on.
4006
4007 =item Default values
4008
4009   * R: 'even'
4010   * F: 40
4011   * A: undef
4012   * P: undef
4013
4014 =item Remarks
4015
4016   * The defaults are set up so that the new code gives the same results as
4017     the old code (except in a few cases on fdiv):
4018     + Both A and P are undefined and thus will not be used for rounding
4019       after each operation.
4020     + round() is thus a no-op, unless given extra parameters A and P
4021
4022 =back
4023
4024 =head1 Infinity and Not a Number
4025
4026 While BigInt has extensive handling of inf and NaN, certain quirks remain.
4027
4028 =over 2
4029
4030 =item oct()/hex()
4031
4032 These perl routines currently (as of Perl v.5.8.6) cannot handle passed
4033 inf.
4034
4035         te@linux:~> perl -wle 'print 2 ** 3333'
4036         inf
4037         te@linux:~> perl -wle 'print 2 ** 3333 == 2 ** 3333'
4038         1
4039         te@linux:~> perl -wle 'print oct(2 ** 3333)'
4040         0
4041         te@linux:~> perl -wle 'print hex(2 ** 3333)'
4042         Illegal hexadecimal digit 'i' ignored at -e line 1.
4043         0
4044
4045 The same problems occur if you pass them Math::BigInt->binf() objects. Since
4046 overloading these routines is not possible, this cannot be fixed from BigInt.
4047
4048 =item ==, !=, <, >, <=, >= with NaNs
4049
4050 BigInt's bcmp() routine currently returns undef to signal that a NaN was
4051 involved in a comparison. However, the overload code turns that into
4052 either 1 or '' and thus operations like C<< NaN != NaN >> might return
4053 wrong values.
4054
4055 =item log(-inf)
4056
4057 C<< log(-inf) >> is highly weird. Since log(-x)=pi*i+log(x), then
4058 log(-inf)=pi*i+inf. However, since the imaginary part is finite, the real
4059 infinity "overshadows" it, so the number might as well just be infinity.
4060 However, the result is a complex number, and since BigInt/BigFloat can only
4061 have real numbers as results, the result is NaN.
4062
4063 =item exp(), cos(), sin(), atan2()
4064
4065 These all might have problems handling infinity right.
4066
4067 =back
4068
4069 =head1 INTERNALS
4070
4071 The actual numbers are stored as unsigned big integers (with seperate sign).
4072
4073 You should neither care about nor depend on the internal representation; it
4074 might change without notice. Use B<ONLY> method calls like C<< $x->sign(); >>
4075 instead relying on the internal representation.
4076
4077 =head2 MATH LIBRARY
4078
4079 Math with the numbers is done (by default) by a module called
4080 C<Math::BigInt::Calc>. This is equivalent to saying:
4081
4082         use Math::BigInt lib => 'Calc';
4083
4084 You can change this by using:
4085
4086         use Math::BigInt lib => 'BitVect';
4087
4088 The following would first try to find Math::BigInt::Foo, then
4089 Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:
4090
4091         use Math::BigInt lib => 'Foo,Math::BigInt::Bar';
4092
4093 Since Math::BigInt::GMP is in almost all cases faster than Calc (especially in
4094 math involving really big numbers, where it is B<much> faster), and there is
4095 no penalty if Math::BigInt::GMP is not installed, it is a good idea to always
4096 use the following:
4097
4098         use Math::BigInt lib => 'GMP';
4099
4100 Different low-level libraries use different formats to store the
4101 numbers. You should B<NOT> depend on the number having a specific format
4102 internally.
4103
4104 See the respective math library module documentation for further details.
4105
4106 =head2 SIGN
4107
4108 The sign is either '+', '-', 'NaN', '+inf' or '-inf'.
4109
4110 A sign of 'NaN' is used to represent the result when input arguments are not
4111 numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively
4112 minus infinity. You will get '+inf' when dividing a positive number by 0, and
4113 '-inf' when dividing any negative number by 0.
4114
4115 =head2 mantissa(), exponent() and parts()
4116
4117 C<mantissa()> and C<exponent()> return the said parts of the BigInt such
4118 that:
4119
4120         $m = $x->mantissa();
4121         $e = $x->exponent();
4122         $y = $m * ( 10 ** $e );
4123         print "ok\n" if $x == $y;
4124
4125 C<< ($m,$e) = $x->parts() >> is just a shortcut that gives you both of them
4126 in one go. Both the returned mantissa and exponent have a sign.
4127
4128 Currently, for BigInts C<$e> is always 0, except +inf and -inf, where it is
4129 C<+inf>; and for NaN, where it is C<NaN>; and for C<$x == 0>, where it is C<1>
4130 (to be compatible with Math::BigFloat's internal representation of a zero as
4131 C<0E1>).
4132
4133 C<$m> is currently just a copy of the original number. The relation between
4134 C<$e> and C<$m> will stay always the same, though their real values might
4135 change.
4136
4137 =head1 EXAMPLES
4138
4139   use Math::BigInt;
4140
4141   sub bint { Math::BigInt->new(shift); }
4142
4143   $x = Math::BigInt->bstr("1234")       # string "1234"
4144   $x = "$x";                            # same as bstr()
4145   $x = Math::BigInt->bneg("1234");      # BigInt "-1234"
4146   $x = Math::BigInt->babs("-12345");    # BigInt "12345"
4147   $x = Math::BigInt->bnorm("-0.00");    # BigInt "0"
4148   $x = bint(1) + bint(2);               # BigInt "3"
4149   $x = bint(1) + "2";                   # ditto (auto-BigIntify of "2")
4150   $x = bint(1);                         # BigInt "1"
4151   $x = $x + 5 / 2;                      # BigInt "3"
4152   $x = $x ** 3;                         # BigInt "27"
4153   $x *= 2;                              # BigInt "54"
4154   $x = Math::BigInt->new(0);            # BigInt "0"
4155   $x--;                                 # BigInt "-1"
4156   $x = Math::BigInt->badd(4,5)          # BigInt "9"
4157   print $x->bsstr();                    # 9e+0
4158
4159 Examples for rounding:
4160
4161   use Math::BigFloat;
4162   use Test;
4163
4164   $x = Math::BigFloat->new(123.4567);
4165   $y = Math::BigFloat->new(123.456789);
4166   Math::BigFloat->accuracy(4);          # no more A than 4
4167
4168   ok ($x->copy()->fround(),123.4);      # even rounding
4169   print $x->copy()->fround(),"\n";      # 123.4
4170   Math::BigFloat->round_mode('odd');    # round to odd
4171   print $x->copy()->fround(),"\n";      # 123.5
4172   Math::BigFloat->accuracy(5);          # no more A than 5
4173   Math::BigFloat->round_mode('odd');    # round to odd
4174   print $x->copy()->fround(),"\n";      # 123.46
4175   $y = $x->copy()->fround(4),"\n";      # A = 4: 123.4
4176   print "$y, ",$y->accuracy(),"\n";     # 123.4, 4
4177
4178   Math::BigFloat->accuracy(undef);      # A not important now
4179   Math::BigFloat->precision(2);         # P important
4180   print $x->copy()->bnorm(),"\n";       # 123.46
4181   print $x->copy()->fround(),"\n";      # 123.46
4182
4183 Examples for converting:
4184
4185   my $x = Math::BigInt->new('0b1'.'01' x 123);
4186   print "bin: ",$x->as_bin()," hex:",$x->as_hex()," dec: ",$x,"\n";
4187
4188 =head1 Autocreating constants
4189
4190 After C<use Math::BigInt ':constant'> all the B<integer> decimal, hexadecimal
4191 and binary constants in the given scope are converted to C<Math::BigInt>.
4192 This conversion happens at compile time.
4193
4194 In particular,
4195
4196   perl -MMath::BigInt=:constant -e 'print 2**100,"\n"'
4197
4198 prints the integer value of C<2**100>. Note that without conversion of
4199 constants the expression 2**100 will be calculated as perl scalar.
4200
4201 Please note that strings and floating point constants are not affected,
4202 so that
4203
4204         use Math::BigInt qw/:constant/;
4205
4206         $x = 1234567890123456789012345678901234567890
4207                 + 123456789123456789;
4208         $y = '1234567890123456789012345678901234567890'
4209                 + '123456789123456789';
4210
4211 do not work. You need an explicit Math::BigInt->new() around one of the
4212 operands. You should also quote large constants to protect loss of precision:
4213
4214         use Math::BigInt;
4215
4216         $x = Math::BigInt->new('1234567889123456789123456789123456789');
4217
4218 Without the quotes Perl would convert the large number to a floating point
4219 constant at compile time and then hand the result to BigInt, which results in
4220 an truncated result or a NaN.
4221
4222 This also applies to integers that look like floating point constants:
4223
4224         use Math::BigInt ':constant';
4225
4226         print ref(123e2),"\n";
4227         print ref(123.2e2),"\n";
4228
4229 will print nothing but newlines. Use either L<bignum> or L<Math::BigFloat>
4230 to get this to work.
4231
4232 =head1 PERFORMANCE
4233
4234 Using the form $x += $y; etc over $x = $x + $y is faster, since a copy of $x
4235 must be made in the second case. For long numbers, the copy can eat up to 20%
4236 of the work (in the case of addition/subtraction, less for
4237 multiplication/division). If $y is very small compared to $x, the form
4238 $x += $y is MUCH faster than $x = $x + $y since making the copy of $x takes
4239 more time then the actual addition.
4240
4241 With a technique called copy-on-write, the cost of copying with overload could
4242 be minimized or even completely avoided. A test implementation of COW did show
4243 performance gains for overloaded math, but introduced a performance loss due
4244 to a constant overhead for all other operations. So Math::BigInt does currently
4245 not COW.
4246
4247 The rewritten version of this module (vs. v0.01) is slower on certain
4248 operations, like C<new()>, C<bstr()> and C<numify()>. The reason are that it
4249 does now more work and handles much more cases. The time spent in these
4250 operations is usually gained in the other math operations so that code on
4251 the average should get (much) faster. If they don't, please contact the author.
4252
4253 Some operations may be slower for small numbers, but are significantly faster
4254 for big numbers. Other operations are now constant (O(1), like C<bneg()>,
4255 C<babs()> etc), instead of O(N) and thus nearly always take much less time.
4256 These optimizations were done on purpose.
4257
4258 If you find the Calc module to slow, try to install any of the replacement
4259 modules and see if they help you.
4260
4261 =head2 Alternative math libraries
4262
4263 You can use an alternative library to drive Math::BigInt via:
4264
4265         use Math::BigInt lib => 'Module';
4266
4267 See L<MATH LIBRARY> for more information.
4268
4269 For more benchmark results see L<http://bloodgate.com/perl/benchmarks.html>.
4270
4271 =head2 SUBCLASSING
4272
4273 =head1 Subclassing Math::BigInt
4274
4275 The basic design of Math::BigInt allows simple subclasses with very little
4276 work, as long as a few simple rules are followed:
4277
4278 =over 2
4279
4280 =item *
4281
4282 The public API must remain consistent, i.e. if a sub-class is overloading
4283 addition, the sub-class must use the same name, in this case badd(). The
4284 reason for this is that Math::BigInt is optimized to call the object methods
4285 directly.
4286
4287 =item *
4288
4289 The private object hash keys like C<$x->{sign}> may not be changed, but
4290 additional keys can be added, like C<$x->{_custom}>.
4291
4292 =item *
4293
4294 Accessor functions are available for all existing object hash keys and should
4295 be used instead of directly accessing the internal hash keys. The reason for
4296 this is that Math::BigInt itself has a pluggable interface which permits it
4297 to support different storage methods.
4298
4299 =back
4300
4301 More complex sub-classes may have to replicate more of the logic internal of
4302 Math::BigInt if they need to change more basic behaviors. A subclass that
4303 needs to merely change the output only needs to overload C<bstr()>.
4304
4305 All other object methods and overloaded functions can be directly inherited
4306 from the parent class.
4307
4308 At the very minimum, any subclass will need to provide it's own C<new()> and can
4309 store additional hash keys in the object. There are also some package globals
4310 that must be defined, e.g.:
4311
4312   # Globals
4313   $accuracy = undef;
4314   $precision = -2;       # round to 2 decimal places
4315   $round_mode = 'even';
4316   $div_scale = 40;
4317
4318 Additionally, you might want to provide the following two globals to allow
4319 auto-upgrading and auto-downgrading to work correctly:
4320
4321   $upgrade = undef;
4322   $downgrade = undef;
4323
4324 This allows Math::BigInt to correctly retrieve package globals from the
4325 subclass, like C<$SubClass::precision>.  See t/Math/BigInt/Subclass.pm or
4326 t/Math/BigFloat/SubClass.pm completely functional subclass examples.
4327
4328 Don't forget to
4329
4330         use overload;
4331
4332 in your subclass to automatically inherit the overloading from the parent. If
4333 you like, you can change part of the overloading, look at Math::String for an
4334 example.
4335
4336 =head1 UPGRADING
4337
4338 When used like this:
4339
4340         use Math::BigInt upgrade => 'Foo::Bar';
4341
4342 certain operations will 'upgrade' their calculation and thus the result to
4343 the class Foo::Bar. Usually this is used in conjunction with Math::BigFloat:
4344
4345         use Math::BigInt upgrade => 'Math::BigFloat';
4346
4347 As a shortcut, you can use the module C<bignum>:
4348
4349         use bignum;
4350
4351 Also good for oneliners:
4352
4353         perl -Mbignum -le 'print 2 ** 255'
4354
4355 This makes it possible to mix arguments of different classes (as in 2.5 + 2)
4356 as well es preserve accuracy (as in sqrt(3)).
4357
4358 Beware: This feature is not fully implemented yet.
4359
4360 =head2 Auto-upgrade
4361
4362 The following methods upgrade themselves unconditionally; that is if upgrade
4363 is in effect, they will always hand up their work:
4364
4365 =over 2
4366
4367 =item bsqrt()
4368
4369 =item div()
4370
4371 =item blog()
4372
4373 =item bexp()
4374
4375 =back
4376
4377 Beware: This list is not complete.
4378
4379 All other methods upgrade themselves only when one (or all) of their
4380 arguments are of the class mentioned in $upgrade (This might change in later
4381 versions to a more sophisticated scheme):
4382
4383 =head1 BUGS
4384
4385 =over 2
4386
4387 =item broot() does not work
4388
4389 The broot() function in BigInt may only work for small values. This will be
4390 fixed in a later version.
4391
4392 =item Out of Memory!
4393
4394 Under Perl prior to 5.6.0 having an C<use Math::BigInt ':constant';> and
4395 C<eval()> in your code will crash with "Out of memory". This is probably an
4396 overload/exporter bug. You can workaround by not having C<eval()>
4397 and ':constant' at the same time or upgrade your Perl to a newer version.
4398
4399 =item Fails to load Calc on Perl prior 5.6.0
4400
4401 Since eval(' use ...') can not be used in conjunction with ':constant', BigInt
4402 will fall back to eval { require ... } when loading the math lib on Perls
4403 prior to 5.6.0. This simple replaces '::' with '/' and thus might fail on
4404 filesystems using a different seperator.
4405
4406 =back
4407
4408 =head1 CAVEATS
4409
4410 Some things might not work as you expect them. Below is documented what is
4411 known to be troublesome:
4412
4413 =over 1
4414
4415 =item bstr(), bsstr() and 'cmp'
4416
4417 Both C<bstr()> and C<bsstr()> as well as automated stringify via overload now
4418 drop the leading '+'. The old code would return '+3', the new returns '3'.
4419 This is to be consistent with Perl and to make C<cmp> (especially with
4420 overloading) to work as you expect. It also solves problems with C<Test.pm>,
4421 because it's C<ok()> uses 'eq' internally.
4422
4423 Mark Biggar said, when asked about to drop the '+' altogether, or make only
4424 C<cmp> work:
4425
4426         I agree (with the first alternative), don't add the '+' on positive
4427         numbers.  It's not as important anymore with the new internal
4428         form for numbers.  It made doing things like abs and neg easier,
4429         but those have to be done differently now anyway.
4430
4431 So, the following examples will now work all as expected:
4432
4433         use Test;
4434         BEGIN { plan tests => 1 }
4435         use Math::BigInt;
4436
4437         my $x = new Math::BigInt 3*3;
4438         my $y = new Math::BigInt 3*3;
4439
4440         ok ($x,3*3);
4441         print "$x eq 9" if $x eq $y;
4442         print "$x eq 9" if $x eq '9';
4443         print "$x eq 9" if $x eq 3*3;
4444
4445 Additionally, the following still works:
4446
4447         print "$x == 9" if $x == $y;
4448         print "$x == 9" if $x == 9;
4449         print "$x == 9" if $x == 3*3;
4450
4451 There is now a C<bsstr()> method to get the string in scientific notation aka
4452 C<1e+2> instead of C<100>. Be advised that overloaded 'eq' always uses bstr()
4453 for comparison, but Perl will represent some numbers as 100 and others
4454 as 1e+308. If in doubt, convert both arguments to Math::BigInt before
4455 comparing them as strings:
4456
4457         use Test;
4458         BEGIN { plan tests => 3 }
4459         use Math::BigInt;
4460
4461         $x = Math::BigInt->new('1e56'); $y = 1e56;
4462         ok ($x,$y);                     # will fail
4463         ok ($x->bsstr(),$y);            # okay
4464         $y = Math::BigInt->new($y);
4465         ok ($x,$y);                     # okay
4466
4467 Alternatively, simple use C<< <=> >> for comparisons, this will get it
4468 always right. There is not yet a way to get a number automatically represented
4469 as a string that matches exactly the way Perl represents it.
4470
4471 See also the section about L<Infinity and Not a Number> for problems in
4472 comparing NaNs.
4473
4474 =item int()
4475
4476 C<int()> will return (at least for Perl v5.7.1 and up) another BigInt, not a
4477 Perl scalar:
4478
4479         $x = Math::BigInt->new(123);
4480         $y = int($x);                           # BigInt 123
4481         $x = Math::BigFloat->new(123.45);
4482         $y = int($x);                           # BigInt 123
4483
4484 In all Perl versions you can use C<as_number()> or C<as_int> for the same
4485 effect:
4486
4487         $x = Math::BigFloat->new(123.45);
4488         $y = $x->as_number();                   # BigInt 123
4489         $y = $x->as_int();                      # ditto
4490
4491 This also works for other subclasses, like Math::String.
4492
4493 If you want a real Perl scalar, use C<numify()>:
4494
4495         $y = $x->numify();                      # 123 as scalar
4496
4497 This is seldom necessary, though, because this is done automatically, like
4498 when you access an array:
4499
4500         $z = $array[$x];                        # does work automatically
4501
4502 =item length
4503
4504 The following will probably not do what you expect:
4505
4506         $c = Math::BigInt->new(123);
4507         print $c->length(),"\n";                # prints 30
4508
4509 It prints both the number of digits in the number and in the fraction part
4510 since print calls C<length()> in list context. Use something like:
4511
4512         print scalar $c->length(),"\n";         # prints 3
4513
4514 =item bdiv
4515
4516 The following will probably not do what you expect:
4517
4518         print $c->bdiv(10000),"\n";
4519
4520 It prints both quotient and remainder since print calls C<bdiv()> in list
4521 context. Also, C<bdiv()> will modify $c, so be careful. You probably want
4522 to use
4523
4524         print $c / 10000,"\n";
4525         print scalar $c->bdiv(10000),"\n";  # or if you want to modify $c
4526
4527 instead.
4528
4529 The quotient is always the greatest integer less than or equal to the
4530 real-valued quotient of the two operands, and the remainder (when it is
4531 nonzero) always has the same sign as the second operand; so, for
4532 example,
4533
4534           1 / 4  => ( 0, 1)
4535           1 / -4 => (-1,-3)
4536          -3 / 4  => (-1, 1)
4537          -3 / -4 => ( 0,-3)
4538         -11 / 2  => (-5,1)
4539          11 /-2  => (-5,-1)
4540
4541 As a consequence, the behavior of the operator % agrees with the
4542 behavior of Perl's built-in % operator (as documented in the perlop
4543 manpage), and the equation
4544
4545         $x == ($x / $y) * $y + ($x % $y)
4546
4547 holds true for any $x and $y, which justifies calling the two return
4548 values of bdiv() the quotient and remainder. The only exception to this rule
4549 are when $y == 0 and $x is negative, then the remainder will also be
4550 negative. See below under "infinity handling" for the reasoning behind this.
4551
4552 Perl's 'use integer;' changes the behaviour of % and / for scalars, but will
4553 not change BigInt's way to do things. This is because under 'use integer' Perl
4554 will do what the underlying C thinks is right and this is different for each
4555 system. If you need BigInt's behaving exactly like Perl's 'use integer', bug
4556 the author to implement it ;)
4557
4558 =item infinity handling
4559
4560 Here are some examples that explain the reasons why certain results occur while
4561 handling infinity:
4562
4563 The following table shows the result of the division and the remainder, so that
4564 the equation above holds true. Some "ordinary" cases are strewn in to show more
4565 clearly the reasoning:
4566
4567         A /  B  =   C,     R so that C *    B +    R =    A
4568      =========================================================
4569         5 /   8 =   0,     5         0 *    8 +    5 =    5
4570         0 /   8 =   0,     0         0 *    8 +    0 =    0
4571         0 / inf =   0,     0         0 *  inf +    0 =    0
4572         0 /-inf =   0,     0         0 * -inf +    0 =    0
4573         5 / inf =   0,     5         0 *  inf +    5 =    5
4574         5 /-inf =   0,     5         0 * -inf +    5 =    5
4575         -5/ inf =   0,    -5         0 *  inf +   -5 =   -5
4576         -5/-inf =   0,    -5         0 * -inf +   -5 =   -5
4577        inf/   5 =  inf,    0       inf *    5 +    0 =  inf
4578       -inf/   5 = -inf,    0      -inf *    5 +    0 = -inf
4579        inf/  -5 = -inf,    0      -inf *   -5 +    0 =  inf
4580       -inf/  -5 =  inf,    0       inf *   -5 +    0 = -inf
4581          5/   5 =    1,    0         1 *    5 +    0 =    5
4582         -5/  -5 =    1,    0         1 *   -5 +    0 =   -5
4583        inf/ inf =    1,    0         1 *  inf +    0 =  inf
4584       -inf/-inf =    1,    0         1 * -inf +    0 = -inf
4585        inf/-inf =   -1,    0        -1 * -inf +    0 =  inf
4586       -inf/ inf =   -1,    0         1 * -inf +    0 = -inf
4587          8/   0 =  inf,    8       inf *    0 +    8 =    8
4588        inf/   0 =  inf,  inf       inf *    0 +  inf =  inf
4589          0/   0 =  NaN
4590
4591 These cases below violate the "remainder has the sign of the second of the two
4592 arguments", since they wouldn't match up otherwise.
4593
4594         A /  B  =   C,     R so that C *    B +    R =    A
4595      ========================================================
4596       -inf/   0 = -inf, -inf      -inf *    0 +  inf = -inf
4597         -8/   0 = -inf,   -8      -inf *    0 +    8 = -8
4598
4599 =item Modifying and =
4600
4601 Beware of:
4602
4603         $x = Math::BigFloat->new(5);
4604         $y = $x;
4605
4606 It will not do what you think, e.g. making a copy of $x. Instead it just makes
4607 a second reference to the B<same> object and stores it in $y. Thus anything
4608 that modifies $x (except overloaded operators) will modify $y, and vice versa.
4609 Or in other words, C<=> is only safe if you modify your BigInts only via
4610 overloaded math. As soon as you use a method call it breaks:
4611
4612         $x->bmul(2);
4613         print "$x, $y\n";       # prints '10, 10'
4614
4615 If you want a true copy of $x, use:
4616
4617         $y = $x->copy();
4618
4619 You can also chain the calls like this, this will make first a copy and then
4620 multiply it by 2:
4621
4622         $y = $x->copy()->bmul(2);
4623
4624 See also the documentation for overload.pm regarding C<=>.
4625
4626 =item bpow
4627
4628 C<bpow()> (and the rounding functions) now modifies the first argument and
4629 returns it, unlike the old code which left it alone and only returned the
4630 result. This is to be consistent with C<badd()> etc. The first three will
4631 modify $x, the last one won't:
4632
4633         print bpow($x,$i),"\n";         # modify $x
4634         print $x->bpow($i),"\n";        # ditto
4635         print $x **= $i,"\n";           # the same
4636         print $x ** $i,"\n";            # leave $x alone
4637
4638 The form C<$x **= $y> is faster than C<$x = $x ** $y;>, though.
4639
4640 =item Overloading -$x
4641
4642 The following:
4643
4644         $x = -$x;
4645
4646 is slower than
4647
4648         $x->bneg();
4649
4650 since overload calls C<sub($x,0,1);> instead of C<neg($x)>. The first variant
4651 needs to preserve $x since it does not know that it later will get overwritten.
4652 This makes a copy of $x and takes O(N), but $x->bneg() is O(1).
4653
4654 =item Mixing different object types
4655
4656 In Perl you will get a floating point value if you do one of the following:
4657
4658         $float = 5.0 + 2;
4659         $float = 2 + 5.0;
4660         $float = 5 / 2;
4661
4662 With overloaded math, only the first two variants will result in a BigFloat:
4663
4664         use Math::BigInt;
4665         use Math::BigFloat;
4666
4667         $mbf = Math::BigFloat->new(5);
4668         $mbi2 = Math::BigInteger->new(5);
4669         $mbi = Math::BigInteger->new(2);
4670
4671                                         # what actually gets called:
4672         $float = $mbf + $mbi;           # $mbf->badd()
4673         $float = $mbf / $mbi;           # $mbf->bdiv()
4674         $integer = $mbi + $mbf;         # $mbi->badd()
4675         $integer = $mbi2 / $mbi;        # $mbi2->bdiv()
4676         $integer = $mbi2 / $mbf;        # $mbi2->bdiv()
4677
4678 This is because math with overloaded operators follows the first (dominating)
4679 operand, and the operation of that is called and returns thus the result. So,
4680 Math::BigInt::bdiv() will always return a Math::BigInt, regardless whether
4681 the result should be a Math::BigFloat or the second operant is one.
4682
4683 To get a Math::BigFloat you either need to call the operation manually,
4684 make sure the operands are already of the proper type or casted to that type
4685 via Math::BigFloat->new():
4686
4687         $float = Math::BigFloat->new($mbi2) / $mbi;     # = 2.5
4688
4689 Beware of simple "casting" the entire expression, this would only convert
4690 the already computed result:
4691
4692         $float = Math::BigFloat->new($mbi2 / $mbi);     # = 2.0 thus wrong!
4693
4694 Beware also of the order of more complicated expressions like:
4695
4696         $integer = ($mbi2 + $mbi) / $mbf;               # int / float => int
4697         $integer = $mbi2 / Math::BigFloat->new($mbi);   # ditto
4698
4699 If in doubt, break the expression into simpler terms, or cast all operands
4700 to the desired resulting type.
4701
4702 Scalar values are a bit different, since:
4703
4704         $float = 2 + $mbf;
4705         $float = $mbf + 2;
4706
4707 will both result in the proper type due to the way the overloaded math works.
4708
4709 This section also applies to other overloaded math packages, like Math::String.
4710
4711 One solution to you problem might be autoupgrading|upgrading. See the
4712 pragmas L<bignum>, L<bigint> and L<bigrat> for an easy way to do this.
4713
4714 =item bsqrt()
4715
4716 C<bsqrt()> works only good if the result is a big integer, e.g. the square
4717 root of 144 is 12, but from 12 the square root is 3, regardless of rounding
4718 mode. The reason is that the result is always truncated to an integer.
4719
4720 If you want a better approximation of the square root, then use:
4721
4722         $x = Math::BigFloat->new(12);
4723         Math::BigFloat->precision(0);
4724         Math::BigFloat->round_mode('even');
4725         print $x->copy->bsqrt(),"\n";           # 4
4726
4727         Math::BigFloat->precision(2);
4728         print $x->bsqrt(),"\n";                 # 3.46
4729         print $x->bsqrt(3),"\n";                # 3.464
4730
4731 =item brsft()
4732
4733 For negative numbers in base see also L<brsft|brsft>.
4734
4735 =back
4736
4737 =head1 LICENSE
4738
4739 This program is free software; you may redistribute it and/or modify it under
4740 the same terms as Perl itself.
4741
4742 =head1 SEE ALSO
4743
4744 L<Math::BigFloat>, L<Math::BigRat> and L<Math::Big> as well as
4745 L<Math::BigInt::BitVect>, L<Math::BigInt::Pari> and  L<Math::BigInt::GMP>.
4746
4747 The pragmas L<bignum>, L<bigint> and L<bigrat> also might be of interest
4748 because they solve the autoupgrading/downgrading issue, at least partly.
4749
4750 The package at
4751 L<http://search.cpan.org/search?mode=module&query=Math%3A%3ABigInt> contains
4752 more documentation including a full version history, testcases, empty
4753 subclass files and benchmarks.
4754
4755 =head1 AUTHORS
4756
4757 Original code by Mark Biggar, overloaded interface by Ilya Zakharevich.
4758 Completely rewritten by Tels http://bloodgate.com in late 2000, 2001 - 2006
4759 and still at it in 2007.
4760
4761 Many people contributed in one or more ways to the final beast, see the file
4762 CREDITS for an (incomplete) list. If you miss your name, please drop me a
4763 mail. Thank you!
4764
4765 =cut