lib/Math/BigInt.pm

   1 package Math::BigInt;
   2
   3 #
   4 # "Mike had an infinite amount to do and a negative amount of time in which
   5 # to do it." - Before and After
   6 #
   7
   8 # The following hash values are used:
   9 #   value: unsigned int with actual value (as a Math::BigInt::Calc or similiar)
  10 #   sign : +,-,NaN,+inf,-inf
  11 #   _a   : accuracy
  12 #   _p   : precision
  13 #   _f   : flags, used by MBF to flag parts of a float as untouchable
  14
  15 # Remember not to take shortcuts ala $xs = $x->{value}; $CALC->foo($xs); since
  16 # underlying lib might change the reference!
  17
  18 my $class = "Math::BigInt";
  19 require 5.005;
  20
  21 $VERSION = '1.71';
  22 use Exporter;
  23 @ISA =       qw( Exporter );
  24 @EXPORT_OK = qw( objectify bgcd blcm);
  25 # _trap_inf and _trap_nan are internal and should never be accessed from the
  26 # outside
  27 use vars qw/$round_mode $accuracy $precision $div_scale $rnd_mode
  28             $upgrade $downgrade $_trap_nan $_trap_inf/;
  29 use strict;
  30
  31 # Inside overload, the first arg is always an object. If the original code had
  32 # it reversed (like $x = 2 * $y), then the third paramater is true.
  33 # In some cases (like add, $x = $x + 2 is the same as $x = 2 + $x) this makes
  34 # no difference, but in some cases it does.
  35
  36 # For overloaded ops with only one argument we simple use $_[0]->copy() to
  37 # preserve the argument.
  38
  39 # Thus inheritance of overload operators becomes possible and transparent for
  40 # our subclasses without the need to repeat the entire overload section there.
  41
  42 use overload
  43 '='     =>      sub { $_[0]->copy(); },
  44
  45 # some shortcuts for speed (assumes that reversed order of arguments is routed
  46 # to normal '+' and we thus can always modify first arg. If this is changed,
  47 # this breaks and must be adjusted.)
  48 '+='    =>      sub { $_[0]->badd($_[1]); },
  49 '-='    =>      sub { $_[0]->bsub($_[1]); },
  50 '*='    =>      sub { $_[0]->bmul($_[1]); },
  51 '/='    =>      sub { scalar $_[0]->bdiv($_[1]); },
  52 '%='    =>      sub { $_[0]->bmod($_[1]); },
  53 '^='    =>      sub { $_[0]->bxor($_[1]); },
  54 '&='    =>      sub { $_[0]->band($_[1]); },
  55 '|='    =>      sub { $_[0]->bior($_[1]); },
  56 '**='   =>      sub { $_[0]->bpow($_[1]); },
  57
  58 # not supported by Perl yet
  59 '..'    =>      \&_pointpoint,
  60
  61 '<=>'   =>      sub { $_[2] ?
  62                       ref($_[0])->bcmp($_[1],$_[0]) :
  63                       $_[0]->bcmp($_[1])},
  64 'cmp'   =>      sub {
  65          $_[2] ?
  66                "$_[1]" cmp $_[0]->bstr() :
  67                $_[0]->bstr() cmp "$_[1]" },
  68
  69 # make cos()/sin()/exp() "work" with BigInt's or subclasses
  70 'cos'   =>      sub { cos($_[0]->numify()) },
  71 'sin'   =>      sub { sin($_[0]->numify()) },
  72 'exp'   =>      sub { exp($_[0]->numify()) },
  73 'atan2' =>      sub { atan2($_[0]->numify(),$_[1]) },
  74
  75 'log'   =>      sub { $_[0]->copy()->blog($_[1]); },
  76 'int'   =>      sub { $_[0]->copy(); },
  77 'neg'   =>      sub { $_[0]->copy()->bneg(); },
  78 'abs'   =>      sub { $_[0]->copy()->babs(); },
  79 'sqrt'  =>      sub { $_[0]->copy()->bsqrt(); },
  80 '~'     =>      sub { $_[0]->copy()->bnot(); },
  81
  82 # for sub it is a bit tricky to keep b: b-a => -a+b
  83 '-'     =>      sub { my $c = $_[0]->copy; $_[2] ?
  84                    $c->bneg()->badd($_[1]) :
  85                    $c->bsub( $_[1]) },
  86 '+'     =>      sub { $_[0]->copy()->badd($_[1]); },
  87 '*'     =>      sub { $_[0]->copy()->bmul($_[1]); },
  88
  89 '/'     =>      sub {
  90    $_[2] ? ref($_[0])->new($_[1])->bdiv($_[0]) : $_[0]->copy->bdiv($_[1]);
  91   },
  92 '%'     =>      sub {
  93    $_[2] ? ref($_[0])->new($_[1])->bmod($_[0]) : $_[0]->copy->bmod($_[1]);
  94   },
  95 '**'    =>      sub {
  96    $_[2] ? ref($_[0])->new($_[1])->bpow($_[0]) : $_[0]->copy->bpow($_[1]);
  97   },
  98 '<<'    =>      sub {
  99    $_[2] ? ref($_[0])->new($_[1])->blsft($_[0]) : $_[0]->copy->blsft($_[1]);
 100   },
 101 '>>'    =>      sub {
 102    $_[2] ? ref($_[0])->new($_[1])->brsft($_[0]) : $_[0]->copy->brsft($_[1]);
 103   },
 104 '&'     =>      sub {
 105    $_[2] ? ref($_[0])->new($_[1])->band($_[0]) : $_[0]->copy->band($_[1]);
 106   },
 107 '|'     =>      sub {
 108    $_[2] ? ref($_[0])->new($_[1])->bior($_[0]) : $_[0]->copy->bior($_[1]);
 109   },
 110 '^'     =>      sub {
 111    $_[2] ? ref($_[0])->new($_[1])->bxor($_[0]) : $_[0]->copy->bxor($_[1]);
 112   },
 113
 114 # can modify arg of ++ and --, so avoid a copy() for speed, but don't
 115 # use $_[0]->bone(), it would modify $_[0] to be 1!
 116 '++'    =>      sub { $_[0]->binc() },
 117 '--'    =>      sub { $_[0]->bdec() },
 118
 119 # if overloaded, O(1) instead of O(N) and twice as fast for small numbers
 120 'bool'  =>      sub {
 121   # this kludge is needed for perl prior 5.6.0 since returning 0 here fails :-/
 122   # v5.6.1 dumps on this: return !$_[0]->is_zero() || undef;                :-(
 123   my $t = undef;
 124   $t = 1 if !$_[0]->is_zero();
 125   $t;
 126   },
 127
 128 # the original qw() does not work with the TIESCALAR below, why?
 129 # Order of arguments unsignificant
 130 '""' => sub { $_[0]->bstr(); },
 131 '0+' => sub { $_[0]->numify(); }
 132 ;
 133
 134 ##############################################################################
 135 # global constants, flags and accessory
 136
 137 # these are public, but their usage is not recommended, use the accessor
 138 # methods instead
 139
 140 $round_mode = 'even'; # one of 'even', 'odd', '+inf', '-inf', 'zero' or 'trunc'
 141 $accuracy   = undef;
 142 $precision  = undef;
 143 $div_scale  = 40;
 144
 145 $upgrade = undef;                       # default is no upgrade
 146 $downgrade = undef;                     # default is no downgrade
 147
 148 # these are internally, and not to be used from the outside
 149
 150 sub MB_NEVER_ROUND () { 0x0001; }
 151
 152 $_trap_nan = 0;                         # are NaNs ok? set w/ config()
 153 $_trap_inf = 0;                         # are infs ok? set w/ config()
 154 my $nan = 'NaN';                        # constants for easier life
 155
 156 my $CALC = 'Math::BigInt::Calc';        # module to do the low level math
 157                                         # default is Calc.pm
 158 my $IMPORT = 0;                         # was import() called yet?
 159                                         # used to make require work
 160 my %WARN;                               # warn only once for low-level libs
 161 my %CAN;                                # cache for $CALC->can(...)
 162 my $EMU_LIB = 'Math/BigInt/CalcEmu.pm'; # emulate low-level math
 163
 164 ##############################################################################
 165 # the old code had $rnd_mode, so we need to support it, too
 166
 167 $rnd_mode   = 'even';
 168 sub TIESCALAR  { my ($class) = @_; bless \$round_mode, $class; }
 169 sub FETCH      { return $round_mode; }
 170 sub STORE      { $rnd_mode = $_[0]->round_mode($_[1]); }
 171
 172 BEGIN
 173   {
 174   # tie to enable $rnd_mode to work transparently
 175   tie $rnd_mode, 'Math::BigInt';
 176
 177   # set up some handy alias names
 178   *as_int = \&as_number;
 179   *is_pos = \&is_positive;
 180   *is_neg = \&is_negative;
 181   }
 182
 183 ##############################################################################
 184
 185 sub round_mode
 186   {
 187   no strict 'refs';
 188   # make Class->round_mode() work
 189   my $self = shift;
 190   my $class = ref($self) || $self || __PACKAGE__;
 191   if (defined $_[0])
 192     {
 193     my $m = shift;
 194     if ($m !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 195       {
 196       require Carp; Carp::croak ("Unknown round mode '$m'");
 197       }
 198     return ${"${class}::round_mode"} = $m;
 199     }
 200   ${"${class}::round_mode"};
 201   }
 202
 203 sub upgrade
 204   {
 205   no strict 'refs';
 206   # make Class->upgrade() work
 207   my $self = shift;
 208   my $class = ref($self) || $self || __PACKAGE__;
 209   # need to set new value?
 210   if (@_ > 0)
 211     {
 212     my $u = shift;
 213     return ${"${class}::upgrade"} = $u;
 214     }
 215   ${"${class}::upgrade"};
 216   }
 217
 218 sub downgrade
 219   {
 220   no strict 'refs';
 221   # make Class->downgrade() work
 222   my $self = shift;
 223   my $class = ref($self) || $self || __PACKAGE__;
 224   # need to set new value?
 225   if (@_ > 0)
 226     {
 227     my $u = shift;
 228     return ${"${class}::downgrade"} = $u;
 229     }
 230   ${"${class}::downgrade"};
 231   }
 232
 233 sub div_scale
 234   {
 235   no strict 'refs';
 236   # make Class->div_scale() work
 237   my $self = shift;
 238   my $class = ref($self) || $self || __PACKAGE__;
 239   if (defined $_[0])
 240     {
 241     if ($_[0] < 0)
 242       {
 243       require Carp; Carp::croak ('div_scale must be greater than zero');
 244       }
 245     ${"${class}::div_scale"} = shift;
 246     }
 247   ${"${class}::div_scale"};
 248   }
 249
 250 sub accuracy
 251   {
 252   # $x->accuracy($a);           ref($x) $a
 253   # $x->accuracy();             ref($x)
 254   # Class->accuracy();          class
 255   # Class->accuracy($a);        class $a
 256
 257   my $x = shift;
 258   my $class = ref($x) || $x || __PACKAGE__;
 259
 260   no strict 'refs';
 261   # need to set new value?
 262   if (@_ > 0)
 263     {
 264     my $a = shift;
 265     # convert objects to scalars to avoid deep recursion. If object doesn't
 266     # have numify(), then hopefully it will have overloading for int() and
 267     # boolean test without wandering into a deep recursion path...
 268     $a = $a->numify() if ref($a) && $a->can('numify');
 269
 270     if (defined $a)
 271       {
 272       # also croak on non-numerical
 273       if (!$a || $a <= 0)
 274         {
 275         require Carp;
 276         Carp::croak ('Argument to accuracy must be greater than zero');
 277         }
 278       if (int($a) != $a)
 279         {
 280         require Carp; Carp::croak ('Argument to accuracy must be an integer');
 281         }
 282       }
 283     if (ref($x))
 284       {
 285       # $object->accuracy() or fallback to global
 286       $x->bround($a) if $a;             # not for undef, 0
 287       $x->{_a} = $a;                    # set/overwrite, even if not rounded
 288       delete $x->{_p};                  # clear P
 289       $a = ${"${class}::accuracy"} unless defined $a;   # proper return value
 290       }
 291     else
 292       {
 293       ${"${class}::accuracy"} = $a;     # set global A
 294       ${"${class}::precision"} = undef; # clear global P
 295       }
 296     return $a;                          # shortcut
 297     }
 298
 299   my $r;
 300   # $object->accuracy() or fallback to global
 301   $r = $x->{_a} if ref($x);
 302   # but don't return global undef, when $x's accuracy is 0!
 303   $r = ${"${class}::accuracy"} if !defined $r;
 304   $r;
 305   }
 306
 307 sub precision
 308   {
 309   # $x->precision($p);          ref($x) $p
 310   # $x->precision();            ref($x)
 311   # Class->precision();         class
 312   # Class->precision($p);       class $p
 313
 314   my $x = shift;
 315   my $class = ref($x) || $x || __PACKAGE__;
 316
 317   no strict 'refs';
 318   if (@_ > 0)
 319     {
 320     my $p = shift;
 321     # convert objects to scalars to avoid deep recursion. If object doesn't
 322     # have numify(), then hopefully it will have overloading for int() and
 323     # boolean test without wandering into a deep recursion path...
 324     $p = $p->numify() if ref($p) && $p->can('numify');
 325     if ((defined $p) && (int($p) != $p))
 326       {
 327       require Carp; Carp::croak ('Argument to precision must be an integer');
 328       }
 329     if (ref($x))
 330       {
 331       # $object->precision() or fallback to global
 332       $x->bfround($p) if $p;            # not for undef, 0
 333       $x->{_p} = $p;                    # set/overwrite, even if not rounded
 334       delete $x->{_a};                  # clear A
 335       $p = ${"${class}::precision"} unless defined $p;  # proper return value
 336       }
 337     else
 338       {
 339       ${"${class}::precision"} = $p;    # set global P
 340       ${"${class}::accuracy"} = undef;  # clear global A
 341       }
 342     return $p;                          # shortcut
 343     }
 344
 345   my $r;
 346   # $object->precision() or fallback to global
 347   $r = $x->{_p} if ref($x);
 348   # but don't return global undef, when $x's precision is 0!
 349   $r = ${"${class}::precision"} if !defined $r;
 350   $r;
 351   }
 352
 353 sub config
 354   {
 355   # return (or set) configuration data as hash ref
 356   my $class = shift || 'Math::BigInt';
 357
 358   no strict 'refs';
 359   if (@_ > 0)
 360     {
 361     # try to set given options as arguments from hash
 362
 363     my $args = $_[0];
 364     if (ref($args) ne 'HASH')
 365       {
 366       $args = { @_ };
 367       }
 368     # these values can be "set"
 369     my $set_args = {};
 370     foreach my $key (
 371      qw/trap_inf trap_nan
 372         upgrade downgrade precision accuracy round_mode div_scale/
 373      )
 374       {
 375       $set_args->{$key} = $args->{$key} if exists $args->{$key};
 376       delete $args->{$key};
 377       }
 378     if (keys %$args > 0)
 379       {
 380       require Carp;
 381       Carp::croak ("Illegal key(s) '",
 382        join("','",keys %$args),"' passed to $class\->config()");
 383       }
 384     foreach my $key (keys %$set_args)
 385       {
 386       if ($key =~ /^trap_(inf|nan)\z/)
 387         {
 388         ${"${class}::_trap_$1"} = ($set_args->{"trap_$1"} ? 1 : 0);
 389         next;
 390         }
 391       # use a call instead of just setting the $variable to check argument
 392       $class->$key($set_args->{$key});
 393       }
 394     }
 395
 396   # now return actual configuration
 397
 398   my $cfg = {
 399     lib => $CALC,
 400     lib_version => ${"${CALC}::VERSION"},
 401     class => $class,
 402     trap_nan => ${"${class}::_trap_nan"},
 403     trap_inf => ${"${class}::_trap_inf"},
 404     version => ${"${class}::VERSION"},
 405     };
 406   foreach my $key (qw/
 407      upgrade downgrade precision accuracy round_mode div_scale
 408      /)
 409     {
 410     $cfg->{$key} = ${"${class}::$key"};
 411     };
 412   $cfg;
 413   }
 414
 415 sub _scale_a
 416   {
 417   # select accuracy parameter based on precedence,
 418   # used by bround() and bfround(), may return undef for scale (means no op)
 419   my ($x,$s,$m,$scale,$mode) = @_;
 420   $scale = $x->{_a} if !defined $scale;
 421   $scale = $s if (!defined $scale);
 422   $mode = $m if !defined $mode;
 423   return ($scale,$mode);
 424   }
 425
 426 sub _scale_p
 427   {
 428   # select precision parameter based on precedence,
 429   # used by bround() and bfround(), may return undef for scale (means no op)
 430   my ($x,$s,$m,$scale,$mode) = @_;
 431   $scale = $x->{_p} if !defined $scale;
 432   $scale = $s if (!defined $scale);
 433   $mode = $m if !defined $mode;
 434   return ($scale,$mode);
 435   }
 436
 437 ##############################################################################
 438 # constructors
 439
 440 sub copy
 441   {
 442   my ($c,$x);
 443   if (@_ > 1)
 444     {
 445     # if two arguments, the first one is the class to "swallow" subclasses
 446     ($c,$x) = @_;
 447     }
 448   else
 449     {
 450     $x = shift;
 451     $c = ref($x);
 452     }
 453   return unless ref($x); # only for objects
 454
 455   my $self = {}; bless $self,$c;
 456
 457   $self->{sign} = $x->{sign};
 458   $self->{value} = $CALC->_copy($x->{value});
 459   $self->{_a} = $x->{_a} if defined $x->{_a};
 460   $self->{_p} = $x->{_p} if defined $x->{_p};
 461   $self;
 462   }
 463
 464 sub new
 465   {
 466   # create a new BigInt object from a string or another BigInt object.
 467   # see hash keys documented at top
 468
 469   # the argument could be an object, so avoid ||, && etc on it, this would
 470   # cause costly overloaded code to be called. The only allowed ops are
 471   # ref() and defined.
 472
 473   my ($class,$wanted,$a,$p,$r) = @_;
 474
 475   # avoid numify-calls by not using || on $wanted!
 476   return $class->bzero($a,$p) if !defined $wanted;      # default to 0
 477   return $class->copy($wanted,$a,$p,$r)
 478    if ref($wanted) && $wanted->isa($class);             # MBI or subclass
 479
 480   $class->import() if $IMPORT == 0;             # make require work
 481
 482   my $self = bless {}, $class;
 483
 484   # shortcut for "normal" numbers
 485   if ((!ref $wanted) && ($wanted =~ /^([+-]?)[1-9][0-9]*\z/))
 486     {
 487     $self->{sign} = $1 || '+';
 488
 489     if ($wanted =~ /^[+-]/)
 490      {
 491       # remove sign without touching wanted to make it work with constants
 492       my $t = $wanted; $t =~ s/^[+-]//;
 493       $self->{value} = $CALC->_new($t);
 494       }
 495     else
 496       {
 497       $self->{value} = $CALC->_new($wanted);
 498       }
 499     no strict 'refs';
 500     if ( (defined $a) || (defined $p)
 501         || (defined ${"${class}::precision"})
 502         || (defined ${"${class}::accuracy"})
 503        )
 504       {
 505       $self->round($a,$p,$r) unless (@_ == 4 && !defined $a && !defined $p);
 506       }
 507     return $self;
 508     }
 509
 510   # handle '+inf', '-inf' first
 511   if ($wanted =~ /^[+-]?inf$/)
 512     {
 513     $self->{value} = $CALC->_zero();
 514     $self->{sign} = $wanted; $self->{sign} = '+inf' if $self->{sign} eq 'inf';
 515     return $self;
 516     }
 517   # split str in m mantissa, e exponent, i integer, f fraction, v value, s sign
 518   my ($mis,$miv,$mfv,$es,$ev) = _split($wanted);
 519   if (!ref $mis)
 520     {
 521     if ($_trap_nan)
 522       {
 523       require Carp; Carp::croak("$wanted is not a number in $class");
 524       }
 525     $self->{value} = $CALC->_zero();
 526     $self->{sign} = $nan;
 527     return $self;
 528     }
 529   if (!ref $miv)
 530     {
 531     # _from_hex or _from_bin
 532     $self->{value} = $mis->{value};
 533     $self->{sign} = $mis->{sign};
 534     return $self;       # throw away $mis
 535     }
 536   # make integer from mantissa by adjusting exp, then convert to bigint
 537   $self->{sign} = $$mis;                        # store sign
 538   $self->{value} = $CALC->_zero();              # for all the NaN cases
 539   my $e = int("$$es$$ev");                      # exponent (avoid recursion)
 540   if ($e > 0)
 541     {
 542     my $diff = $e - CORE::length($$mfv);
 543     if ($diff < 0)                              # Not integer
 544       {
 545       if ($_trap_nan)
 546         {
 547         require Carp; Carp::croak("$wanted not an integer in $class");
 548         }
 549       #print "NOI 1\n";
 550       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 551       $self->{sign} = $nan;
 552       }
 553     else                                        # diff >= 0
 554       {
 555       # adjust fraction and add it to value
 556       #print "diff > 0 $$miv\n";
 557       $$miv = $$miv . ($$mfv . '0' x $diff);
 558       }
 559     }
 560   else
 561     {
 562     if ($$mfv ne '')                            # e <= 0
 563       {
 564       # fraction and negative/zero E => NOI
 565       if ($_trap_nan)
 566         {
 567         require Carp; Carp::croak("$wanted not an integer in $class");
 568         }
 569       #print "NOI 2 \$\$mfv '$$mfv'\n";
 570       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 571       $self->{sign} = $nan;
 572       }
 573     elsif ($e < 0)
 574       {
 575       # xE-y, and empty mfv
 576       #print "xE-y\n";
 577       $e = abs($e);
 578       if ($$miv !~ s/0{$e}$//)          # can strip so many zero's?
 579         {
 580         if ($_trap_nan)
 581           {
 582           require Carp; Carp::croak("$wanted not an integer in $class");
 583           }
 584         #print "NOI 3\n";
 585         return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 586         $self->{sign} = $nan;
 587         }
 588       }
 589     }
 590   $self->{sign} = '+' if $$miv eq '0';                  # normalize -0 => +0
 591   $self->{value} = $CALC->_new($$miv) if $self->{sign} =~ /^[+-]$/;
 592   # if any of the globals is set, use them to round and store them inside $self
 593   # do not round for new($x,undef,undef) since that is used by MBF to signal
 594   # no rounding
 595   $self->round($a,$p,$r) unless @_ == 4 && !defined $a && !defined $p;
 596   $self;
 597   }
 598
 599 sub bnan
 600   {
 601   # create a bigint 'NaN', if given a BigInt, set it to 'NaN'
 602   my $self = shift;
 603   $self = $class if !defined $self;
 604   if (!ref($self))
 605     {
 606     my $c = $self; $self = {}; bless $self, $c;
 607     }
 608   no strict 'refs';
 609   if (${"${class}::_trap_nan"})
 610     {
 611     require Carp;
 612     Carp::croak ("Tried to set $self to NaN in $class\::bnan()");
 613     }
 614   $self->import() if $IMPORT == 0;              # make require work
 615   return if $self->modify('bnan');
 616   if ($self->can('_bnan'))
 617     {
 618     # use subclass to initialize
 619     $self->_bnan();
 620     }
 621   else
 622     {
 623     # otherwise do our own thing
 624     $self->{value} = $CALC->_zero();
 625     }
 626   $self->{sign} = $nan;
 627   delete $self->{_a}; delete $self->{_p};       # rounding NaN is silly
 628   $self;
 629   }
 630
 631 sub binf
 632   {
 633   # create a bigint '+-inf', if given a BigInt, set it to '+-inf'
 634   # the sign is either '+', or if given, used from there
 635   my $self = shift;
 636   my $sign = shift; $sign = '+' if !defined $sign || $sign !~ /^-(inf)?$/;
 637   $self = $class if !defined $self;
 638   if (!ref($self))
 639     {
 640     my $c = $self; $self = {}; bless $self, $c;
 641     }
 642   no strict 'refs';
 643   if (${"${class}::_trap_inf"})
 644     {
 645     require Carp;
 646     Carp::croak ("Tried to set $self to +-inf in $class\::binfn()");
 647     }
 648   $self->import() if $IMPORT == 0;              # make require work
 649   return if $self->modify('binf');
 650   if ($self->can('_binf'))
 651     {
 652     # use subclass to initialize
 653     $self->_binf();
 654     }
 655   else
 656     {
 657     # otherwise do our own thing
 658     $self->{value} = $CALC->_zero();
 659     }
 660   $sign = $sign . 'inf' if $sign !~ /inf$/;     # - => -inf
 661   $self->{sign} = $sign;
 662   ($self->{_a},$self->{_p}) = @_;               # take over requested rounding
 663   $self;
 664   }
 665
 666 sub bzero
 667   {
 668   # create a bigint '+0', if given a BigInt, set it to 0
 669   my $self = shift;
 670   $self = $class if !defined $self;
 671
 672   if (!ref($self))
 673     {
 674     my $c = $self; $self = {}; bless $self, $c;
 675     }
 676   $self->import() if $IMPORT == 0;              # make require work
 677   return if $self->modify('bzero');
 678
 679   if ($self->can('_bzero'))
 680     {
 681     # use subclass to initialize
 682     $self->_bzero();
 683     }
 684   else
 685     {
 686     # otherwise do our own thing
 687     $self->{value} = $CALC->_zero();
 688     }
 689   $self->{sign} = '+';
 690   if (@_ > 0)
 691     {
 692     if (@_ > 3)
 693       {
 694       # call like: $x->bzero($a,$p,$r,$y);
 695       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 696       }
 697     else
 698       {
 699       $self->{_a} = $_[0]
 700        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 701       $self->{_p} = $_[1]
 702        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 703       }
 704     }
 705   $self;
 706   }
 707
 708 sub bone
 709   {
 710   # create a bigint '+1' (or -1 if given sign '-'),
 711   # if given a BigInt, set it to +1 or -1, respecively
 712   my $self = shift;
 713   my $sign = shift; $sign = '+' if !defined $sign || $sign ne '-';
 714   $self = $class if !defined $self;
 715
 716   if (!ref($self))
 717     {
 718     my $c = $self; $self = {}; bless $self, $c;
 719     }
 720   $self->import() if $IMPORT == 0;              # make require work
 721   return if $self->modify('bone');
 722
 723   if ($self->can('_bone'))
 724     {
 725     # use subclass to initialize
 726     $self->_bone();
 727     }
 728   else
 729     {
 730     # otherwise do our own thing
 731     $self->{value} = $CALC->_one();
 732     }
 733   $self->{sign} = $sign;
 734   if (@_ > 0)
 735     {
 736     if (@_ > 3)
 737       {
 738       # call like: $x->bone($sign,$a,$p,$r,$y);
 739       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 740       }
 741     else
 742       {
 743       # call like: $x->bone($sign,$a,$p,$r);
 744       $self->{_a} = $_[0]
 745        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 746       $self->{_p} = $_[1]
 747        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 748       }
 749     }
 750   $self;
 751   }
 752
 753 ##############################################################################
 754 # string conversation
 755
 756 sub bsstr
 757   {
 758   # (ref to BFLOAT or num_str ) return num_str
 759   # Convert number from internal format to scientific string format.
 760   # internal format is always normalized (no leading zeros, "-0E0" => "+0E0")
 761   my $x = shift; $class = ref($x) || $x; $x = $class->new(shift) if !ref($x);
 762   # my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 763
 764   if ($x->{sign} !~ /^[+-]$/)
 765     {
 766     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 767     return 'inf';                                       # +inf
 768     }
 769   my ($m,$e) = $x->parts();
 770   #$m->bstr() . 'e+' . $e->bstr();      # e can only be positive in BigInt
 771   # 'e+' because E can only be positive in BigInt
 772   $m->bstr() . 'e+' . $CALC->_str($e->{value});
 773   }
 774
 775 sub bstr
 776   {
 777   # make a string from bigint object
 778   my $x = shift; $class = ref($x) || $x; $x = $class->new(shift) if !ref($x);
 779   # my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 780
 781   if ($x->{sign} !~ /^[+-]$/)
 782     {
 783     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 784     return 'inf';                                       # +inf
 785     }
 786   my $es = ''; $es = $x->{sign} if $x->{sign} eq '-';
 787   $es.$CALC->_str($x->{value});
 788   }
 789
 790 sub numify
 791   {
 792   # Make a "normal" scalar from a BigInt object
 793   my $x = shift; $x = $class->new($x) unless ref $x;
 794
 795   return $x->bstr() if $x->{sign} !~ /^[+-]$/;
 796   my $num = $CALC->_num($x->{value});
 797   return -$num if $x->{sign} eq '-';
 798   $num;
 799   }
 800
 801 ##############################################################################
 802 # public stuff (usually prefixed with "b")
 803
 804 sub sign
 805   {
 806   # return the sign of the number: +/-/-inf/+inf/NaN
 807   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 808
 809   $x->{sign};
 810   }
 811
 812 sub _find_round_parameters
 813   {
 814   # After any operation or when calling round(), the result is rounded by
 815   # regarding the A & P from arguments, local parameters, or globals.
 816
 817   # !!!!!!! If you change this, remember to change round(), too! !!!!!!!!!!
 818
 819   # This procedure finds the round parameters, but it is for speed reasons
 820   # duplicated in round. Otherwise, it is tested by the testsuite and used
 821   # by fdiv().
 822
 823   # returns ($self) or ($self,$a,$p,$r) - sets $self to NaN of both A and P
 824   # were requested/defined (locally or globally or both)
 825
 826   my ($self,$a,$p,$r,@args) = @_;
 827   # $a accuracy, if given by caller
 828   # $p precision, if given by caller
 829   # $r round_mode, if given by caller
 830   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 831
 832   # leave bigfloat parts alone
 833   return ($self) if exists $self->{_f} && ($self->{_f} & MB_NEVER_ROUND) != 0;
 834
 835   my $c = ref($self);                           # find out class of argument(s)
 836   no strict 'refs';
 837
 838   # now pick $a or $p, but only if we have got "arguments"
 839   if (!defined $a)
 840     {
 841     foreach ($self,@args)
 842       {
 843       # take the defined one, or if both defined, the one that is smaller
 844       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 845       }
 846     }
 847   if (!defined $p)
 848     {
 849     # even if $a is defined, take $p, to signal error for both defined
 850     foreach ($self,@args)
 851       {
 852       # take the defined one, or if both defined, the one that is bigger
 853       # -2 > -3, and 3 > 2
 854       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 855       }
 856     }
 857   # if still none defined, use globals (#2)
 858   $a = ${"$c\::accuracy"} unless defined $a;
 859   $p = ${"$c\::precision"} unless defined $p;
 860
 861   # A == 0 is useless, so undef it to signal no rounding
 862   $a = undef if defined $a && $a == 0;
 863
 864   # no rounding today?
 865   return ($self) unless defined $a || defined $p;               # early out
 866
 867   # set A and set P is an fatal error
 868   return ($self->bnan()) if defined $a && defined $p;           # error
 869
 870   $r = ${"$c\::round_mode"} unless defined $r;
 871   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 872     {
 873     require Carp; Carp::croak ("Unknown round mode '$r'");
 874     }
 875
 876   ($self,$a,$p,$r);
 877   }
 878
 879 sub round
 880   {
 881   # Round $self according to given parameters, or given second argument's
 882   # parameters or global defaults
 883
 884   # for speed reasons, _find_round_parameters is embeded here:
 885
 886   my ($self,$a,$p,$r,@args) = @_;
 887   # $a accuracy, if given by caller
 888   # $p precision, if given by caller
 889   # $r round_mode, if given by caller
 890   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 891
 892   # leave bigfloat parts alone
 893   return ($self) if exists $self->{_f} && ($self->{_f} & MB_NEVER_ROUND) != 0;
 894
 895   my $c = ref($self);                           # find out class of argument(s)
 896   no strict 'refs';
 897
 898   # now pick $a or $p, but only if we have got "arguments"
 899   if (!defined $a)
 900     {
 901     foreach ($self,@args)
 902       {
 903       # take the defined one, or if both defined, the one that is smaller
 904       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 905       }
 906     }
 907   if (!defined $p)
 908     {
 909     # even if $a is defined, take $p, to signal error for both defined
 910     foreach ($self,@args)
 911       {
 912       # take the defined one, or if both defined, the one that is bigger
 913       # -2 > -3, and 3 > 2
 914       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 915       }
 916     }
 917   # if still none defined, use globals (#2)
 918   $a = ${"$c\::accuracy"} unless defined $a;
 919   $p = ${"$c\::precision"} unless defined $p;
 920
 921   # A == 0 is useless, so undef it to signal no rounding
 922   $a = undef if defined $a && $a == 0;
 923
 924   # no rounding today?
 925   return $self unless defined $a || defined $p;         # early out
 926
 927   # set A and set P is an fatal error
 928   return $self->bnan() if defined $a && defined $p;
 929
 930   $r = ${"$c\::round_mode"} unless defined $r;
 931   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc)$/)
 932     {
 933     require Carp; Carp::croak ("Unknown round mode '$r'");
 934     }
 935
 936   # now round, by calling either fround or ffround:
 937   if (defined $a)
 938     {
 939     $self->bround($a,$r) if !defined $self->{_a} || $self->{_a} >= $a;
 940     }
 941   else # both can't be undefined due to early out
 942     {
 943     $self->bfround($p,$r) if !defined $self->{_p} || $self->{_p} <= $p;
 944     }
 945   $self->bnorm();                       # after round, normalize
 946   }
 947
 948 sub bnorm
 949   {
 950   # (numstr or BINT) return BINT
 951   # Normalize number -- no-op here
 952   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 953   $x;
 954   }
 955
 956 sub babs
 957   {
 958   # (BINT or num_str) return BINT
 959   # make number absolute, or return absolute BINT from string
 960   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 961
 962   return $x if $x->modify('babs');
 963   # post-normalized abs for internal use (does nothing for NaN)
 964   $x->{sign} =~ s/^-/+/;
 965   $x;
 966   }
 967
 968 sub bneg
 969   {
 970   # (BINT or num_str) return BINT
 971   # negate number or make a negated number from string
 972   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
 973
 974   return $x if $x->modify('bneg');
 975
 976   # for +0 dont negate (to have always normalized)
 977   $x->{sign} =~ tr/+-/-+/ if !$x->is_zero();    # does nothing for NaN
 978   $x;
 979   }
 980
 981 sub bcmp
 982   {
 983   # Compares 2 values.  Returns one of undef, <0, =0, >0. (suitable for sort)
 984   # (BINT or num_str, BINT or num_str) return cond_code
 985
 986   # set up parameters
 987   my ($self,$x,$y) = (ref($_[0]),@_);
 988
 989   # objectify is costly, so avoid it
 990   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
 991     {
 992     ($self,$x,$y) = objectify(2,@_);
 993     }
 994
 995   return $upgrade->bcmp($x,$y) if defined $upgrade &&
 996     ((!$x->isa($self)) || (!$y->isa($self)));
 997
 998   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
 999     {
1000     # handle +-inf and NaN
1001     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1002     return 0 if $x->{sign} eq $y->{sign} && $x->{sign} =~ /^[+-]inf$/;
1003     return +1 if $x->{sign} eq '+inf';
1004     return -1 if $x->{sign} eq '-inf';
1005     return -1 if $y->{sign} eq '+inf';
1006     return +1;
1007     }
1008   # check sign for speed first
1009   return 1 if $x->{sign} eq '+' && $y->{sign} eq '-';   # does also 0 <=> -y
1010   return -1 if $x->{sign} eq '-' && $y->{sign} eq '+';  # does also -x <=> 0
1011
1012   # have same sign, so compare absolute values. Don't make tests for zero here
1013   # because it's actually slower than testin in Calc (especially w/ Pari et al)
1014
1015   # post-normalized compare for internal use (honors signs)
1016   if ($x->{sign} eq '+')
1017     {
1018     # $x and $y both > 0
1019     return $CALC->_acmp($x->{value},$y->{value});
1020     }
1021
1022   # $x && $y both < 0
1023   $CALC->_acmp($y->{value},$x->{value});        # swaped acmp (lib returns 0,1,-1)
1024   }
1025
1026 sub bacmp
1027   {
1028   # Compares 2 values, ignoring their signs.
1029   # Returns one of undef, <0, =0, >0. (suitable for sort)
1030   # (BINT, BINT) return cond_code
1031
1032   # set up parameters
1033   my ($self,$x,$y) = (ref($_[0]),@_);
1034   # objectify is costly, so avoid it
1035   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1036     {
1037     ($self,$x,$y) = objectify(2,@_);
1038     }
1039
1040   return $upgrade->bacmp($x,$y) if defined $upgrade &&
1041     ((!$x->isa($self)) || (!$y->isa($self)));
1042
1043   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1044     {
1045     # handle +-inf and NaN
1046     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1047     return 0 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} =~ /^[+-]inf$/;
1048     return 1 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} !~ /^[+-]inf$/;
1049     return -1;
1050     }
1051   $CALC->_acmp($x->{value},$y->{value});        # lib does only 0,1,-1
1052   }
1053
1054 sub badd
1055   {
1056   # add second arg (BINT or string) to first (BINT) (modifies first)
1057   # return result as BINT
1058
1059   # set up parameters
1060   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1061   # objectify is costly, so avoid it
1062   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1063     {
1064     ($self,$x,$y,@r) = objectify(2,@_);
1065     }
1066
1067   return $x if $x->modify('badd');
1068   return $upgrade->badd($upgrade->new($x),$upgrade->new($y),@r) if defined $upgrade &&
1069     ((!$x->isa($self)) || (!$y->isa($self)));
1070
1071   $r[3] = $y;                           # no push!
1072   # inf and NaN handling
1073   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1074     {
1075     # NaN first
1076     return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1077     # inf handling
1078     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1079       {
1080       # +inf++inf or -inf+-inf => same, rest is NaN
1081       return $x if $x->{sign} eq $y->{sign};
1082       return $x->bnan();
1083       }
1084     # +-inf + something => +inf
1085     # something +-inf => +-inf
1086     $x->{sign} = $y->{sign}, return $x if $y->{sign} =~ /^[+-]inf$/;
1087     return $x;
1088     }
1089
1090   my ($sx, $sy) = ( $x->{sign}, $y->{sign} );           # get signs
1091
1092   if ($sx eq $sy)
1093     {
1094     $x->{value} = $CALC->_add($x->{value},$y->{value}); # same sign, abs add
1095     }
1096   else
1097     {
1098     my $a = $CALC->_acmp ($y->{value},$x->{value});     # absolute compare
1099     if ($a > 0)
1100       {
1101       $x->{value} = $CALC->_sub($y->{value},$x->{value},1); # abs sub w/ swap
1102       $x->{sign} = $sy;
1103       }
1104     elsif ($a == 0)
1105       {
1106       # speedup, if equal, set result to 0
1107       $x->{value} = $CALC->_zero();
1108       $x->{sign} = '+';
1109       }
1110     else # a < 0
1111       {
1112       $x->{value} = $CALC->_sub($x->{value}, $y->{value}); # abs sub
1113       }
1114     }
1115   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1116   $x;
1117   }
1118
1119 sub bsub
1120   {
1121   # (BINT or num_str, BINT or num_str) return BINT
1122   # subtract second arg from first, modify first
1123
1124   # set up parameters
1125   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1126   # objectify is costly, so avoid it
1127   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1128     {
1129     ($self,$x,$y,@r) = objectify(2,@_);
1130     }
1131
1132   return $x if $x->modify('bsub');
1133
1134   return $upgrade->new($x)->bsub($upgrade->new($y),@r) if defined $upgrade &&
1135    ((!$x->isa($self)) || (!$y->isa($self)));
1136
1137   if ($y->is_zero())
1138     {
1139     $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1140     return $x;
1141     }
1142
1143   if (overload::StrVal($x) eq overload::StrVal($y))
1144     {
1145     # if we get the same variable twice, the result must be zero (the code
1146     # below fails in that case)
1147     return $x->bzero(@r) if $x->{sign} =~ /^[+-]$/;
1148     return $x->bnan();          # NaN, -inf, +inf
1149     }
1150   $y->{sign} =~ tr/+\-/-+/;     # does nothing for NaN
1151   $x->badd($y,@r);              # badd does not leave internal zeros
1152   $y->{sign} =~ tr/+\-/-+/;     # refix $y (does nothing for NaN)
1153   $x;                           # already rounded by badd() or no round necc.
1154   }
1155
1156 sub binc
1157   {
1158   # increment arg by one
1159   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1160   return $x if $x->modify('binc');
1161
1162   if ($x->{sign} eq '+')
1163     {
1164     $x->{value} = $CALC->_inc($x->{value});
1165     $x->round($a,$p,$r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1166     return $x;
1167     }
1168   elsif ($x->{sign} eq '-')
1169     {
1170     $x->{value} = $CALC->_dec($x->{value});
1171     $x->{sign} = '+' if $CALC->_is_zero($x->{value}); # -1 +1 => -0 => +0
1172     $x->round($a,$p,$r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1173     return $x;
1174     }
1175   # inf, nan handling etc
1176   $x->badd($self->bone(),$a,$p,$r);             # badd does round
1177   }
1178
1179 sub bdec
1180   {
1181   # decrement arg by one
1182   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1183   return $x if $x->modify('bdec');
1184
1185   if ($x->{sign} eq '-')
1186     {
1187     # < 0
1188     $x->{value} = $CALC->_inc($x->{value});
1189     }
1190   else
1191     {
1192     return $x->badd($self->bone('-'),@r) unless $x->{sign} eq '+'; # inf/NaN
1193     # >= 0
1194     if ($CALC->_is_zero($x->{value}))
1195       {
1196       # == 0
1197       $x->{value} = $CALC->_one(); $x->{sign} = '-';            # 0 => -1
1198       }
1199     else
1200       {
1201       # > 0
1202       $x->{value} = $CALC->_dec($x->{value});
1203       }
1204     }
1205   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1206   $x;
1207   }
1208
1209 sub blog
1210   {
1211   # calculate $x = $a ** $base + $b and return $a (e.g. the log() to base
1212   # $base of $x)
1213
1214   # set up parameters
1215   my ($self,$x,$base,@r) = (ref($_[0]),@_);
1216   # objectify is costly, so avoid it
1217   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1218     {
1219     ($self,$x,$base,@r) = objectify(1,$class,@_);
1220     }
1221
1222   return $x if $x->modify('blog');
1223
1224   # inf, -inf, NaN, <0 => NaN
1225   return $x->bnan()
1226    if $x->{sign} ne '+' || (defined $base && $base->{sign} ne '+');
1227
1228   return $upgrade->blog($upgrade->new($x),$base,@r) if
1229     defined $upgrade;
1230
1231   my ($rc,$exact) = $CALC->_log_int($x->{value},$base->{value});
1232   return $x->bnan() unless defined $rc;         # not possible to take log?
1233   $x->{value} = $rc;
1234   $x->round(@r);
1235   }
1236
1237 sub blcm
1238   {
1239   # (BINT or num_str, BINT or num_str) return BINT
1240   # does not modify arguments, but returns new object
1241   # Lowest Common Multiplicator
1242
1243   my $y = shift; my ($x);
1244   if (ref($y))
1245     {
1246     $x = $y->copy();
1247     }
1248   else
1249     {
1250     $x = __PACKAGE__->new($y);
1251     }
1252   my $self = ref($x);
1253   while (@_)
1254     {
1255     my $y = shift; $y = $self->new($y) if !ref ($y);
1256     $x = __lcm($x,$y);
1257     }
1258   $x;
1259   }
1260
1261 sub bgcd
1262   {
1263   # (BINT or num_str, BINT or num_str) return BINT
1264   # does not modify arguments, but returns new object
1265   # GCD -- Euclids algorithm, variant C (Knuth Vol 3, pg 341 ff)
1266
1267   my $y = shift;
1268   $y = __PACKAGE__->new($y) if !ref($y);
1269   my $self = ref($y);
1270   my $x = $y->copy()->babs();                   # keep arguments
1271   return $x->bnan() if $x->{sign} !~ /^[+-]$/;  # x NaN?
1272
1273   while (@_)
1274     {
1275     $y = shift; $y = $self->new($y) if !ref($y);
1276     next if $y->is_zero();
1277     return $x->bnan() if $y->{sign} !~ /^[+-]$/;        # y NaN?
1278     $x->{value} = $CALC->_gcd($x->{value},$y->{value}); last if $x->is_one();
1279     }
1280   $x;
1281   }
1282
1283 sub bnot
1284   {
1285   # (num_str or BINT) return BINT
1286   # represent ~x as twos-complement number
1287   # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1288   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1289
1290   return $x if $x->modify('bnot');
1291   $x->binc()->bneg();                   # binc already does round
1292   }
1293
1294 ##############################################################################
1295 # is_foo test routines
1296 # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1297
1298 sub is_zero
1299   {
1300   # return true if arg (BINT or num_str) is zero (array '+', '0')
1301   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1302
1303   return 0 if $x->{sign} !~ /^\+$/;                     # -, NaN & +-inf aren't
1304   $CALC->_is_zero($x->{value});
1305   }
1306
1307 sub is_nan
1308   {
1309   # return true if arg (BINT or num_str) is NaN
1310   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1311
1312   $x->{sign} eq $nan ? 1 : 0;
1313   }
1314
1315 sub is_inf
1316   {
1317   # return true if arg (BINT or num_str) is +-inf
1318   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1319
1320   if (defined $sign)
1321     {
1322     $sign = '[+-]inf' if $sign eq '';   # +- doesn't matter, only that's inf
1323     $sign = "[$1]inf" if $sign =~ /^([+-])(inf)?$/;     # extract '+' or '-'
1324     return $x->{sign} =~ /^$sign$/ ? 1 : 0;
1325     }
1326   $x->{sign} =~ /^[+-]inf$/ ? 1 : 0;            # only +-inf is infinity
1327   }
1328
1329 sub is_one
1330   {
1331   # return true if arg (BINT or num_str) is +1, or -1 if sign is given
1332   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1333
1334   $sign = '+' if !defined $sign || $sign ne '-';
1335
1336   return 0 if $x->{sign} ne $sign;      # -1 != +1, NaN, +-inf aren't either
1337   $CALC->_is_one($x->{value});
1338   }
1339
1340 sub is_odd
1341   {
1342   # return true when arg (BINT or num_str) is odd, false for even
1343   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1344
1345   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1346   $CALC->_is_odd($x->{value});
1347   }
1348
1349 sub is_even
1350   {
1351   # return true when arg (BINT or num_str) is even, false for odd
1352   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1353
1354   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1355   $CALC->_is_even($x->{value});
1356   }
1357
1358 sub is_positive
1359   {
1360   # return true when arg (BINT or num_str) is positive (>= 0)
1361   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1362
1363   $x->{sign} =~ /^\+/ ? 1 : 0;          # +inf is also positive, but NaN not
1364   }
1365
1366 sub is_negative
1367   {
1368   # return true when arg (BINT or num_str) is negative (< 0)
1369   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1370
1371   $x->{sign} =~ /^-/ ? 1 : 0;           # -inf is also negative, but NaN not
1372   }
1373
1374 sub is_int
1375   {
1376   # return true when arg (BINT or num_str) is an integer
1377   # always true for BigInt, but different for BigFloats
1378   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1379
1380   $x->{sign} =~ /^[+-]$/ ? 1 : 0;               # inf/-inf/NaN aren't
1381   }
1382
1383 ###############################################################################
1384
1385 sub bmul
1386   {
1387   # multiply two numbers -- stolen from Knuth Vol 2 pg 233
1388   # (BINT or num_str, BINT or num_str) return BINT
1389
1390   # set up parameters
1391   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1392   # objectify is costly, so avoid it
1393   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1394     {
1395     ($self,$x,$y,@r) = objectify(2,@_);
1396     }
1397
1398   return $x if $x->modify('bmul');
1399
1400   return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1401
1402   # inf handling
1403   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1404     {
1405     return $x->bnan() if $x->is_zero() || $y->is_zero();
1406     # result will always be +-inf:
1407     # +inf * +/+inf => +inf, -inf * -/-inf => +inf
1408     # +inf * -/-inf => -inf, -inf * +/+inf => -inf
1409     return $x->binf() if ($x->{sign} =~ /^\+/ && $y->{sign} =~ /^\+/);
1410     return $x->binf() if ($x->{sign} =~ /^-/ && $y->{sign} =~ /^-/);
1411     return $x->binf('-');
1412     }
1413
1414   return $upgrade->bmul($x,$upgrade->new($y),@r)
1415    if defined $upgrade && !$y->isa($self);
1416
1417   $r[3] = $y;                           # no push here
1418
1419   $x->{sign} = $x->{sign} eq $y->{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 => +
1420
1421   $x->{value} = $CALC->_mul($x->{value},$y->{value});   # do actual math
1422   $x->{sign} = '+' if $CALC->_is_zero($x->{value});     # no -0
1423
1424   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1425   $x;
1426   }
1427
1428 sub _div_inf
1429   {
1430   # helper function that handles +-inf cases for bdiv()/bmod() to reuse code
1431   my ($self,$x,$y) = @_;
1432
1433   # NaN if x == NaN or y == NaN or x==y==0
1434   return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan()
1435    if (($x->is_nan() || $y->is_nan())   ||
1436        ($x->is_zero() && $y->is_zero()));
1437
1438   # +-inf / +-inf == NaN, reminder also NaN
1439   if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1440     {
1441     return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan();
1442     }
1443   # x / +-inf => 0, remainder x (works even if x == 0)
1444   if ($y->{sign} =~ /^[+-]inf$/)
1445     {
1446     my $t = $x->copy();         # bzero clobbers up $x
1447     return wantarray ? ($x->bzero(),$t) : $x->bzero()
1448     }
1449
1450   # 5 / 0 => +inf, -6 / 0 => -inf
1451   # +inf / 0 = inf, inf,  and -inf / 0 => -inf, -inf
1452   # exception:   -8 / 0 has remainder -8, not 8
1453   # exception: -inf / 0 has remainder -inf, not inf
1454   if ($y->is_zero())
1455     {
1456     # +-inf / 0 => special case for -inf
1457     return wantarray ?  ($x,$x->copy()) : $x if $x->is_inf();
1458     if (!$x->is_zero() && !$x->is_inf())
1459       {
1460       my $t = $x->copy();               # binf clobbers up $x
1461       return wantarray ?
1462        ($x->binf($x->{sign}),$t) : $x->binf($x->{sign})
1463       }
1464     }
1465
1466   # last case: +-inf / ordinary number
1467   my $sign = '+inf';
1468   $sign = '-inf' if substr($x->{sign},0,1) ne $y->{sign};
1469   $x->{sign} = $sign;
1470   return wantarray ? ($x,$self->bzero()) : $x;
1471   }
1472
1473 sub bdiv
1474   {
1475   # (dividend: BINT or num_str, divisor: BINT or num_str) return
1476   # (BINT,BINT) (quo,rem) or BINT (only rem)
1477
1478   # set up parameters
1479   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1480   # objectify is costly, so avoid it
1481   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1482     {
1483     ($self,$x,$y,@r) = objectify(2,@_);
1484     }
1485
1486   return $x if $x->modify('bdiv');
1487
1488   return $self->_div_inf($x,$y)
1489    if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero());
1490
1491   return $upgrade->bdiv($upgrade->new($x),$upgrade->new($y),@r)
1492    if defined $upgrade;
1493
1494   $r[3] = $y;                                   # no push!
1495
1496   # calc new sign and in case $y == +/- 1, return $x
1497   my $xsign = $x->{sign};                               # keep
1498   $x->{sign} = ($x->{sign} ne $y->{sign} ? '-' : '+');
1499
1500   if (wantarray)
1501     {
1502     my $rem = $self->bzero();
1503     ($x->{value},$rem->{value}) = $CALC->_div($x->{value},$y->{value});
1504     $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1505     $rem->{_a} = $x->{_a};
1506     $rem->{_p} = $x->{_p};
1507     $x->round(@r) if !exists $x->{_f} || ($x->{_f} & MB_NEVER_ROUND) == 0;
1508     if (! $CALC->_is_zero($rem->{value}))
1509       {
1510       $rem->{sign} = $y->{sign};
1511       $rem = $y->copy()->bsub($rem) if $xsign ne $y->{sign}; # one of them '-'
1512       }
1513     else
1514       {
1515       $rem->{sign} = '+';                       # dont leave -0
1516       }
1517     $rem->round(@r) if !exists $rem->{_f} || ($rem->{_f} & MB_NEVER_ROUND) == 0;
1518     return ($x,$rem);
1519     }
1520
1521   $x->{value} = $CALC->_div($x->{value},$y->{value});
1522   $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1523
1524   $x->round(@r) if !exists $x->{_f} || ($x->{_f} & MB_NEVER_ROUND) == 0;
1525   $x;
1526   }
1527
1528 ###############################################################################
1529 # modulus functions
1530
1531 sub bmod
1532   {
1533   # modulus (or remainder)
1534   # (BINT or num_str, BINT or num_str) return BINT
1535
1536   # set up parameters
1537   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1538   # objectify is costly, so avoid it
1539   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1540     {
1541     ($self,$x,$y,@r) = objectify(2,@_);
1542     }
1543
1544   return $x if $x->modify('bmod');
1545   $r[3] = $y;                                   # no push!
1546   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero())
1547     {
1548     my ($d,$r) = $self->_div_inf($x,$y);
1549     $x->{sign} = $r->{sign};
1550     $x->{value} = $r->{value};
1551     return $x->round(@r);
1552     }
1553
1554   # calc new sign and in case $y == +/- 1, return $x
1555   $x->{value} = $CALC->_mod($x->{value},$y->{value});
1556   if (!$CALC->_is_zero($x->{value}))
1557     {
1558     my $xsign = $x->{sign};
1559     $x->{sign} = $y->{sign};
1560     if ($xsign ne $y->{sign})
1561       {
1562       my $t = $CALC->_copy($x->{value});                # copy $x
1563       $x->{value} = $CALC->_sub($y->{value},$t,1);      # $y-$x
1564       }
1565     }
1566    else
1567     {
1568     $x->{sign} = '+';                           # dont leave -0
1569     }
1570   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1571   $x;
1572   }
1573
1574 sub bmodinv
1575   {
1576   # Modular inverse.  given a number which is (hopefully) relatively
1577   # prime to the modulus, calculate its inverse using Euclid's
1578   # alogrithm.  If the number is not relatively prime to the modulus
1579   # (i.e. their gcd is not one) then NaN is returned.
1580
1581   # set up parameters
1582   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1583   # objectify is costly, so avoid it
1584   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1585     {
1586     ($self,$x,$y,@r) = objectify(2,@_);
1587     }
1588
1589   return $x if $x->modify('bmodinv');
1590
1591   return $x->bnan()
1592         if ($y->{sign} ne '+'                           # -, NaN, +inf, -inf
1593          || $x->is_zero()                               # or num == 0
1594          || $x->{sign} !~ /^[+-]$/                      # or num NaN, inf, -inf
1595         );
1596
1597   # put least residue into $x if $x was negative, and thus make it positive
1598   $x->bmod($y) if $x->{sign} eq '-';
1599
1600   my $sign;
1601   ($x->{value},$sign) = $CALC->_modinv($x->{value},$y->{value});
1602   return $x->bnan() if !defined $x->{value};            # in case no GCD found
1603   return $x if !defined $sign;                  # already real result
1604   $x->{sign} = $sign;                           # flip/flop see below
1605   $x->bmod($y);                                 # calc real result
1606   $x;
1607   }
1608
1609 sub bmodpow
1610   {
1611   # takes a very large number to a very large exponent in a given very
1612   # large modulus, quickly, thanks to binary exponentation.  supports
1613   # negative exponents.
1614   my ($self,$num,$exp,$mod,@r) = objectify(3,@_);
1615
1616   return $num if $num->modify('bmodpow');
1617
1618   # check modulus for valid values
1619   return $num->bnan() if ($mod->{sign} ne '+'           # NaN, - , -inf, +inf
1620                        || $mod->is_zero());
1621
1622   # check exponent for valid values
1623   if ($exp->{sign} =~ /\w/)
1624     {
1625     # i.e., if it's NaN, +inf, or -inf...
1626     return $num->bnan();
1627     }
1628
1629   $num->bmodinv ($mod) if ($exp->{sign} eq '-');
1630
1631   # check num for valid values (also NaN if there was no inverse but $exp < 0)
1632   return $num->bnan() if $num->{sign} !~ /^[+-]$/;
1633
1634   # $mod is positive, sign on $exp is ignored, result also positive
1635   $num->{value} = $CALC->_modpow($num->{value},$exp->{value},$mod->{value});
1636   $num;
1637   }
1638
1639 ###############################################################################
1640
1641 sub bfac
1642   {
1643   # (BINT or num_str, BINT or num_str) return BINT
1644   # compute factorial number from $x, modify $x in place
1645   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1646
1647   return $x if $x->modify('bfac');
1648
1649   return $x if $x->{sign} eq '+inf';            # inf => inf
1650   return $x->bnan() if $x->{sign} ne '+';       # NaN, <0 etc => NaN
1651
1652   $x->{value} = $CALC->_fac($x->{value});
1653   $x->round(@r);
1654   }
1655
1656 sub bpow
1657   {
1658   # (BINT or num_str, BINT or num_str) return BINT
1659   # compute power of two numbers -- stolen from Knuth Vol 2 pg 233
1660   # modifies first argument
1661
1662   # set up parameters
1663   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1664   # objectify is costly, so avoid it
1665   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1666     {
1667     ($self,$x,$y,@r) = objectify(2,@_);
1668     }
1669
1670   return $x if $x->modify('bpow');
1671
1672   return $upgrade->bpow($upgrade->new($x),$y,@r)
1673    if defined $upgrade && !$y->isa($self);
1674
1675   $r[3] = $y;                                   # no push!
1676   return $x if $x->{sign} =~ /^[+-]inf$/;       # -inf/+inf ** x
1677   return $x->bnan() if $x->{sign} eq $nan || $y->{sign} eq $nan;
1678
1679   # cases 0 ** Y, X ** 0, X ** 1, 1 ** Y are handled by Calc or Emu
1680
1681   my $new_sign = '+';
1682   $new_sign = $y->is_odd() ? '-' : '+' if ($x->{sign} ne '+');
1683
1684   # 0 ** -7 => ( 1 / (0 ** 7)) => 1 / 0 => +inf
1685   return $x->binf()
1686     if $y->{sign} eq '-' && $x->{sign} eq '+' && $CALC->_is_zero($x->{value});
1687   # 1 ** -y => 1 / (1 ** |y|)
1688   # so do test for negative $y after above's clause
1689   return $x->bnan() if $y->{sign} eq '-' && !$CALC->_is_one($x->{value});
1690
1691   $x->{value} = $CALC->_pow($x->{value},$y->{value});
1692   $x->{sign} = $new_sign;
1693   $x->{sign} = '+' if $CALC->_is_zero($y->{value});
1694   $x->round(@r) if !exists $x->{_f} || $x->{_f} & MB_NEVER_ROUND == 0;
1695   $x;
1696   }
1697
1698 sub blsft
1699   {
1700   # (BINT or num_str, BINT or num_str) return BINT
1701   # compute x << y, base n, y >= 0
1702
1703   # set up parameters
1704   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1705   # objectify is costly, so avoid it
1706   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1707     {
1708     ($self,$x,$y,$n,@r) = objectify(2,@_);
1709     }
1710
1711   return $x if $x->modify('blsft');
1712   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1713   return $x->round(@r) if $y->is_zero();
1714
1715   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1716
1717   $x->{value} = $CALC->_lsft($x->{value},$y->{value},$n);
1718   $x->round(@r);
1719   }
1720
1721 sub brsft
1722   {
1723   # (BINT or num_str, BINT or num_str) return BINT
1724   # compute x >> y, base n, y >= 0
1725
1726   # set up parameters
1727   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1728   # objectify is costly, so avoid it
1729   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1730     {
1731     ($self,$x,$y,$n,@r) = objectify(2,@_);
1732     }
1733
1734   return $x if $x->modify('brsft');
1735   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1736   return $x->round(@r) if $y->is_zero();
1737   return $x->bzero(@r) if $x->is_zero();                # 0 => 0
1738
1739   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1740
1741    # this only works for negative numbers when shifting in base 2
1742   if (($x->{sign} eq '-') && ($n == 2))
1743     {
1744     return $x->round(@r) if $x->is_one('-');    # -1 => -1
1745     if (!$y->is_one())
1746       {
1747       # although this is O(N*N) in calc (as_bin!) it is O(N) in Pari et al
1748       # but perhaps there is a better emulation for two's complement shift...
1749       # if $y != 1, we must simulate it by doing:
1750       # convert to bin, flip all bits, shift, and be done
1751       $x->binc();                       # -3 => -2
1752       my $bin = $x->as_bin();
1753       $bin =~ s/^-0b//;                 # strip '-0b' prefix
1754       $bin =~ tr/10/01/;                # flip bits
1755       # now shift
1756       if (CORE::length($bin) <= $y)
1757         {
1758         $bin = '0';                     # shifting to far right creates -1
1759                                         # 0, because later increment makes
1760                                         # that 1, attached '-' makes it '-1'
1761                                         # because -1 >> x == -1 !
1762         }
1763       else
1764         {
1765         $bin =~ s/.{$y}$//;             # cut off at the right side
1766         $bin = '1' . $bin;              # extend left side by one dummy '1'
1767         $bin =~ tr/10/01/;              # flip bits back
1768         }
1769       my $res = $self->new('0b'.$bin);  # add prefix and convert back
1770       $res->binc();                     # remember to increment
1771       $x->{value} = $res->{value};      # take over value
1772       return $x->round(@r);             # we are done now, magic, isn't?
1773       }
1774     # x < 0, n == 2, y == 1
1775     $x->bdec();                         # n == 2, but $y == 1: this fixes it
1776     }
1777
1778   $x->{value} = $CALC->_rsft($x->{value},$y->{value},$n);
1779   $x->round(@r);
1780   }
1781
1782 sub band
1783   {
1784   #(BINT or num_str, BINT or num_str) return BINT
1785   # compute x & y
1786
1787   # set up parameters
1788   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1789   # objectify is costly, so avoid it
1790   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1791     {
1792     ($self,$x,$y,@r) = objectify(2,@_);
1793     }
1794
1795   return $x if $x->modify('band');
1796
1797   $r[3] = $y;                           # no push!
1798
1799   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1800
1801   my $sx = $x->{sign} eq '+' ? 1 : -1;
1802   my $sy = $y->{sign} eq '+' ? 1 : -1;
1803
1804   if ($sx == 1 && $sy == 1)
1805     {
1806     $x->{value} = $CALC->_and($x->{value},$y->{value});
1807     return $x->round(@r);
1808     }
1809
1810   if ($CAN{signed_and})
1811     {
1812     $x->{value} = $CALC->_signed_and($x->{value},$y->{value},$sx,$sy);
1813     return $x->round(@r);
1814     }
1815
1816   require $EMU_LIB;
1817   __emu_band($self,$x,$y,$sx,$sy,@r);
1818   }
1819
1820 sub bior
1821   {
1822   #(BINT or num_str, BINT or num_str) return BINT
1823   # compute x | y
1824
1825   # set up parameters
1826   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1827   # objectify is costly, so avoid it
1828   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1829     {
1830     ($self,$x,$y,@r) = objectify(2,@_);
1831     }
1832
1833   return $x if $x->modify('bior');
1834   $r[3] = $y;                           # no push!
1835
1836   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1837
1838   my $sx = $x->{sign} eq '+' ? 1 : -1;
1839   my $sy = $y->{sign} eq '+' ? 1 : -1;
1840
1841   # the sign of X follows the sign of X, e.g. sign of Y irrelevant for bior()
1842
1843   # don't use lib for negative values
1844   if ($sx == 1 && $sy == 1)
1845     {
1846     $x->{value} = $CALC->_or($x->{value},$y->{value});
1847     return $x->round(@r);
1848     }
1849
1850   # if lib can do negative values, let it handle this
1851   if ($CAN{signed_or})
1852     {
1853     $x->{value} = $CALC->_signed_or($x->{value},$y->{value},$sx,$sy);
1854     return $x->round(@r);
1855     }
1856
1857   require $EMU_LIB;
1858   __emu_bior($self,$x,$y,$sx,$sy,@r);
1859   }
1860
1861 sub bxor
1862   {
1863   #(BINT or num_str, BINT or num_str) return BINT
1864   # compute x ^ y
1865
1866   # set up parameters
1867   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1868   # objectify is costly, so avoid it
1869   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1870     {
1871     ($self,$x,$y,@r) = objectify(2,@_);
1872     }
1873
1874   return $x if $x->modify('bxor');
1875   $r[3] = $y;                           # no push!
1876
1877   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1878
1879   my $sx = $x->{sign} eq '+' ? 1 : -1;
1880   my $sy = $y->{sign} eq '+' ? 1 : -1;
1881
1882   # don't use lib for negative values
1883   if ($sx == 1 && $sy == 1)
1884     {
1885     $x->{value} = $CALC->_xor($x->{value},$y->{value});
1886     return $x->round(@r);
1887     }
1888
1889   # if lib can do negative values, let it handle this
1890   if ($CAN{signed_xor})
1891     {
1892     $x->{value} = $CALC->_signed_xor($x->{value},$y->{value},$sx,$sy);
1893     return $x->round(@r);
1894     }
1895
1896   require $EMU_LIB;
1897   __emu_bxor($self,$x,$y,$sx,$sy,@r);
1898   }
1899
1900 sub length
1901   {
1902   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1903
1904   my $e = $CALC->_len($x->{value});
1905   wantarray ? ($e,0) : $e;
1906   }
1907
1908 sub digit
1909   {
1910   # return the nth decimal digit, negative values count backward, 0 is right
1911   my ($self,$x,$n) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1912
1913   $n = $n->numify() if ref($n);
1914   $CALC->_digit($x->{value},$n||0);
1915   }
1916
1917 sub _trailing_zeros
1918   {
1919   # return the amount of trailing zeros in $x (as scalar)
1920   my $x = shift;
1921   $x = $class->new($x) unless ref $x;
1922
1923   return 0 if $x->{sign} !~ /^[+-]$/;   # NaN, inf, -inf etc
1924
1925   $CALC->_zeros($x->{value});           # must handle odd values, 0 etc
1926   }
1927
1928 sub bsqrt
1929   {
1930   # calculate square root of $x
1931   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1932
1933   return $x if $x->modify('bsqrt');
1934
1935   return $x->bnan() if $x->{sign} !~ /^\+/;     # -x or -inf or NaN => NaN
1936   return $x if $x->{sign} eq '+inf';            # sqrt(+inf) == inf
1937
1938   return $upgrade->bsqrt($x,@r) if defined $upgrade;
1939
1940   $x->{value} = $CALC->_sqrt($x->{value});
1941   $x->round(@r);
1942   }
1943
1944 sub broot
1945   {
1946   # calculate $y'th root of $x
1947
1948   # set up parameters
1949   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1950
1951   $y = $self->new(2) unless defined $y;
1952
1953   # objectify is costly, so avoid it
1954   if ((!ref($x)) || (ref($x) ne ref($y)))
1955     {
1956     ($self,$x,$y,@r) = objectify(2,$self || $class,@_);
1957     }
1958
1959   return $x if $x->modify('broot');
1960
1961   # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
1962   return $x->bnan() if $x->{sign} !~ /^\+/ || $y->is_zero() ||
1963          $y->{sign} !~ /^\+$/;
1964
1965   return $x->round(@r)
1966     if $x->is_zero() || $x->is_one() || $x->is_inf() || $y->is_one();
1967
1968   return $upgrade->new($x)->broot($upgrade->new($y),@r) if defined $upgrade;
1969
1970   $x->{value} = $CALC->_root($x->{value},$y->{value});
1971   $x->round(@r);
1972   }
1973
1974 sub exponent
1975   {
1976   # return a copy of the exponent (here always 0, NaN or 1 for $m == 0)
1977   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
1978
1979   if ($x->{sign} !~ /^[+-]$/)
1980     {
1981     my $s = $x->{sign}; $s =~ s/^[+-]//;  # NaN, -inf,+inf => NaN or inf
1982     return $self->new($s);
1983     }
1984   return $self->bone() if $x->is_zero();
1985
1986   $self->new($x->_trailing_zeros());
1987   }
1988
1989 sub mantissa
1990   {
1991   # return the mantissa (compatible to Math::BigFloat, e.g. reduced)
1992   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
1993
1994   if ($x->{sign} !~ /^[+-]$/)
1995     {
1996     # for NaN, +inf, -inf: keep the sign
1997     return $self->new($x->{sign});
1998     }
1999   my $m = $x->copy(); delete $m->{_p}; delete $m->{_a};
2000   # that's a bit inefficient:
2001   my $zeros = $m->_trailing_zeros();
2002   $m->brsft($zeros,10) if $zeros != 0;
2003   $m;
2004   }
2005
2006 sub parts
2007   {
2008   # return a copy of both the exponent and the mantissa
2009   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2010
2011   ($x->mantissa(),$x->exponent());
2012   }
2013
2014 ##############################################################################
2015 # rounding functions
2016
2017 sub bfround
2018   {
2019   # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
2020   # $n == 0 || $n == 1 => round to integer
2021   my $x = shift; my $self = ref($x) || $x; $x = $self->new($x) unless ref $x;
2022
2023   my ($scale,$mode) = $x->_scale_p($x->precision(),$x->round_mode(),@_);
2024
2025   return $x if !defined $scale || $x->modify('bfround');        # no-op
2026
2027   # no-op for BigInts if $n <= 0
2028   $x->bround( $x->length()-$scale, $mode) if $scale > 0;
2029
2030   delete $x->{_a};      # delete to save memory
2031   $x->{_p} = $scale;    # store new _p
2032   $x;
2033   }
2034
2035 sub _scan_for_nonzero
2036   {
2037   # internal, used by bround()
2038   my ($x,$pad,$xs) = @_;
2039
2040   my $len = $x->length();
2041   return 0 if $len == 1;                # '5' is trailed by invisible zeros
2042   my $follow = $pad - 1;
2043   return 0 if $follow > $len || $follow < 1;
2044
2045   # since we do not know underlying represention of $x, use decimal string
2046   my $r = substr ("$x",-$follow);
2047   $r =~ /[^0]/ ? 1 : 0;
2048   }
2049
2050 sub fround
2051   {
2052   # Exists to make life easier for switch between MBF and MBI (should we
2053   # autoload fxxx() like MBF does for bxxx()?)
2054   my $x = shift;
2055   $x->bround(@_);
2056   }
2057
2058 sub bround
2059   {
2060   # accuracy: +$n preserve $n digits from left,
2061   #           -$n preserve $n digits from right (f.i. for 0.1234 style in MBF)
2062   # no-op for $n == 0
2063   # and overwrite the rest with 0's, return normalized number
2064   # do not return $x->bnorm(), but $x
2065
2066   my $x = shift; $x = $class->new($x) unless ref $x;
2067   my ($scale,$mode) = $x->_scale_a($x->accuracy(),$x->round_mode(),@_);
2068   return $x if !defined $scale;                 # no-op
2069   return $x if $x->modify('bround');
2070
2071   if ($x->is_zero() || $scale == 0)
2072     {
2073     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2074     return $x;
2075     }
2076   return $x if $x->{sign} !~ /^[+-]$/;          # inf, NaN
2077
2078   # we have fewer digits than we want to scale to
2079   my $len = $x->length();
2080   # convert $scale to a scalar in case it is an object (put's a limit on the
2081   # number length, but this would already limited by memory constraints), makes
2082   # it faster
2083   $scale = $scale->numify() if ref ($scale);
2084
2085   # scale < 0, but > -len (not >=!)
2086   if (($scale < 0 && $scale < -$len-1) || ($scale >= $len))
2087     {
2088     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2089     return $x;
2090     }
2091
2092   # count of 0's to pad, from left (+) or right (-): 9 - +6 => 3, or |-6| => 6
2093   my ($pad,$digit_round,$digit_after);
2094   $pad = $len - $scale;
2095   $pad = abs($scale-1) if $scale < 0;
2096
2097   # do not use digit(), it is costly for binary => decimal
2098
2099   my $xs = $CALC->_str($x->{value});
2100   my $pl = -$pad-1;
2101
2102   # pad:   123: 0 => -1, at 1 => -2, at 2 => -3, at 3 => -4
2103   # pad+1: 123: 0 => 0,  at 1 => -1, at 2 => -2, at 3 => -3
2104   $digit_round = '0'; $digit_round = substr($xs,$pl,1) if $pad <= $len;
2105   $pl++; $pl ++ if $pad >= $len;
2106   $digit_after = '0'; $digit_after = substr($xs,$pl,1) if $pad > 0;
2107
2108   # in case of 01234 we round down, for 6789 up, and only in case 5 we look
2109   # closer at the remaining digits of the original $x, remember decision
2110   my $round_up = 1;                                     # default round up
2111   $round_up -- if
2112     ($mode eq 'trunc')                          ||      # trunc by round down
2113     ($digit_after =~ /[01234]/)                 ||      # round down anyway,
2114                                                         # 6789 => round up
2115     ($digit_after eq '5')                       &&      # not 5000...0000
2116     ($x->_scan_for_nonzero($pad,$xs) == 0)              &&
2117     (
2118      ($mode eq 'even') && ($digit_round =~ /[24680]/) ||
2119      ($mode eq 'odd')  && ($digit_round =~ /[13579]/) ||
2120      ($mode eq '+inf') && ($x->{sign} eq '-')   ||
2121      ($mode eq '-inf') && ($x->{sign} eq '+')   ||
2122      ($mode eq 'zero')          # round down if zero, sign adjusted below
2123     );
2124   my $put_back = 0;                                     # not yet modified
2125
2126   if (($pad > 0) && ($pad <= $len))
2127     {
2128     substr($xs,-$pad,$pad) = '0' x $pad;
2129     $put_back = 1;
2130     }
2131   elsif ($pad > $len)
2132     {
2133     $x->bzero();                                        # round to '0'
2134     }
2135
2136   if ($round_up)                                        # what gave test above?
2137     {
2138     $put_back = 1;
2139     $pad = $len, $xs = '0' x $pad if $scale < 0;        # tlr: whack 0.51=>1.0
2140
2141     # we modify directly the string variant instead of creating a number and
2142     # adding it, since that is faster (we already have the string)
2143     my $c = 0; $pad ++;                         # for $pad == $len case
2144     while ($pad <= $len)
2145       {
2146       $c = substr($xs,-$pad,1) + 1; $c = '0' if $c eq '10';
2147       substr($xs,-$pad,1) = $c; $pad++;
2148       last if $c != 0;                          # no overflow => early out
2149       }
2150     $xs = '1'.$xs if $c == 0;
2151
2152     }
2153   $x->{value} = $CALC->_new($xs) if $put_back == 1;     # put back in if needed
2154
2155   $x->{_a} = $scale if $scale >= 0;
2156   if ($scale < 0)
2157     {
2158     $x->{_a} = $len+$scale;
2159     $x->{_a} = 0 if $scale < -$len;
2160     }
2161   $x;
2162   }
2163
2164 sub bfloor
2165   {
2166   # return integer less or equal then number; no-op since it's already integer
2167   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2168
2169   $x->round(@r);
2170   }
2171
2172 sub bceil
2173   {
2174   # return integer greater or equal then number; no-op since it's already int
2175   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2176
2177   $x->round(@r);
2178   }
2179
2180 sub as_number
2181   {
2182   # An object might be asked to return itself as bigint on certain overloaded
2183   # operations, this does exactly this, so that sub classes can simple inherit
2184   # it or override with their own integer conversion routine.
2185   $_[0]->copy();
2186   }
2187
2188 sub as_hex
2189   {
2190   # return as hex string, with prefixed 0x
2191   my $x = shift; $x = $class->new($x) if !ref($x);
2192
2193   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2194
2195   my $s = '';
2196   $s = $x->{sign} if $x->{sign} eq '-';
2197   $s . $CALC->_as_hex($x->{value});
2198   }
2199
2200 sub as_bin
2201   {
2202   # return as binary string, with prefixed 0b
2203   my $x = shift; $x = $class->new($x) if !ref($x);
2204
2205   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2206
2207   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2208   return $s . $CALC->_as_bin($x->{value});
2209   }
2210
2211 ##############################################################################
2212 # private stuff (internal use only)
2213
2214 sub objectify
2215   {
2216   # check for strings, if yes, return objects instead
2217
2218   # the first argument is number of args objectify() should look at it will
2219   # return $count+1 elements, the first will be a classname. This is because
2220   # overloaded '""' calls bstr($object,undef,undef) and this would result in
2221   # useless objects beeing created and thrown away. So we cannot simple loop
2222   # over @_. If the given count is 0, all arguments will be used.
2223
2224   # If the second arg is a ref, use it as class.
2225   # If not, try to use it as classname, unless undef, then use $class
2226   # (aka Math::BigInt). The latter shouldn't happen,though.
2227
2228   # caller:                        gives us:
2229   # $x->badd(1);                => ref x, scalar y
2230   # Class->badd(1,2);           => classname x (scalar), scalar x, scalar y
2231   # Class->badd( Class->(1),2); => classname x (scalar), ref x, scalar y
2232   # Math::BigInt::badd(1,2);    => scalar x, scalar y
2233   # In the last case we check number of arguments to turn it silently into
2234   # $class,1,2. (We can not take '1' as class ;o)
2235   # badd($class,1) is not supported (it should, eventually, try to add undef)
2236   # currently it tries 'Math::BigInt' + 1, which will not work.
2237
2238   # some shortcut for the common cases
2239   # $x->unary_op();
2240   return (ref($_[1]),$_[1]) if (@_ == 2) && ($_[0]||0 == 1) && ref($_[1]);
2241
2242   my $count = abs(shift || 0);
2243
2244   my (@a,$k,$d);                # resulting array, temp, and downgrade
2245   if (ref $_[0])
2246     {
2247     # okay, got object as first
2248     $a[0] = ref $_[0];
2249     }
2250   else
2251     {
2252     # nope, got 1,2 (Class->xxx(1) => Class,1 and not supported)
2253     $a[0] = $class;
2254     $a[0] = shift if $_[0] =~ /^[A-Z].*::/;     # classname as first?
2255     }
2256
2257   no strict 'refs';
2258   # disable downgrading, because Math::BigFLoat->foo('1.0','2.0') needs floats
2259   if (defined ${"$a[0]::downgrade"})
2260     {
2261     $d = ${"$a[0]::downgrade"};
2262     ${"$a[0]::downgrade"} = undef;
2263     }
2264
2265   my $up = ${"$a[0]::upgrade"};
2266   #print "Now in objectify, my class is today $a[0], count = $count\n";
2267   if ($count == 0)
2268     {
2269     while (@_)
2270       {
2271       $k = shift;
2272       if (!ref($k))
2273         {
2274         $k = $a[0]->new($k);
2275         }
2276       elsif (!defined $up && ref($k) ne $a[0])
2277         {
2278         # foreign object, try to convert to integer
2279         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2280         }
2281       push @a,$k;
2282       }
2283     }
2284   else
2285     {
2286     while ($count > 0)
2287       {
2288       $count--;
2289       $k = shift;
2290       if (!ref($k))
2291         {
2292         $k = $a[0]->new($k);
2293         }
2294       elsif (!defined $up && ref($k) ne $a[0])
2295         {
2296         # foreign object, try to convert to integer
2297         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2298         }
2299       push @a,$k;
2300       }
2301     push @a,@_;         # return other params, too
2302     }
2303   if (! wantarray)
2304     {
2305     require Carp; Carp::croak ("$class objectify needs list context");
2306     }
2307   ${"$a[0]::downgrade"} = $d;
2308   @a;
2309   }
2310
2311 sub import
2312   {
2313   my $self = shift;
2314
2315   $IMPORT++;                            # remember we did import()
2316   my @a; my $l = scalar @_;
2317   for ( my $i = 0; $i < $l ; $i++ )
2318     {
2319     if ($_[$i] eq ':constant')
2320       {
2321       # this causes overlord er load to step in
2322       overload::constant
2323         integer => sub { $self->new(shift) },
2324         binary => sub { $self->new(shift) };
2325       }
2326     elsif ($_[$i] eq 'upgrade')
2327       {
2328       # this causes upgrading
2329       $upgrade = $_[$i+1];              # or undef to disable
2330       $i++;
2331       }
2332     elsif ($_[$i] =~ /^lib$/i)
2333       {
2334       # this causes a different low lib to take care...
2335       $CALC = $_[$i+1] || '';
2336       $i++;
2337       }
2338     else
2339       {
2340       push @a, $_[$i];
2341       }
2342     }
2343   # any non :constant stuff is handled by our parent, Exporter
2344   # even if @_ is empty, to give it a chance
2345   $self->SUPER::import(@a);                     # need it for subclasses
2346   $self->export_to_level(1,$self,@a);           # need it for MBF
2347
2348   # try to load core math lib
2349   my @c = split /\s*,\s*/,$CALC;
2350   push @c,'Calc';                               # if all fail, try this
2351   $CALC = '';                                   # signal error
2352   foreach my $lib (@c)
2353     {
2354     next if ($lib || '') eq '';
2355     $lib = 'Math::BigInt::'.$lib if $lib !~ /^Math::BigInt/i;
2356     $lib =~ s/\.pm$//;
2357     if ($] < 5.006)
2358       {
2359       # Perl < 5.6.0 dies with "out of memory!" when eval() and ':constant' is
2360       # used in the same script, or eval inside import().
2361       my @parts = split /::/, $lib;             # Math::BigInt => Math BigInt
2362       my $file = pop @parts; $file .= '.pm';    # BigInt => BigInt.pm
2363       require File::Spec;
2364       $file = File::Spec->catfile (@parts, $file);
2365       eval { require "$file"; $lib->import( @c ); }
2366       }
2367     else
2368       {
2369       eval "use $lib qw/@c/;";
2370       }
2371     if ($@ eq '')
2372       {
2373       my $ok = 1;
2374       # loaded it ok, see if the api_version() is high enough
2375       if ($lib->can('api_version') && $lib->api_version() >= 1.0)
2376         {
2377         $ok = 0;
2378         # api_version matches, check if it really provides anything we need
2379         for my $method (qw/
2380                 one two ten
2381                 str num
2382                 add mul div sub dec inc
2383                 acmp len digit is_one is_zero is_even is_odd
2384                 is_two is_ten
2385                 new copy check from_hex from_bin as_hex as_bin zeros
2386                 rsft lsft xor and or
2387                 mod sqrt root fac pow modinv modpow log_int gcd
2388          /)
2389           {
2390           if (!$lib->can("_$method"))
2391             {
2392             if (($WARN{$lib}||0) < 2)
2393               {
2394               require Carp;
2395               Carp::carp ("$lib is missing method '_$method'");
2396               $WARN{$lib} = 1;          # still warn about the lib
2397               }
2398             $ok++; last;
2399             }
2400           }
2401         }
2402       if ($ok == 0)
2403         {
2404         $CALC = $lib;
2405         last;                   # found a usable one, break
2406         }
2407       else
2408         {
2409         if (($WARN{$lib}||0) < 2)
2410           {
2411           my $ver = eval "\$$lib\::VERSION";
2412           require Carp;
2413           Carp::carp ("Cannot load outdated $lib v$ver, please upgrade");
2414           $WARN{$lib} = 2;              # never warn again
2415           }
2416         }
2417       }
2418     }
2419   if ($CALC eq '')
2420     {
2421     require Carp;
2422     Carp::croak ("Couldn't load any math lib, not even 'Calc.pm'");
2423     }
2424   _fill_can_cache();            # for emulating lower math lib functions
2425   }
2426
2427 sub _fill_can_cache
2428   {
2429   # fill $CAN with the results of $CALC->can(...)
2430
2431   %CAN = ();
2432   for my $method (qw/ signed_and or signed_or xor signed_xor /)
2433     {
2434     $CAN{$method} = $CALC->can("_$method") ? 1 : 0;
2435     }
2436   }
2437
2438 sub __from_hex
2439   {
2440   # convert a (ref to) big hex string to BigInt, return undef for error
2441   my $hs = shift;
2442
2443   my $x = Math::BigInt->bzero();
2444
2445   # strip underscores
2446   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2447   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2448
2449   return $x->bnan() if $hs !~ /^[\-\+]?0x[0-9A-Fa-f]+$/;
2450
2451   my $sign = '+'; $sign = '-' if $hs =~ /^-/;
2452
2453   $hs =~ s/^[+-]//;                                             # strip sign
2454   $x->{value} = $CALC->_from_hex($hs);
2455   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2456   $x;
2457   }
2458
2459 sub __from_bin
2460   {
2461   # convert a (ref to) big binary string to BigInt, return undef for error
2462   my $bs = shift;
2463
2464   my $x = Math::BigInt->bzero();
2465   # strip underscores
2466   $bs =~ s/([01])_([01])/$1$2/g;
2467   $bs =~ s/([01])_([01])/$1$2/g;
2468   return $x->bnan() if $bs !~ /^[+-]?0b[01]+$/;
2469
2470   my $sign = '+'; $sign = '-' if $bs =~ /^\-/;
2471   $bs =~ s/^[+-]//;                                             # strip sign
2472
2473   $x->{value} = $CALC->_from_bin($bs);
2474   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2475   $x;
2476   }
2477
2478 sub _split
2479   {
2480   # (ref to num_str) return num_str
2481   # internal, take apart a string and return the pieces
2482   # strip leading/trailing whitespace, leading zeros, underscore and reject
2483   # invalid input
2484   my $x = shift;
2485
2486   # strip white space at front, also extranous leading zeros
2487   $x =~ s/^\s*([-]?)0*([0-9])/$1$2/g;   # will not strip '  .2'
2488   $x =~ s/^\s+//;                       # but this will
2489   $x =~ s/\s+$//g;                      # strip white space at end
2490
2491   # shortcut, if nothing to split, return early
2492   if ($x =~ /^[+-]?\d+\z/)
2493     {
2494     $x =~ s/^([+-])0*([0-9])/$2/; my $sign = $1 || '+';
2495     return (\$sign, \$x, \'', \'', \0);
2496     }
2497
2498   # invalid starting char?
2499   return if $x !~ /^[+-]?(\.?[0-9]|0b[0-1]|0x[0-9a-fA-F])/;
2500
2501   return __from_hex($x) if $x =~ /^[\-\+]?0x/;  # hex string
2502   return __from_bin($x) if $x =~ /^[\-\+]?0b/;  # binary string
2503
2504   # strip underscores between digits
2505   $x =~ s/(\d)_(\d)/$1$2/g;
2506   $x =~ s/(\d)_(\d)/$1$2/g;             # do twice for 1_2_3
2507
2508   # some possible inputs:
2509   # 2.1234 # 0.12        # 1          # 1E1 # 2.134E1 # 434E-10 # 1.02009E-2
2510   # .2     # 1_2_3.4_5_6 # 1.4E1_2_3  # 1e3 # +.2     # 0e999
2511
2512   my ($m,$e,$last) = split /[Ee]/,$x;
2513   return if defined $last;              # last defined => 1e2E3 or others
2514   $e = '0' if !defined $e || $e eq "";
2515
2516   # sign,value for exponent,mantint,mantfrac
2517   my ($es,$ev,$mis,$miv,$mfv);
2518   # valid exponent?
2519   if ($e =~ /^([+-]?)0*(\d+)$/) # strip leading zeros
2520     {
2521     $es = $1; $ev = $2;
2522     # valid mantissa?
2523     return if $m eq '.' || $m eq '';
2524     my ($mi,$mf,$lastf) = split /\./,$m;
2525     return if defined $lastf;           # lastf defined => 1.2.3 or others
2526     $mi = '0' if !defined $mi;
2527     $mi .= '0' if $mi =~ /^[\-\+]?$/;
2528     $mf = '0' if !defined $mf || $mf eq '';
2529     if ($mi =~ /^([+-]?)0*(\d+)$/) # strip leading zeros
2530       {
2531       $mis = $1||'+'; $miv = $2;
2532       return unless ($mf =~ /^(\d*?)0*$/);      # strip trailing zeros
2533       $mfv = $1;
2534       # handle the 0e999 case here
2535       $ev = 0 if $miv eq '0' && $mfv eq '';
2536       return (\$mis,\$miv,\$mfv,\$es,\$ev);
2537       }
2538     }
2539   return; # NaN, not a number
2540   }
2541
2542 ##############################################################################
2543 # internal calculation routines (others are in Math::BigInt::Calc etc)
2544
2545 sub __lcm
2546   {
2547   # (BINT or num_str, BINT or num_str) return BINT
2548   # does modify first argument
2549   # LCM
2550
2551   my $x = shift; my $ty = shift;
2552   return $x->bnan() if ($x->{sign} eq $nan) || ($ty->{sign} eq $nan);
2553   $x * $ty / bgcd($x,$ty);
2554   }
2555
2556 ###############################################################################
2557 # this method return 0 if the object can be modified, or 1 for not
2558 # We use a fast constant sub() here, to avoid costly calls. Subclasses
2559 # may override it with special code (f.i. Math::BigInt::Constant does so)
2560
2561 sub modify () { 0; }
2562
2563 1;
2564 __END__
2565
2566 =head1 NAME
2567
2568 Math::BigInt - Arbitrary size integer math package
2569
2570 =head1 SYNOPSIS
2571
2572   use Math::BigInt;
2573
2574   # or make it faster: install (optional) Math::BigInt::GMP
2575   # and always use (it will fall back to pure Perl if the
2576   # GMP library is not installed):
2577
2578   use Math::BigInt lib => 'GMP';
2579
2580   my $str = '1234567890';
2581   my @values = (64,74,18);
2582   my $n = 1; my $sign = '-';
2583
2584   # Number creation
2585   $x = Math::BigInt->new($str);         # defaults to 0
2586   $y = $x->copy();                      # make a true copy
2587   $nan  = Math::BigInt->bnan();         # create a NotANumber
2588   $zero = Math::BigInt->bzero();        # create a +0
2589   $inf = Math::BigInt->binf();          # create a +inf
2590   $inf = Math::BigInt->binf('-');       # create a -inf
2591   $one = Math::BigInt->bone();          # create a +1
2592   $one = Math::BigInt->bone('-');       # create a -1
2593
2594   # Testing (don't modify their arguments)
2595   # (return true if the condition is met, otherwise false)
2596
2597   $x->is_zero();        # if $x is +0
2598   $x->is_nan();         # if $x is NaN
2599   $x->is_one();         # if $x is +1
2600   $x->is_one('-');      # if $x is -1
2601   $x->is_odd();         # if $x is odd
2602   $x->is_even();        # if $x is even
2603   $x->is_pos();         # if $x >= 0
2604   $x->is_neg();         # if $x <  0
2605   $x->is_inf($sign);    # if $x is +inf, or -inf (sign is default '+')
2606   $x->is_int();         # if $x is an integer (not a float)
2607
2608   # comparing and digit/sign extration
2609   $x->bcmp($y);         # compare numbers (undef,<0,=0,>0)
2610   $x->bacmp($y);        # compare absolutely (undef,<0,=0,>0)
2611   $x->sign();           # return the sign, either +,- or NaN
2612   $x->digit($n);        # return the nth digit, counting from right
2613   $x->digit(-$n);       # return the nth digit, counting from left
2614
2615   # The following all modify their first argument. If you want to preserve
2616   # $x, use $z = $x->copy()->bXXX($y); See under L<CAVEATS> for why this is
2617   # neccessary when mixing $a = $b assigments with non-overloaded math.
2618
2619   $x->bzero();          # set $x to 0
2620   $x->bnan();           # set $x to NaN
2621   $x->bone();           # set $x to +1
2622   $x->bone('-');        # set $x to -1
2623   $x->binf();           # set $x to inf
2624   $x->binf('-');        # set $x to -inf
2625
2626   $x->bneg();           # negation
2627   $x->babs();           # absolute value
2628   $x->bnorm();          # normalize (no-op in BigInt)
2629   $x->bnot();           # two's complement (bit wise not)
2630   $x->binc();           # increment $x by 1
2631   $x->bdec();           # decrement $x by 1
2632
2633   $x->badd($y);         # addition (add $y to $x)
2634   $x->bsub($y);         # subtraction (subtract $y from $x)
2635   $x->bmul($y);         # multiplication (multiply $x by $y)
2636   $x->bdiv($y);         # divide, set $x to quotient
2637                         # return (quo,rem) or quo if scalar
2638
2639   $x->bmod($y);            # modulus (x % y)
2640   $x->bmodpow($exp,$mod);  # modular exponentation (($num**$exp) % $mod))
2641   $x->bmodinv($mod);       # the inverse of $x in the given modulus $mod
2642
2643   $x->bpow($y);            # power of arguments (x ** y)
2644   $x->blsft($y);           # left shift
2645   $x->brsft($y);           # right shift
2646   $x->blsft($y,$n);        # left shift, by base $n (like 10)
2647   $x->brsft($y,$n);        # right shift, by base $n (like 10)
2648
2649   $x->band($y);            # bitwise and
2650   $x->bior($y);            # bitwise inclusive or
2651   $x->bxor($y);            # bitwise exclusive or
2652   $x->bnot();              # bitwise not (two's complement)
2653
2654   $x->bsqrt();             # calculate square-root
2655   $x->broot($y);           # $y'th root of $x (e.g. $y == 3 => cubic root)
2656   $x->bfac();              # factorial of $x (1*2*3*4*..$x)
2657
2658   $x->round($A,$P,$mode);  # round to accuracy or precision using mode $mode
2659   $x->bround($n);          # accuracy: preserve $n digits
2660   $x->bfround($n);         # round to $nth digit, no-op for BigInts
2661
2662   # The following do not modify their arguments in BigInt (are no-ops),
2663   # but do so in BigFloat:
2664
2665   $x->bfloor();            # return integer less or equal than $x
2666   $x->bceil();             # return integer greater or equal than $x
2667
2668   # The following do not modify their arguments:
2669
2670   # greatest common divisor (no OO style)
2671   my $gcd = Math::BigInt::bgcd(@values);
2672   # lowest common multiplicator (no OO style)
2673   my $lcm = Math::BigInt::blcm(@values);
2674
2675   $x->length();            # return number of digits in number
2676   ($xl,$f) = $x->length(); # length of number and length of fraction part,
2677                            # latter is always 0 digits long for BigInt's
2678
2679   $x->exponent();          # return exponent as BigInt
2680   $x->mantissa();          # return (signed) mantissa as BigInt
2681   $x->parts();             # return (mantissa,exponent) as BigInt
2682   $x->copy();              # make a true copy of $x (unlike $y = $x;)
2683   $x->as_int();            # return as BigInt (in BigInt: same as copy())
2684   $x->numify();            # return as scalar (might overflow!)
2685
2686   # conversation to string (do not modify their argument)
2687   $x->bstr();              # normalized string
2688   $x->bsstr();             # normalized string in scientific notation
2689   $x->as_hex();            # as signed hexadecimal string with prefixed 0x
2690   $x->as_bin();            # as signed binary string with prefixed 0b
2691
2692
2693   # precision and accuracy (see section about rounding for more)
2694   $x->precision();         # return P of $x (or global, if P of $x undef)
2695   $x->precision($n);       # set P of $x to $n
2696   $x->accuracy();          # return A of $x (or global, if A of $x undef)
2697   $x->accuracy($n);        # set A $x to $n
2698
2699   # Global methods
2700   Math::BigInt->precision(); # get/set global P for all BigInt objects
2701   Math::BigInt->accuracy();  # get/set global A for all BigInt objects
2702   Math::BigInt->config();    # return hash containing configuration
2703
2704 =head1 DESCRIPTION
2705
2706 All operators (inlcuding basic math operations) are overloaded if you
2707 declare your big integers as
2708
2709   $i = new Math::BigInt '123_456_789_123_456_789';
2710
2711 Operations with overloaded operators preserve the arguments which is
2712 exactly what you expect.
2713
2714 =over 2
2715
2716 =item Input
2717
2718 Input values to these routines may be any string, that looks like a number
2719 and results in an integer, including hexadecimal and binary numbers.
2720
2721 Scalars holding numbers may also be passed, but note that non-integer numbers
2722 may already have lost precision due to the conversation to float. Quote
2723 your input if you want BigInt to see all the digits:
2724
2725         $x = Math::BigInt->new(12345678890123456789);   # bad
2726         $x = Math::BigInt->new('12345678901234567890'); # good
2727
2728 You can include one underscore between any two digits.
2729
2730 This means integer values like 1.01E2 or even 1000E-2 are also accepted.
2731 Non-integer values result in NaN.
2732
2733 Currently, Math::BigInt::new() defaults to 0, while Math::BigInt::new('')
2734 results in 'NaN'. This might change in the future, so use always the following
2735 explicit forms to get a zero or NaN:
2736
2737         $zero = Math::BigInt->bzero();
2738         $nan = Math::BigInt->bnan();
2739
2740 C<bnorm()> on a BigInt object is now effectively a no-op, since the numbers
2741 are always stored in normalized form. If passed a string, creates a BigInt
2742 object from the input.
2743
2744 =item Output
2745
2746 Output values are BigInt objects (normalized), except for bstr(), which
2747 returns a string in normalized form.
2748 Some routines (C<is_odd()>, C<is_even()>, C<is_zero()>, C<is_one()>,
2749 C<is_nan()>) return true or false, while others (C<bcmp()>, C<bacmp()>)
2750 return either undef, <0, 0 or >0 and are suited for sort.
2751
2752 =back
2753
2754 =head1 METHODS
2755
2756 Each of the methods below (except config(), accuracy() and precision())
2757 accepts three additional parameters. These arguments $A, $P and $R are
2758 accuracy, precision and round_mode. Please see the section about
2759 L<ACCURACY and PRECISION> for more information.
2760
2761 =head2 config
2762
2763         use Data::Dumper;
2764
2765         print Dumper ( Math::BigInt->config() );
2766         print Math::BigInt->config()->{lib},"\n";
2767
2768 Returns a hash containing the configuration, e.g. the version number, lib
2769 loaded etc. The following hash keys are currently filled in with the
2770 appropriate information.
2771
2772         key             Description
2773                         Example
2774         ============================================================
2775         lib             Name of the low-level math library
2776                         Math::BigInt::Calc
2777         lib_version     Version of low-level math library (see 'lib')
2778                         0.30
2779         class           The class name of config() you just called
2780                         Math::BigInt
2781         upgrade         To which class math operations might be upgraded
2782                         Math::BigFloat
2783         downgrade       To which class math operations might be downgraded
2784                         undef
2785         precision       Global precision
2786                         undef
2787         accuracy        Global accuracy
2788                         undef
2789         round_mode      Global round mode
2790                         even
2791         version         version number of the class you used
2792                         1.61
2793         div_scale       Fallback acccuracy for div
2794                         40
2795         trap_nan        If true, traps creation of NaN via croak()
2796                         1
2797         trap_inf        If true, traps creation of +inf/-inf via croak()
2798                         1
2799
2800 The following values can be set by passing C<config()> a reference to a hash:
2801
2802         trap_inf trap_nan
2803         upgrade downgrade precision accuracy round_mode div_scale
2804
2805 Example:
2806
2807         $new_cfg = Math::BigInt->config( { trap_inf => 1, precision => 5 } );
2808
2809 =head2 accuracy
2810
2811         $x->accuracy(5);                # local for $x
2812         CLASS->accuracy(5);             # global for all members of CLASS
2813         $A = $x->accuracy();            # read out
2814         $A = CLASS->accuracy();         # read out
2815
2816 Set or get the global or local accuracy, aka how many significant digits the
2817 results have.
2818
2819 Please see the section about L<ACCURACY AND PRECISION> for further details.
2820
2821 Value must be greater than zero. Pass an undef value to disable it:
2822
2823         $x->accuracy(undef);
2824         Math::BigInt->accuracy(undef);
2825
2826 Returns the current accuracy. For C<$x->accuracy()> it will return either the
2827 local accuracy, or if not defined, the global. This means the return value
2828 represents the accuracy that will be in effect for $x:
2829
2830         $y = Math::BigInt->new(1234567);        # unrounded
2831         print Math::BigInt->accuracy(4),"\n";   # set 4, print 4
2832         $x = Math::BigInt->new(123456);         # will be automatically rounded
2833         print "$x $y\n";                        # '123500 1234567'
2834         print $x->accuracy(),"\n";              # will be 4
2835         print $y->accuracy(),"\n";              # also 4, since global is 4
2836         print Math::BigInt->accuracy(5),"\n";   # set to 5, print 5
2837         print $x->accuracy(),"\n";              # still 4
2838         print $y->accuracy(),"\n";              # 5, since global is 5
2839
2840 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
2841 globals separated from Math::BigInt, but it is possible to subclass
2842 Math::BigInt and make the globals of the subclass aliases to the ones from
2843 Math::BigInt.
2844
2845 =head2 precision
2846
2847         $x->precision(-2);              # local for $x, round right of the dot
2848         $x->precision(2);               # ditto, but round left of the dot
2849         CLASS->accuracy(5);             # global for all members of CLASS
2850         CLASS->precision(-5);           # ditto
2851         $P = CLASS->precision();        # read out
2852         $P = $x->precision();           # read out
2853
2854 Set or get the global or local precision, aka how many digits the result has
2855 after the dot (or where to round it when passing a positive number). In
2856 Math::BigInt, passing a negative number precision has no effect since no
2857 numbers have digits after the dot.
2858
2859 Please see the section about L<ACCURACY AND PRECISION> for further details.
2860
2861 Value must be greater than zero. Pass an undef value to disable it:
2862
2863         $x->precision(undef);
2864         Math::BigInt->precision(undef);
2865
2866 Returns the current precision. For C<$x->precision()> it will return either the
2867 local precision of $x, or if not defined, the global. This means the return
2868 value represents the accuracy that will be in effect for $x:
2869
2870         $y = Math::BigInt->new(1234567);        # unrounded
2871         print Math::BigInt->precision(4),"\n";  # set 4, print 4
2872         $x = Math::BigInt->new(123456);         # will be automatically rounded
2873
2874 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
2875 globals separated from Math::BigInt, but it is possible to subclass
2876 Math::BigInt and make the globals of the subclass aliases to the ones from
2877 Math::BigInt.
2878
2879 =head2 brsft
2880
2881         $x->brsft($y,$n);
2882
2883 Shifts $x right by $y in base $n. Default is base 2, used are usually 10 and
2884 2, but others work, too.
2885
2886 Right shifting usually amounts to dividing $x by $n ** $y and truncating the
2887 result:
2888
2889
2890         $x = Math::BigInt->new(10);
2891         $x->brsft(1);                   # same as $x >> 1: 5
2892         $x = Math::BigInt->new(1234);
2893         $x->brsft(2,10);                # result 12
2894
2895 There is one exception, and that is base 2 with negative $x:
2896
2897
2898         $x = Math::BigInt->new(-5);
2899         print $x->brsft(1);
2900
2901 This will print -3, not -2 (as it would if you divide -5 by 2 and truncate the
2902 result).
2903
2904 =head2 new
2905
2906         $x = Math::BigInt->new($str,$A,$P,$R);
2907
2908 Creates a new BigInt object from a scalar or another BigInt object. The
2909 input is accepted as decimal, hex (with leading '0x') or binary (with leading
2910 '0b').
2911
2912 See L<Input> for more info on accepted input formats.
2913
2914 =head2 bnan
2915
2916         $x = Math::BigInt->bnan();
2917
2918 Creates a new BigInt object representing NaN (Not A Number).
2919 If used on an object, it will set it to NaN:
2920
2921         $x->bnan();
2922
2923 =head2 bzero
2924
2925         $x = Math::BigInt->bzero();
2926
2927 Creates a new BigInt object representing zero.
2928 If used on an object, it will set it to zero:
2929
2930         $x->bzero();
2931
2932 =head2 binf
2933
2934         $x = Math::BigInt->binf($sign);
2935
2936 Creates a new BigInt object representing infinity. The optional argument is
2937 either '-' or '+', indicating whether you want infinity or minus infinity.
2938 If used on an object, it will set it to infinity:
2939
2940         $x->binf();
2941         $x->binf('-');
2942
2943 =head2 bone
2944
2945         $x = Math::BigInt->binf($sign);
2946
2947 Creates a new BigInt object representing one. The optional argument is
2948 either '-' or '+', indicating whether you want one or minus one.
2949 If used on an object, it will set it to one:
2950
2951         $x->bone();             # +1
2952         $x->bone('-');          # -1
2953
2954 =head2 is_one()/is_zero()/is_nan()/is_inf()
2955
2956
2957         $x->is_zero();                  # true if arg is +0
2958         $x->is_nan();                   # true if arg is NaN
2959         $x->is_one();                   # true if arg is +1
2960         $x->is_one('-');                # true if arg is -1
2961         $x->is_inf();                   # true if +inf
2962         $x->is_inf('-');                # true if -inf (sign is default '+')
2963
2964 These methods all test the BigInt for beeing one specific value and return
2965 true or false depending on the input. These are faster than doing something
2966 like:
2967
2968         if ($x == 0)
2969
2970 =head2 is_pos()/is_neg()
2971
2972         $x->is_pos();                   # true if >= 0
2973         $x->is_neg();                   # true if <  0
2974
2975 The methods return true if the argument is positive or negative, respectively.
2976 C<NaN> is neither positive nor negative, while C<+inf> counts as positive, and
2977 C<-inf> is negative. A C<zero> is positive.
2978
2979 These methods are only testing the sign, and not the value.
2980
2981 C<is_positive()> and C<is_negative()> are aliase to C<is_pos()> and
2982 C<is_neg()>, respectively. C<is_positive()> and C<is_negative()> were
2983 introduced in v1.36, while C<is_pos()> and C<is_neg()> were only introduced
2984 in v1.68.
2985
2986 =head2 is_odd()/is_even()/is_int()
2987
2988         $x->is_odd();                   # true if odd, false for even
2989         $x->is_even();                  # true if even, false for odd
2990         $x->is_int();                   # true if $x is an integer
2991
2992 The return true when the argument satisfies the condition. C<NaN>, C<+inf>,
2993 C<-inf> are not integers and are neither odd nor even.
2994
2995 In BigInt, all numbers except C<NaN>, C<+inf> and C<-inf> are integers.
2996
2997 =head2 bcmp
2998
2999         $x->bcmp($y);
3000
3001 Compares $x with $y and takes the sign into account.
3002 Returns -1, 0, 1 or undef.
3003
3004 =head2 bacmp
3005
3006         $x->bacmp($y);
3007
3008 Compares $x with $y while ignoring their. Returns -1, 0, 1 or undef.
3009
3010 =head2 sign
3011
3012         $x->sign();
3013
3014 Return the sign, of $x, meaning either C<+>, C<->, C<-inf>, C<+inf> or NaN.
3015
3016 =head2 digit
3017
3018         $x->digit($n);          # return the nth digit, counting from right
3019
3020 If C<$n> is negative, returns the digit counting from left.
3021
3022 =head2 bneg
3023
3024         $x->bneg();
3025
3026 Negate the number, e.g. change the sign between '+' and '-', or between '+inf'
3027 and '-inf', respectively. Does nothing for NaN or zero.
3028
3029 =head2 babs
3030
3031         $x->babs();
3032
3033 Set the number to it's absolute value, e.g. change the sign from '-' to '+'
3034 and from '-inf' to '+inf', respectively. Does nothing for NaN or positive
3035 numbers.
3036
3037 =head2 bnorm
3038
3039         $x->bnorm();                    # normalize (no-op)
3040
3041 =head2 bnot
3042
3043         $x->bnot();
3044
3045 Two's complement (bit wise not). This is equivalent to
3046
3047         $x->binc()->bneg();
3048
3049 but faster.
3050
3051 =head2 binc
3052
3053         $x->binc();                     # increment x by 1
3054
3055 =head2 bdec
3056
3057         $x->bdec();                     # decrement x by 1
3058
3059 =head2 badd
3060
3061         $x->badd($y);                   # addition (add $y to $x)
3062
3063 =head2 bsub
3064
3065         $x->bsub($y);                   # subtraction (subtract $y from $x)
3066
3067 =head2 bmul
3068
3069         $x->bmul($y);                   # multiplication (multiply $x by $y)
3070
3071 =head2 bdiv
3072
3073         $x->bdiv($y);                   # divide, set $x to quotient
3074                                         # return (quo,rem) or quo if scalar
3075
3076 =head2 bmod
3077
3078         $x->bmod($y);                   # modulus (x % y)
3079
3080 =head2 bmodinv
3081
3082         num->bmodinv($mod);             # modular inverse
3083
3084 Returns the inverse of C<$num> in the given modulus C<$mod>.  'C<NaN>' is
3085 returned unless C<$num> is relatively prime to C<$mod>, i.e. unless
3086 C<bgcd($num, $mod)==1>.
3087
3088 =head2 bmodpow
3089
3090         $num->bmodpow($exp,$mod);       # modular exponentation
3091                                         # ($num**$exp % $mod)
3092
3093 Returns the value of C<$num> taken to the power C<$exp> in the modulus
3094 C<$mod> using binary exponentation.  C<bmodpow> is far superior to
3095 writing
3096
3097         $num ** $exp % $mod
3098
3099 because it is much faster - it reduces internal variables into
3100 the modulus whenever possible, so it operates on smaller numbers.
3101
3102 C<bmodpow> also supports negative exponents.
3103
3104         bmodpow($num, -1, $mod)
3105
3106 is exactly equivalent to
3107
3108         bmodinv($num, $mod)
3109
3110 =head2 bpow
3111
3112         $x->bpow($y);                   # power of arguments (x ** y)
3113
3114 =head2 blsft
3115
3116         $x->blsft($y);          # left shift
3117         $x->blsft($y,$n);       # left shift, in base $n (like 10)
3118
3119 =head2 brsft
3120
3121         $x->brsft($y);          # right shift
3122         $x->brsft($y,$n);       # right shift, in base $n (like 10)
3123
3124 =head2 band
3125
3126         $x->band($y);                   # bitwise and
3127
3128 =head2 bior
3129
3130         $x->bior($y);                   # bitwise inclusive or
3131
3132 =head2 bxor
3133
3134         $x->bxor($y);                   # bitwise exclusive or
3135
3136 =head2 bnot
3137
3138         $x->bnot();                     # bitwise not (two's complement)
3139
3140 =head2 bsqrt
3141
3142         $x->bsqrt();                    # calculate square-root
3143
3144 =head2 bfac
3145
3146         $x->bfac();                     # factorial of $x (1*2*3*4*..$x)
3147
3148 =head2 round
3149
3150         $x->round($A,$P,$round_mode);
3151
3152 Round $x to accuracy C<$A> or precision C<$P> using the round mode
3153 C<$round_mode>.
3154
3155 =head2 bround
3156
3157         $x->bround($N);               # accuracy: preserve $N digits
3158
3159 =head2 bfround
3160
3161         $x->bfround($N);              # round to $Nth digit, no-op for BigInts
3162
3163 =head2 bfloor
3164
3165         $x->bfloor();
3166
3167 Set $x to the integer less or equal than $x. This is a no-op in BigInt, but
3168 does change $x in BigFloat.
3169
3170 =head2 bceil
3171
3172         $x->bceil();
3173
3174 Set $x to the integer greater or equal than $x. This is a no-op in BigInt, but
3175 does change $x in BigFloat.
3176
3177 =head2 bgcd
3178
3179         bgcd(@values);          # greatest common divisor (no OO style)
3180
3181 =head2 blcm
3182
3183         blcm(@values);          # lowest common multiplicator (no OO style)
3184
3185 head2 length
3186
3187         $x->length();
3188         ($xl,$fl) = $x->length();
3189
3190 Returns the number of digits in the decimal representation of the number.
3191 In list context, returns the length of the integer and fraction part. For
3192 BigInt's, the length of the fraction part will always be 0.
3193
3194 =head2 exponent
3195
3196         $x->exponent();
3197
3198 Return the exponent of $x as BigInt.
3199
3200 =head2 mantissa
3201
3202         $x->mantissa();
3203
3204 Return the signed mantissa of $x as BigInt.
3205
3206 =head2 parts
3207
3208         $x->parts();            # return (mantissa,exponent) as BigInt
3209
3210 =head2 copy
3211
3212         $x->copy();             # make a true copy of $x (unlike $y = $x;)
3213
3214 =head2 as_int
3215
3216         $x->as_int();
3217
3218 Returns $x as a BigInt (truncated towards zero). In BigInt this is the same as
3219 C<copy()>.
3220
3221 C<as_number()> is an alias to this method. C<as_number> was introduced in
3222 v1.22, while C<as_int()> was only introduced in v1.68.
3223
3224 =head2 bstr
3225
3226         $x->bstr();
3227
3228 Returns a normalized string represantation of C<$x>.
3229
3230 =head2 bsstr
3231
3232         $x->bsstr();            # normalized string in scientific notation
3233
3234 =head2 as_hex
3235
3236         $x->as_hex();           # as signed hexadecimal string with prefixed 0x
3237
3238 =head2 as_bin
3239
3240         $x->as_bin();           # as signed binary string with prefixed 0b
3241
3242 =head1 ACCURACY and PRECISION
3243
3244 Since version v1.33, Math::BigInt and Math::BigFloat have full support for
3245 accuracy and precision based rounding, both automatically after every
3246 operation, as well as manually.
3247
3248 This section describes the accuracy/precision handling in Math::Big* as it
3249 used to be and as it is now, complete with an explanation of all terms and
3250 abbreviations.
3251
3252 Not yet implemented things (but with correct description) are marked with '!',
3253 things that need to be answered are marked with '?'.
3254
3255 In the next paragraph follows a short description of terms used here (because
3256 these may differ from terms used by others people or documentation).
3257
3258 During the rest of this document, the shortcuts A (for accuracy), P (for
3259 precision), F (fallback) and R (rounding mode) will be used.
3260
3261 =head2 Precision P
3262
3263 A fixed number of digits before (positive) or after (negative)
3264 the decimal point. For example, 123.45 has a precision of -2. 0 means an
3265 integer like 123 (or 120). A precision of 2 means two digits to the left
3266 of the decimal point are zero, so 123 with P = 1 becomes 120. Note that
3267 numbers with zeros before the decimal point may have different precisions,
3268 because 1200 can have p = 0, 1 or 2 (depending on what the inital value
3269 was). It could also have p < 0, when the digits after the decimal point
3270 are zero.
3271
3272 The string output (of floating point numbers) will be padded with zeros:
3273
3274         Initial value   P       A       Result          String
3275         ------------------------------------------------------------
3276         1234.01         -3              1000            1000
3277         1234            -2              1200            1200
3278         1234.5          -1              1230            1230
3279         1234.001        1               1234            1234.0
3280         1234.01         0               1234            1234
3281         1234.01         2               1234.01         1234.01
3282         1234.01         5               1234.01         1234.01000
3283
3284 For BigInts, no padding occurs.
3285
3286 =head2 Accuracy A
3287
3288 Number of significant digits. Leading zeros are not counted. A
3289 number may have an accuracy greater than the non-zero digits
3290 when there are zeros in it or trailing zeros. For example, 123.456 has
3291 A of 6, 10203 has 5, 123.0506 has 7, 123.450000 has 8 and 0.000123 has 3.
3292
3293 The string output (of floating point numbers) will be padded with zeros:
3294
3295         Initial value   P       A       Result          String
3296         ------------------------------------------------------------
3297         1234.01                 3       1230            1230
3298         1234.01                 6       1234.01         1234.01
3299         1234.1                  8       1234.1          1234.1000
3300
3301 For BigInts, no padding occurs.
3302
3303 =head2 Fallback F
3304
3305 When both A and P are undefined, this is used as a fallback accuracy when
3306 dividing numbers.
3307
3308 =head2 Rounding mode R
3309
3310 When rounding a number, different 'styles' or 'kinds'
3311 of rounding are possible. (Note that random rounding, as in
3312 Math::Round, is not implemented.)
3313
3314 =over 2
3315
3316 =item 'trunc'
3317
3318 truncation invariably removes all digits following the
3319 rounding place, replacing them with zeros. Thus, 987.65 rounded
3320 to tens (P=1) becomes 980, and rounded to the fourth sigdig
3321 becomes 987.6 (A=4). 123.456 rounded to the second place after the
3322 decimal point (P=-2) becomes 123.46.
3323
3324 All other implemented styles of rounding attempt to round to the
3325 "nearest digit." If the digit D immediately to the right of the
3326 rounding place (skipping the decimal point) is greater than 5, the
3327 number is incremented at the rounding place (possibly causing a
3328 cascade of incrementation): e.g. when rounding to units, 0.9 rounds
3329 to 1, and -19.9 rounds to -20. If D < 5, the number is similarly
3330 truncated at the rounding place: e.g. when rounding to units, 0.4
3331 rounds to 0, and -19.4 rounds to -19.
3332
3333 However the results of other styles of rounding differ if the
3334 digit immediately to the right of the rounding place (skipping the
3335 decimal point) is 5 and if there are no digits, or no digits other
3336 than 0, after that 5. In such cases:
3337
3338 =item 'even'
3339
3340 rounds the digit at the rounding place to 0, 2, 4, 6, or 8
3341 if it is not already. E.g., when rounding to the first sigdig, 0.45
3342 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.
3343
3344 =item 'odd'
3345
3346 rounds the digit at the rounding place to 1, 3, 5, 7, or 9 if
3347 it is not already. E.g., when rounding to the first sigdig, 0.45
3348 becomes 0.5, -0.55 becomes -0.5, but 0.5501 becomes 0.6.
3349
3350 =item '+inf'
3351
3352 round to plus infinity, i.e. always round up. E.g., when
3353 rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5,
3354 and 0.4501 also becomes 0.5.
3355
3356 =item '-inf'
3357
3358 round to minus infinity, i.e. always round down. E.g., when
3359 rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6,
3360 but 0.4501 becomes 0.5.
3361
3362 =item 'zero'
3363
3364 round to zero, i.e. positive numbers down, negative ones up.
3365 E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55
3366 becomes -0.5, but 0.4501 becomes 0.5.
3367
3368 =back
3369
3370 The handling of A & P in MBI/MBF (the old core code shipped with Perl
3371 versions <= 5.7.2) is like this:
3372
3373 =over 2
3374
3375 =item Precision
3376
3377   * ffround($p) is able to round to $p number of digits after the decimal
3378     point
3379   * otherwise P is unused
3380
3381 =item Accuracy (significant digits)
3382
3383   * fround($a) rounds to $a significant digits
3384   * only fdiv() and fsqrt() take A as (optional) paramater
3385     + other operations simply create the same number (fneg etc), or more (fmul)
3386       of digits
3387     + rounding/truncating is only done when explicitly calling one of fround
3388       or ffround, and never for BigInt (not implemented)
3389   * fsqrt() simply hands its accuracy argument over to fdiv.
3390   * the documentation and the comment in the code indicate two different ways
3391     on how fdiv() determines the maximum number of digits it should calculate,
3392     and the actual code does yet another thing
3393     POD:
3394       max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
3395     Comment:
3396       result has at most max(scale, length(dividend), length(divisor)) digits
3397     Actual code:
3398       scale = max(scale, length(dividend)-1,length(divisor)-1);
3399       scale += length(divisior) - length(dividend);
3400     So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10+9-3).
3401     Actually, the 'difference' added to the scale is calculated from the
3402     number of "significant digits" in dividend and divisor, which is derived
3403     by looking at the length of the mantissa. Which is wrong, since it includes
3404     the + sign (oops) and actually gets 2 for '+100' and 4 for '+101'. Oops
3405     again. Thus 124/3 with div_scale=1 will get you '41.3' based on the strange
3406     assumption that 124 has 3 significant digits, while 120/7 will get you
3407     '17', not '17.1' since 120 is thought to have 2 significant digits.
3408     The rounding after the division then uses the remainder and $y to determine
3409     wether it must round up or down.
3410  ?  I have no idea which is the right way. That's why I used a slightly more
3411  ?  simple scheme and tweaked the few failing testcases to match it.
3412
3413 =back
3414
3415 This is how it works now:
3416
3417 =over 2
3418
3419 =item Setting/Accessing
3420
3421   * You can set the A global via C<< Math::BigInt->accuracy() >> or
3422     C<< Math::BigFloat->accuracy() >> or whatever class you are using.
3423   * You can also set P globally by using C<< Math::SomeClass->precision() >>
3424     likewise.
3425   * Globals are classwide, and not inherited by subclasses.
3426   * to undefine A, use C<< Math::SomeCLass->accuracy(undef); >>
3427   * to undefine P, use C<< Math::SomeClass->precision(undef); >>
3428   * Setting C<< Math::SomeClass->accuracy() >> clears automatically
3429     C<< Math::SomeClass->precision() >>, and vice versa.
3430   * To be valid, A must be > 0, P can have any value.
3431   * If P is negative, this means round to the P'th place to the right of the
3432     decimal point; positive values mean to the left of the decimal point.
3433     P of 0 means round to integer.
3434   * to find out the current global A, use C<< Math::SomeClass->accuracy() >>
3435   * to find out the current global P, use C<< Math::SomeClass->precision() >>
3436   * use C<< $x->accuracy() >> respective C<< $x->precision() >> for the local
3437     setting of C<< $x >>.
3438   * Please note that C<< $x->accuracy() >> respecive C<< $x->precision() >>
3439     return eventually defined global A or P, when C<< $x >>'s A or P is not
3440     set.
3441
3442 =item Creating numbers
3443
3444   * When you create a number, you can give it's desired A or P via:
3445     $x = Math::BigInt->new($number,$A,$P);
3446   * Only one of A or P can be defined, otherwise the result is NaN
3447   * If no A or P is give ($x = Math::BigInt->new($number) form), then the
3448     globals (if set) will be used. Thus changing the global defaults later on
3449     will not change the A or P of previously created numbers (i.e., A and P of
3450     $x will be what was in effect when $x was created)
3451   * If given undef for A and P, B<no> rounding will occur, and the globals will
3452     B<not> be used. This is used by subclasses to create numbers without
3453     suffering rounding in the parent. Thus a subclass is able to have it's own
3454     globals enforced upon creation of a number by using
3455     C<< $x = Math::BigInt->new($number,undef,undef) >>:
3456
3457         use Math::BigInt::SomeSubclass;
3458         use Math::BigInt;
3459
3460         Math::BigInt->accuracy(2);
3461         Math::BigInt::SomeSubClass->accuracy(3);
3462         $x = Math::BigInt::SomeSubClass->new(1234);
3463
3464     $x is now 1230, and not 1200. A subclass might choose to implement
3465     this otherwise, e.g. falling back to the parent's A and P.
3466
3467 =item Usage
3468
3469   * If A or P are enabled/defined, they are used to round the result of each
3470     operation according to the rules below
3471   * Negative P is ignored in Math::BigInt, since BigInts never have digits
3472     after the decimal point
3473   * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
3474     Math::BigInt as globals does not tamper with the parts of a BigFloat.
3475     A flag is used to mark all Math::BigFloat numbers as 'never round'.
3476
3477 =item Precedence
3478
3479   * It only makes sense that a number has only one of A or P at a time.
3480     If you set either A or P on one object, or globally, the other one will
3481     be automatically cleared.
3482   * If two objects are involved in an operation, and one of them has A in
3483     effect, and the other P, this results in an error (NaN).
3484   * A takes precendence over P (Hint: A comes before P).
3485     If neither of them is defined, nothing is used, i.e. the result will have
3486     as many digits as it can (with an exception for fdiv/fsqrt) and will not
3487     be rounded.
3488   * There is another setting for fdiv() (and thus for fsqrt()). If neither of
3489     A or P is defined, fdiv() will use a fallback (F) of $div_scale digits.
3490     If either the dividend's or the divisor's mantissa has more digits than
3491     the value of F, the higher value will be used instead of F.
3492     This is to limit the digits (A) of the result (just consider what would
3493     happen with unlimited A and P in the case of 1/3 :-)
3494   * fdiv will calculate (at least) 4 more digits than required (determined by
3495     A, P or F), and, if F is not used, round the result
3496     (this will still fail in the case of a result like 0.12345000000001 with A
3497     or P of 5, but this can not be helped - or can it?)
3498   * Thus you can have the math done by on Math::Big* class in two modi:
3499     + never round (this is the default):
3500       This is done by setting A and P to undef. No math operation
3501       will round the result, with fdiv() and fsqrt() as exceptions to guard
3502       against overflows. You must explicitely call bround(), bfround() or
3503       round() (the latter with parameters).
3504       Note: Once you have rounded a number, the settings will 'stick' on it
3505       and 'infect' all other numbers engaged in math operations with it, since
3506       local settings have the highest precedence. So, to get SaferRound[tm],
3507       use a copy() before rounding like this:
3508
3509         $x = Math::BigFloat->new(12.34);
3510         $y = Math::BigFloat->new(98.76);
3511         $z = $x * $y;                           # 1218.6984
3512         print $x->copy()->fround(3);            # 12.3 (but A is now 3!)
3513         $z = $x * $y;                           # still 1218.6984, without
3514                                                 # copy would have been 1210!
3515
3516     + round after each op:
3517       After each single operation (except for testing like is_zero()), the
3518       method round() is called and the result is rounded appropriately. By
3519       setting proper values for A and P, you can have all-the-same-A or
3520       all-the-same-P modes. For example, Math::Currency might set A to undef,
3521       and P to -2, globally.
3522
3523  ?Maybe an extra option that forbids local A & P settings would be in order,
3524  ?so that intermediate rounding does not 'poison' further math?
3525
3526 =item Overriding globals
3527
3528   * you will be able to give A, P and R as an argument to all the calculation
3529     routines; the second parameter is A, the third one is P, and the fourth is
3530     R (shift right by one for binary operations like badd). P is used only if
3531     the first parameter (A) is undefined. These three parameters override the
3532     globals in the order detailed as follows, i.e. the first defined value
3533     wins:
3534     (local: per object, global: global default, parameter: argument to sub)
3535       + parameter A
3536       + parameter P
3537       + local A (if defined on both of the operands: smaller one is taken)
3538       + local P (if defined on both of the operands: bigger one is taken)
3539       + global A
3540       + global P
3541       + global F
3542   * fsqrt() will hand its arguments to fdiv(), as it used to, only now for two
3543     arguments (A and P) instead of one
3544
3545 =item Local settings
3546
3547   * You can set A or P locally by using C<< $x->accuracy() >> or
3548     C<< $x->precision() >>
3549     and thus force different A and P for different objects/numbers.
3550   * Setting A or P this way immediately rounds $x to the new value.
3551   * C<< $x->accuracy() >> clears C<< $x->precision() >>, and vice versa.
3552
3553 =item Rounding
3554
3555   * the rounding routines will use the respective global or local settings.
3556     fround()/bround() is for accuracy rounding, while ffround()/bfround()
3557     is for precision
3558   * the two rounding functions take as the second parameter one of the
3559     following rounding modes (R):
3560     'even', 'odd', '+inf', '-inf', 'zero', 'trunc'
3561   * you can set/get the global R by using C<< Math::SomeClass->round_mode() >>
3562     or by setting C<< $Math::SomeClass::round_mode >>
3563   * after each operation, C<< $result->round() >> is called, and the result may
3564     eventually be rounded (that is, if A or P were set either locally,
3565     globally or as parameter to the operation)
3566   * to manually round a number, call C<< $x->round($A,$P,$round_mode); >>
3567     this will round the number by using the appropriate rounding function
3568     and then normalize it.
3569   * rounding modifies the local settings of the number:
3570
3571         $x = Math::BigFloat->new(123.456);
3572         $x->accuracy(5);
3573         $x->bround(4);
3574
3575     Here 4 takes precedence over 5, so 123.5 is the result and $x->accuracy()
3576     will be 4 from now on.
3577
3578 =item Default values
3579
3580   * R: 'even'
3581   * F: 40
3582   * A: undef
3583   * P: undef
3584
3585 =item Remarks
3586
3587   * The defaults are set up so that the new code gives the same results as
3588     the old code (except in a few cases on fdiv):
3589     + Both A and P are undefined and thus will not be used for rounding
3590       after each operation.
3591     + round() is thus a no-op, unless given extra parameters A and P
3592
3593 =back
3594
3595 =head1 INTERNALS
3596
3597 The actual numbers are stored as unsigned big integers (with seperate sign).
3598 You should neither care about nor depend on the internal representation; it
3599 might change without notice. Use only method calls like C<< $x->sign(); >>
3600 instead relying on the internal hash keys like in C<< $x->{sign}; >>.
3601
3602 =head2 MATH LIBRARY
3603
3604 Math with the numbers is done (by default) by a module called
3605 C<Math::BigInt::Calc>. This is equivalent to saying:
3606
3607         use Math::BigInt lib => 'Calc';
3608
3609 You can change this by using:
3610
3611         use Math::BigInt lib => 'BitVect';
3612
3613 The following would first try to find Math::BigInt::Foo, then
3614 Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:
3615
3616         use Math::BigInt lib => 'Foo,Math::BigInt::Bar';
3617
3618 Since Math::BigInt::GMP is in almost all cases faster than Calc (especially in
3619 cases involving really big numbers, where it is B<much> faster), and there is
3620 no penalty if Math::BigInt::GMP is not installed, it is a good idea to always
3621 use the following:
3622
3623         use Math::BigInt lib => 'GMP';
3624
3625 Different low-level libraries use different formats to store the
3626 numbers. You should not depend on the number having a specific format.
3627
3628 See the respective math library module documentation for further details.
3629
3630 =head2 SIGN
3631
3632 The sign is either '+', '-', 'NaN', '+inf' or '-inf' and stored seperately.
3633
3634 A sign of 'NaN' is used to represent the result when input arguments are not
3635 numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively
3636 minus infinity. You will get '+inf' when dividing a positive number by 0, and
3637 '-inf' when dividing any negative number by 0.
3638
3639 =head2 mantissa(), exponent() and parts()
3640
3641 C<mantissa()> and C<exponent()> return the said parts of the BigInt such
3642 that:
3643
3644         $m = $x->mantissa();
3645         $e = $x->exponent();
3646         $y = $m * ( 10 ** $e );
3647         print "ok\n" if $x == $y;
3648
3649 C<< ($m,$e) = $x->parts() >> is just a shortcut that gives you both of them
3650 in one go. Both the returned mantissa and exponent have a sign.
3651
3652 Currently, for BigInts C<$e> is always 0, except for NaN, +inf and -inf,
3653 where it is C<NaN>; and for C<$x == 0>, where it is C<1> (to be compatible
3654 with Math::BigFloat's internal representation of a zero as C<0E1>).
3655
3656 C<$m> is currently just a copy of the original number. The relation between
3657 C<$e> and C<$m> will stay always the same, though their real values might
3658 change.
3659
3660 =head1 EXAMPLES
3661
3662   use Math::BigInt;
3663
3664   sub bint { Math::BigInt->new(shift); }
3665
3666   $x = Math::BigInt->bstr("1234")       # string "1234"
3667   $x = "$x";                            # same as bstr()
3668   $x = Math::BigInt->bneg("1234");      # BigInt "-1234"
3669   $x = Math::BigInt->babs("-12345");    # BigInt "12345"
3670   $x = Math::BigInt->bnorm("-0 00");    # BigInt "0"
3671   $x = bint(1) + bint(2);               # BigInt "3"
3672   $x = bint(1) + "2";                   # ditto (auto-BigIntify of "2")
3673   $x = bint(1);                         # BigInt "1"
3674   $x = $x + 5 / 2;                      # BigInt "3"
3675   $x = $x ** 3;                         # BigInt "27"
3676   $x *= 2;                              # BigInt "54"
3677   $x = Math::BigInt->new(0);            # BigInt "0"
3678   $x--;                                 # BigInt "-1"
3679   $x = Math::BigInt->badd(4,5)          # BigInt "9"
3680   print $x->bsstr();                    # 9e+0
3681
3682 Examples for rounding:
3683
3684   use Math::BigFloat;
3685   use Test;
3686
3687   $x = Math::BigFloat->new(123.4567);
3688   $y = Math::BigFloat->new(123.456789);
3689   Math::BigFloat->accuracy(4);          # no more A than 4
3690
3691   ok ($x->copy()->fround(),123.4);      # even rounding
3692   print $x->copy()->fround(),"\n";      # 123.4
3693   Math::BigFloat->round_mode('odd');    # round to odd
3694   print $x->copy()->fround(),"\n";      # 123.5
3695   Math::BigFloat->accuracy(5);          # no more A than 5
3696   Math::BigFloat->round_mode('odd');    # round to odd
3697   print $x->copy()->fround(),"\n";      # 123.46
3698   $y = $x->copy()->fround(4),"\n";      # A = 4: 123.4
3699   print "$y, ",$y->accuracy(),"\n";     # 123.4, 4
3700
3701   Math::BigFloat->accuracy(undef);      # A not important now
3702   Math::BigFloat->precision(2);         # P important
3703   print $x->copy()->bnorm(),"\n";       # 123.46
3704   print $x->copy()->fround(),"\n";      # 123.46
3705
3706 Examples for converting:
3707
3708   my $x = Math::BigInt->new('0b1'.'01' x 123);
3709   print "bin: ",$x->as_bin()," hex:",$x->as_hex()," dec: ",$x,"\n";
3710
3711 =head1 Autocreating constants
3712
3713 After C<use Math::BigInt ':constant'> all the B<integer> decimal, hexadecimal
3714 and binary constants in the given scope are converted to C<Math::BigInt>.
3715 This conversion happens at compile time.
3716
3717 In particular,
3718
3719   perl -MMath::BigInt=:constant -e 'print 2**100,"\n"'
3720
3721 prints the integer value of C<2**100>. Note that without conversion of
3722 constants the expression 2**100 will be calculated as perl scalar.
3723
3724 Please note that strings and floating point constants are not affected,
3725 so that
3726
3727         use Math::BigInt qw/:constant/;
3728
3729         $x = 1234567890123456789012345678901234567890
3730                 + 123456789123456789;
3731         $y = '1234567890123456789012345678901234567890'
3732                 + '123456789123456789';
3733
3734 do not work. You need an explicit Math::BigInt->new() around one of the
3735 operands. You should also quote large constants to protect loss of precision:
3736
3737         use Math::BigInt;
3738
3739         $x = Math::BigInt->new('1234567889123456789123456789123456789');
3740
3741 Without the quotes Perl would convert the large number to a floating point
3742 constant at compile time and then hand the result to BigInt, which results in
3743 an truncated result or a NaN.
3744
3745 This also applies to integers that look like floating point constants:
3746
3747         use Math::BigInt ':constant';
3748
3749         print ref(123e2),"\n";
3750         print ref(123.2e2),"\n";
3751
3752 will print nothing but newlines. Use either L<bignum> or L<Math::BigFloat>
3753 to get this to work.
3754
3755 =head1 PERFORMANCE
3756
3757 Using the form $x += $y; etc over $x = $x + $y is faster, since a copy of $x
3758 must be made in the second case. For long numbers, the copy can eat up to 20%
3759 of the work (in the case of addition/subtraction, less for
3760 multiplication/division). If $y is very small compared to $x, the form
3761 $x += $y is MUCH faster than $x = $x + $y since making the copy of $x takes
3762 more time then the actual addition.
3763
3764 With a technique called copy-on-write, the cost of copying with overload could
3765 be minimized or even completely avoided. A test implementation of COW did show
3766 performance gains for overloaded math, but introduced a performance loss due
3767 to a constant overhead for all other operatons. So Math::BigInt does currently
3768 not COW.
3769
3770 The rewritten version of this module (vs. v0.01) is slower on certain
3771 operations, like C<new()>, C<bstr()> and C<numify()>. The reason are that it
3772 does now more work and handles much more cases. The time spent in these
3773 operations is usually gained in the other math operations so that code on
3774 the average should get (much) faster. If they don't, please contact the author.
3775
3776 Some operations may be slower for small numbers, but are significantly faster
3777 for big numbers. Other operations are now constant (O(1), like C<bneg()>,
3778 C<babs()> etc), instead of O(N) and thus nearly always take much less time.
3779 These optimizations were done on purpose.
3780
3781 If you find the Calc module to slow, try to install any of the replacement
3782 modules and see if they help you.
3783
3784 =head2 Alternative math libraries
3785
3786 You can use an alternative library to drive Math::BigInt via:
3787
3788         use Math::BigInt lib => 'Module';
3789
3790 See L<MATH LIBRARY> for more information.
3791
3792 For more benchmark results see L<http://bloodgate.com/perl/benchmarks.html>.
3793
3794 =head2 SUBCLASSING
3795
3796 =head1 Subclassing Math::BigInt
3797
3798 The basic design of Math::BigInt allows simple subclasses with very little
3799 work, as long as a few simple rules are followed:
3800
3801 =over 2
3802
3803 =item *
3804
3805 The public API must remain consistent, i.e. if a sub-class is overloading
3806 addition, the sub-class must use the same name, in this case badd(). The
3807 reason for this is that Math::BigInt is optimized to call the object methods
3808 directly.
3809
3810 =item *
3811
3812 The private object hash keys like C<$x->{sign}> may not be changed, but
3813 additional keys can be added, like C<$x->{_custom}>.
3814
3815 =item *
3816
3817 Accessor functions are available for all existing object hash keys and should
3818 be used instead of directly accessing the internal hash keys. The reason for
3819 this is that Math::BigInt itself has a pluggable interface which permits it
3820 to support different storage methods.
3821
3822 =back
3823
3824 More complex sub-classes may have to replicate more of the logic internal of
3825 Math::BigInt if they need to change more basic behaviors. A subclass that
3826 needs to merely change the output only needs to overload C<bstr()>.
3827
3828 All other object methods and overloaded functions can be directly inherited
3829 from the parent class.
3830
3831 At the very minimum, any subclass will need to provide it's own C<new()> and can
3832 store additional hash keys in the object. There are also some package globals
3833 that must be defined, e.g.:
3834
3835   # Globals
3836   $accuracy = undef;
3837   $precision = -2;       # round to 2 decimal places
3838   $round_mode = 'even';
3839   $div_scale = 40;
3840
3841 Additionally, you might want to provide the following two globals to allow
3842 auto-upgrading and auto-downgrading to work correctly:
3843
3844   $upgrade = undef;
3845   $downgrade = undef;
3846
3847 This allows Math::BigInt to correctly retrieve package globals from the
3848 subclass, like C<$SubClass::precision>.  See t/Math/BigInt/Subclass.pm or
3849 t/Math/BigFloat/SubClass.pm completely functional subclass examples.
3850
3851 Don't forget to
3852
3853         use overload;
3854
3855 in your subclass to automatically inherit the overloading from the parent. If
3856 you like, you can change part of the overloading, look at Math::String for an
3857 example.
3858
3859 =head1 UPGRADING
3860
3861 When used like this:
3862
3863         use Math::BigInt upgrade => 'Foo::Bar';
3864
3865 certain operations will 'upgrade' their calculation and thus the result to
3866 the class Foo::Bar. Usually this is used in conjunction with Math::BigFloat:
3867
3868         use Math::BigInt upgrade => 'Math::BigFloat';
3869
3870 As a shortcut, you can use the module C<bignum>:
3871
3872         use bignum;
3873
3874 Also good for oneliners:
3875
3876         perl -Mbignum -le 'print 2 ** 255'
3877
3878 This makes it possible to mix arguments of different classes (as in 2.5 + 2)
3879 as well es preserve accuracy (as in sqrt(3)).
3880
3881 Beware: This feature is not fully implemented yet.
3882
3883 =head2 Auto-upgrade
3884
3885 The following methods upgrade themselves unconditionally; that is if upgrade
3886 is in effect, they will always hand up their work:
3887
3888 =over 2
3889
3890 =item bsqrt()
3891
3892 =item div()
3893
3894 =item blog()
3895
3896 =back
3897
3898 Beware: This list is not complete.
3899
3900 All other methods upgrade themselves only when one (or all) of their
3901 arguments are of the class mentioned in $upgrade (This might change in later
3902 versions to a more sophisticated scheme):
3903
3904 =head1 BUGS
3905
3906 =over 2
3907
3908 =item broot() does not work
3909
3910 The broot() function in BigInt may only work for small values. This will be
3911 fixed in a later version.
3912
3913 =item Out of Memory!
3914
3915 Under Perl prior to 5.6.0 having an C<use Math::BigInt ':constant';> and
3916 C<eval()> in your code will crash with "Out of memory". This is probably an
3917 overload/exporter bug. You can workaround by not having C<eval()>
3918 and ':constant' at the same time or upgrade your Perl to a newer version.
3919
3920 =item Fails to load Calc on Perl prior 5.6.0
3921
3922 Since eval(' use ...') can not be used in conjunction with ':constant', BigInt
3923 will fall back to eval { require ... } when loading the math lib on Perls
3924 prior to 5.6.0. This simple replaces '::' with '/' and thus might fail on
3925 filesystems using a different seperator.
3926
3927 =back
3928
3929 =head1 CAVEATS
3930
3931 Some things might not work as you expect them. Below is documented what is
3932 known to be troublesome:
3933
3934 =over 1
3935
3936 =item bstr(), bsstr() and 'cmp'
3937
3938 Both C<bstr()> and C<bsstr()> as well as automated stringify via overload now
3939 drop the leading '+'. The old code would return '+3', the new returns '3'.
3940 This is to be consistent with Perl and to make C<cmp> (especially with
3941 overloading) to work as you expect. It also solves problems with C<Test.pm>,
3942 because it's C<ok()> uses 'eq' internally.
3943
3944 Mark Biggar said, when asked about to drop the '+' altogether, or make only
3945 C<cmp> work:
3946
3947         I agree (with the first alternative), don't add the '+' on positive
3948         numbers.  It's not as important anymore with the new internal
3949         form for numbers.  It made doing things like abs and neg easier,
3950         but those have to be done differently now anyway.
3951
3952 So, the following examples will now work all as expected:
3953
3954         use Test;
3955         BEGIN { plan tests => 1 }
3956         use Math::BigInt;
3957
3958         my $x = new Math::BigInt 3*3;
3959         my $y = new Math::BigInt 3*3;
3960
3961         ok ($x,3*3);
3962         print "$x eq 9" if $x eq $y;
3963         print "$x eq 9" if $x eq '9';
3964         print "$x eq 9" if $x eq 3*3;
3965
3966 Additionally, the following still works:
3967
3968         print "$x == 9" if $x == $y;
3969         print "$x == 9" if $x == 9;
3970         print "$x == 9" if $x == 3*3;
3971
3972 There is now a C<bsstr()> method to get the string in scientific notation aka
3973 C<1e+2> instead of C<100>. Be advised that overloaded 'eq' always uses bstr()
3974 for comparisation, but Perl will represent some numbers as 100 and others
3975 as 1e+308. If in doubt, convert both arguments to Math::BigInt before
3976 comparing them as strings:
3977
3978         use Test;
3979         BEGIN { plan tests => 3 }
3980         use Math::BigInt;
3981
3982         $x = Math::BigInt->new('1e56'); $y = 1e56;
3983         ok ($x,$y);                     # will fail
3984         ok ($x->bsstr(),$y);            # okay
3985         $y = Math::BigInt->new($y);
3986         ok ($x,$y);                     # okay
3987
3988 Alternatively, simple use C<< <=> >> for comparisations, this will get it
3989 always right. There is not yet a way to get a number automatically represented
3990 as a string that matches exactly the way Perl represents it.
3991
3992 =item int()
3993
3994 C<int()> will return (at least for Perl v5.7.1 and up) another BigInt, not a
3995 Perl scalar:
3996
3997         $x = Math::BigInt->new(123);
3998         $y = int($x);                           # BigInt 123
3999         $x = Math::BigFloat->new(123.45);
4000         $y = int($x);                           # BigInt 123
4001
4002 In all Perl versions you can use C<as_number()> for the same effect:
4003
4004         $x = Math::BigFloat->new(123.45);
4005         $y = $x->as_number();                   # BigInt 123
4006
4007 This also works for other subclasses, like Math::String.
4008
4009 It is yet unlcear whether overloaded int() should return a scalar or a BigInt.
4010
4011 =item length
4012
4013 The following will probably not do what you expect:
4014
4015         $c = Math::BigInt->new(123);
4016         print $c->length(),"\n";                # prints 30
4017
4018 It prints both the number of digits in the number and in the fraction part
4019 since print calls C<length()> in list context. Use something like:
4020
4021         print scalar $c->length(),"\n";         # prints 3
4022
4023 =item bdiv
4024
4025 The following will probably not do what you expect:
4026
4027         print $c->bdiv(10000),"\n";
4028
4029 It prints both quotient and remainder since print calls C<bdiv()> in list
4030 context. Also, C<bdiv()> will modify $c, so be carefull. You probably want
4031 to use
4032
4033         print $c / 10000,"\n";
4034         print scalar $c->bdiv(10000),"\n";  # or if you want to modify $c
4035
4036 instead.
4037
4038 The quotient is always the greatest integer less than or equal to the
4039 real-valued quotient of the two operands, and the remainder (when it is
4040 nonzero) always has the same sign as the second operand; so, for
4041 example,
4042
4043           1 / 4  => ( 0, 1)
4044           1 / -4 => (-1,-3)
4045          -3 / 4  => (-1, 1)
4046          -3 / -4 => ( 0,-3)
4047         -11 / 2  => (-5,1)
4048          11 /-2  => (-5,-1)
4049
4050 As a consequence, the behavior of the operator % agrees with the
4051 behavior of Perl's built-in % operator (as documented in the perlop
4052 manpage), and the equation
4053
4054         $x == ($x / $y) * $y + ($x % $y)
4055
4056 holds true for any $x and $y, which justifies calling the two return
4057 values of bdiv() the quotient and remainder. The only exception to this rule
4058 are when $y == 0 and $x is negative, then the remainder will also be
4059 negative. See below under "infinity handling" for the reasoning behing this.
4060
4061 Perl's 'use integer;' changes the behaviour of % and / for scalars, but will
4062 not change BigInt's way to do things. This is because under 'use integer' Perl
4063 will do what the underlying C thinks is right and this is different for each
4064 system. If you need BigInt's behaving exactly like Perl's 'use integer', bug
4065 the author to implement it ;)
4066
4067 =item infinity handling
4068
4069 Here are some examples that explain the reasons why certain results occur while
4070 handling infinity:
4071
4072 The following table shows the result of the division and the remainder, so that
4073 the equation above holds true. Some "ordinary" cases are strewn in to show more
4074 clearly the reasoning:
4075
4076         A /  B  =   C,     R so that C *    B +    R =    A
4077      =========================================================
4078         5 /   8 =   0,     5         0 *    8 +    5 =    5
4079         0 /   8 =   0,     0         0 *    8 +    0 =    0
4080         0 / inf =   0,     0         0 *  inf +    0 =    0
4081         0 /-inf =   0,     0         0 * -inf +    0 =    0
4082         5 / inf =   0,     5         0 *  inf +    5 =    5
4083         5 /-inf =   0,     5         0 * -inf +    5 =    5
4084         -5/ inf =   0,    -5         0 *  inf +   -5 =   -5
4085         -5/-inf =   0,    -5         0 * -inf +   -5 =   -5
4086        inf/   5 =  inf,    0       inf *    5 +    0 =  inf
4087       -inf/   5 = -inf,    0      -inf *    5 +    0 = -inf
4088        inf/  -5 = -inf,    0      -inf *   -5 +    0 =  inf
4089       -inf/  -5 =  inf,    0       inf *   -5 +    0 = -inf
4090          5/   5 =    1,    0         1 *    5 +    0 =    5
4091         -5/  -5 =    1,    0         1 *   -5 +    0 =   -5
4092        inf/ inf =    1,    0         1 *  inf +    0 =  inf
4093       -inf/-inf =    1,    0         1 * -inf +    0 = -inf
4094        inf/-inf =   -1,    0        -1 * -inf +    0 =  inf
4095       -inf/ inf =   -1,    0         1 * -inf +    0 = -inf
4096          8/   0 =  inf,    8       inf *    0 +    8 =    8
4097        inf/   0 =  inf,  inf       inf *    0 +  inf =  inf
4098          0/   0 =  NaN
4099
4100 These cases below violate the "remainder has the sign of the second of the two
4101 arguments", since they wouldn't match up otherwise.
4102
4103         A /  B  =   C,     R so that C *    B +    R =    A
4104      ========================================================
4105       -inf/   0 = -inf, -inf      -inf *    0 +  inf = -inf
4106         -8/   0 = -inf,   -8      -inf *    0 +    8 = -8
4107
4108 =item Modifying and =
4109
4110 Beware of:
4111
4112         $x = Math::BigFloat->new(5);
4113         $y = $x;
4114
4115 It will not do what you think, e.g. making a copy of $x. Instead it just makes
4116 a second reference to the B<same> object and stores it in $y. Thus anything
4117 that modifies $x (except overloaded operators) will modify $y, and vice versa.
4118 Or in other words, C<=> is only safe if you modify your BigInts only via
4119 overloaded math. As soon as you use a method call it breaks:
4120
4121         $x->bmul(2);
4122         print "$x, $y\n";       # prints '10, 10'
4123
4124 If you want a true copy of $x, use:
4125
4126         $y = $x->copy();
4127
4128 You can also chain the calls like this, this will make first a copy and then
4129 multiply it by 2:
4130
4131         $y = $x->copy()->bmul(2);
4132
4133 See also the documentation for overload.pm regarding C<=>.
4134
4135 =item bpow
4136
4137 C<bpow()> (and the rounding functions) now modifies the first argument and
4138 returns it, unlike the old code which left it alone and only returned the
4139 result. This is to be consistent with C<badd()> etc. The first three will
4140 modify $x, the last one won't:
4141
4142         print bpow($x,$i),"\n";         # modify $x
4143         print $x->bpow($i),"\n";        # ditto
4144         print $x **= $i,"\n";           # the same
4145         print $x ** $i,"\n";            # leave $x alone
4146
4147 The form C<$x **= $y> is faster than C<$x = $x ** $y;>, though.
4148
4149 =item Overloading -$x
4150
4151 The following:
4152
4153         $x = -$x;
4154
4155 is slower than
4156
4157         $x->bneg();
4158
4159 since overload calls C<sub($x,0,1);> instead of C<neg($x)>. The first variant
4160 needs to preserve $x since it does not know that it later will get overwritten.
4161 This makes a copy of $x and takes O(N), but $x->bneg() is O(1).
4162
4163 With Copy-On-Write, this issue would be gone, but C-o-W is not implemented
4164 since it is slower for all other things.
4165
4166 =item Mixing different object types
4167
4168 In Perl you will get a floating point value if you do one of the following:
4169
4170         $float = 5.0 + 2;
4171         $float = 2 + 5.0;
4172         $float = 5 / 2;
4173
4174 With overloaded math, only the first two variants will result in a BigFloat:
4175
4176         use Math::BigInt;
4177         use Math::BigFloat;
4178
4179         $mbf = Math::BigFloat->new(5);
4180         $mbi2 = Math::BigInteger->new(5);
4181         $mbi = Math::BigInteger->new(2);
4182
4183                                         # what actually gets called:
4184         $float = $mbf + $mbi;           # $mbf->badd()
4185         $float = $mbf / $mbi;           # $mbf->bdiv()
4186         $integer = $mbi + $mbf;         # $mbi->badd()
4187         $integer = $mbi2 / $mbi;        # $mbi2->bdiv()
4188         $integer = $mbi2 / $mbf;        # $mbi2->bdiv()
4189
4190 This is because math with overloaded operators follows the first (dominating)
4191 operand, and the operation of that is called and returns thus the result. So,
4192 Math::BigInt::bdiv() will always return a Math::BigInt, regardless whether
4193 the result should be a Math::BigFloat or the second operant is one.
4194
4195 To get a Math::BigFloat you either need to call the operation manually,
4196 make sure the operands are already of the proper type or casted to that type
4197 via Math::BigFloat->new():
4198
4199         $float = Math::BigFloat->new($mbi2) / $mbi;     # = 2.5
4200
4201 Beware of simple "casting" the entire expression, this would only convert
4202 the already computed result:
4203
4204         $float = Math::BigFloat->new($mbi2 / $mbi);     # = 2.0 thus wrong!
4205
4206 Beware also of the order of more complicated expressions like:
4207
4208         $integer = ($mbi2 + $mbi) / $mbf;               # int / float => int
4209         $integer = $mbi2 / Math::BigFloat->new($mbi);   # ditto
4210
4211 If in doubt, break the expression into simpler terms, or cast all operands
4212 to the desired resulting type.
4213
4214 Scalar values are a bit different, since:
4215
4216         $float = 2 + $mbf;
4217         $float = $mbf + 2;
4218
4219 will both result in the proper type due to the way the overloaded math works.
4220
4221 This section also applies to other overloaded math packages, like Math::String.
4222
4223 One solution to you problem might be autoupgrading|upgrading. See the
4224 pragmas L<bignum>, L<bigint> and L<bigrat> for an easy way to do this.
4225
4226 =item bsqrt()
4227
4228 C<bsqrt()> works only good if the result is a big integer, e.g. the square
4229 root of 144 is 12, but from 12 the square root is 3, regardless of rounding
4230 mode. The reason is that the result is always truncated to an integer.
4231
4232 If you want a better approximation of the square root, then use:
4233
4234         $x = Math::BigFloat->new(12);
4235         Math::BigFloat->precision(0);
4236         Math::BigFloat->round_mode('even');
4237         print $x->copy->bsqrt(),"\n";           # 4
4238
4239         Math::BigFloat->precision(2);
4240         print $x->bsqrt(),"\n";                 # 3.46
4241         print $x->bsqrt(3),"\n";                # 3.464
4242
4243 =item brsft()
4244
4245 For negative numbers in base see also L<brsft|brsft>.
4246
4247 =back
4248
4249 =head1 LICENSE
4250
4251 This program is free software; you may redistribute it and/or modify it under
4252 the same terms as Perl itself.
4253
4254 =head1 SEE ALSO
4255
4256 L<Math::BigFloat>, L<Math::BigRat> and L<Math::Big> as well as
4257 L<Math::BigInt::BitVect>, L<Math::BigInt::Pari> and  L<Math::BigInt::GMP>.
4258
4259 The pragmas L<bignum>, L<bigint> and L<bigrat> also might be of interest
4260 because they solve the autoupgrading/downgrading issue, at least partly.
4261
4262 The package at
4263 L<http://search.cpan.org/search?mode=module&query=Math%3A%3ABigInt> contains
4264 more documentation including a full version history, testcases, empty
4265 subclass files and benchmarks.
4266
4267 =head1 AUTHORS
4268
4269 Original code by Mark Biggar, overloaded interface by Ilya Zakharevich.
4270 Completely rewritten by Tels http://bloodgate.com in late 2000, 2001 - 2003
4271 and still at it in 2004.
4272
4273 Many people contributed in one or more ways to the final beast, see the file
4274 CREDITS for an (uncomplete) list. If you miss your name, please drop me a
4275 mail. Thank you!
4276
4277 =cut