lib/Math/BigInt.pm

   1 package Math::BigInt;
   2
   3 #
   4 # "Mike had an infinite amount to do and a negative amount of time in which
   5 # to do it." - Before and After
   6 #
   7
   8 # The following hash values are used:
   9 #   value: unsigned int with actual value (as a Math::BigInt::Calc or similiar)
  10 #   sign : +,-,NaN,+inf,-inf
  11 #   _a   : accuracy
  12 #   _p   : precision
  13 #   _f   : flags, used by MBF to flag parts of a float as untouchable
  14
  15 # Remember not to take shortcuts ala $xs = $x->{value}; $CALC->foo($xs); since
  16 # underlying lib might change the reference!
  17
  18 my $class = "Math::BigInt";
  19 require 5.005;
  20
  21 $VERSION = '1.73';
  22 use Exporter;
  23 @ISA =       qw( Exporter );
  24 @EXPORT_OK = qw( objectify bgcd blcm);
  25 # _trap_inf and _trap_nan are internal and should never be accessed from the
  26 # outside
  27 use vars qw/$round_mode $accuracy $precision $div_scale $rnd_mode
  28             $upgrade $downgrade $_trap_nan $_trap_inf/;
  29 use strict;
  30
  31 # Inside overload, the first arg is always an object. If the original code had
  32 # it reversed (like $x = 2 * $y), then the third paramater is true.
  33 # In some cases (like add, $x = $x + 2 is the same as $x = 2 + $x) this makes
  34 # no difference, but in some cases it does.
  35
  36 # For overloaded ops with only one argument we simple use $_[0]->copy() to
  37 # preserve the argument.
  38
  39 # Thus inheritance of overload operators becomes possible and transparent for
  40 # our subclasses without the need to repeat the entire overload section there.
  41
  42 use overload
  43 '='     =>      sub { $_[0]->copy(); },
  44
  45 # some shortcuts for speed (assumes that reversed order of arguments is routed
  46 # to normal '+' and we thus can always modify first arg. If this is changed,
  47 # this breaks and must be adjusted.)
  48 '+='    =>      sub { $_[0]->badd($_[1]); },
  49 '-='    =>      sub { $_[0]->bsub($_[1]); },
  50 '*='    =>      sub { $_[0]->bmul($_[1]); },
  51 '/='    =>      sub { scalar $_[0]->bdiv($_[1]); },
  52 '%='    =>      sub { $_[0]->bmod($_[1]); },
  53 '^='    =>      sub { $_[0]->bxor($_[1]); },
  54 '&='    =>      sub { $_[0]->band($_[1]); },
  55 '|='    =>      sub { $_[0]->bior($_[1]); },
  56 '**='   =>      sub { $_[0]->bpow($_[1]); },
  57
  58 '<<='   =>      sub { $_[0]->blsft($_[1]); },
  59 '>>='   =>      sub { $_[0]->brsft($_[1]); },
  60
  61 # not supported by Perl yet
  62 '..'    =>      \&_pointpoint,
  63
  64 '<=>'   =>      sub { $_[2] ?
  65                       ref($_[0])->bcmp($_[1],$_[0]) :
  66                       $_[0]->bcmp($_[1])},
  67 'cmp'   =>      sub {
  68          $_[2] ?
  69                "$_[1]" cmp $_[0]->bstr() :
  70                $_[0]->bstr() cmp "$_[1]" },
  71
  72 # make cos()/sin()/exp() "work" with BigInt's or subclasses
  73 'cos'   =>      sub { cos($_[0]->numify()) },
  74 'sin'   =>      sub { sin($_[0]->numify()) },
  75 'exp'   =>      sub { exp($_[0]->numify()) },
  76 'atan2' =>      sub { atan2($_[0]->numify(),$_[1]) },
  77
  78 'log'   =>      sub { $_[0]->copy()->blog($_[1]); },
  79 'int'   =>      sub { $_[0]->copy(); },
  80 'neg'   =>      sub { $_[0]->copy()->bneg(); },
  81 'abs'   =>      sub { $_[0]->copy()->babs(); },
  82 'sqrt'  =>      sub { $_[0]->copy()->bsqrt(); },
  83 '~'     =>      sub { $_[0]->copy()->bnot(); },
  84
  85 # for subtract it is a bit tricky to keep b: b-a => -a+b
  86 '-'     =>      sub { my $c = $_[0]->copy; $_[2] ?
  87                    $c->bneg()->badd($_[1]) :
  88                    $c->bsub( $_[1]) },
  89 '+'     =>      sub { $_[0]->copy()->badd($_[1]); },
  90 '*'     =>      sub { $_[0]->copy()->bmul($_[1]); },
  91
  92 '/'     =>      sub {
  93    $_[2] ? ref($_[0])->new($_[1])->bdiv($_[0]) : $_[0]->copy->bdiv($_[1]);
  94   },
  95 '%'     =>      sub {
  96    $_[2] ? ref($_[0])->new($_[1])->bmod($_[0]) : $_[0]->copy->bmod($_[1]);
  97   },
  98 '**'    =>      sub {
  99    $_[2] ? ref($_[0])->new($_[1])->bpow($_[0]) : $_[0]->copy->bpow($_[1]);
 100   },
 101 '<<'    =>      sub {
 102    $_[2] ? ref($_[0])->new($_[1])->blsft($_[0]) : $_[0]->copy->blsft($_[1]);
 103   },
 104 '>>'    =>      sub {
 105    $_[2] ? ref($_[0])->new($_[1])->brsft($_[0]) : $_[0]->copy->brsft($_[1]);
 106   },
 107 '&'     =>      sub {
 108    $_[2] ? ref($_[0])->new($_[1])->band($_[0]) : $_[0]->copy->band($_[1]);
 109   },
 110 '|'     =>      sub {
 111    $_[2] ? ref($_[0])->new($_[1])->bior($_[0]) : $_[0]->copy->bior($_[1]);
 112   },
 113 '^'     =>      sub {
 114    $_[2] ? ref($_[0])->new($_[1])->bxor($_[0]) : $_[0]->copy->bxor($_[1]);
 115   },
 116
 117 # can modify arg of ++ and --, so avoid a copy() for speed, but don't
 118 # use $_[0]->bone(), it would modify $_[0] to be 1!
 119 '++'    =>      sub { $_[0]->binc() },
 120 '--'    =>      sub { $_[0]->bdec() },
 121
 122 # if overloaded, O(1) instead of O(N) and twice as fast for small numbers
 123 'bool'  =>      sub {
 124   # this kludge is needed for perl prior 5.6.0 since returning 0 here fails :-/
 125   # v5.6.1 dumps on this: return !$_[0]->is_zero() || undef;                :-(
 126   my $t = undef;
 127   $t = 1 if !$_[0]->is_zero();
 128   $t;
 129   },
 130
 131 # the original qw() does not work with the TIESCALAR below, why?
 132 # Order of arguments unsignificant
 133 '""' => sub { $_[0]->bstr(); },
 134 '0+' => sub { $_[0]->numify(); }
 135 ;
 136
 137 ##############################################################################
 138 # global constants, flags and accessory
 139
 140 # these are public, but their usage is not recommended, use the accessor
 141 # methods instead
 142
 143 $round_mode = 'even'; # one of 'even', 'odd', '+inf', '-inf', 'zero' or 'trunc'
 144 $accuracy   = undef;
 145 $precision  = undef;
 146 $div_scale  = 40;
 147
 148 $upgrade = undef;                       # default is no upgrade
 149 $downgrade = undef;                     # default is no downgrade
 150
 151 # these are internally, and not to be used from the outside
 152
 153 sub MB_NEVER_ROUND () { 0x0001; }
 154
 155 $_trap_nan = 0;                         # are NaNs ok? set w/ config()
 156 $_trap_inf = 0;                         # are infs ok? set w/ config()
 157 my $nan = 'NaN';                        # constants for easier life
 158
 159 my $CALC = 'Math::BigInt::Calc';        # module to do the low level math
 160                                         # default is Calc.pm
 161 my $IMPORT = 0;                         # was import() called yet?
 162                                         # used to make require work
 163 my %WARN;                               # warn only once for low-level libs
 164 my %CAN;                                # cache for $CALC->can(...)
 165 my $EMU_LIB = 'Math/BigInt/CalcEmu.pm'; # emulate low-level math
 166
 167 ##############################################################################
 168 # the old code had $rnd_mode, so we need to support it, too
 169
 170 $rnd_mode   = 'even';
 171 sub TIESCALAR  { my ($class) = @_; bless \$round_mode, $class; }
 172 sub FETCH      { return $round_mode; }
 173 sub STORE      { $rnd_mode = $_[0]->round_mode($_[1]); }
 174
 175 BEGIN
 176   {
 177   # tie to enable $rnd_mode to work transparently
 178   tie $rnd_mode, 'Math::BigInt';
 179
 180   # set up some handy alias names
 181   *as_int = \&as_number;
 182   *is_pos = \&is_positive;
 183   *is_neg = \&is_negative;
 184   }
 185
 186 ##############################################################################
 187
 188 sub round_mode
 189   {
 190   no strict 'refs';
 191   # make Class->round_mode() work
 192   my $self = shift;
 193   my $class = ref($self) || $self || __PACKAGE__;
 194   if (defined $_[0])
 195     {
 196     my $m = shift;
 197     if ($m !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 198       {
 199       require Carp; Carp::croak ("Unknown round mode '$m'");
 200       }
 201     return ${"${class}::round_mode"} = $m;
 202     }
 203   ${"${class}::round_mode"};
 204   }
 205
 206 sub upgrade
 207   {
 208   no strict 'refs';
 209   # make Class->upgrade() work
 210   my $self = shift;
 211   my $class = ref($self) || $self || __PACKAGE__;
 212   # need to set new value?
 213   if (@_ > 0)
 214     {
 215     my $u = shift;
 216     return ${"${class}::upgrade"} = $u;
 217     }
 218   ${"${class}::upgrade"};
 219   }
 220
 221 sub downgrade
 222   {
 223   no strict 'refs';
 224   # make Class->downgrade() work
 225   my $self = shift;
 226   my $class = ref($self) || $self || __PACKAGE__;
 227   # need to set new value?
 228   if (@_ > 0)
 229     {
 230     my $u = shift;
 231     return ${"${class}::downgrade"} = $u;
 232     }
 233   ${"${class}::downgrade"};
 234   }
 235
 236 sub div_scale
 237   {
 238   no strict 'refs';
 239   # make Class->div_scale() work
 240   my $self = shift;
 241   my $class = ref($self) || $self || __PACKAGE__;
 242   if (defined $_[0])
 243     {
 244     if ($_[0] < 0)
 245       {
 246       require Carp; Carp::croak ('div_scale must be greater than zero');
 247       }
 248     ${"${class}::div_scale"} = shift;
 249     }
 250   ${"${class}::div_scale"};
 251   }
 252
 253 sub accuracy
 254   {
 255   # $x->accuracy($a);           ref($x) $a
 256   # $x->accuracy();             ref($x)
 257   # Class->accuracy();          class
 258   # Class->accuracy($a);        class $a
 259
 260   my $x = shift;
 261   my $class = ref($x) || $x || __PACKAGE__;
 262
 263   no strict 'refs';
 264   # need to set new value?
 265   if (@_ > 0)
 266     {
 267     my $a = shift;
 268     # convert objects to scalars to avoid deep recursion. If object doesn't
 269     # have numify(), then hopefully it will have overloading for int() and
 270     # boolean test without wandering into a deep recursion path...
 271     $a = $a->numify() if ref($a) && $a->can('numify');
 272
 273     if (defined $a)
 274       {
 275       # also croak on non-numerical
 276       if (!$a || $a <= 0)
 277         {
 278         require Carp;
 279         Carp::croak ('Argument to accuracy must be greater than zero');
 280         }
 281       if (int($a) != $a)
 282         {
 283         require Carp; Carp::croak ('Argument to accuracy must be an integer');
 284         }
 285       }
 286     if (ref($x))
 287       {
 288       # $object->accuracy() or fallback to global
 289       $x->bround($a) if $a;             # not for undef, 0
 290       $x->{_a} = $a;                    # set/overwrite, even if not rounded
 291       delete $x->{_p};                  # clear P
 292       $a = ${"${class}::accuracy"} unless defined $a;   # proper return value
 293       }
 294     else
 295       {
 296       ${"${class}::accuracy"} = $a;     # set global A
 297       ${"${class}::precision"} = undef; # clear global P
 298       }
 299     return $a;                          # shortcut
 300     }
 301
 302   my $r;
 303   # $object->accuracy() or fallback to global
 304   $r = $x->{_a} if ref($x);
 305   # but don't return global undef, when $x's accuracy is 0!
 306   $r = ${"${class}::accuracy"} if !defined $r;
 307   $r;
 308   }
 309
 310 sub precision
 311   {
 312   # $x->precision($p);          ref($x) $p
 313   # $x->precision();            ref($x)
 314   # Class->precision();         class
 315   # Class->precision($p);       class $p
 316
 317   my $x = shift;
 318   my $class = ref($x) || $x || __PACKAGE__;
 319
 320   no strict 'refs';
 321   if (@_ > 0)
 322     {
 323     my $p = shift;
 324     # convert objects to scalars to avoid deep recursion. If object doesn't
 325     # have numify(), then hopefully it will have overloading for int() and
 326     # boolean test without wandering into a deep recursion path...
 327     $p = $p->numify() if ref($p) && $p->can('numify');
 328     if ((defined $p) && (int($p) != $p))
 329       {
 330       require Carp; Carp::croak ('Argument to precision must be an integer');
 331       }
 332     if (ref($x))
 333       {
 334       # $object->precision() or fallback to global
 335       $x->bfround($p) if $p;            # not for undef, 0
 336       $x->{_p} = $p;                    # set/overwrite, even if not rounded
 337       delete $x->{_a};                  # clear A
 338       $p = ${"${class}::precision"} unless defined $p;  # proper return value
 339       }
 340     else
 341       {
 342       ${"${class}::precision"} = $p;    # set global P
 343       ${"${class}::accuracy"} = undef;  # clear global A
 344       }
 345     return $p;                          # shortcut
 346     }
 347
 348   my $r;
 349   # $object->precision() or fallback to global
 350   $r = $x->{_p} if ref($x);
 351   # but don't return global undef, when $x's precision is 0!
 352   $r = ${"${class}::precision"} if !defined $r;
 353   $r;
 354   }
 355
 356 sub config
 357   {
 358   # return (or set) configuration data as hash ref
 359   my $class = shift || 'Math::BigInt';
 360
 361   no strict 'refs';
 362   if (@_ > 0)
 363     {
 364     # try to set given options as arguments from hash
 365
 366     my $args = $_[0];
 367     if (ref($args) ne 'HASH')
 368       {
 369       $args = { @_ };
 370       }
 371     # these values can be "set"
 372     my $set_args = {};
 373     foreach my $key (
 374      qw/trap_inf trap_nan
 375         upgrade downgrade precision accuracy round_mode div_scale/
 376      )
 377       {
 378       $set_args->{$key} = $args->{$key} if exists $args->{$key};
 379       delete $args->{$key};
 380       }
 381     if (keys %$args > 0)
 382       {
 383       require Carp;
 384       Carp::croak ("Illegal key(s) '",
 385        join("','",keys %$args),"' passed to $class\->config()");
 386       }
 387     foreach my $key (keys %$set_args)
 388       {
 389       if ($key =~ /^trap_(inf|nan)\z/)
 390         {
 391         ${"${class}::_trap_$1"} = ($set_args->{"trap_$1"} ? 1 : 0);
 392         next;
 393         }
 394       # use a call instead of just setting the $variable to check argument
 395       $class->$key($set_args->{$key});
 396       }
 397     }
 398
 399   # now return actual configuration
 400
 401   my $cfg = {
 402     lib => $CALC,
 403     lib_version => ${"${CALC}::VERSION"},
 404     class => $class,
 405     trap_nan => ${"${class}::_trap_nan"},
 406     trap_inf => ${"${class}::_trap_inf"},
 407     version => ${"${class}::VERSION"},
 408     };
 409   foreach my $key (qw/
 410      upgrade downgrade precision accuracy round_mode div_scale
 411      /)
 412     {
 413     $cfg->{$key} = ${"${class}::$key"};
 414     };
 415   $cfg;
 416   }
 417
 418 sub _scale_a
 419   {
 420   # select accuracy parameter based on precedence,
 421   # used by bround() and bfround(), may return undef for scale (means no op)
 422   my ($x,$s,$m,$scale,$mode) = @_;
 423   $scale = $x->{_a} if !defined $scale;
 424   $scale = $s if (!defined $scale);
 425   $mode = $m if !defined $mode;
 426   return ($scale,$mode);
 427   }
 428
 429 sub _scale_p
 430   {
 431   # select precision parameter based on precedence,
 432   # used by bround() and bfround(), may return undef for scale (means no op)
 433   my ($x,$s,$m,$scale,$mode) = @_;
 434   $scale = $x->{_p} if !defined $scale;
 435   $scale = $s if (!defined $scale);
 436   $mode = $m if !defined $mode;
 437   return ($scale,$mode);
 438   }
 439
 440 ##############################################################################
 441 # constructors
 442
 443 sub copy
 444   {
 445   my ($c,$x);
 446   if (@_ > 1)
 447     {
 448     # if two arguments, the first one is the class to "swallow" subclasses
 449     ($c,$x) = @_;
 450     }
 451   else
 452     {
 453     $x = shift;
 454     $c = ref($x);
 455     }
 456   return unless ref($x); # only for objects
 457
 458   my $self = {}; bless $self,$c;
 459
 460   $self->{sign} = $x->{sign};
 461   $self->{value} = $CALC->_copy($x->{value});
 462   $self->{_a} = $x->{_a} if defined $x->{_a};
 463   $self->{_p} = $x->{_p} if defined $x->{_p};
 464   $self;
 465   }
 466
 467 sub new
 468   {
 469   # create a new BigInt object from a string or another BigInt object.
 470   # see hash keys documented at top
 471
 472   # the argument could be an object, so avoid ||, && etc on it, this would
 473   # cause costly overloaded code to be called. The only allowed ops are
 474   # ref() and defined.
 475
 476   my ($class,$wanted,$a,$p,$r) = @_;
 477
 478   # avoid numify-calls by not using || on $wanted!
 479   return $class->bzero($a,$p) if !defined $wanted;      # default to 0
 480   return $class->copy($wanted,$a,$p,$r)
 481    if ref($wanted) && $wanted->isa($class);             # MBI or subclass
 482
 483   $class->import() if $IMPORT == 0;             # make require work
 484
 485   my $self = bless {}, $class;
 486
 487   # shortcut for "normal" numbers
 488   if ((!ref $wanted) && ($wanted =~ /^([+-]?)[1-9][0-9]*\z/))
 489     {
 490     $self->{sign} = $1 || '+';
 491
 492     if ($wanted =~ /^[+-]/)
 493      {
 494       # remove sign without touching wanted to make it work with constants
 495       my $t = $wanted; $t =~ s/^[+-]//;
 496       $self->{value} = $CALC->_new($t);
 497       }
 498     else
 499       {
 500       $self->{value} = $CALC->_new($wanted);
 501       }
 502     no strict 'refs';
 503     if ( (defined $a) || (defined $p)
 504         || (defined ${"${class}::precision"})
 505         || (defined ${"${class}::accuracy"})
 506        )
 507       {
 508       $self->round($a,$p,$r) unless (@_ == 4 && !defined $a && !defined $p);
 509       }
 510     return $self;
 511     }
 512
 513   # handle '+inf', '-inf' first
 514   if ($wanted =~ /^[+-]?inf$/)
 515     {
 516     $self->{value} = $CALC->_zero();
 517     $self->{sign} = $wanted; $self->{sign} = '+inf' if $self->{sign} eq 'inf';
 518     return $self;
 519     }
 520   # split str in m mantissa, e exponent, i integer, f fraction, v value, s sign
 521   my ($mis,$miv,$mfv,$es,$ev) = _split($wanted);
 522   if (!ref $mis)
 523     {
 524     if ($_trap_nan)
 525       {
 526       require Carp; Carp::croak("$wanted is not a number in $class");
 527       }
 528     $self->{value} = $CALC->_zero();
 529     $self->{sign} = $nan;
 530     return $self;
 531     }
 532   if (!ref $miv)
 533     {
 534     # _from_hex or _from_bin
 535     $self->{value} = $mis->{value};
 536     $self->{sign} = $mis->{sign};
 537     return $self;       # throw away $mis
 538     }
 539   # make integer from mantissa by adjusting exp, then convert to bigint
 540   $self->{sign} = $$mis;                        # store sign
 541   $self->{value} = $CALC->_zero();              # for all the NaN cases
 542   my $e = int("$$es$$ev");                      # exponent (avoid recursion)
 543   if ($e > 0)
 544     {
 545     my $diff = $e - CORE::length($$mfv);
 546     if ($diff < 0)                              # Not integer
 547       {
 548       if ($_trap_nan)
 549         {
 550         require Carp; Carp::croak("$wanted not an integer in $class");
 551         }
 552       #print "NOI 1\n";
 553       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 554       $self->{sign} = $nan;
 555       }
 556     else                                        # diff >= 0
 557       {
 558       # adjust fraction and add it to value
 559       #print "diff > 0 $$miv\n";
 560       $$miv = $$miv . ($$mfv . '0' x $diff);
 561       }
 562     }
 563   else
 564     {
 565     if ($$mfv ne '')                            # e <= 0
 566       {
 567       # fraction and negative/zero E => NOI
 568       if ($_trap_nan)
 569         {
 570         require Carp; Carp::croak("$wanted not an integer in $class");
 571         }
 572       #print "NOI 2 \$\$mfv '$$mfv'\n";
 573       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 574       $self->{sign} = $nan;
 575       }
 576     elsif ($e < 0)
 577       {
 578       # xE-y, and empty mfv
 579       #print "xE-y\n";
 580       $e = abs($e);
 581       if ($$miv !~ s/0{$e}$//)          # can strip so many zero's?
 582         {
 583         if ($_trap_nan)
 584           {
 585           require Carp; Carp::croak("$wanted not an integer in $class");
 586           }
 587         #print "NOI 3\n";
 588         return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 589         $self->{sign} = $nan;
 590         }
 591       }
 592     }
 593   $self->{sign} = '+' if $$miv eq '0';                  # normalize -0 => +0
 594   $self->{value} = $CALC->_new($$miv) if $self->{sign} =~ /^[+-]$/;
 595   # if any of the globals is set, use them to round and store them inside $self
 596   # do not round for new($x,undef,undef) since that is used by MBF to signal
 597   # no rounding
 598   $self->round($a,$p,$r) unless @_ == 4 && !defined $a && !defined $p;
 599   $self;
 600   }
 601
 602 sub bnan
 603   {
 604   # create a bigint 'NaN', if given a BigInt, set it to 'NaN'
 605   my $self = shift;
 606   $self = $class if !defined $self;
 607   if (!ref($self))
 608     {
 609     my $c = $self; $self = {}; bless $self, $c;
 610     }
 611   no strict 'refs';
 612   if (${"${class}::_trap_nan"})
 613     {
 614     require Carp;
 615     Carp::croak ("Tried to set $self to NaN in $class\::bnan()");
 616     }
 617   $self->import() if $IMPORT == 0;              # make require work
 618   return if $self->modify('bnan');
 619   if ($self->can('_bnan'))
 620     {
 621     # use subclass to initialize
 622     $self->_bnan();
 623     }
 624   else
 625     {
 626     # otherwise do our own thing
 627     $self->{value} = $CALC->_zero();
 628     }
 629   $self->{sign} = $nan;
 630   delete $self->{_a}; delete $self->{_p};       # rounding NaN is silly
 631   $self;
 632   }
 633
 634 sub binf
 635   {
 636   # create a bigint '+-inf', if given a BigInt, set it to '+-inf'
 637   # the sign is either '+', or if given, used from there
 638   my $self = shift;
 639   my $sign = shift; $sign = '+' if !defined $sign || $sign !~ /^-(inf)?$/;
 640   $self = $class if !defined $self;
 641   if (!ref($self))
 642     {
 643     my $c = $self; $self = {}; bless $self, $c;
 644     }
 645   no strict 'refs';
 646   if (${"${class}::_trap_inf"})
 647     {
 648     require Carp;
 649     Carp::croak ("Tried to set $self to +-inf in $class\::binfn()");
 650     }
 651   $self->import() if $IMPORT == 0;              # make require work
 652   return if $self->modify('binf');
 653   if ($self->can('_binf'))
 654     {
 655     # use subclass to initialize
 656     $self->_binf();
 657     }
 658   else
 659     {
 660     # otherwise do our own thing
 661     $self->{value} = $CALC->_zero();
 662     }
 663   $sign = $sign . 'inf' if $sign !~ /inf$/;     # - => -inf
 664   $self->{sign} = $sign;
 665   ($self->{_a},$self->{_p}) = @_;               # take over requested rounding
 666   $self;
 667   }
 668
 669 sub bzero
 670   {
 671   # create a bigint '+0', if given a BigInt, set it to 0
 672   my $self = shift;
 673   $self = $class if !defined $self;
 674
 675   if (!ref($self))
 676     {
 677     my $c = $self; $self = {}; bless $self, $c;
 678     }
 679   $self->import() if $IMPORT == 0;              # make require work
 680   return if $self->modify('bzero');
 681
 682   if ($self->can('_bzero'))
 683     {
 684     # use subclass to initialize
 685     $self->_bzero();
 686     }
 687   else
 688     {
 689     # otherwise do our own thing
 690     $self->{value} = $CALC->_zero();
 691     }
 692   $self->{sign} = '+';
 693   if (@_ > 0)
 694     {
 695     if (@_ > 3)
 696       {
 697       # call like: $x->bzero($a,$p,$r,$y);
 698       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 699       }
 700     else
 701       {
 702       $self->{_a} = $_[0]
 703        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 704       $self->{_p} = $_[1]
 705        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 706       }
 707     }
 708   $self;
 709   }
 710
 711 sub bone
 712   {
 713   # create a bigint '+1' (or -1 if given sign '-'),
 714   # if given a BigInt, set it to +1 or -1, respecively
 715   my $self = shift;
 716   my $sign = shift; $sign = '+' if !defined $sign || $sign ne '-';
 717   $self = $class if !defined $self;
 718
 719   if (!ref($self))
 720     {
 721     my $c = $self; $self = {}; bless $self, $c;
 722     }
 723   $self->import() if $IMPORT == 0;              # make require work
 724   return if $self->modify('bone');
 725
 726   if ($self->can('_bone'))
 727     {
 728     # use subclass to initialize
 729     $self->_bone();
 730     }
 731   else
 732     {
 733     # otherwise do our own thing
 734     $self->{value} = $CALC->_one();
 735     }
 736   $self->{sign} = $sign;
 737   if (@_ > 0)
 738     {
 739     if (@_ > 3)
 740       {
 741       # call like: $x->bone($sign,$a,$p,$r,$y);
 742       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 743       }
 744     else
 745       {
 746       # call like: $x->bone($sign,$a,$p,$r);
 747       $self->{_a} = $_[0]
 748        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 749       $self->{_p} = $_[1]
 750        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 751       }
 752     }
 753   $self;
 754   }
 755
 756 ##############################################################################
 757 # string conversation
 758
 759 sub bsstr
 760   {
 761   # (ref to BFLOAT or num_str ) return num_str
 762   # Convert number from internal format to scientific string format.
 763   # internal format is always normalized (no leading zeros, "-0E0" => "+0E0")
 764   my $x = shift; $class = ref($x) || $x; $x = $class->new(shift) if !ref($x);
 765   # my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 766
 767   if ($x->{sign} !~ /^[+-]$/)
 768     {
 769     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 770     return 'inf';                                       # +inf
 771     }
 772   my ($m,$e) = $x->parts();
 773   #$m->bstr() . 'e+' . $e->bstr();      # e can only be positive in BigInt
 774   # 'e+' because E can only be positive in BigInt
 775   $m->bstr() . 'e+' . $CALC->_str($e->{value});
 776   }
 777
 778 sub bstr
 779   {
 780   # make a string from bigint object
 781   my $x = shift; $class = ref($x) || $x; $x = $class->new(shift) if !ref($x);
 782   # my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 783
 784   if ($x->{sign} !~ /^[+-]$/)
 785     {
 786     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 787     return 'inf';                                       # +inf
 788     }
 789   my $es = ''; $es = $x->{sign} if $x->{sign} eq '-';
 790   $es.$CALC->_str($x->{value});
 791   }
 792
 793 sub numify
 794   {
 795   # Make a "normal" scalar from a BigInt object
 796   my $x = shift; $x = $class->new($x) unless ref $x;
 797
 798   return $x->bstr() if $x->{sign} !~ /^[+-]$/;
 799   my $num = $CALC->_num($x->{value});
 800   return -$num if $x->{sign} eq '-';
 801   $num;
 802   }
 803
 804 ##############################################################################
 805 # public stuff (usually prefixed with "b")
 806
 807 sub sign
 808   {
 809   # return the sign of the number: +/-/-inf/+inf/NaN
 810   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 811
 812   $x->{sign};
 813   }
 814
 815 sub _find_round_parameters
 816   {
 817   # After any operation or when calling round(), the result is rounded by
 818   # regarding the A & P from arguments, local parameters, or globals.
 819
 820   # !!!!!!! If you change this, remember to change round(), too! !!!!!!!!!!
 821
 822   # This procedure finds the round parameters, but it is for speed reasons
 823   # duplicated in round. Otherwise, it is tested by the testsuite and used
 824   # by fdiv().
 825
 826   # returns ($self) or ($self,$a,$p,$r) - sets $self to NaN of both A and P
 827   # were requested/defined (locally or globally or both)
 828
 829   my ($self,$a,$p,$r,@args) = @_;
 830   # $a accuracy, if given by caller
 831   # $p precision, if given by caller
 832   # $r round_mode, if given by caller
 833   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 834
 835   # leave bigfloat parts alone
 836   return ($self) if exists $self->{_f} && ($self->{_f} & MB_NEVER_ROUND) != 0;
 837
 838   my $c = ref($self);                           # find out class of argument(s)
 839   no strict 'refs';
 840
 841   # now pick $a or $p, but only if we have got "arguments"
 842   if (!defined $a)
 843     {
 844     foreach ($self,@args)
 845       {
 846       # take the defined one, or if both defined, the one that is smaller
 847       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 848       }
 849     }
 850   if (!defined $p)
 851     {
 852     # even if $a is defined, take $p, to signal error for both defined
 853     foreach ($self,@args)
 854       {
 855       # take the defined one, or if both defined, the one that is bigger
 856       # -2 > -3, and 3 > 2
 857       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 858       }
 859     }
 860   # if still none defined, use globals (#2)
 861   $a = ${"$c\::accuracy"} unless defined $a;
 862   $p = ${"$c\::precision"} unless defined $p;
 863
 864   # A == 0 is useless, so undef it to signal no rounding
 865   $a = undef if defined $a && $a == 0;
 866
 867   # no rounding today?
 868   return ($self) unless defined $a || defined $p;               # early out
 869
 870   # set A and set P is an fatal error
 871   return ($self->bnan()) if defined $a && defined $p;           # error
 872
 873   $r = ${"$c\::round_mode"} unless defined $r;
 874   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 875     {
 876     require Carp; Carp::croak ("Unknown round mode '$r'");
 877     }
 878
 879   ($self,$a,$p,$r);
 880   }
 881
 882 sub round
 883   {
 884   # Round $self according to given parameters, or given second argument's
 885   # parameters or global defaults
 886
 887   # for speed reasons, _find_round_parameters is embeded here:
 888
 889   my ($self,$a,$p,$r,@args) = @_;
 890   # $a accuracy, if given by caller
 891   # $p precision, if given by caller
 892   # $r round_mode, if given by caller
 893   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 894
 895   # leave bigfloat parts alone
 896   return ($self) if exists $self->{_f} && ($self->{_f} & MB_NEVER_ROUND) != 0;
 897
 898   my $c = ref($self);                           # find out class of argument(s)
 899   no strict 'refs';
 900
 901   # now pick $a or $p, but only if we have got "arguments"
 902   if (!defined $a)
 903     {
 904     foreach ($self,@args)
 905       {
 906       # take the defined one, or if both defined, the one that is smaller
 907       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 908       }
 909     }
 910   if (!defined $p)
 911     {
 912     # even if $a is defined, take $p, to signal error for both defined
 913     foreach ($self,@args)
 914       {
 915       # take the defined one, or if both defined, the one that is bigger
 916       # -2 > -3, and 3 > 2
 917       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 918       }
 919     }
 920   # if still none defined, use globals (#2)
 921   $a = ${"$c\::accuracy"} unless defined $a;
 922   $p = ${"$c\::precision"} unless defined $p;
 923
 924   # A == 0 is useless, so undef it to signal no rounding
 925   $a = undef if defined $a && $a == 0;
 926
 927   # no rounding today?
 928   return $self unless defined $a || defined $p;         # early out
 929
 930   # set A and set P is an fatal error
 931   return $self->bnan() if defined $a && defined $p;
 932
 933   $r = ${"$c\::round_mode"} unless defined $r;
 934   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 935     {
 936     require Carp; Carp::croak ("Unknown round mode '$r'");
 937     }
 938
 939   # now round, by calling either fround or ffround:
 940   if (defined $a)
 941     {
 942     $self->bround($a,$r) if !defined $self->{_a} || $self->{_a} >= $a;
 943     }
 944   else # both can't be undefined due to early out
 945     {
 946     $self->bfround($p,$r) if !defined $self->{_p} || $self->{_p} <= $p;
 947     }
 948   $self->bnorm();                       # after round, normalize
 949   }
 950
 951 sub bnorm
 952   {
 953   # (numstr or BINT) return BINT
 954   # Normalize number -- no-op here
 955   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 956   $x;
 957   }
 958
 959 sub babs
 960   {
 961   # (BINT or num_str) return BINT
 962   # make number absolute, or return absolute BINT from string
 963   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 964
 965   return $x if $x->modify('babs');
 966   # post-normalized abs for internal use (does nothing for NaN)
 967   $x->{sign} =~ s/^-/+/;
 968   $x;
 969   }
 970
 971 sub bneg
 972   {
 973   # (BINT or num_str) return BINT
 974   # negate number or make a negated number from string
 975   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 976
 977   return $x if $x->modify('bneg');
 978
 979   # for +0 dont negate (to have always normalized)
 980   $x->{sign} =~ tr/+-/-+/ if !$x->is_zero();    # does nothing for NaN
 981   $x;
 982   }
 983
 984 sub bcmp
 985   {
 986   # Compares 2 values.  Returns one of undef, <0, =0, >0. (suitable for sort)
 987   # (BINT or num_str, BINT or num_str) return cond_code
 988
 989   # set up parameters
 990   my ($self,$x,$y) = (ref($_[0]),@_);
 991
 992   # objectify is costly, so avoid it
 993   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
 994     {
 995     ($self,$x,$y) = objectify(2,@_);
 996     }
 997
 998   return $upgrade->bcmp($x,$y) if defined $upgrade &&
 999     ((!$x->isa($self)) || (!$y->isa($self)));
1000
1001   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1002     {
1003     # handle +-inf and NaN
1004     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1005     return 0 if $x->{sign} eq $y->{sign} && $x->{sign} =~ /^[+-]inf$/;
1006     return +1 if $x->{sign} eq '+inf';
1007     return -1 if $x->{sign} eq '-inf';
1008     return -1 if $y->{sign} eq '+inf';
1009     return +1;
1010     }
1011   # check sign for speed first
1012   return 1 if $x->{sign} eq '+' && $y->{sign} eq '-';   # does also 0 <=> -y
1013   return -1 if $x->{sign} eq '-' && $y->{sign} eq '+';  # does also -x <=> 0
1014
1015   # have same sign, so compare absolute values. Don't make tests for zero here
1016   # because it's actually slower than testin in Calc (especially w/ Pari et al)
1017
1018   # post-normalized compare for internal use (honors signs)
1019   if ($x->{sign} eq '+')
1020     {
1021     # $x and $y both > 0
1022     return $CALC->_acmp($x->{value},$y->{value});
1023     }
1024
1025   # $x && $y both < 0
1026   $CALC->_acmp($y->{value},$x->{value});        # swaped acmp (lib returns 0,1,-1)
1027   }
1028
1029 sub bacmp
1030   {
1031   # Compares 2 values, ignoring their signs.
1032   # Returns one of undef, <0, =0, >0. (suitable for sort)
1033   # (BINT, BINT) return cond_code
1034
1035   # set up parameters
1036   my ($self,$x,$y) = (ref($_[0]),@_);
1037   # objectify is costly, so avoid it
1038   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1039     {
1040     ($self,$x,$y) = objectify(2,@_);
1041     }
1042
1043   return $upgrade->bacmp($x,$y) if defined $upgrade &&
1044     ((!$x->isa($self)) || (!$y->isa($self)));
1045
1046   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1047     {
1048     # handle +-inf and NaN
1049     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1050     return 0 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} =~ /^[+-]inf$/;
1051     return 1 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} !~ /^[+-]inf$/;
1052     return -1;
1053     }
1054   $CALC->_acmp($x->{value},$y->{value});        # lib does only 0,1,-1
1055   }
1056
1057 sub badd
1058   {
1059   # add second arg (BINT or string) to first (BINT) (modifies first)
1060   # return result as BINT
1061
1062   # set up parameters
1063   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1064   # objectify is costly, so avoid it
1065   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1066     {
1067     ($self,$x,$y,@r) = objectify(2,@_);
1068     }
1069
1070   return $x if $x->modify('badd');
1071   return $upgrade->badd($upgrade->new($x),$upgrade->new($y),@r) if defined $upgrade &&
1072     ((!$x->isa($self)) || (!$y->isa($self)));
1073
1074   $r[3] = $y;                           # no push!
1075   # inf and NaN handling
1076   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1077     {
1078     # NaN first
1079     return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1080     # inf handling
1081     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1082       {
1083       # +inf++inf or -inf+-inf => same, rest is NaN
1084       return $x if $x->{sign} eq $y->{sign};
1085       return $x->bnan();
1086       }
1087     # +-inf + something => +inf
1088     # something +-inf => +-inf
1089     $x->{sign} = $y->{sign}, return $x if $y->{sign} =~ /^[+-]inf$/;
1090     return $x;
1091     }
1092
1093   my ($sx, $sy) = ( $x->{sign}, $y->{sign} );           # get signs
1094
1095   if ($sx eq $sy)
1096     {
1097     $x->{value} = $CALC->_add($x->{value},$y->{value}); # same sign, abs add
1098     }
1099   else
1100     {
1101     my $a = $CALC->_acmp ($y->{value},$x->{value});     # absolute compare
1102     if ($a > 0)
1103       {
1104       $x->{value} = $CALC->_sub($y->{value},$x->{value},1); # abs sub w/ swap
1105       $x->{sign} = $sy;
1106       }
1107     elsif ($a == 0)
1108       {
1109       # speedup, if equal, set result to 0
1110       $x->{value} = $CALC->_zero();
1111       $x->{sign} = '+';
1112       }
1113     else # a < 0
1114       {
1115       $x->{value} = $CALC->_sub($x->{value}, $y->{value}); # abs sub
1116       }
1117     }
1118   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1119   $x;
1120   }
1121
1122 sub bsub
1123   {
1124   # (BINT or num_str, BINT or num_str) return BINT
1125   # subtract second arg from first, modify first
1126
1127   # set up parameters
1128   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1129   # objectify is costly, so avoid it
1130   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1131     {
1132     ($self,$x,$y,@r) = objectify(2,@_);
1133     }
1134
1135   return $x if $x->modify('bsub');
1136
1137   return $upgrade->new($x)->bsub($upgrade->new($y),@r) if defined $upgrade &&
1138    ((!$x->isa($self)) || (!$y->isa($self)));
1139
1140   if ($y->is_zero())
1141     {
1142     $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1143     return $x;
1144     }
1145
1146   require Scalar::Util;
1147   if (Scalar::Util::refaddr($x) == Scalar::Util::refaddr($y))
1148     {
1149     # if we get the same variable twice, the result must be zero (the code
1150     # below fails in that case)
1151     return $x->bzero(@r) if $x->{sign} =~ /^[+-]$/;
1152     return $x->bnan();          # NaN, -inf, +inf
1153     }
1154   $y->{sign} =~ tr/+\-/-+/;     # does nothing for NaN
1155   $x->badd($y,@r);              # badd does not leave internal zeros
1156   $y->{sign} =~ tr/+\-/-+/;     # refix $y (does nothing for NaN)
1157   $x;                           # already rounded by badd() or no round necc.
1158   }
1159
1160 sub binc
1161   {
1162   # increment arg by one
1163   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1164   return $x if $x->modify('binc');
1165
1166   if ($x->{sign} eq '+')
1167     {
1168     $x->{value} = $CALC->_inc($x->{value});
1169     $x->round($a,$p,$r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1170     return $x;
1171     }
1172   elsif ($x->{sign} eq '-')
1173     {
1174     $x->{value} = $CALC->_dec($x->{value});
1175     $x->{sign} = '+' if $CALC->_is_zero($x->{value}); # -1 +1 => -0 => +0
1176     $x->round($a,$p,$r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1177     return $x;
1178     }
1179   # inf, nan handling etc
1180   $x->badd($self->bone(),$a,$p,$r);             # badd does round
1181   }
1182
1183 sub bdec
1184   {
1185   # decrement arg by one
1186   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1187   return $x if $x->modify('bdec');
1188
1189   if ($x->{sign} eq '-')
1190     {
1191     # < 0
1192     $x->{value} = $CALC->_inc($x->{value});
1193     }
1194   else
1195     {
1196     return $x->badd($self->bone('-'),@r) unless $x->{sign} eq '+'; # inf/NaN
1197     # >= 0
1198     if ($CALC->_is_zero($x->{value}))
1199       {
1200       # == 0
1201       $x->{value} = $CALC->_one(); $x->{sign} = '-';            # 0 => -1
1202       }
1203     else
1204       {
1205       # > 0
1206       $x->{value} = $CALC->_dec($x->{value});
1207       }
1208     }
1209   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1210   $x;
1211   }
1212
1213 sub blog
1214   {
1215   # calculate $x = $a ** $base + $b and return $a (e.g. the log() to base
1216   # $base of $x)
1217
1218   # set up parameters
1219   my ($self,$x,$base,@r) = (ref($_[0]),@_);
1220   # objectify is costly, so avoid it
1221   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1222     {
1223     ($self,$x,$base,@r) = objectify(1,$class,@_);
1224     }
1225
1226   return $x if $x->modify('blog');
1227
1228   # inf, -inf, NaN, <0 => NaN
1229   return $x->bnan()
1230    if $x->{sign} ne '+' || (defined $base && $base->{sign} ne '+');
1231
1232   return $upgrade->blog($upgrade->new($x),$base,@r) if
1233     defined $upgrade;
1234
1235   my ($rc,$exact) = $CALC->_log_int($x->{value},$base->{value});
1236   return $x->bnan() unless defined $rc;         # not possible to take log?
1237   $x->{value} = $rc;
1238   $x->round(@r);
1239   }
1240
1241 sub blcm
1242   {
1243   # (BINT or num_str, BINT or num_str) return BINT
1244   # does not modify arguments, but returns new object
1245   # Lowest Common Multiplicator
1246
1247   my $y = shift; my ($x);
1248   if (ref($y))
1249     {
1250     $x = $y->copy();
1251     }
1252   else
1253     {
1254     $x = __PACKAGE__->new($y);
1255     }
1256   my $self = ref($x);
1257   while (@_)
1258     {
1259     my $y = shift; $y = $self->new($y) if !ref ($y);
1260     $x = __lcm($x,$y);
1261     }
1262   $x;
1263   }
1264
1265 sub bgcd
1266   {
1267   # (BINT or num_str, BINT or num_str) return BINT
1268   # does not modify arguments, but returns new object
1269   # GCD -- Euclids algorithm, variant C (Knuth Vol 3, pg 341 ff)
1270
1271   my $y = shift;
1272   $y = __PACKAGE__->new($y) if !ref($y);
1273   my $self = ref($y);
1274   my $x = $y->copy()->babs();                   # keep arguments
1275   return $x->bnan() if $x->{sign} !~ /^[+-]$/;  # x NaN?
1276
1277   while (@_)
1278     {
1279     $y = shift; $y = $self->new($y) if !ref($y);
1280     next if $y->is_zero();
1281     return $x->bnan() if $y->{sign} !~ /^[+-]$/;        # y NaN?
1282     $x->{value} = $CALC->_gcd($x->{value},$y->{value}); last if $x->is_one();
1283     }
1284   $x;
1285   }
1286
1287 sub bnot
1288   {
1289   # (num_str or BINT) return BINT
1290   # represent ~x as twos-complement number
1291   # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1292   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1293
1294   return $x if $x->modify('bnot');
1295   $x->binc()->bneg();                   # binc already does round
1296   }
1297
1298 ##############################################################################
1299 # is_foo test routines
1300 # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1301
1302 sub is_zero
1303   {
1304   # return true if arg (BINT or num_str) is zero (array '+', '0')
1305   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1306
1307   return 0 if $x->{sign} !~ /^\+$/;                     # -, NaN & +-inf aren't
1308   $CALC->_is_zero($x->{value});
1309   }
1310
1311 sub is_nan
1312   {
1313   # return true if arg (BINT or num_str) is NaN
1314   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1315
1316   $x->{sign} eq $nan ? 1 : 0;
1317   }
1318
1319 sub is_inf
1320   {
1321   # return true if arg (BINT or num_str) is +-inf
1322   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1323
1324   if (defined $sign)
1325     {
1326     $sign = '[+-]inf' if $sign eq '';   # +- doesn't matter, only that's inf
1327     $sign = "[$1]inf" if $sign =~ /^([+-])(inf)?$/;     # extract '+' or '-'
1328     return $x->{sign} =~ /^$sign$/ ? 1 : 0;
1329     }
1330   $x->{sign} =~ /^[+-]inf$/ ? 1 : 0;            # only +-inf is infinity
1331   }
1332
1333 sub is_one
1334   {
1335   # return true if arg (BINT or num_str) is +1, or -1 if sign is given
1336   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1337
1338   $sign = '+' if !defined $sign || $sign ne '-';
1339
1340   return 0 if $x->{sign} ne $sign;      # -1 != +1, NaN, +-inf aren't either
1341   $CALC->_is_one($x->{value});
1342   }
1343
1344 sub is_odd
1345   {
1346   # return true when arg (BINT or num_str) is odd, false for even
1347   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1348
1349   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1350   $CALC->_is_odd($x->{value});
1351   }
1352
1353 sub is_even
1354   {
1355   # return true when arg (BINT or num_str) is even, false for odd
1356   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1357
1358   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1359   $CALC->_is_even($x->{value});
1360   }
1361
1362 sub is_positive
1363   {
1364   # return true when arg (BINT or num_str) is positive (>= 0)
1365   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1366
1367   $x->{sign} =~ /^\+/ ? 1 : 0;          # +inf is also positive, but NaN not
1368   }
1369
1370 sub is_negative
1371   {
1372   # return true when arg (BINT or num_str) is negative (< 0)
1373   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1374
1375   $x->{sign} =~ /^-/ ? 1 : 0;           # -inf is also negative, but NaN not
1376   }
1377
1378 sub is_int
1379   {
1380   # return true when arg (BINT or num_str) is an integer
1381   # always true for BigInt, but different for BigFloats
1382   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1383
1384   $x->{sign} =~ /^[+-]$/ ? 1 : 0;               # inf/-inf/NaN aren't
1385   }
1386
1387 ###############################################################################
1388
1389 sub bmul
1390   {
1391   # multiply two numbers -- stolen from Knuth Vol 2 pg 233
1392   # (BINT or num_str, BINT or num_str) return BINT
1393
1394   # set up parameters
1395   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1396   # objectify is costly, so avoid it
1397   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1398     {
1399     ($self,$x,$y,@r) = objectify(2,@_);
1400     }
1401
1402   return $x if $x->modify('bmul');
1403
1404   return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1405
1406   # inf handling
1407   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1408     {
1409     return $x->bnan() if $x->is_zero() || $y->is_zero();
1410     # result will always be +-inf:
1411     # +inf * +/+inf => +inf, -inf * -/-inf => +inf
1412     # +inf * -/-inf => -inf, -inf * +/+inf => -inf
1413     return $x->binf() if ($x->{sign} =~ /^\+/ && $y->{sign} =~ /^\+/);
1414     return $x->binf() if ($x->{sign} =~ /^-/ && $y->{sign} =~ /^-/);
1415     return $x->binf('-');
1416     }
1417
1418   return $upgrade->bmul($x,$upgrade->new($y),@r)
1419    if defined $upgrade && !$y->isa($self);
1420
1421   $r[3] = $y;                           # no push here
1422
1423   $x->{sign} = $x->{sign} eq $y->{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 => +
1424
1425   $x->{value} = $CALC->_mul($x->{value},$y->{value});   # do actual math
1426   $x->{sign} = '+' if $CALC->_is_zero($x->{value});     # no -0
1427
1428   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1429   $x;
1430   }
1431
1432 sub _div_inf
1433   {
1434   # helper function that handles +-inf cases for bdiv()/bmod() to reuse code
1435   my ($self,$x,$y) = @_;
1436
1437   # NaN if x == NaN or y == NaN or x==y==0
1438   return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan()
1439    if (($x->is_nan() || $y->is_nan())   ||
1440        ($x->is_zero() && $y->is_zero()));
1441
1442   # +-inf / +-inf == NaN, reminder also NaN
1443   if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1444     {
1445     return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan();
1446     }
1447   # x / +-inf => 0, remainder x (works even if x == 0)
1448   if ($y->{sign} =~ /^[+-]inf$/)
1449     {
1450     my $t = $x->copy();         # bzero clobbers up $x
1451     return wantarray ? ($x->bzero(),$t) : $x->bzero()
1452     }
1453
1454   # 5 / 0 => +inf, -6 / 0 => -inf
1455   # +inf / 0 = inf, inf,  and -inf / 0 => -inf, -inf
1456   # exception:   -8 / 0 has remainder -8, not 8
1457   # exception: -inf / 0 has remainder -inf, not inf
1458   if ($y->is_zero())
1459     {
1460     # +-inf / 0 => special case for -inf
1461     return wantarray ?  ($x,$x->copy()) : $x if $x->is_inf();
1462     if (!$x->is_zero() && !$x->is_inf())
1463       {
1464       my $t = $x->copy();               # binf clobbers up $x
1465       return wantarray ?
1466        ($x->binf($x->{sign}),$t) : $x->binf($x->{sign})
1467       }
1468     }
1469
1470   # last case: +-inf / ordinary number
1471   my $sign = '+inf';
1472   $sign = '-inf' if substr($x->{sign},0,1) ne $y->{sign};
1473   $x->{sign} = $sign;
1474   return wantarray ? ($x,$self->bzero()) : $x;
1475   }
1476
1477 sub bdiv
1478   {
1479   # (dividend: BINT or num_str, divisor: BINT or num_str) return
1480   # (BINT,BINT) (quo,rem) or BINT (only rem)
1481
1482   # set up parameters
1483   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1484   # objectify is costly, so avoid it
1485   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1486     {
1487     ($self,$x,$y,@r) = objectify(2,@_);
1488     }
1489
1490   return $x if $x->modify('bdiv');
1491
1492   return $self->_div_inf($x,$y)
1493    if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero());
1494
1495   return $upgrade->bdiv($upgrade->new($x),$upgrade->new($y),@r)
1496    if defined $upgrade;
1497
1498   $r[3] = $y;                                   # no push!
1499
1500   # calc new sign and in case $y == +/- 1, return $x
1501   my $xsign = $x->{sign};                               # keep
1502   $x->{sign} = ($x->{sign} ne $y->{sign} ? '-' : '+');
1503
1504   if (wantarray)
1505     {
1506     my $rem = $self->bzero();
1507     ($x->{value},$rem->{value}) = $CALC->_div($x->{value},$y->{value});
1508     $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1509     $rem->{_a} = $x->{_a};
1510     $rem->{_p} = $x->{_p};
1511     $x->round(@r) if !exists $x->{_f} || ($x->{_f} & MB_NEVER_ROUND) == 0;
1512     if (! $CALC->_is_zero($rem->{value}))
1513       {
1514       $rem->{sign} = $y->{sign};
1515       $rem = $y->copy()->bsub($rem) if $xsign ne $y->{sign}; # one of them '-'
1516       }
1517     else
1518       {
1519       $rem->{sign} = '+';                       # dont leave -0
1520       }
1521     $rem->round(@r) if !exists $rem->{_f} || ($rem->{_f} & MB_NEVER_ROUND) == 0;
1522     return ($x,$rem);
1523     }
1524
1525   $x->{value} = $CALC->_div($x->{value},$y->{value});
1526   $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1527
1528   $x->round(@r) if !exists $x->{_f} || ($x->{_f} & MB_NEVER_ROUND) == 0;
1529   $x;
1530   }
1531
1532 ###############################################################################
1533 # modulus functions
1534
1535 sub bmod
1536   {
1537   # modulus (or remainder)
1538   # (BINT or num_str, BINT or num_str) return BINT
1539
1540   # set up parameters
1541   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1542   # objectify is costly, so avoid it
1543   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1544     {
1545     ($self,$x,$y,@r) = objectify(2,@_);
1546     }
1547
1548   return $x if $x->modify('bmod');
1549   $r[3] = $y;                                   # no push!
1550   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero())
1551     {
1552     my ($d,$r) = $self->_div_inf($x,$y);
1553     $x->{sign} = $r->{sign};
1554     $x->{value} = $r->{value};
1555     return $x->round(@r);
1556     }
1557
1558   # calc new sign and in case $y == +/- 1, return $x
1559   $x->{value} = $CALC->_mod($x->{value},$y->{value});
1560   if (!$CALC->_is_zero($x->{value}))
1561     {
1562     my $xsign = $x->{sign};
1563     $x->{sign} = $y->{sign};
1564     if ($xsign ne $y->{sign})
1565       {
1566       my $t = $CALC->_copy($x->{value});                # copy $x
1567       $x->{value} = $CALC->_sub($y->{value},$t,1);      # $y-$x
1568       }
1569     }
1570    else
1571     {
1572     $x->{sign} = '+';                           # dont leave -0
1573     }
1574   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1575   $x;
1576   }
1577
1578 sub bmodinv
1579   {
1580   # Modular inverse.  given a number which is (hopefully) relatively
1581   # prime to the modulus, calculate its inverse using Euclid's
1582   # alogrithm.  If the number is not relatively prime to the modulus
1583   # (i.e. their gcd is not one) then NaN is returned.
1584
1585   # set up parameters
1586   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1587   # objectify is costly, so avoid it
1588   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1589     {
1590     ($self,$x,$y,@r) = objectify(2,@_);
1591     }
1592
1593   return $x if $x->modify('bmodinv');
1594
1595   return $x->bnan()
1596         if ($y->{sign} ne '+'                           # -, NaN, +inf, -inf
1597          || $x->is_zero()                               # or num == 0
1598          || $x->{sign} !~ /^[+-]$/                      # or num NaN, inf, -inf
1599         );
1600
1601   # put least residue into $x if $x was negative, and thus make it positive
1602   $x->bmod($y) if $x->{sign} eq '-';
1603
1604   my $sign;
1605   ($x->{value},$sign) = $CALC->_modinv($x->{value},$y->{value});
1606   return $x->bnan() if !defined $x->{value};            # in case no GCD found
1607   return $x if !defined $sign;                  # already real result
1608   $x->{sign} = $sign;                           # flip/flop see below
1609   $x->bmod($y);                                 # calc real result
1610   $x;
1611   }
1612
1613 sub bmodpow
1614   {
1615   # takes a very large number to a very large exponent in a given very
1616   # large modulus, quickly, thanks to binary exponentation.  supports
1617   # negative exponents.
1618   my ($self,$num,$exp,$mod,@r) = objectify(3,@_);
1619
1620   return $num if $num->modify('bmodpow');
1621
1622   # check modulus for valid values
1623   return $num->bnan() if ($mod->{sign} ne '+'           # NaN, - , -inf, +inf
1624                        || $mod->is_zero());
1625
1626   # check exponent for valid values
1627   if ($exp->{sign} =~ /\w/)
1628     {
1629     # i.e., if it's NaN, +inf, or -inf...
1630     return $num->bnan();
1631     }
1632
1633   $num->bmodinv ($mod) if ($exp->{sign} eq '-');
1634
1635   # check num for valid values (also NaN if there was no inverse but $exp < 0)
1636   return $num->bnan() if $num->{sign} !~ /^[+-]$/;
1637
1638   # $mod is positive, sign on $exp is ignored, result also positive
1639   $num->{value} = $CALC->_modpow($num->{value},$exp->{value},$mod->{value});
1640   $num;
1641   }
1642
1643 ###############################################################################
1644
1645 sub bfac
1646   {
1647   # (BINT or num_str, BINT or num_str) return BINT
1648   # compute factorial number from $x, modify $x in place
1649   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1650
1651   return $x if $x->modify('bfac');
1652
1653   return $x if $x->{sign} eq '+inf';            # inf => inf
1654   return $x->bnan() if $x->{sign} ne '+';       # NaN, <0 etc => NaN
1655
1656   $x->{value} = $CALC->_fac($x->{value});
1657   $x->round(@r);
1658   }
1659
1660 sub bpow
1661   {
1662   # (BINT or num_str, BINT or num_str) return BINT
1663   # compute power of two numbers -- stolen from Knuth Vol 2 pg 233
1664   # modifies first argument
1665
1666   # set up parameters
1667   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1668   # objectify is costly, so avoid it
1669   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1670     {
1671     ($self,$x,$y,@r) = objectify(2,@_);
1672     }
1673
1674   return $x if $x->modify('bpow');
1675
1676   return $x->bnan() if $x->{sign} eq $nan || $y->{sign} eq $nan;
1677
1678   # inf handling
1679   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1680     {
1681     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1682       {
1683       # +-inf ** +-inf
1684       return $x->bnan();
1685       }
1686     # +-inf ** Y
1687     if ($x->{sign} =~ /^[+-]inf/)
1688       {
1689       # +inf ** 0 => NaN
1690       return $x->bnan() if $y->is_zero();
1691       # -inf ** -1 => 1/inf => 0
1692       return $x->bzero() if $y->is_one('-') && $x->is_negative();
1693
1694       # +inf ** Y => inf
1695       return $x if $x->{sign} eq '+inf';
1696
1697       # -inf ** Y => -inf if Y is odd
1698       return $x if $y->is_odd();
1699       return $x->babs();
1700       }
1701     # X ** +-inf
1702
1703     # 1 ** +inf => 1
1704     return $x if $x->is_one();
1705
1706     # 0 ** inf => 0
1707     return $x if $x->is_zero() && $y->{sign} =~ /^[+]/;
1708
1709     # 0 ** -inf => inf
1710     return $x->binf() if $x->is_zero();
1711
1712     # -1 ** -inf => NaN
1713     return $x->bnan() if $x->is_one('-') && $y->{sign} =~ /^[-]/;
1714
1715     # -X ** -inf => 0
1716     return $x->bzero() if $x->{sign} eq '-' && $y->{sign} =~ /^[-]/;
1717
1718     # -1 ** inf => NaN
1719     return $x->bnan() if $x->{sign} eq '-';
1720
1721     # X ** inf => inf
1722     return $x->binf() if $y->{sign} =~ /^[+]/;
1723     # X ** -inf => 0
1724     return $x->bzero();
1725     }
1726
1727   return $upgrade->bpow($upgrade->new($x),$y,@r)
1728    if defined $upgrade && !$y->isa($self);
1729
1730   $r[3] = $y;                                   # no push!
1731
1732   # cases 0 ** Y, X ** 0, X ** 1, 1 ** Y are handled by Calc or Emu
1733
1734   my $new_sign = '+';
1735   $new_sign = $y->is_odd() ? '-' : '+' if ($x->{sign} ne '+');
1736
1737   # 0 ** -7 => ( 1 / (0 ** 7)) => 1 / 0 => +inf
1738   return $x->binf()
1739     if $y->{sign} eq '-' && $x->{sign} eq '+' && $CALC->_is_zero($x->{value});
1740   # 1 ** -y => 1 / (1 ** |y|)
1741   # so do test for negative $y after above's clause
1742   return $x->bnan() if $y->{sign} eq '-' && !$CALC->_is_one($x->{value});
1743
1744   $x->{value} = $CALC->_pow($x->{value},$y->{value});
1745   $x->{sign} = $new_sign;
1746   $x->{sign} = '+' if $CALC->_is_zero($y->{value});
1747   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1748   $x;
1749   }
1750
1751 sub blsft
1752   {
1753   # (BINT or num_str, BINT or num_str) return BINT
1754   # compute x << y, base n, y >= 0
1755
1756   # set up parameters
1757   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1758   # objectify is costly, so avoid it
1759   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1760     {
1761     ($self,$x,$y,$n,@r) = objectify(2,@_);
1762     }
1763
1764   return $x if $x->modify('blsft');
1765   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1766   return $x->round(@r) if $y->is_zero();
1767
1768   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1769
1770   $x->{value} = $CALC->_lsft($x->{value},$y->{value},$n);
1771   $x->round(@r);
1772   }
1773
1774 sub brsft
1775   {
1776   # (BINT or num_str, BINT or num_str) return BINT
1777   # compute x >> y, base n, y >= 0
1778
1779   # set up parameters
1780   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1781   # objectify is costly, so avoid it
1782   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1783     {
1784     ($self,$x,$y,$n,@r) = objectify(2,@_);
1785     }
1786
1787   return $x if $x->modify('brsft');
1788   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1789   return $x->round(@r) if $y->is_zero();
1790   return $x->bzero(@r) if $x->is_zero();                # 0 => 0
1791
1792   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1793
1794    # this only works for negative numbers when shifting in base 2
1795   if (($x->{sign} eq '-') && ($n == 2))
1796     {
1797     return $x->round(@r) if $x->is_one('-');    # -1 => -1
1798     if (!$y->is_one())
1799       {
1800       # although this is O(N*N) in calc (as_bin!) it is O(N) in Pari et al
1801       # but perhaps there is a better emulation for two's complement shift...
1802       # if $y != 1, we must simulate it by doing:
1803       # convert to bin, flip all bits, shift, and be done
1804       $x->binc();                       # -3 => -2
1805       my $bin = $x->as_bin();
1806       $bin =~ s/^-0b//;                 # strip '-0b' prefix
1807       $bin =~ tr/10/01/;                # flip bits
1808       # now shift
1809       if (CORE::length($bin) <= $y)
1810         {
1811         $bin = '0';                     # shifting to far right creates -1
1812                                         # 0, because later increment makes
1813                                         # that 1, attached '-' makes it '-1'
1814                                         # because -1 >> x == -1 !
1815         }
1816       else
1817         {
1818         $bin =~ s/.{$y}$//;             # cut off at the right side
1819         $bin = '1' . $bin;              # extend left side by one dummy '1'
1820         $bin =~ tr/10/01/;              # flip bits back
1821         }
1822       my $res = $self->new('0b'.$bin);  # add prefix and convert back
1823       $res->binc();                     # remember to increment
1824       $x->{value} = $res->{value};      # take over value
1825       return $x->round(@r);             # we are done now, magic, isn't?
1826       }
1827     # x < 0, n == 2, y == 1
1828     $x->bdec();                         # n == 2, but $y == 1: this fixes it
1829     }
1830
1831   $x->{value} = $CALC->_rsft($x->{value},$y->{value},$n);
1832   $x->round(@r);
1833   }
1834
1835 sub band
1836   {
1837   #(BINT or num_str, BINT or num_str) return BINT
1838   # compute x & y
1839
1840   # set up parameters
1841   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1842   # objectify is costly, so avoid it
1843   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1844     {
1845     ($self,$x,$y,@r) = objectify(2,@_);
1846     }
1847
1848   return $x if $x->modify('band');
1849
1850   $r[3] = $y;                           # no push!
1851
1852   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1853
1854   my $sx = $x->{sign} eq '+' ? 1 : -1;
1855   my $sy = $y->{sign} eq '+' ? 1 : -1;
1856
1857   if ($sx == 1 && $sy == 1)
1858     {
1859     $x->{value} = $CALC->_and($x->{value},$y->{value});
1860     return $x->round(@r);
1861     }
1862
1863   if ($CAN{signed_and})
1864     {
1865     $x->{value} = $CALC->_signed_and($x->{value},$y->{value},$sx,$sy);
1866     return $x->round(@r);
1867     }
1868
1869   require $EMU_LIB;
1870   __emu_band($self,$x,$y,$sx,$sy,@r);
1871   }
1872
1873 sub bior
1874   {
1875   #(BINT or num_str, BINT or num_str) return BINT
1876   # compute x | y
1877
1878   # set up parameters
1879   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1880   # objectify is costly, so avoid it
1881   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1882     {
1883     ($self,$x,$y,@r) = objectify(2,@_);
1884     }
1885
1886   return $x if $x->modify('bior');
1887   $r[3] = $y;                           # no push!
1888
1889   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1890
1891   my $sx = $x->{sign} eq '+' ? 1 : -1;
1892   my $sy = $y->{sign} eq '+' ? 1 : -1;
1893
1894   # the sign of X follows the sign of X, e.g. sign of Y irrelevant for bior()
1895
1896   # don't use lib for negative values
1897   if ($sx == 1 && $sy == 1)
1898     {
1899     $x->{value} = $CALC->_or($x->{value},$y->{value});
1900     return $x->round(@r);
1901     }
1902
1903   # if lib can do negative values, let it handle this
1904   if ($CAN{signed_or})
1905     {
1906     $x->{value} = $CALC->_signed_or($x->{value},$y->{value},$sx,$sy);
1907     return $x->round(@r);
1908     }
1909
1910   require $EMU_LIB;
1911   __emu_bior($self,$x,$y,$sx,$sy,@r);
1912   }
1913
1914 sub bxor
1915   {
1916   #(BINT or num_str, BINT or num_str) return BINT
1917   # compute x ^ y
1918
1919   # set up parameters
1920   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1921   # objectify is costly, so avoid it
1922   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1923     {
1924     ($self,$x,$y,@r) = objectify(2,@_);
1925     }
1926
1927   return $x if $x->modify('bxor');
1928   $r[3] = $y;                           # no push!
1929
1930   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1931
1932   my $sx = $x->{sign} eq '+' ? 1 : -1;
1933   my $sy = $y->{sign} eq '+' ? 1 : -1;
1934
1935   # don't use lib for negative values
1936   if ($sx == 1 && $sy == 1)
1937     {
1938     $x->{value} = $CALC->_xor($x->{value},$y->{value});
1939     return $x->round(@r);
1940     }
1941
1942   # if lib can do negative values, let it handle this
1943   if ($CAN{signed_xor})
1944     {
1945     $x->{value} = $CALC->_signed_xor($x->{value},$y->{value},$sx,$sy);
1946     return $x->round(@r);
1947     }
1948
1949   require $EMU_LIB;
1950   __emu_bxor($self,$x,$y,$sx,$sy,@r);
1951   }
1952
1953 sub length
1954   {
1955   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1956
1957   my $e = $CALC->_len($x->{value});
1958   wantarray ? ($e,0) : $e;
1959   }
1960
1961 sub digit
1962   {
1963   # return the nth decimal digit, negative values count backward, 0 is right
1964   my ($self,$x,$n) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1965
1966   $n = $n->numify() if ref($n);
1967   $CALC->_digit($x->{value},$n||0);
1968   }
1969
1970 sub _trailing_zeros
1971   {
1972   # return the amount of trailing zeros in $x (as scalar)
1973   my $x = shift;
1974   $x = $class->new($x) unless ref $x;
1975
1976   return 0 if $x->{sign} !~ /^[+-]$/;   # NaN, inf, -inf etc
1977
1978   $CALC->_zeros($x->{value});           # must handle odd values, 0 etc
1979   }
1980
1981 sub bsqrt
1982   {
1983   # calculate square root of $x
1984   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1985
1986   return $x if $x->modify('bsqrt');
1987
1988   return $x->bnan() if $x->{sign} !~ /^\+/;     # -x or -inf or NaN => NaN
1989   return $x if $x->{sign} eq '+inf';            # sqrt(+inf) == inf
1990
1991   return $upgrade->bsqrt($x,@r) if defined $upgrade;
1992
1993   $x->{value} = $CALC->_sqrt($x->{value});
1994   $x->round(@r);
1995   }
1996
1997 sub broot
1998   {
1999   # calculate $y'th root of $x
2000
2001   # set up parameters
2002   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2003
2004   $y = $self->new(2) unless defined $y;
2005
2006   # objectify is costly, so avoid it
2007   if ((!ref($x)) || (ref($x) ne ref($y)))
2008     {
2009     ($self,$x,$y,@r) = objectify(2,$self || $class,@_);
2010     }
2011
2012   return $x if $x->modify('broot');
2013
2014   # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
2015   return $x->bnan() if $x->{sign} !~ /^\+/ || $y->is_zero() ||
2016          $y->{sign} !~ /^\+$/;
2017
2018   return $x->round(@r)
2019     if $x->is_zero() || $x->is_one() || $x->is_inf() || $y->is_one();
2020
2021   return $upgrade->new($x)->broot($upgrade->new($y),@r) if defined $upgrade;
2022
2023   $x->{value} = $CALC->_root($x->{value},$y->{value});
2024   $x->round(@r);
2025   }
2026
2027 sub exponent
2028   {
2029   # return a copy of the exponent (here always 0, NaN or 1 for $m == 0)
2030   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2031
2032   if ($x->{sign} !~ /^[+-]$/)
2033     {
2034     my $s = $x->{sign}; $s =~ s/^[+-]//;  # NaN, -inf,+inf => NaN or inf
2035     return $self->new($s);
2036     }
2037   return $self->bone() if $x->is_zero();
2038
2039   $self->new($x->_trailing_zeros());
2040   }
2041
2042 sub mantissa
2043   {
2044   # return the mantissa (compatible to Math::BigFloat, e.g. reduced)
2045   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2046
2047   if ($x->{sign} !~ /^[+-]$/)
2048     {
2049     # for NaN, +inf, -inf: keep the sign
2050     return $self->new($x->{sign});
2051     }
2052   my $m = $x->copy(); delete $m->{_p}; delete $m->{_a};
2053   # that's a bit inefficient:
2054   my $zeros = $m->_trailing_zeros();
2055   $m->brsft($zeros,10) if $zeros != 0;
2056   $m;
2057   }
2058
2059 sub parts
2060   {
2061   # return a copy of both the exponent and the mantissa
2062   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2063
2064   ($x->mantissa(),$x->exponent());
2065   }
2066
2067 ##############################################################################
2068 # rounding functions
2069
2070 sub bfround
2071   {
2072   # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
2073   # $n == 0 || $n == 1 => round to integer
2074   my $x = shift; my $self = ref($x) || $x; $x = $self->new($x) unless ref $x;
2075
2076   my ($scale,$mode) = $x->_scale_p($x->precision(),$x->round_mode(),@_);
2077
2078   return $x if !defined $scale || $x->modify('bfround');        # no-op
2079
2080   # no-op for BigInts if $n <= 0
2081   $x->bround( $x->length()-$scale, $mode) if $scale > 0;
2082
2083   delete $x->{_a};      # delete to save memory
2084   $x->{_p} = $scale;    # store new _p
2085   $x;
2086   }
2087
2088 sub _scan_for_nonzero
2089   {
2090   # internal, used by bround() to scan for non-zeros after a '5'
2091   my ($x,$pad,$xs,$len) = @_;
2092
2093   return 0 if $len == 1;                # "5" is trailed by invisible zeros
2094   my $follow = $pad - 1;
2095   return 0 if $follow > $len || $follow < 1;
2096
2097   # use the string form to check whether only '0's follow or not
2098   substr ($xs,-$follow) =~ /[^0]/ ? 1 : 0;
2099   }
2100
2101 sub fround
2102   {
2103   # Exists to make life easier for switch between MBF and MBI (should we
2104   # autoload fxxx() like MBF does for bxxx()?)
2105   my $x = shift;
2106   $x->bround(@_);
2107   }
2108
2109 sub bround
2110   {
2111   # accuracy: +$n preserve $n digits from left,
2112   #           -$n preserve $n digits from right (f.i. for 0.1234 style in MBF)
2113   # no-op for $n == 0
2114   # and overwrite the rest with 0's, return normalized number
2115   # do not return $x->bnorm(), but $x
2116
2117   my $x = shift; $x = $class->new($x) unless ref $x;
2118   my ($scale,$mode) = $x->_scale_a($x->accuracy(),$x->round_mode(),@_);
2119   return $x if !defined $scale;                 # no-op
2120   return $x if $x->modify('bround');
2121
2122   if ($x->is_zero() || $scale == 0)
2123     {
2124     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2125     return $x;
2126     }
2127   return $x if $x->{sign} !~ /^[+-]$/;          # inf, NaN
2128
2129   # we have fewer digits than we want to scale to
2130   my $len = $x->length();
2131   # convert $scale to a scalar in case it is an object (put's a limit on the
2132   # number length, but this would already limited by memory constraints), makes
2133   # it faster
2134   $scale = $scale->numify() if ref ($scale);
2135
2136   # scale < 0, but > -len (not >=!)
2137   if (($scale < 0 && $scale < -$len-1) || ($scale >= $len))
2138     {
2139     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2140     return $x;
2141     }
2142
2143   # count of 0's to pad, from left (+) or right (-): 9 - +6 => 3, or |-6| => 6
2144   my ($pad,$digit_round,$digit_after);
2145   $pad = $len - $scale;
2146   $pad = abs($scale-1) if $scale < 0;
2147
2148   # do not use digit(), it is very costly for binary => decimal
2149   # getting the entire string is also costly, but we need to do it only once
2150   my $xs = $CALC->_str($x->{value});
2151   my $pl = -$pad-1;
2152
2153   # pad:   123: 0 => -1, at 1 => -2, at 2 => -3, at 3 => -4
2154   # pad+1: 123: 0 => 0,  at 1 => -1, at 2 => -2, at 3 => -3
2155   $digit_round = '0'; $digit_round = substr($xs,$pl,1) if $pad <= $len;
2156   $pl++; $pl ++ if $pad >= $len;
2157   $digit_after = '0'; $digit_after = substr($xs,$pl,1) if $pad > 0;
2158
2159   # in case of 01234 we round down, for 6789 up, and only in case 5 we look
2160   # closer at the remaining digits of the original $x, remember decision
2161   my $round_up = 1;                                     # default round up
2162   $round_up -- if
2163     ($mode eq 'trunc')                          ||      # trunc by round down
2164     ($digit_after =~ /[01234]/)                 ||      # round down anyway,
2165                                                         # 6789 => round up
2166     ($digit_after eq '5')                       &&      # not 5000...0000
2167     ($x->_scan_for_nonzero($pad,$xs,$len) == 0)         &&
2168     (
2169      ($mode eq 'even') && ($digit_round =~ /[24680]/) ||
2170      ($mode eq 'odd')  && ($digit_round =~ /[13579]/) ||
2171      ($mode eq '+inf') && ($x->{sign} eq '-')   ||
2172      ($mode eq '-inf') && ($x->{sign} eq '+')   ||
2173      ($mode eq 'zero')          # round down if zero, sign adjusted below
2174     );
2175   my $put_back = 0;                                     # not yet modified
2176
2177   if (($pad > 0) && ($pad <= $len))
2178     {
2179     substr($xs,-$pad,$pad) = '0' x $pad;                # replace with '00...'
2180     $put_back = 1;                                      # need to put back
2181     }
2182   elsif ($pad > $len)
2183     {
2184     $x->bzero();                                        # round to '0'
2185     }
2186
2187   if ($round_up)                                        # what gave test above?
2188     {
2189     $put_back = 1;                                      # need to put back
2190     $pad = $len, $xs = '0' x $pad if $scale < 0;        # tlr: whack 0.51=>1.0
2191
2192     # we modify directly the string variant instead of creating a number and
2193     # adding it, since that is faster (we already have the string)
2194     my $c = 0; $pad ++;                         # for $pad == $len case
2195     while ($pad <= $len)
2196       {
2197       $c = substr($xs,-$pad,1) + 1; $c = '0' if $c eq '10';
2198       substr($xs,-$pad,1) = $c; $pad++;
2199       last if $c != 0;                          # no overflow => early out
2200       }
2201     $xs = '1'.$xs if $c == 0;
2202
2203     }
2204   $x->{value} = $CALC->_new($xs) if $put_back == 1;     # put back, if needed
2205
2206   $x->{_a} = $scale if $scale >= 0;
2207   if ($scale < 0)
2208     {
2209     $x->{_a} = $len+$scale;
2210     $x->{_a} = 0 if $scale < -$len;
2211     }
2212   $x;
2213   }
2214
2215 sub bfloor
2216   {
2217   # return integer less or equal then number; no-op since it's already integer
2218   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2219
2220   $x->round(@r);
2221   }
2222
2223 sub bceil
2224   {
2225   # return integer greater or equal then number; no-op since it's already int
2226   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2227
2228   $x->round(@r);
2229   }
2230
2231 sub as_number
2232   {
2233   # An object might be asked to return itself as bigint on certain overloaded
2234   # operations, this does exactly this, so that sub classes can simple inherit
2235   # it or override with their own integer conversion routine.
2236   $_[0]->copy();
2237   }
2238
2239 sub as_hex
2240   {
2241   # return as hex string, with prefixed 0x
2242   my $x = shift; $x = $class->new($x) if !ref($x);
2243
2244   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2245
2246   my $s = '';
2247   $s = $x->{sign} if $x->{sign} eq '-';
2248   $s . $CALC->_as_hex($x->{value});
2249   }
2250
2251 sub as_bin
2252   {
2253   # return as binary string, with prefixed 0b
2254   my $x = shift; $x = $class->new($x) if !ref($x);
2255
2256   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2257
2258   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2259   return $s . $CALC->_as_bin($x->{value});
2260   }
2261
2262 ##############################################################################
2263 # private stuff (internal use only)
2264
2265 sub objectify
2266   {
2267   # check for strings, if yes, return objects instead
2268
2269   # the first argument is number of args objectify() should look at it will
2270   # return $count+1 elements, the first will be a classname. This is because
2271   # overloaded '""' calls bstr($object,undef,undef) and this would result in
2272   # useless objects beeing created and thrown away. So we cannot simple loop
2273   # over @_. If the given count is 0, all arguments will be used.
2274
2275   # If the second arg is a ref, use it as class.
2276   # If not, try to use it as classname, unless undef, then use $class
2277   # (aka Math::BigInt). The latter shouldn't happen,though.
2278
2279   # caller:                        gives us:
2280   # $x->badd(1);                => ref x, scalar y
2281   # Class->badd(1,2);           => classname x (scalar), scalar x, scalar y
2282   # Class->badd( Class->(1),2); => classname x (scalar), ref x, scalar y
2283   # Math::BigInt::badd(1,2);    => scalar x, scalar y
2284   # In the last case we check number of arguments to turn it silently into
2285   # $class,1,2. (We can not take '1' as class ;o)
2286   # badd($class,1) is not supported (it should, eventually, try to add undef)
2287   # currently it tries 'Math::BigInt' + 1, which will not work.
2288
2289   # some shortcut for the common cases
2290   # $x->unary_op();
2291   return (ref($_[1]),$_[1]) if (@_ == 2) && ($_[0]||0 == 1) && ref($_[1]);
2292
2293   my $count = abs(shift || 0);
2294
2295   my (@a,$k,$d);                # resulting array, temp, and downgrade
2296   if (ref $_[0])
2297     {
2298     # okay, got object as first
2299     $a[0] = ref $_[0];
2300     }
2301   else
2302     {
2303     # nope, got 1,2 (Class->xxx(1) => Class,1 and not supported)
2304     $a[0] = $class;
2305     $a[0] = shift if $_[0] =~ /^[A-Z].*::/;     # classname as first?
2306     }
2307
2308   no strict 'refs';
2309   # disable downgrading, because Math::BigFLoat->foo('1.0','2.0') needs floats
2310   if (defined ${"$a[0]::downgrade"})
2311     {
2312     $d = ${"$a[0]::downgrade"};
2313     ${"$a[0]::downgrade"} = undef;
2314     }
2315
2316   my $up = ${"$a[0]::upgrade"};
2317   #print "Now in objectify, my class is today $a[0], count = $count\n";
2318   if ($count == 0)
2319     {
2320     while (@_)
2321       {
2322       $k = shift;
2323       if (!ref($k))
2324         {
2325         $k = $a[0]->new($k);
2326         }
2327       elsif (!defined $up && ref($k) ne $a[0])
2328         {
2329         # foreign object, try to convert to integer
2330         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2331         }
2332       push @a,$k;
2333       }
2334     }
2335   else
2336     {
2337     while ($count > 0)
2338       {
2339       $count--;
2340       $k = shift;
2341       if (!ref($k))
2342         {
2343         $k = $a[0]->new($k);
2344         }
2345       elsif (!defined $up && ref($k) ne $a[0])
2346         {
2347         # foreign object, try to convert to integer
2348         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2349         }
2350       push @a,$k;
2351       }
2352     push @a,@_;         # return other params, too
2353     }
2354   if (! wantarray)
2355     {
2356     require Carp; Carp::croak ("$class objectify needs list context");
2357     }
2358   ${"$a[0]::downgrade"} = $d;
2359   @a;
2360   }
2361
2362 sub import
2363   {
2364   my $self = shift;
2365
2366   $IMPORT++;                            # remember we did import()
2367   my @a; my $l = scalar @_;
2368   for ( my $i = 0; $i < $l ; $i++ )
2369     {
2370     if ($_[$i] eq ':constant')
2371       {
2372       # this causes overlord er load to step in
2373       overload::constant
2374         integer => sub { $self->new(shift) },
2375         binary => sub { $self->new(shift) };
2376       }
2377     elsif ($_[$i] eq 'upgrade')
2378       {
2379       # this causes upgrading
2380       $upgrade = $_[$i+1];              # or undef to disable
2381       $i++;
2382       }
2383     elsif ($_[$i] =~ /^lib$/i)
2384       {
2385       # this causes a different low lib to take care...
2386       $CALC = $_[$i+1] || '';
2387       $i++;
2388       }
2389     else
2390       {
2391       push @a, $_[$i];
2392       }
2393     }
2394   # any non :constant stuff is handled by our parent, Exporter
2395   # even if @_ is empty, to give it a chance
2396   $self->SUPER::import(@a);                     # need it for subclasses
2397   $self->export_to_level(1,$self,@a);           # need it for MBF
2398
2399   # try to load core math lib
2400   my @c = split /\s*,\s*/,$CALC;
2401   push @c,'Calc';                               # if all fail, try this
2402   $CALC = '';                                   # signal error
2403   foreach my $lib (@c)
2404     {
2405     next if ($lib || '') eq '';
2406     $lib = 'Math::BigInt::'.$lib if $lib !~ /^Math::BigInt/i;
2407     $lib =~ s/\.pm$//;
2408     if ($] < 5.006)
2409       {
2410       # Perl < 5.6.0 dies with "out of memory!" when eval() and ':constant' is
2411       # used in the same script, or eval inside import().
2412       my @parts = split /::/, $lib;             # Math::BigInt => Math BigInt
2413       my $file = pop @parts; $file .= '.pm';    # BigInt => BigInt.pm
2414       require File::Spec;
2415       $file = File::Spec->catfile (@parts, $file);
2416       eval { require "$file"; $lib->import( @c ); }
2417       }
2418     else
2419       {
2420       eval "use $lib qw/@c/;";
2421       }
2422     if ($@ eq '')
2423       {
2424       my $ok = 1;
2425       # loaded it ok, see if the api_version() is high enough
2426       if ($lib->can('api_version') && $lib->api_version() >= 1.0)
2427         {
2428         $ok = 0;
2429         # api_version matches, check if it really provides anything we need
2430         for my $method (qw/
2431                 one two ten
2432                 str num
2433                 add mul div sub dec inc
2434                 acmp len digit is_one is_zero is_even is_odd
2435                 is_two is_ten
2436                 new copy check from_hex from_bin as_hex as_bin zeros
2437                 rsft lsft xor and or
2438                 mod sqrt root fac pow modinv modpow log_int gcd
2439          /)
2440           {
2441           if (!$lib->can("_$method"))
2442             {
2443             if (($WARN{$lib}||0) < 2)
2444               {
2445               require Carp;
2446               Carp::carp ("$lib is missing method '_$method'");
2447               $WARN{$lib} = 1;          # still warn about the lib
2448               }
2449             $ok++; last;
2450             }
2451           }
2452         }
2453       if ($ok == 0)
2454         {
2455         $CALC = $lib;
2456         last;                   # found a usable one, break
2457         }
2458       else
2459         {
2460         if (($WARN{$lib}||0) < 2)
2461           {
2462           my $ver = eval "\$$lib\::VERSION";
2463           require Carp;
2464           Carp::carp ("Cannot load outdated $lib v$ver, please upgrade");
2465           $WARN{$lib} = 2;              # never warn again
2466           }
2467         }
2468       }
2469     }
2470   if ($CALC eq '')
2471     {
2472     require Carp;
2473     Carp::croak ("Couldn't load any math lib, not even 'Calc.pm'");
2474     }
2475   _fill_can_cache();            # for emulating lower math lib functions
2476   }
2477
2478 sub _fill_can_cache
2479   {
2480   # fill $CAN with the results of $CALC->can(...)
2481
2482   %CAN = ();
2483   for my $method (qw/ signed_and or signed_or xor signed_xor /)
2484     {
2485     $CAN{$method} = $CALC->can("_$method") ? 1 : 0;
2486     }
2487   }
2488
2489 sub __from_hex
2490   {
2491   # convert a (ref to) big hex string to BigInt, return undef for error
2492   my $hs = shift;
2493
2494   my $x = Math::BigInt->bzero();
2495
2496   # strip underscores
2497   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2498   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2499
2500   return $x->bnan() if $hs !~ /^[\-\+]?0x[0-9A-Fa-f]+$/;
2501
2502   my $sign = '+'; $sign = '-' if $hs =~ /^-/;
2503
2504   $hs =~ s/^[+-]//;                                             # strip sign
2505   $x->{value} = $CALC->_from_hex($hs);
2506   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2507   $x;
2508   }
2509
2510 sub __from_bin
2511   {
2512   # convert a (ref to) big binary string to BigInt, return undef for error
2513   my $bs = shift;
2514
2515   my $x = Math::BigInt->bzero();
2516   # strip underscores
2517   $bs =~ s/([01])_([01])/$1$2/g;
2518   $bs =~ s/([01])_([01])/$1$2/g;
2519   return $x->bnan() if $bs !~ /^[+-]?0b[01]+$/;
2520
2521   my $sign = '+'; $sign = '-' if $bs =~ /^\-/;
2522   $bs =~ s/^[+-]//;                                             # strip sign
2523
2524   $x->{value} = $CALC->_from_bin($bs);
2525   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2526   $x;
2527   }
2528
2529 sub _split
2530   {
2531   # (ref to num_str) return num_str
2532   # internal, take apart a string and return the pieces
2533   # strip leading/trailing whitespace, leading zeros, underscore and reject
2534   # invalid input
2535   my $x = shift;
2536
2537   # strip white space at front, also extranous leading zeros
2538   $x =~ s/^\s*([-]?)0*([0-9])/$1$2/g;   # will not strip '  .2'
2539   $x =~ s/^\s+//;                       # but this will
2540   $x =~ s/\s+$//g;                      # strip white space at end
2541
2542   # shortcut, if nothing to split, return early
2543   if ($x =~ /^[+-]?\d+\z/)
2544     {
2545     $x =~ s/^([+-])0*([0-9])/$2/; my $sign = $1 || '+';
2546     return (\$sign, \$x, \'', \'', \0);
2547     }
2548
2549   # invalid starting char?
2550   return if $x !~ /^[+-]?(\.?[0-9]|0b[0-1]|0x[0-9a-fA-F])/;
2551
2552   return __from_hex($x) if $x =~ /^[\-\+]?0x/;  # hex string
2553   return __from_bin($x) if $x =~ /^[\-\+]?0b/;  # binary string
2554
2555   # strip underscores between digits
2556   $x =~ s/(\d)_(\d)/$1$2/g;
2557   $x =~ s/(\d)_(\d)/$1$2/g;             # do twice for 1_2_3
2558
2559   # some possible inputs:
2560   # 2.1234 # 0.12        # 1          # 1E1 # 2.134E1 # 434E-10 # 1.02009E-2
2561   # .2     # 1_2_3.4_5_6 # 1.4E1_2_3  # 1e3 # +.2     # 0e999
2562
2563   my ($m,$e,$last) = split /[Ee]/,$x;
2564   return if defined $last;              # last defined => 1e2E3 or others
2565   $e = '0' if !defined $e || $e eq "";
2566
2567   # sign,value for exponent,mantint,mantfrac
2568   my ($es,$ev,$mis,$miv,$mfv);
2569   # valid exponent?
2570   if ($e =~ /^([+-]?)0*(\d+)$/) # strip leading zeros
2571     {
2572     $es = $1; $ev = $2;
2573     # valid mantissa?
2574     return if $m eq '.' || $m eq '';
2575     my ($mi,$mf,$lastf) = split /\./,$m;
2576     return if defined $lastf;           # lastf defined => 1.2.3 or others
2577     $mi = '0' if !defined $mi;
2578     $mi .= '0' if $mi =~ /^[\-\+]?$/;
2579     $mf = '0' if !defined $mf || $mf eq '';
2580     if ($mi =~ /^([+-]?)0*(\d+)$/) # strip leading zeros
2581       {
2582       $mis = $1||'+'; $miv = $2;
2583       return unless ($mf =~ /^(\d*?)0*$/);      # strip trailing zeros
2584       $mfv = $1;
2585       # handle the 0e999 case here
2586       $ev = 0 if $miv eq '0' && $mfv eq '';
2587       return (\$mis,\$miv,\$mfv,\$es,\$ev);
2588       }
2589     }
2590   return; # NaN, not a number
2591   }
2592
2593 ##############################################################################
2594 # internal calculation routines (others are in Math::BigInt::Calc etc)
2595
2596 sub __lcm
2597   {
2598   # (BINT or num_str, BINT or num_str) return BINT
2599   # does modify first argument
2600   # LCM
2601
2602   my $x = shift; my $ty = shift;
2603   return $x->bnan() if ($x->{sign} eq $nan) || ($ty->{sign} eq $nan);
2604   $x * $ty / bgcd($x,$ty);
2605   }
2606
2607 ###############################################################################
2608 # this method return 0 if the object can be modified, or 1 for not
2609 # We use a fast constant sub() here, to avoid costly calls. Subclasses
2610 # may override it with special code (f.i. Math::BigInt::Constant does so)
2611
2612 sub modify () { 0; }
2613
2614 1;
2615 __END__
2616
2617 =head1 NAME
2618
2619 Math::BigInt - Arbitrary size integer math package
2620
2621 =head1 SYNOPSIS
2622
2623   use Math::BigInt;
2624
2625   # or make it faster: install (optional) Math::BigInt::GMP
2626   # and always use (it will fall back to pure Perl if the
2627   # GMP library is not installed):
2628
2629   use Math::BigInt lib => 'GMP';
2630
2631   my $str = '1234567890';
2632   my @values = (64,74,18);
2633   my $n = 1; my $sign = '-';
2634
2635   # Number creation
2636   $x = Math::BigInt->new($str);         # defaults to 0
2637   $y = $x->copy();                      # make a true copy
2638   $nan  = Math::BigInt->bnan();         # create a NotANumber
2639   $zero = Math::BigInt->bzero();        # create a +0
2640   $inf = Math::BigInt->binf();          # create a +inf
2641   $inf = Math::BigInt->binf('-');       # create a -inf
2642   $one = Math::BigInt->bone();          # create a +1
2643   $one = Math::BigInt->bone('-');       # create a -1
2644
2645   # Testing (don't modify their arguments)
2646   # (return true if the condition is met, otherwise false)
2647
2648   $x->is_zero();        # if $x is +0
2649   $x->is_nan();         # if $x is NaN
2650   $x->is_one();         # if $x is +1
2651   $x->is_one('-');      # if $x is -1
2652   $x->is_odd();         # if $x is odd
2653   $x->is_even();        # if $x is even
2654   $x->is_pos();         # if $x >= 0
2655   $x->is_neg();         # if $x <  0
2656   $x->is_inf($sign);    # if $x is +inf, or -inf (sign is default '+')
2657   $x->is_int();         # if $x is an integer (not a float)
2658
2659   # comparing and digit/sign extration
2660   $x->bcmp($y);         # compare numbers (undef,<0,=0,>0)
2661   $x->bacmp($y);        # compare absolutely (undef,<0,=0,>0)
2662   $x->sign();           # return the sign, either +,- or NaN
2663   $x->digit($n);        # return the nth digit, counting from right
2664   $x->digit(-$n);       # return the nth digit, counting from left
2665
2666   # The following all modify their first argument. If you want to preserve
2667   # $x, use $z = $x->copy()->bXXX($y); See under L<CAVEATS> for why this is
2668   # neccessary when mixing $a = $b assigments with non-overloaded math.
2669
2670   $x->bzero();          # set $x to 0
2671   $x->bnan();           # set $x to NaN
2672   $x->bone();           # set $x to +1
2673   $x->bone('-');        # set $x to -1
2674   $x->binf();           # set $x to inf
2675   $x->binf('-');        # set $x to -inf
2676
2677   $x->bneg();           # negation
2678   $x->babs();           # absolute value
2679   $x->bnorm();          # normalize (no-op in BigInt)
2680   $x->bnot();           # two's complement (bit wise not)
2681   $x->binc();           # increment $x by 1
2682   $x->bdec();           # decrement $x by 1
2683
2684   $x->badd($y);         # addition (add $y to $x)
2685   $x->bsub($y);         # subtraction (subtract $y from $x)
2686   $x->bmul($y);         # multiplication (multiply $x by $y)
2687   $x->bdiv($y);         # divide, set $x to quotient
2688                         # return (quo,rem) or quo if scalar
2689
2690   $x->bmod($y);            # modulus (x % y)
2691   $x->bmodpow($exp,$mod);  # modular exponentation (($num**$exp) % $mod))
2692   $x->bmodinv($mod);       # the inverse of $x in the given modulus $mod
2693
2694   $x->bpow($y);            # power of arguments (x ** y)
2695   $x->blsft($y);           # left shift
2696   $x->brsft($y);           # right shift
2697   $x->blsft($y,$n);        # left shift, by base $n (like 10)
2698   $x->brsft($y,$n);        # right shift, by base $n (like 10)
2699
2700   $x->band($y);            # bitwise and
2701   $x->bior($y);            # bitwise inclusive or
2702   $x->bxor($y);            # bitwise exclusive or
2703   $x->bnot();              # bitwise not (two's complement)
2704
2705   $x->bsqrt();             # calculate square-root
2706   $x->broot($y);           # $y'th root of $x (e.g. $y == 3 => cubic root)
2707   $x->bfac();              # factorial of $x (1*2*3*4*..$x)
2708
2709   $x->round($A,$P,$mode);  # round to accuracy or precision using mode $mode
2710   $x->bround($n);          # accuracy: preserve $n digits
2711   $x->bfround($n);         # round to $nth digit, no-op for BigInts
2712
2713   # The following do not modify their arguments in BigInt (are no-ops),
2714   # but do so in BigFloat:
2715
2716   $x->bfloor();            # return integer less or equal than $x
2717   $x->bceil();             # return integer greater or equal than $x
2718
2719   # The following do not modify their arguments:
2720
2721   # greatest common divisor (no OO style)
2722   my $gcd = Math::BigInt::bgcd(@values);
2723   # lowest common multiplicator (no OO style)
2724   my $lcm = Math::BigInt::blcm(@values);
2725
2726   $x->length();            # return number of digits in number
2727   ($xl,$f) = $x->length(); # length of number and length of fraction part,
2728                            # latter is always 0 digits long for BigInt's
2729
2730   $x->exponent();          # return exponent as BigInt
2731   $x->mantissa();          # return (signed) mantissa as BigInt
2732   $x->parts();             # return (mantissa,exponent) as BigInt
2733   $x->copy();              # make a true copy of $x (unlike $y = $x;)
2734   $x->as_int();            # return as BigInt (in BigInt: same as copy())
2735   $x->numify();            # return as scalar (might overflow!)
2736
2737   # conversation to string (do not modify their argument)
2738   $x->bstr();              # normalized string
2739   $x->bsstr();             # normalized string in scientific notation
2740   $x->as_hex();            # as signed hexadecimal string with prefixed 0x
2741   $x->as_bin();            # as signed binary string with prefixed 0b
2742
2743
2744   # precision and accuracy (see section about rounding for more)
2745   $x->precision();         # return P of $x (or global, if P of $x undef)
2746   $x->precision($n);       # set P of $x to $n
2747   $x->accuracy();          # return A of $x (or global, if A of $x undef)
2748   $x->accuracy($n);        # set A $x to $n
2749
2750   # Global methods
2751   Math::BigInt->precision(); # get/set global P for all BigInt objects
2752   Math::BigInt->accuracy();  # get/set global A for all BigInt objects
2753   Math::BigInt->config();    # return hash containing configuration
2754
2755 =head1 DESCRIPTION
2756
2757 All operators (inlcuding basic math operations) are overloaded if you
2758 declare your big integers as
2759
2760   $i = new Math::BigInt '123_456_789_123_456_789';
2761
2762 Operations with overloaded operators preserve the arguments which is
2763 exactly what you expect.
2764
2765 =over 2
2766
2767 =item Input
2768
2769 Input values to these routines may be any string, that looks like a number
2770 and results in an integer, including hexadecimal and binary numbers.
2771
2772 Scalars holding numbers may also be passed, but note that non-integer numbers
2773 may already have lost precision due to the conversation to float. Quote
2774 your input if you want BigInt to see all the digits:
2775
2776         $x = Math::BigInt->new(12345678890123456789);   # bad
2777         $x = Math::BigInt->new('12345678901234567890'); # good
2778
2779 You can include one underscore between any two digits.
2780
2781 This means integer values like 1.01E2 or even 1000E-2 are also accepted.
2782 Non-integer values result in NaN.
2783
2784 Currently, Math::BigInt::new() defaults to 0, while Math::BigInt::new('')
2785 results in 'NaN'. This might change in the future, so use always the following
2786 explicit forms to get a zero or NaN:
2787
2788         $zero = Math::BigInt->bzero();
2789         $nan = Math::BigInt->bnan();
2790
2791 C<bnorm()> on a BigInt object is now effectively a no-op, since the numbers
2792 are always stored in normalized form. If passed a string, creates a BigInt
2793 object from the input.
2794
2795 =item Output
2796
2797 Output values are BigInt objects (normalized), except for bstr(), which
2798 returns a string in normalized form.
2799 Some routines (C<is_odd()>, C<is_even()>, C<is_zero()>, C<is_one()>,
2800 C<is_nan()>) return true or false, while others (C<bcmp()>, C<bacmp()>)
2801 return either undef, <0, 0 or >0 and are suited for sort.
2802
2803 =back
2804
2805 =head1 METHODS
2806
2807 Each of the methods below (except config(), accuracy() and precision())
2808 accepts three additional parameters. These arguments $A, $P and $R are
2809 accuracy, precision and round_mode. Please see the section about
2810 L<ACCURACY and PRECISION> for more information.
2811
2812 =head2 config
2813
2814         use Data::Dumper;
2815
2816         print Dumper ( Math::BigInt->config() );
2817         print Math::BigInt->config()->{lib},"\n";
2818
2819 Returns a hash containing the configuration, e.g. the version number, lib
2820 loaded etc. The following hash keys are currently filled in with the
2821 appropriate information.
2822
2823         key             Description
2824                         Example
2825         ============================================================
2826         lib             Name of the low-level math library
2827                         Math::BigInt::Calc
2828         lib_version     Version of low-level math library (see 'lib')
2829                         0.30
2830         class           The class name of config() you just called
2831                         Math::BigInt
2832         upgrade         To which class math operations might be upgraded
2833                         Math::BigFloat
2834         downgrade       To which class math operations might be downgraded
2835                         undef
2836         precision       Global precision
2837                         undef
2838         accuracy        Global accuracy
2839                         undef
2840         round_mode      Global round mode
2841                         even
2842         version         version number of the class you used
2843                         1.61
2844         div_scale       Fallback acccuracy for div
2845                         40
2846         trap_nan        If true, traps creation of NaN via croak()
2847                         1
2848         trap_inf        If true, traps creation of +inf/-inf via croak()
2849                         1
2850
2851 The following values can be set by passing C<config()> a reference to a hash:
2852
2853         trap_inf trap_nan
2854         upgrade downgrade precision accuracy round_mode div_scale
2855
2856 Example:
2857
2858         $new_cfg = Math::BigInt->config( { trap_inf => 1, precision => 5 } );
2859
2860 =head2 accuracy
2861
2862         $x->accuracy(5);                # local for $x
2863         CLASS->accuracy(5);             # global for all members of CLASS
2864         $A = $x->accuracy();            # read out
2865         $A = CLASS->accuracy();         # read out
2866
2867 Set or get the global or local accuracy, aka how many significant digits the
2868 results have.
2869
2870 Please see the section about L<ACCURACY AND PRECISION> for further details.
2871
2872 Value must be greater than zero. Pass an undef value to disable it:
2873
2874         $x->accuracy(undef);
2875         Math::BigInt->accuracy(undef);
2876
2877 Returns the current accuracy. For C<$x->accuracy()> it will return either the
2878 local accuracy, or if not defined, the global. This means the return value
2879 represents the accuracy that will be in effect for $x:
2880
2881         $y = Math::BigInt->new(1234567);        # unrounded
2882         print Math::BigInt->accuracy(4),"\n";   # set 4, print 4
2883         $x = Math::BigInt->new(123456);         # will be automatically rounded
2884         print "$x $y\n";                        # '123500 1234567'
2885         print $x->accuracy(),"\n";              # will be 4
2886         print $y->accuracy(),"\n";              # also 4, since global is 4
2887         print Math::BigInt->accuracy(5),"\n";   # set to 5, print 5
2888         print $x->accuracy(),"\n";              # still 4
2889         print $y->accuracy(),"\n";              # 5, since global is 5
2890
2891 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
2892 globals separated from Math::BigInt, but it is possible to subclass
2893 Math::BigInt and make the globals of the subclass aliases to the ones from
2894 Math::BigInt.
2895
2896 =head2 precision
2897
2898         $x->precision(-2);              # local for $x, round right of the dot
2899         $x->precision(2);               # ditto, but round left of the dot
2900         CLASS->accuracy(5);             # global for all members of CLASS
2901         CLASS->precision(-5);           # ditto
2902         $P = CLASS->precision();        # read out
2903         $P = $x->precision();           # read out
2904
2905 Set or get the global or local precision, aka how many digits the result has
2906 after the dot (or where to round it when passing a positive number). In
2907 Math::BigInt, passing a negative number precision has no effect since no
2908 numbers have digits after the dot.
2909
2910 Please see the section about L<ACCURACY AND PRECISION> for further details.
2911
2912 Value must be greater than zero. Pass an undef value to disable it:
2913
2914         $x->precision(undef);
2915         Math::BigInt->precision(undef);
2916
2917 Returns the current precision. For C<$x->precision()> it will return either the
2918 local precision of $x, or if not defined, the global. This means the return
2919 value represents the accuracy that will be in effect for $x:
2920
2921         $y = Math::BigInt->new(1234567);        # unrounded
2922         print Math::BigInt->precision(4),"\n";  # set 4, print 4
2923         $x = Math::BigInt->new(123456);         # will be automatically rounded
2924
2925 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
2926 globals separated from Math::BigInt, but it is possible to subclass
2927 Math::BigInt and make the globals of the subclass aliases to the ones from
2928 Math::BigInt.
2929
2930 =head2 brsft
2931
2932         $x->brsft($y,$n);
2933
2934 Shifts $x right by $y in base $n. Default is base 2, used are usually 10 and
2935 2, but others work, too.
2936
2937 Right shifting usually amounts to dividing $x by $n ** $y and truncating the
2938 result:
2939
2940
2941         $x = Math::BigInt->new(10);
2942         $x->brsft(1);                   # same as $x >> 1: 5
2943         $x = Math::BigInt->new(1234);
2944         $x->brsft(2,10);                # result 12
2945
2946 There is one exception, and that is base 2 with negative $x:
2947
2948
2949         $x = Math::BigInt->new(-5);
2950         print $x->brsft(1);
2951
2952 This will print -3, not -2 (as it would if you divide -5 by 2 and truncate the
2953 result).
2954
2955 =head2 new
2956
2957         $x = Math::BigInt->new($str,$A,$P,$R);
2958
2959 Creates a new BigInt object from a scalar or another BigInt object. The
2960 input is accepted as decimal, hex (with leading '0x') or binary (with leading
2961 '0b').
2962
2963 See L<Input> for more info on accepted input formats.
2964
2965 =head2 bnan
2966
2967         $x = Math::BigInt->bnan();
2968
2969 Creates a new BigInt object representing NaN (Not A Number).
2970 If used on an object, it will set it to NaN:
2971
2972         $x->bnan();
2973
2974 =head2 bzero
2975
2976         $x = Math::BigInt->bzero();
2977
2978 Creates a new BigInt object representing zero.
2979 If used on an object, it will set it to zero:
2980
2981         $x->bzero();
2982
2983 =head2 binf
2984
2985         $x = Math::BigInt->binf($sign);
2986
2987 Creates a new BigInt object representing infinity. The optional argument is
2988 either '-' or '+', indicating whether you want infinity or minus infinity.
2989 If used on an object, it will set it to infinity:
2990
2991         $x->binf();
2992         $x->binf('-');
2993
2994 =head2 bone
2995
2996         $x = Math::BigInt->binf($sign);
2997
2998 Creates a new BigInt object representing one. The optional argument is
2999 either '-' or '+', indicating whether you want one or minus one.
3000 If used on an object, it will set it to one:
3001
3002         $x->bone();             # +1
3003         $x->bone('-');          # -1
3004
3005 =head2 is_one()/is_zero()/is_nan()/is_inf()
3006
3007
3008         $x->is_zero();                  # true if arg is +0
3009         $x->is_nan();                   # true if arg is NaN
3010         $x->is_one();                   # true if arg is +1
3011         $x->is_one('-');                # true if arg is -1
3012         $x->is_inf();                   # true if +inf
3013         $x->is_inf('-');                # true if -inf (sign is default '+')
3014
3015 These methods all test the BigInt for beeing one specific value and return
3016 true or false depending on the input. These are faster than doing something
3017 like:
3018
3019         if ($x == 0)
3020
3021 =head2 is_pos()/is_neg()
3022
3023         $x->is_pos();                   # true if >= 0
3024         $x->is_neg();                   # true if <  0
3025
3026 The methods return true if the argument is positive or negative, respectively.
3027 C<NaN> is neither positive nor negative, while C<+inf> counts as positive, and
3028 C<-inf> is negative. A C<zero> is positive.
3029
3030 These methods are only testing the sign, and not the value.
3031
3032 C<is_positive()> and C<is_negative()> are aliase to C<is_pos()> and
3033 C<is_neg()>, respectively. C<is_positive()> and C<is_negative()> were
3034 introduced in v1.36, while C<is_pos()> and C<is_neg()> were only introduced
3035 in v1.68.
3036
3037 =head2 is_odd()/is_even()/is_int()
3038
3039         $x->is_odd();                   # true if odd, false for even
3040         $x->is_even();                  # true if even, false for odd
3041         $x->is_int();                   # true if $x is an integer
3042
3043 The return true when the argument satisfies the condition. C<NaN>, C<+inf>,
3044 C<-inf> are not integers and are neither odd nor even.
3045
3046 In BigInt, all numbers except C<NaN>, C<+inf> and C<-inf> are integers.
3047
3048 =head2 bcmp
3049
3050         $x->bcmp($y);
3051
3052 Compares $x with $y and takes the sign into account.
3053 Returns -1, 0, 1 or undef.
3054
3055 =head2 bacmp
3056
3057         $x->bacmp($y);
3058
3059 Compares $x with $y while ignoring their. Returns -1, 0, 1 or undef.
3060
3061 =head2 sign
3062
3063         $x->sign();
3064
3065 Return the sign, of $x, meaning either C<+>, C<->, C<-inf>, C<+inf> or NaN.
3066
3067 =head2 digit
3068
3069         $x->digit($n);          # return the nth digit, counting from right
3070
3071 If C<$n> is negative, returns the digit counting from left.
3072
3073 =head2 bneg
3074
3075         $x->bneg();
3076
3077 Negate the number, e.g. change the sign between '+' and '-', or between '+inf'
3078 and '-inf', respectively. Does nothing for NaN or zero.
3079
3080 =head2 babs
3081
3082         $x->babs();
3083
3084 Set the number to it's absolute value, e.g. change the sign from '-' to '+'
3085 and from '-inf' to '+inf', respectively. Does nothing for NaN or positive
3086 numbers.
3087
3088 =head2 bnorm
3089
3090         $x->bnorm();                    # normalize (no-op)
3091
3092 =head2 bnot
3093
3094         $x->bnot();
3095
3096 Two's complement (bit wise not). This is equivalent to
3097
3098         $x->binc()->bneg();
3099
3100 but faster.
3101
3102 =head2 binc
3103
3104         $x->binc();                     # increment x by 1
3105
3106 =head2 bdec
3107
3108         $x->bdec();                     # decrement x by 1
3109
3110 =head2 badd
3111
3112         $x->badd($y);                   # addition (add $y to $x)
3113
3114 =head2 bsub
3115
3116         $x->bsub($y);                   # subtraction (subtract $y from $x)
3117
3118 =head2 bmul
3119
3120         $x->bmul($y);                   # multiplication (multiply $x by $y)
3121
3122 =head2 bdiv
3123
3124         $x->bdiv($y);                   # divide, set $x to quotient
3125                                         # return (quo,rem) or quo if scalar
3126
3127 =head2 bmod
3128
3129         $x->bmod($y);                   # modulus (x % y)
3130
3131 =head2 bmodinv
3132
3133         num->bmodinv($mod);             # modular inverse
3134
3135 Returns the inverse of C<$num> in the given modulus C<$mod>.  'C<NaN>' is
3136 returned unless C<$num> is relatively prime to C<$mod>, i.e. unless
3137 C<bgcd($num, $mod)==1>.
3138
3139 =head2 bmodpow
3140
3141         $num->bmodpow($exp,$mod);       # modular exponentation
3142                                         # ($num**$exp % $mod)
3143
3144 Returns the value of C<$num> taken to the power C<$exp> in the modulus
3145 C<$mod> using binary exponentation.  C<bmodpow> is far superior to
3146 writing
3147
3148         $num ** $exp % $mod
3149
3150 because it is much faster - it reduces internal variables into
3151 the modulus whenever possible, so it operates on smaller numbers.
3152
3153 C<bmodpow> also supports negative exponents.
3154
3155         bmodpow($num, -1, $mod)
3156
3157 is exactly equivalent to
3158
3159         bmodinv($num, $mod)
3160
3161 =head2 bpow
3162
3163         $x->bpow($y);                   # power of arguments (x ** y)
3164
3165 =head2 blsft
3166
3167         $x->blsft($y);          # left shift
3168         $x->blsft($y,$n);       # left shift, in base $n (like 10)
3169
3170 =head2 brsft
3171
3172         $x->brsft($y);          # right shift
3173         $x->brsft($y,$n);       # right shift, in base $n (like 10)
3174
3175 =head2 band
3176
3177         $x->band($y);                   # bitwise and
3178
3179 =head2 bior
3180
3181         $x->bior($y);                   # bitwise inclusive or
3182
3183 =head2 bxor
3184
3185         $x->bxor($y);                   # bitwise exclusive or
3186
3187 =head2 bnot
3188
3189         $x->bnot();                     # bitwise not (two's complement)
3190
3191 =head2 bsqrt
3192
3193         $x->bsqrt();                    # calculate square-root
3194
3195 =head2 bfac
3196
3197         $x->bfac();                     # factorial of $x (1*2*3*4*..$x)
3198
3199 =head2 round
3200
3201         $x->round($A,$P,$round_mode);
3202
3203 Round $x to accuracy C<$A> or precision C<$P> using the round mode
3204 C<$round_mode>.
3205
3206 =head2 bround
3207
3208         $x->bround($N);               # accuracy: preserve $N digits
3209
3210 =head2 bfround
3211
3212         $x->bfround($N);              # round to $Nth digit, no-op for BigInts
3213
3214 =head2 bfloor
3215
3216         $x->bfloor();
3217
3218 Set $x to the integer less or equal than $x. This is a no-op in BigInt, but
3219 does change $x in BigFloat.
3220
3221 =head2 bceil
3222
3223         $x->bceil();
3224
3225 Set $x to the integer greater or equal than $x. This is a no-op in BigInt, but
3226 does change $x in BigFloat.
3227
3228 =head2 bgcd
3229
3230         bgcd(@values);          # greatest common divisor (no OO style)
3231
3232 =head2 blcm
3233
3234         blcm(@values);          # lowest common multiplicator (no OO style)
3235
3236 head2 length
3237
3238         $x->length();
3239         ($xl,$fl) = $x->length();
3240
3241 Returns the number of digits in the decimal representation of the number.
3242 In list context, returns the length of the integer and fraction part. For
3243 BigInt's, the length of the fraction part will always be 0.
3244
3245 =head2 exponent
3246
3247         $x->exponent();
3248
3249 Return the exponent of $x as BigInt.
3250
3251 =head2 mantissa
3252
3253         $x->mantissa();
3254
3255 Return the signed mantissa of $x as BigInt.
3256
3257 =head2 parts
3258
3259         $x->parts();            # return (mantissa,exponent) as BigInt
3260
3261 =head2 copy
3262
3263         $x->copy();             # make a true copy of $x (unlike $y = $x;)
3264
3265 =head2 as_int
3266
3267         $x->as_int();
3268
3269 Returns $x as a BigInt (truncated towards zero). In BigInt this is the same as
3270 C<copy()>.
3271
3272 C<as_number()> is an alias to this method. C<as_number> was introduced in
3273 v1.22, while C<as_int()> was only introduced in v1.68.
3274
3275 =head2 bstr
3276
3277         $x->bstr();
3278
3279 Returns a normalized string represantation of C<$x>.
3280
3281 =head2 bsstr
3282
3283         $x->bsstr();            # normalized string in scientific notation
3284
3285 =head2 as_hex
3286
3287         $x->as_hex();           # as signed hexadecimal string with prefixed 0x
3288
3289 =head2 as_bin
3290
3291         $x->as_bin();           # as signed binary string with prefixed 0b
3292
3293 =head1 ACCURACY and PRECISION
3294
3295 Since version v1.33, Math::BigInt and Math::BigFloat have full support for
3296 accuracy and precision based rounding, both automatically after every
3297 operation, as well as manually.
3298
3299 This section describes the accuracy/precision handling in Math::Big* as it
3300 used to be and as it is now, complete with an explanation of all terms and
3301 abbreviations.
3302
3303 Not yet implemented things (but with correct description) are marked with '!',
3304 things that need to be answered are marked with '?'.
3305
3306 In the next paragraph follows a short description of terms used here (because
3307 these may differ from terms used by others people or documentation).
3308
3309 During the rest of this document, the shortcuts A (for accuracy), P (for
3310 precision), F (fallback) and R (rounding mode) will be used.
3311
3312 =head2 Precision P
3313
3314 A fixed number of digits before (positive) or after (negative)
3315 the decimal point. For example, 123.45 has a precision of -2. 0 means an
3316 integer like 123 (or 120). A precision of 2 means two digits to the left
3317 of the decimal point are zero, so 123 with P = 1 becomes 120. Note that
3318 numbers with zeros before the decimal point may have different precisions,
3319 because 1200 can have p = 0, 1 or 2 (depending on what the inital value
3320 was). It could also have p < 0, when the digits after the decimal point
3321 are zero.
3322
3323 The string output (of floating point numbers) will be padded with zeros:
3324
3325         Initial value   P       A       Result          String
3326         ------------------------------------------------------------
3327         1234.01         -3              1000            1000
3328         1234            -2              1200            1200
3329         1234.5          -1              1230            1230
3330         1234.001        1               1234            1234.0
3331         1234.01         0               1234            1234
3332         1234.01         2               1234.01         1234.01
3333         1234.01         5               1234.01         1234.01000
3334
3335 For BigInts, no padding occurs.
3336
3337 =head2 Accuracy A
3338
3339 Number of significant digits. Leading zeros are not counted. A
3340 number may have an accuracy greater than the non-zero digits
3341 when there are zeros in it or trailing zeros. For example, 123.456 has
3342 A of 6, 10203 has 5, 123.0506 has 7, 123.450000 has 8 and 0.000123 has 3.
3343
3344 The string output (of floating point numbers) will be padded with zeros:
3345
3346         Initial value   P       A       Result          String
3347         ------------------------------------------------------------
3348         1234.01                 3       1230            1230
3349         1234.01                 6       1234.01         1234.01
3350         1234.1                  8       1234.1          1234.1000
3351
3352 For BigInts, no padding occurs.
3353
3354 =head2 Fallback F
3355
3356 When both A and P are undefined, this is used as a fallback accuracy when
3357 dividing numbers.
3358
3359 =head2 Rounding mode R
3360
3361 When rounding a number, different 'styles' or 'kinds'
3362 of rounding are possible. (Note that random rounding, as in
3363 Math::Round, is not implemented.)
3364
3365 =over 2
3366
3367 =item 'trunc'
3368
3369 truncation invariably removes all digits following the
3370 rounding place, replacing them with zeros. Thus, 987.65 rounded
3371 to tens (P=1) becomes 980, and rounded to the fourth sigdig
3372 becomes 987.6 (A=4). 123.456 rounded to the second place after the
3373 decimal point (P=-2) becomes 123.46.
3374
3375 All other implemented styles of rounding attempt to round to the
3376 "nearest digit." If the digit D immediately to the right of the
3377 rounding place (skipping the decimal point) is greater than 5, the
3378 number is incremented at the rounding place (possibly causing a
3379 cascade of incrementation): e.g. when rounding to units, 0.9 rounds
3380 to 1, and -19.9 rounds to -20. If D < 5, the number is similarly
3381 truncated at the rounding place: e.g. when rounding to units, 0.4
3382 rounds to 0, and -19.4 rounds to -19.
3383
3384 However the results of other styles of rounding differ if the
3385 digit immediately to the right of the rounding place (skipping the
3386 decimal point) is 5 and if there are no digits, or no digits other
3387 than 0, after that 5. In such cases:
3388
3389 =item 'even'
3390
3391 rounds the digit at the rounding place to 0, 2, 4, 6, or 8
3392 if it is not already. E.g., when rounding to the first sigdig, 0.45
3393 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.
3394
3395 =item 'odd'
3396
3397 rounds the digit at the rounding place to 1, 3, 5, 7, or 9 if
3398 it is not already. E.g., when rounding to the first sigdig, 0.45
3399 becomes 0.5, -0.55 becomes -0.5, but 0.5501 becomes 0.6.
3400
3401 =item '+inf'
3402
3403 round to plus infinity, i.e. always round up. E.g., when
3404 rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5,
3405 and 0.4501 also becomes 0.5.
3406
3407 =item '-inf'
3408
3409 round to minus infinity, i.e. always round down. E.g., when
3410 rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6,
3411 but 0.4501 becomes 0.5.
3412
3413 =item 'zero'
3414
3415 round to zero, i.e. positive numbers down, negative ones up.
3416 E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55
3417 becomes -0.5, but 0.4501 becomes 0.5.
3418
3419 =back
3420
3421 The handling of A & P in MBI/MBF (the old core code shipped with Perl
3422 versions <= 5.7.2) is like this:
3423
3424 =over 2
3425
3426 =item Precision
3427
3428   * ffround($p) is able to round to $p number of digits after the decimal
3429     point
3430   * otherwise P is unused
3431
3432 =item Accuracy (significant digits)
3433
3434   * fround($a) rounds to $a significant digits
3435   * only fdiv() and fsqrt() take A as (optional) paramater
3436     + other operations simply create the same number (fneg etc), or more (fmul)
3437       of digits
3438     + rounding/truncating is only done when explicitly calling one of fround
3439       or ffround, and never for BigInt (not implemented)
3440   * fsqrt() simply hands its accuracy argument over to fdiv.
3441   * the documentation and the comment in the code indicate two different ways
3442     on how fdiv() determines the maximum number of digits it should calculate,
3443     and the actual code does yet another thing
3444     POD:
3445       max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
3446     Comment:
3447       result has at most max(scale, length(dividend), length(divisor)) digits
3448     Actual code:
3449       scale = max(scale, length(dividend)-1,length(divisor)-1);
3450       scale += length(divisior) - length(dividend);
3451     So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10+9-3).
3452     Actually, the 'difference' added to the scale is calculated from the
3453     number of "significant digits" in dividend and divisor, which is derived
3454     by looking at the length of the mantissa. Which is wrong, since it includes
3455     the + sign (oops) and actually gets 2 for '+100' and 4 for '+101'. Oops
3456     again. Thus 124/3 with div_scale=1 will get you '41.3' based on the strange
3457     assumption that 124 has 3 significant digits, while 120/7 will get you
3458     '17', not '17.1' since 120 is thought to have 2 significant digits.
3459     The rounding after the division then uses the remainder and $y to determine
3460     wether it must round up or down.
3461  ?  I have no idea which is the right way. That's why I used a slightly more
3462  ?  simple scheme and tweaked the few failing testcases to match it.
3463
3464 =back
3465
3466 This is how it works now:
3467
3468 =over 2
3469
3470 =item Setting/Accessing
3471
3472   * You can set the A global via C<< Math::BigInt->accuracy() >> or
3473     C<< Math::BigFloat->accuracy() >> or whatever class you are using.
3474   * You can also set P globally by using C<< Math::SomeClass->precision() >>
3475     likewise.
3476   * Globals are classwide, and not inherited by subclasses.
3477   * to undefine A, use C<< Math::SomeCLass->accuracy(undef); >>
3478   * to undefine P, use C<< Math::SomeClass->precision(undef); >>
3479   * Setting C<< Math::SomeClass->accuracy() >> clears automatically
3480     C<< Math::SomeClass->precision() >>, and vice versa.
3481   * To be valid, A must be > 0, P can have any value.
3482   * If P is negative, this means round to the P'th place to the right of the
3483     decimal point; positive values mean to the left of the decimal point.
3484     P of 0 means round to integer.
3485   * to find out the current global A, use C<< Math::SomeClass->accuracy() >>
3486   * to find out the current global P, use C<< Math::SomeClass->precision() >>
3487   * use C<< $x->accuracy() >> respective C<< $x->precision() >> for the local
3488     setting of C<< $x >>.
3489   * Please note that C<< $x->accuracy() >> respecive C<< $x->precision() >>
3490     return eventually defined global A or P, when C<< $x >>'s A or P is not
3491     set.
3492
3493 =item Creating numbers
3494
3495   * When you create a number, you can give it's desired A or P via:
3496     $x = Math::BigInt->new($number,$A,$P);
3497   * Only one of A or P can be defined, otherwise the result is NaN
3498   * If no A or P is give ($x = Math::BigInt->new($number) form), then the
3499     globals (if set) will be used. Thus changing the global defaults later on
3500     will not change the A or P of previously created numbers (i.e., A and P of
3501     $x will be what was in effect when $x was created)
3502   * If given undef for A and P, B<no> rounding will occur, and the globals will
3503     B<not> be used. This is used by subclasses to create numbers without
3504     suffering rounding in the parent. Thus a subclass is able to have it's own
3505     globals enforced upon creation of a number by using
3506     C<< $x = Math::BigInt->new($number,undef,undef) >>:
3507
3508         use Math::BigInt::SomeSubclass;
3509         use Math::BigInt;
3510
3511         Math::BigInt->accuracy(2);
3512         Math::BigInt::SomeSubClass->accuracy(3);
3513         $x = Math::BigInt::SomeSubClass->new(1234);
3514
3515     $x is now 1230, and not 1200. A subclass might choose to implement
3516     this otherwise, e.g. falling back to the parent's A and P.
3517
3518 =item Usage
3519
3520   * If A or P are enabled/defined, they are used to round the result of each
3521     operation according to the rules below
3522   * Negative P is ignored in Math::BigInt, since BigInts never have digits
3523     after the decimal point
3524   * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
3525     Math::BigInt as globals does not tamper with the parts of a BigFloat.
3526     A flag is used to mark all Math::BigFloat numbers as 'never round'.
3527
3528 =item Precedence
3529
3530   * It only makes sense that a number has only one of A or P at a time.
3531     If you set either A or P on one object, or globally, the other one will
3532     be automatically cleared.
3533   * If two objects are involved in an operation, and one of them has A in
3534     effect, and the other P, this results in an error (NaN).
3535   * A takes precendence over P (Hint: A comes before P).
3536     If neither of them is defined, nothing is used, i.e. the result will have
3537     as many digits as it can (with an exception for fdiv/fsqrt) and will not
3538     be rounded.
3539   * There is another setting for fdiv() (and thus for fsqrt()). If neither of
3540     A or P is defined, fdiv() will use a fallback (F) of $div_scale digits.
3541     If either the dividend's or the divisor's mantissa has more digits than
3542     the value of F, the higher value will be used instead of F.
3543     This is to limit the digits (A) of the result (just consider what would
3544     happen with unlimited A and P in the case of 1/3 :-)
3545   * fdiv will calculate (at least) 4 more digits than required (determined by
3546     A, P or F), and, if F is not used, round the result
3547     (this will still fail in the case of a result like 0.12345000000001 with A
3548     or P of 5, but this can not be helped - or can it?)
3549   * Thus you can have the math done by on Math::Big* class in two modi:
3550     + never round (this is the default):
3551       This is done by setting A and P to undef. No math operation
3552       will round the result, with fdiv() and fsqrt() as exceptions to guard
3553       against overflows. You must explicitely call bround(), bfround() or
3554       round() (the latter with parameters).
3555       Note: Once you have rounded a number, the settings will 'stick' on it
3556       and 'infect' all other numbers engaged in math operations with it, since
3557       local settings have the highest precedence. So, to get SaferRound[tm],
3558       use a copy() before rounding like this:
3559
3560         $x = Math::BigFloat->new(12.34);
3561         $y = Math::BigFloat->new(98.76);
3562         $z = $x * $y;                           # 1218.6984
3563         print $x->copy()->fround(3);            # 12.3 (but A is now 3!)
3564         $z = $x * $y;                           # still 1218.6984, without
3565                                                 # copy would have been 1210!
3566
3567     + round after each op:
3568       After each single operation (except for testing like is_zero()), the
3569       method round() is called and the result is rounded appropriately. By
3570       setting proper values for A and P, you can have all-the-same-A or
3571       all-the-same-P modes. For example, Math::Currency might set A to undef,
3572       and P to -2, globally.
3573
3574  ?Maybe an extra option that forbids local A & P settings would be in order,
3575  ?so that intermediate rounding does not 'poison' further math?
3576
3577 =item Overriding globals
3578
3579   * you will be able to give A, P and R as an argument to all the calculation
3580     routines; the second parameter is A, the third one is P, and the fourth is
3581     R (shift right by one for binary operations like badd). P is used only if
3582     the first parameter (A) is undefined. These three parameters override the
3583     globals in the order detailed as follows, i.e. the first defined value
3584     wins:
3585     (local: per object, global: global default, parameter: argument to sub)
3586       + parameter A
3587       + parameter P
3588       + local A (if defined on both of the operands: smaller one is taken)
3589       + local P (if defined on both of the operands: bigger one is taken)
3590       + global A
3591       + global P
3592       + global F
3593   * fsqrt() will hand its arguments to fdiv(), as it used to, only now for two
3594     arguments (A and P) instead of one
3595
3596 =item Local settings
3597
3598   * You can set A or P locally by using C<< $x->accuracy() >> or
3599     C<< $x->precision() >>
3600     and thus force different A and P for different objects/numbers.
3601   * Setting A or P this way immediately rounds $x to the new value.
3602   * C<< $x->accuracy() >> clears C<< $x->precision() >>, and vice versa.
3603
3604 =item Rounding
3605
3606   * the rounding routines will use the respective global or local settings.
3607     fround()/bround() is for accuracy rounding, while ffround()/bfround()
3608     is for precision
3609   * the two rounding functions take as the second parameter one of the
3610     following rounding modes (R):
3611     'even', 'odd', '+inf', '-inf', 'zero', 'trunc'
3612   * you can set/get the global R by using C<< Math::SomeClass->round_mode() >>
3613     or by setting C<< $Math::SomeClass::round_mode >>
3614   * after each operation, C<< $result->round() >> is called, and the result may
3615     eventually be rounded (that is, if A or P were set either locally,
3616     globally or as parameter to the operation)
3617   * to manually round a number, call C<< $x->round($A,$P,$round_mode); >>
3618     this will round the number by using the appropriate rounding function
3619     and then normalize it.
3620   * rounding modifies the local settings of the number:
3621
3622         $x = Math::BigFloat->new(123.456);
3623         $x->accuracy(5);
3624         $x->bround(4);
3625
3626     Here 4 takes precedence over 5, so 123.5 is the result and $x->accuracy()
3627     will be 4 from now on.
3628
3629 =item Default values
3630
3631   * R: 'even'
3632   * F: 40
3633   * A: undef
3634   * P: undef
3635
3636 =item Remarks
3637
3638   * The defaults are set up so that the new code gives the same results as
3639     the old code (except in a few cases on fdiv):
3640     + Both A and P are undefined and thus will not be used for rounding
3641       after each operation.
3642     + round() is thus a no-op, unless given extra parameters A and P
3643
3644 =back
3645
3646 =head1 INTERNALS
3647
3648 The actual numbers are stored as unsigned big integers (with seperate sign).
3649 You should neither care about nor depend on the internal representation; it
3650 might change without notice. Use only method calls like C<< $x->sign(); >>
3651 instead relying on the internal hash keys like in C<< $x->{sign}; >>.
3652
3653 =head2 MATH LIBRARY
3654
3655 Math with the numbers is done (by default) by a module called
3656 C<Math::BigInt::Calc>. This is equivalent to saying:
3657
3658         use Math::BigInt lib => 'Calc';
3659
3660 You can change this by using:
3661
3662         use Math::BigInt lib => 'BitVect';
3663
3664 The following would first try to find Math::BigInt::Foo, then
3665 Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:
3666
3667         use Math::BigInt lib => 'Foo,Math::BigInt::Bar';
3668
3669 Since Math::BigInt::GMP is in almost all cases faster than Calc (especially in
3670 cases involving really big numbers, where it is B<much> faster), and there is
3671 no penalty if Math::BigInt::GMP is not installed, it is a good idea to always
3672 use the following:
3673
3674         use Math::BigInt lib => 'GMP';
3675
3676 Different low-level libraries use different formats to store the
3677 numbers. You should not depend on the number having a specific format.
3678
3679 See the respective math library module documentation for further details.
3680
3681 =head2 SIGN
3682
3683 The sign is either '+', '-', 'NaN', '+inf' or '-inf' and stored seperately.
3684
3685 A sign of 'NaN' is used to represent the result when input arguments are not
3686 numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively
3687 minus infinity. You will get '+inf' when dividing a positive number by 0, and
3688 '-inf' when dividing any negative number by 0.
3689
3690 =head2 mantissa(), exponent() and parts()
3691
3692 C<mantissa()> and C<exponent()> return the said parts of the BigInt such
3693 that:
3694
3695         $m = $x->mantissa();
3696         $e = $x->exponent();
3697         $y = $m * ( 10 ** $e );
3698         print "ok\n" if $x == $y;
3699
3700 C<< ($m,$e) = $x->parts() >> is just a shortcut that gives you both of them
3701 in one go. Both the returned mantissa and exponent have a sign.
3702
3703 Currently, for BigInts C<$e> is always 0, except for NaN, +inf and -inf,
3704 where it is C<NaN>; and for C<$x == 0>, where it is C<1> (to be compatible
3705 with Math::BigFloat's internal representation of a zero as C<0E1>).
3706
3707 C<$m> is currently just a copy of the original number. The relation between
3708 C<$e> and C<$m> will stay always the same, though their real values might
3709 change.
3710
3711 =head1 EXAMPLES
3712
3713   use Math::BigInt;
3714
3715   sub bint { Math::BigInt->new(shift); }
3716
3717   $x = Math::BigInt->bstr("1234")       # string "1234"
3718   $x = "$x";                            # same as bstr()
3719   $x = Math::BigInt->bneg("1234");      # BigInt "-1234"
3720   $x = Math::BigInt->babs("-12345");    # BigInt "12345"
3721   $x = Math::BigInt->bnorm("-0 00");    # BigInt "0"
3722   $x = bint(1) + bint(2);               # BigInt "3"
3723   $x = bint(1) + "2";                   # ditto (auto-BigIntify of "2")
3724   $x = bint(1);                         # BigInt "1"
3725   $x = $x + 5 / 2;                      # BigInt "3"
3726   $x = $x ** 3;                         # BigInt "27"
3727   $x *= 2;                              # BigInt "54"
3728   $x = Math::BigInt->new(0);            # BigInt "0"
3729   $x--;                                 # BigInt "-1"
3730   $x = Math::BigInt->badd(4,5)          # BigInt "9"
3731   print $x->bsstr();                    # 9e+0
3732
3733 Examples for rounding:
3734
3735   use Math::BigFloat;
3736   use Test;
3737
3738   $x = Math::BigFloat->new(123.4567);
3739   $y = Math::BigFloat->new(123.456789);
3740   Math::BigFloat->accuracy(4);          # no more A than 4
3741
3742   ok ($x->copy()->fround(),123.4);      # even rounding
3743   print $x->copy()->fround(),"\n";      # 123.4
3744   Math::BigFloat->round_mode('odd');    # round to odd
3745   print $x->copy()->fround(),"\n";      # 123.5
3746   Math::BigFloat->accuracy(5);          # no more A than 5
3747   Math::BigFloat->round_mode('odd');    # round to odd
3748   print $x->copy()->fround(),"\n";      # 123.46
3749   $y = $x->copy()->fround(4),"\n";      # A = 4: 123.4
3750   print "$y, ",$y->accuracy(),"\n";     # 123.4, 4
3751
3752   Math::BigFloat->accuracy(undef);      # A not important now
3753   Math::BigFloat->precision(2);         # P important
3754   print $x->copy()->bnorm(),"\n";       # 123.46
3755   print $x->copy()->fround(),"\n";      # 123.46
3756
3757 Examples for converting:
3758
3759   my $x = Math::BigInt->new('0b1'.'01' x 123);
3760   print "bin: ",$x->as_bin()," hex:",$x->as_hex()," dec: ",$x,"\n";
3761
3762 =head1 Autocreating constants
3763
3764 After C<use Math::BigInt ':constant'> all the B<integer> decimal, hexadecimal
3765 and binary constants in the given scope are converted to C<Math::BigInt>.
3766 This conversion happens at compile time.
3767
3768 In particular,
3769
3770   perl -MMath::BigInt=:constant -e 'print 2**100,"\n"'
3771
3772 prints the integer value of C<2**100>. Note that without conversion of
3773 constants the expression 2**100 will be calculated as perl scalar.
3774
3775 Please note that strings and floating point constants are not affected,
3776 so that
3777
3778         use Math::BigInt qw/:constant/;
3779
3780         $x = 1234567890123456789012345678901234567890
3781                 + 123456789123456789;
3782         $y = '1234567890123456789012345678901234567890'
3783                 + '123456789123456789';
3784
3785 do not work. You need an explicit Math::BigInt->new() around one of the
3786 operands. You should also quote large constants to protect loss of precision:
3787
3788         use Math::BigInt;
3789
3790         $x = Math::BigInt->new('1234567889123456789123456789123456789');
3791
3792 Without the quotes Perl would convert the large number to a floating point
3793 constant at compile time and then hand the result to BigInt, which results in
3794 an truncated result or a NaN.
3795
3796 This also applies to integers that look like floating point constants:
3797
3798         use Math::BigInt ':constant';
3799
3800         print ref(123e2),"\n";
3801         print ref(123.2e2),"\n";
3802
3803 will print nothing but newlines. Use either L<bignum> or L<Math::BigFloat>
3804 to get this to work.
3805
3806 =head1 PERFORMANCE
3807
3808 Using the form $x += $y; etc over $x = $x + $y is faster, since a copy of $x
3809 must be made in the second case. For long numbers, the copy can eat up to 20%
3810 of the work (in the case of addition/subtraction, less for
3811 multiplication/division). If $y is very small compared to $x, the form
3812 $x += $y is MUCH faster than $x = $x + $y since making the copy of $x takes
3813 more time then the actual addition.
3814
3815 With a technique called copy-on-write, the cost of copying with overload could
3816 be minimized or even completely avoided. A test implementation of COW did show
3817 performance gains for overloaded math, but introduced a performance loss due
3818 to a constant overhead for all other operatons. So Math::BigInt does currently
3819 not COW.
3820
3821 The rewritten version of this module (vs. v0.01) is slower on certain
3822 operations, like C<new()>, C<bstr()> and C<numify()>. The reason are that it
3823 does now more work and handles much more cases. The time spent in these
3824 operations is usually gained in the other math operations so that code on
3825 the average should get (much) faster. If they don't, please contact the author.
3826
3827 Some operations may be slower for small numbers, but are significantly faster
3828 for big numbers. Other operations are now constant (O(1), like C<bneg()>,
3829 C<babs()> etc), instead of O(N) and thus nearly always take much less time.
3830 These optimizations were done on purpose.
3831
3832 If you find the Calc module to slow, try to install any of the replacement
3833 modules and see if they help you.
3834
3835 =head2 Alternative math libraries
3836
3837 You can use an alternative library to drive Math::BigInt via:
3838
3839         use Math::BigInt lib => 'Module';
3840
3841 See L<MATH LIBRARY> for more information.
3842
3843 For more benchmark results see L<http://bloodgate.com/perl/benchmarks.html>.
3844
3845 =head2 SUBCLASSING
3846
3847 =head1 Subclassing Math::BigInt
3848
3849 The basic design of Math::BigInt allows simple subclasses with very little
3850 work, as long as a few simple rules are followed:
3851
3852 =over 2
3853
3854 =item *
3855
3856 The public API must remain consistent, i.e. if a sub-class is overloading
3857 addition, the sub-class must use the same name, in this case badd(). The
3858 reason for this is that Math::BigInt is optimized to call the object methods
3859 directly.
3860
3861 =item *
3862
3863 The private object hash keys like C<$x->{sign}> may not be changed, but
3864 additional keys can be added, like C<$x->{_custom}>.
3865
3866 =item *
3867
3868 Accessor functions are available for all existing object hash keys and should
3869 be used instead of directly accessing the internal hash keys. The reason for
3870 this is that Math::BigInt itself has a pluggable interface which permits it
3871 to support different storage methods.
3872
3873 =back
3874
3875 More complex sub-classes may have to replicate more of the logic internal of
3876 Math::BigInt if they need to change more basic behaviors. A subclass that
3877 needs to merely change the output only needs to overload C<bstr()>.
3878
3879 All other object methods and overloaded functions can be directly inherited
3880 from the parent class.
3881
3882 At the very minimum, any subclass will need to provide it's own C<new()> and can
3883 store additional hash keys in the object. There are also some package globals
3884 that must be defined, e.g.:
3885
3886   # Globals
3887   $accuracy = undef;
3888   $precision = -2;       # round to 2 decimal places
3889   $round_mode = 'even';
3890   $div_scale = 40;
3891
3892 Additionally, you might want to provide the following two globals to allow
3893 auto-upgrading and auto-downgrading to work correctly:
3894
3895   $upgrade = undef;
3896   $downgrade = undef;
3897
3898 This allows Math::BigInt to correctly retrieve package globals from the
3899 subclass, like C<$SubClass::precision>.  See t/Math/BigInt/Subclass.pm or
3900 t/Math/BigFloat/SubClass.pm completely functional subclass examples.
3901
3902 Don't forget to
3903
3904         use overload;
3905
3906 in your subclass to automatically inherit the overloading from the parent. If
3907 you like, you can change part of the overloading, look at Math::String for an
3908 example.
3909
3910 =head1 UPGRADING
3911
3912 When used like this:
3913
3914         use Math::BigInt upgrade => 'Foo::Bar';
3915
3916 certain operations will 'upgrade' their calculation and thus the result to
3917 the class Foo::Bar. Usually this is used in conjunction with Math::BigFloat:
3918
3919         use Math::BigInt upgrade => 'Math::BigFloat';
3920
3921 As a shortcut, you can use the module C<bignum>:
3922
3923         use bignum;
3924
3925 Also good for oneliners:
3926
3927         perl -Mbignum -le 'print 2 ** 255'
3928
3929 This makes it possible to mix arguments of different classes (as in 2.5 + 2)
3930 as well es preserve accuracy (as in sqrt(3)).
3931
3932 Beware: This feature is not fully implemented yet.
3933
3934 =head2 Auto-upgrade
3935
3936 The following methods upgrade themselves unconditionally; that is if upgrade
3937 is in effect, they will always hand up their work:
3938
3939 =over 2
3940
3941 =item bsqrt()
3942
3943 =item div()
3944
3945 =item blog()
3946
3947 =back
3948
3949 Beware: This list is not complete.
3950
3951 All other methods upgrade themselves only when one (or all) of their
3952 arguments are of the class mentioned in $upgrade (This might change in later
3953 versions to a more sophisticated scheme):
3954
3955 =head1 BUGS
3956
3957 =over 2
3958
3959 =item broot() does not work
3960
3961 The broot() function in BigInt may only work for small values. This will be
3962 fixed in a later version.
3963
3964 =item Out of Memory!
3965
3966 Under Perl prior to 5.6.0 having an C<use Math::BigInt ':constant';> and
3967 C<eval()> in your code will crash with "Out of memory". This is probably an
3968 overload/exporter bug. You can workaround by not having C<eval()>
3969 and ':constant' at the same time or upgrade your Perl to a newer version.
3970
3971 =item Fails to load Calc on Perl prior 5.6.0
3972
3973 Since eval(' use ...') can not be used in conjunction with ':constant', BigInt
3974 will fall back to eval { require ... } when loading the math lib on Perls
3975 prior to 5.6.0. This simple replaces '::' with '/' and thus might fail on
3976 filesystems using a different seperator.
3977
3978 =back
3979
3980 =head1 CAVEATS
3981
3982 Some things might not work as you expect them. Below is documented what is
3983 known to be troublesome:
3984
3985 =over 1
3986
3987 =item bstr(), bsstr() and 'cmp'
3988
3989 Both C<bstr()> and C<bsstr()> as well as automated stringify via overload now
3990 drop the leading '+'. The old code would return '+3', the new returns '3'.
3991 This is to be consistent with Perl and to make C<cmp> (especially with
3992 overloading) to work as you expect. It also solves problems with C<Test.pm>,
3993 because it's C<ok()> uses 'eq' internally.
3994
3995 Mark Biggar said, when asked about to drop the '+' altogether, or make only
3996 C<cmp> work:
3997
3998         I agree (with the first alternative), don't add the '+' on positive
3999         numbers.  It's not as important anymore with the new internal
4000         form for numbers.  It made doing things like abs and neg easier,
4001         but those have to be done differently now anyway.
4002
4003 So, the following examples will now work all as expected:
4004
4005         use Test;
4006         BEGIN { plan tests => 1 }
4007         use Math::BigInt;
4008
4009         my $x = new Math::BigInt 3*3;
4010         my $y = new Math::BigInt 3*3;
4011
4012         ok ($x,3*3);
4013         print "$x eq 9" if $x eq $y;
4014         print "$x eq 9" if $x eq '9';
4015         print "$x eq 9" if $x eq 3*3;
4016
4017 Additionally, the following still works:
4018
4019         print "$x == 9" if $x == $y;
4020         print "$x == 9" if $x == 9;
4021         print "$x == 9" if $x == 3*3;
4022
4023 There is now a C<bsstr()> method to get the string in scientific notation aka
4024 C<1e+2> instead of C<100>. Be advised that overloaded 'eq' always uses bstr()
4025 for comparisation, but Perl will represent some numbers as 100 and others
4026 as 1e+308. If in doubt, convert both arguments to Math::BigInt before
4027 comparing them as strings:
4028
4029         use Test;
4030         BEGIN { plan tests => 3 }
4031         use Math::BigInt;
4032
4033         $x = Math::BigInt->new('1e56'); $y = 1e56;
4034         ok ($x,$y);                     # will fail
4035         ok ($x->bsstr(),$y);            # okay
4036         $y = Math::BigInt->new($y);
4037         ok ($x,$y);                     # okay
4038
4039 Alternatively, simple use C<< <=> >> for comparisations, this will get it
4040 always right. There is not yet a way to get a number automatically represented
4041 as a string that matches exactly the way Perl represents it.
4042
4043 =item int()
4044
4045 C<int()> will return (at least for Perl v5.7.1 and up) another BigInt, not a
4046 Perl scalar:
4047
4048         $x = Math::BigInt->new(123);
4049         $y = int($x);                           # BigInt 123
4050         $x = Math::BigFloat->new(123.45);
4051         $y = int($x);                           # BigInt 123
4052
4053 In all Perl versions you can use C<as_number()> for the same effect:
4054
4055         $x = Math::BigFloat->new(123.45);
4056         $y = $x->as_number();                   # BigInt 123
4057
4058 This also works for other subclasses, like Math::String.
4059
4060 It is yet unlcear whether overloaded int() should return a scalar or a BigInt.
4061
4062 =item length
4063
4064 The following will probably not do what you expect:
4065
4066         $c = Math::BigInt->new(123);
4067         print $c->length(),"\n";                # prints 30
4068
4069 It prints both the number of digits in the number and in the fraction part
4070 since print calls C<length()> in list context. Use something like:
4071
4072         print scalar $c->length(),"\n";         # prints 3
4073
4074 =item bdiv
4075
4076 The following will probably not do what you expect:
4077
4078         print $c->bdiv(10000),"\n";
4079
4080 It prints both quotient and remainder since print calls C<bdiv()> in list
4081 context. Also, C<bdiv()> will modify $c, so be carefull. You probably want
4082 to use
4083
4084         print $c / 10000,"\n";
4085         print scalar $c->bdiv(10000),"\n";  # or if you want to modify $c
4086
4087 instead.
4088
4089 The quotient is always the greatest integer less than or equal to the
4090 real-valued quotient of the two operands, and the remainder (when it is
4091 nonzero) always has the same sign as the second operand; so, for
4092 example,
4093
4094           1 / 4  => ( 0, 1)
4095           1 / -4 => (-1,-3)
4096          -3 / 4  => (-1, 1)
4097          -3 / -4 => ( 0,-3)
4098         -11 / 2  => (-5,1)
4099          11 /-2  => (-5,-1)
4100
4101 As a consequence, the behavior of the operator % agrees with the
4102 behavior of Perl's built-in % operator (as documented in the perlop
4103 manpage), and the equation
4104
4105         $x == ($x / $y) * $y + ($x % $y)
4106
4107 holds true for any $x and $y, which justifies calling the two return
4108 values of bdiv() the quotient and remainder. The only exception to this rule
4109 are when $y == 0 and $x is negative, then the remainder will also be
4110 negative. See below under "infinity handling" for the reasoning behing this.
4111
4112 Perl's 'use integer;' changes the behaviour of % and / for scalars, but will
4113 not change BigInt's way to do things. This is because under 'use integer' Perl
4114 will do what the underlying C thinks is right and this is different for each
4115 system. If you need BigInt's behaving exactly like Perl's 'use integer', bug
4116 the author to implement it ;)
4117
4118 =item infinity handling
4119
4120 Here are some examples that explain the reasons why certain results occur while
4121 handling infinity:
4122
4123 The following table shows the result of the division and the remainder, so that
4124 the equation above holds true. Some "ordinary" cases are strewn in to show more
4125 clearly the reasoning:
4126
4127         A /  B  =   C,     R so that C *    B +    R =    A
4128      =========================================================
4129         5 /   8 =   0,     5         0 *    8 +    5 =    5
4130         0 /   8 =   0,     0         0 *    8 +    0 =    0
4131         0 / inf =   0,     0         0 *  inf +    0 =    0
4132         0 /-inf =   0,     0         0 * -inf +    0 =    0
4133         5 / inf =   0,     5         0 *  inf +    5 =    5
4134         5 /-inf =   0,     5         0 * -inf +    5 =    5
4135         -5/ inf =   0,    -5         0 *  inf +   -5 =   -5
4136         -5/-inf =   0,    -5         0 * -inf +   -5 =   -5
4137        inf/   5 =  inf,    0       inf *    5 +    0 =  inf
4138       -inf/   5 = -inf,    0      -inf *    5 +    0 = -inf
4139        inf/  -5 = -inf,    0      -inf *   -5 +    0 =  inf
4140       -inf/  -5 =  inf,    0       inf *   -5 +    0 = -inf
4141          5/   5 =    1,    0         1 *    5 +    0 =    5
4142         -5/  -5 =    1,    0         1 *   -5 +    0 =   -5
4143        inf/ inf =    1,    0         1 *  inf +    0 =  inf
4144       -inf/-inf =    1,    0         1 * -inf +    0 = -inf
4145        inf/-inf =   -1,    0        -1 * -inf +    0 =  inf
4146       -inf/ inf =   -1,    0         1 * -inf +    0 = -inf
4147          8/   0 =  inf,    8       inf *    0 +    8 =    8
4148        inf/   0 =  inf,  inf       inf *    0 +  inf =  inf
4149          0/   0 =  NaN
4150
4151 These cases below violate the "remainder has the sign of the second of the two
4152 arguments", since they wouldn't match up otherwise.
4153
4154         A /  B  =   C,     R so that C *    B +    R =    A
4155      ========================================================
4156       -inf/   0 = -inf, -inf      -inf *    0 +  inf = -inf
4157         -8/   0 = -inf,   -8      -inf *    0 +    8 = -8
4158
4159 =item Modifying and =
4160
4161 Beware of:
4162
4163         $x = Math::BigFloat->new(5);
4164         $y = $x;
4165
4166 It will not do what you think, e.g. making a copy of $x. Instead it just makes
4167 a second reference to the B<same> object and stores it in $y. Thus anything
4168 that modifies $x (except overloaded operators) will modify $y, and vice versa.
4169 Or in other words, C<=> is only safe if you modify your BigInts only via
4170 overloaded math. As soon as you use a method call it breaks:
4171
4172         $x->bmul(2);
4173         print "$x, $y\n";       # prints '10, 10'
4174
4175 If you want a true copy of $x, use:
4176
4177         $y = $x->copy();
4178
4179 You can also chain the calls like this, this will make first a copy and then
4180 multiply it by 2:
4181
4182         $y = $x->copy()->bmul(2);
4183
4184 See also the documentation for overload.pm regarding C<=>.
4185
4186 =item bpow
4187
4188 C<bpow()> (and the rounding functions) now modifies the first argument and
4189 returns it, unlike the old code which left it alone and only returned the
4190 result. This is to be consistent with C<badd()> etc. The first three will
4191 modify $x, the last one won't:
4192
4193         print bpow($x,$i),"\n";         # modify $x
4194         print $x->bpow($i),"\n";        # ditto
4195         print $x **= $i,"\n";           # the same
4196         print $x ** $i,"\n";            # leave $x alone
4197
4198 The form C<$x **= $y> is faster than C<$x = $x ** $y;>, though.
4199
4200 =item Overloading -$x
4201
4202 The following:
4203
4204         $x = -$x;
4205
4206 is slower than
4207
4208         $x->bneg();
4209
4210 since overload calls C<sub($x,0,1);> instead of C<neg($x)>. The first variant
4211 needs to preserve $x since it does not know that it later will get overwritten.
4212 This makes a copy of $x and takes O(N), but $x->bneg() is O(1).
4213
4214 With Copy-On-Write, this issue would be gone, but C-o-W is not implemented
4215 since it is slower for all other things.
4216
4217 =item Mixing different object types
4218
4219 In Perl you will get a floating point value if you do one of the following:
4220
4221         $float = 5.0 + 2;
4222         $float = 2 + 5.0;
4223         $float = 5 / 2;
4224
4225 With overloaded math, only the first two variants will result in a BigFloat:
4226
4227         use Math::BigInt;
4228         use Math::BigFloat;
4229
4230         $mbf = Math::BigFloat->new(5);
4231         $mbi2 = Math::BigInteger->new(5);
4232         $mbi = Math::BigInteger->new(2);
4233
4234                                         # what actually gets called:
4235         $float = $mbf + $mbi;           # $mbf->badd()
4236         $float = $mbf / $mbi;           # $mbf->bdiv()
4237         $integer = $mbi + $mbf;         # $mbi->badd()
4238         $integer = $mbi2 / $mbi;        # $mbi2->bdiv()
4239         $integer = $mbi2 / $mbf;        # $mbi2->bdiv()
4240
4241 This is because math with overloaded operators follows the first (dominating)
4242 operand, and the operation of that is called and returns thus the result. So,
4243 Math::BigInt::bdiv() will always return a Math::BigInt, regardless whether
4244 the result should be a Math::BigFloat or the second operant is one.
4245
4246 To get a Math::BigFloat you either need to call the operation manually,
4247 make sure the operands are already of the proper type or casted to that type
4248 via Math::BigFloat->new():
4249
4250         $float = Math::BigFloat->new($mbi2) / $mbi;     # = 2.5
4251
4252 Beware of simple "casting" the entire expression, this would only convert
4253 the already computed result:
4254
4255         $float = Math::BigFloat->new($mbi2 / $mbi);     # = 2.0 thus wrong!
4256
4257 Beware also of the order of more complicated expressions like:
4258
4259         $integer = ($mbi2 + $mbi) / $mbf;               # int / float => int
4260         $integer = $mbi2 / Math::BigFloat->new($mbi);   # ditto
4261
4262 If in doubt, break the expression into simpler terms, or cast all operands
4263 to the desired resulting type.
4264
4265 Scalar values are a bit different, since:
4266
4267         $float = 2 + $mbf;
4268         $float = $mbf + 2;
4269
4270 will both result in the proper type due to the way the overloaded math works.
4271
4272 This section also applies to other overloaded math packages, like Math::String.
4273
4274 One solution to you problem might be autoupgrading|upgrading. See the
4275 pragmas L<bignum>, L<bigint> and L<bigrat> for an easy way to do this.
4276
4277 =item bsqrt()
4278
4279 C<bsqrt()> works only good if the result is a big integer, e.g. the square
4280 root of 144 is 12, but from 12 the square root is 3, regardless of rounding
4281 mode. The reason is that the result is always truncated to an integer.
4282
4283 If you want a better approximation of the square root, then use:
4284
4285         $x = Math::BigFloat->new(12);
4286         Math::BigFloat->precision(0);
4287         Math::BigFloat->round_mode('even');
4288         print $x->copy->bsqrt(),"\n";           # 4
4289
4290         Math::BigFloat->precision(2);
4291         print $x->bsqrt(),"\n";                 # 3.46
4292         print $x->bsqrt(3),"\n";                # 3.464
4293
4294 =item brsft()
4295
4296 For negative numbers in base see also L<brsft|brsft>.
4297
4298 =back
4299
4300 =head1 LICENSE
4301
4302 This program is free software; you may redistribute it and/or modify it under
4303 the same terms as Perl itself.
4304
4305 =head1 SEE ALSO
4306
4307 L<Math::BigFloat>, L<Math::BigRat> and L<Math::Big> as well as
4308 L<Math::BigInt::BitVect>, L<Math::BigInt::Pari> and  L<Math::BigInt::GMP>.
4309
4310 The pragmas L<bignum>, L<bigint> and L<bigrat> also might be of interest
4311 because they solve the autoupgrading/downgrading issue, at least partly.
4312
4313 The package at
4314 L<http://search.cpan.org/search?mode=module&query=Math%3A%3ABigInt> contains
4315 more documentation including a full version history, testcases, empty
4316 subclass files and benchmarks.
4317
4318 =head1 AUTHORS
4319
4320 Original code by Mark Biggar, overloaded interface by Ilya Zakharevich.
4321 Completely rewritten by Tels http://bloodgate.com in late 2000, 2001 - 2003
4322 and still at it in 2004.
4323
4324 Many people contributed in one or more ways to the final beast, see the file
4325 CREDITS for an (uncomplete) list. If you miss your name, please drop me a
4326 mail. Thank you!
4327
4328 =cut