lib/Math/BigInt.pm

   1 package Math::BigInt;
   2
   3 #
   4 # "Mike had an infinite amount to do and a negative amount of time in which
   5 # to do it." - Before and After
   6 #
   7
   8 # The following hash values are used:
   9 #   value: unsigned int with actual value (as a Math::BigInt::Calc or similiar)
  10 #   sign : +,-,NaN,+inf,-inf
  11 #   _a   : accuracy
  12 #   _p   : precision
  13 #   _f   : flags, used by MBF to flag parts of a float as untouchable
  14
  15 # Remember not to take shortcuts ala $xs = $x->{value}; $CALC->foo($xs); since
  16 # underlying lib might change the reference!
  17
  18 my $class = "Math::BigInt";
  19 use 5.006002;
  20
  21 $VERSION = '1.86';
  22
  23 @ISA = qw(Exporter);
  24 @EXPORT_OK = qw(objectify bgcd blcm);
  25
  26 # _trap_inf and _trap_nan are internal and should never be accessed from the
  27 # outside
  28 use vars qw/$round_mode $accuracy $precision $div_scale $rnd_mode
  29             $upgrade $downgrade $_trap_nan $_trap_inf/;
  30 use strict;
  31
  32 # Inside overload, the first arg is always an object. If the original code had
  33 # it reversed (like $x = 2 * $y), then the third paramater is true.
  34 # In some cases (like add, $x = $x + 2 is the same as $x = 2 + $x) this makes
  35 # no difference, but in some cases it does.
  36
  37 # For overloaded ops with only one argument we simple use $_[0]->copy() to
  38 # preserve the argument.
  39
  40 # Thus inheritance of overload operators becomes possible and transparent for
  41 # our subclasses without the need to repeat the entire overload section there.
  42
  43 use overload
  44 '='     =>      sub { $_[0]->copy(); },
  45
  46 # some shortcuts for speed (assumes that reversed order of arguments is routed
  47 # to normal '+' and we thus can always modify first arg. If this is changed,
  48 # this breaks and must be adjusted.)
  49 '+='    =>      sub { $_[0]->badd($_[1]); },
  50 '-='    =>      sub { $_[0]->bsub($_[1]); },
  51 '*='    =>      sub { $_[0]->bmul($_[1]); },
  52 '/='    =>      sub { scalar $_[0]->bdiv($_[1]); },
  53 '%='    =>      sub { $_[0]->bmod($_[1]); },
  54 '^='    =>      sub { $_[0]->bxor($_[1]); },
  55 '&='    =>      sub { $_[0]->band($_[1]); },
  56 '|='    =>      sub { $_[0]->bior($_[1]); },
  57
  58 '**='   =>      sub { $_[0]->bpow($_[1]); },
  59 '<<='   =>      sub { $_[0]->blsft($_[1]); },
  60 '>>='   =>      sub { $_[0]->brsft($_[1]); },
  61
  62 # not supported by Perl yet
  63 '..'    =>      \&_pointpoint,
  64
  65 '<=>'   =>      sub { my $rc = $_[2] ?
  66                       ref($_[0])->bcmp($_[1],$_[0]) :
  67                       $_[0]->bcmp($_[1]);
  68                       $rc = 1 unless defined $rc;
  69                       $rc <=> 0;
  70                 },
  71 # we need '>=' to get things like "1 >= NaN" right:
  72 '>='    =>      sub { my $rc = $_[2] ?
  73                       ref($_[0])->bcmp($_[1],$_[0]) :
  74                       $_[0]->bcmp($_[1]);
  75                       # if there was a NaN involved, return false
  76                       return '' unless defined $rc;
  77                       $rc >= 0;
  78                 },
  79 'cmp'   =>      sub {
  80          $_[2] ?
  81                "$_[1]" cmp $_[0]->bstr() :
  82                $_[0]->bstr() cmp "$_[1]" },
  83
  84 # make cos()/sin()/atan2() "work" with BigInt's or subclasses
  85 'cos'   =>      sub { cos($_[0]->numify()) },
  86 'sin'   =>      sub { sin($_[0]->numify()) },
  87 'atan2' =>      sub { $_[2] ?
  88                         atan2($_[1],$_[0]->numify()) :
  89                         atan2($_[0]->numify(),$_[1]) },
  90
  91 # are not yet overloadable
  92 #'hex'  =>      sub { print "hex"; $_[0]; },
  93 #'oct'  =>      sub { print "oct"; $_[0]; },
  94
  95 # log(N) is log(N, e), where e is Euler's number
  96 'log'   =>      sub { $_[0]->copy()->blog($_[1], undef); },
  97 'exp'   =>      sub { $_[0]->copy()->bexp($_[1]); },
  98 'int'   =>      sub { $_[0]->copy(); },
  99 'neg'   =>      sub { $_[0]->copy()->bneg(); },
 100 'abs'   =>      sub { $_[0]->copy()->babs(); },
 101 'sqrt'  =>      sub { $_[0]->copy()->bsqrt(); },
 102 '~'     =>      sub { $_[0]->copy()->bnot(); },
 103
 104 # for subtract it's a bit tricky to not modify b: b-a => -a+b
 105 '-'     =>      sub { my $c = $_[0]->copy; $_[2] ?
 106                         $c->bneg()->badd( $_[1]) :
 107                         $c->bsub( $_[1]) },
 108 '+'     =>      sub { $_[0]->copy()->badd($_[1]); },
 109 '*'     =>      sub { $_[0]->copy()->bmul($_[1]); },
 110
 111 '/'     =>      sub {
 112    $_[2] ? ref($_[0])->new($_[1])->bdiv($_[0]) : $_[0]->copy->bdiv($_[1]);
 113   },
 114 '%'     =>      sub {
 115    $_[2] ? ref($_[0])->new($_[1])->bmod($_[0]) : $_[0]->copy->bmod($_[1]);
 116   },
 117 '**'    =>      sub {
 118    $_[2] ? ref($_[0])->new($_[1])->bpow($_[0]) : $_[0]->copy->bpow($_[1]);
 119   },
 120 '<<'    =>      sub {
 121    $_[2] ? ref($_[0])->new($_[1])->blsft($_[0]) : $_[0]->copy->blsft($_[1]);
 122   },
 123 '>>'    =>      sub {
 124    $_[2] ? ref($_[0])->new($_[1])->brsft($_[0]) : $_[0]->copy->brsft($_[1]);
 125   },
 126 '&'     =>      sub {
 127    $_[2] ? ref($_[0])->new($_[1])->band($_[0]) : $_[0]->copy->band($_[1]);
 128   },
 129 '|'     =>      sub {
 130    $_[2] ? ref($_[0])->new($_[1])->bior($_[0]) : $_[0]->copy->bior($_[1]);
 131   },
 132 '^'     =>      sub {
 133    $_[2] ? ref($_[0])->new($_[1])->bxor($_[0]) : $_[0]->copy->bxor($_[1]);
 134   },
 135
 136 # can modify arg of ++ and --, so avoid a copy() for speed, but don't
 137 # use $_[0]->bone(), it would modify $_[0] to be 1!
 138 '++'    =>      sub { $_[0]->binc() },
 139 '--'    =>      sub { $_[0]->bdec() },
 140
 141 # if overloaded, O(1) instead of O(N) and twice as fast for small numbers
 142 'bool'  =>      sub {
 143   # this kludge is needed for perl prior 5.6.0 since returning 0 here fails :-/
 144   # v5.6.1 dumps on this: return !$_[0]->is_zero() || undef;                :-(
 145   my $t = undef;
 146   $t = 1 if !$_[0]->is_zero();
 147   $t;
 148   },
 149
 150 # the original qw() does not work with the TIESCALAR below, why?
 151 # Order of arguments unsignificant
 152 '""' => sub { $_[0]->bstr(); },
 153 '0+' => sub { $_[0]->numify(); }
 154 ;
 155
 156 ##############################################################################
 157 # global constants, flags and accessory
 158
 159 # These vars are public, but their direct usage is not recommended, use the
 160 # accessor methods instead
 161
 162 $round_mode = 'even'; # one of 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'
 163 $accuracy   = undef;
 164 $precision  = undef;
 165 $div_scale  = 40;
 166
 167 $upgrade = undef;                       # default is no upgrade
 168 $downgrade = undef;                     # default is no downgrade
 169
 170 # These are internally, and not to be used from the outside at all
 171
 172 $_trap_nan = 0;                         # are NaNs ok? set w/ config()
 173 $_trap_inf = 0;                         # are infs ok? set w/ config()
 174 my $nan = 'NaN';                        # constants for easier life
 175
 176 my $CALC = 'Math::BigInt::FastCalc';    # module to do the low level math
 177                                         # default is FastCalc.pm
 178 my $IMPORT = 0;                         # was import() called yet?
 179                                         # used to make require work
 180 my %WARN;                               # warn only once for low-level libs
 181 my %CAN;                                # cache for $CALC->can(...)
 182 my %CALLBACKS;                          # callbacks to notify on lib loads
 183 my $EMU_LIB = 'Math/BigInt/CalcEmu.pm'; # emulate low-level math
 184
 185 ##############################################################################
 186 # the old code had $rnd_mode, so we need to support it, too
 187
 188 $rnd_mode   = 'even';
 189 sub TIESCALAR  { my ($class) = @_; bless \$round_mode, $class; }
 190 sub FETCH      { return $round_mode; }
 191 sub STORE      { $rnd_mode = $_[0]->round_mode($_[1]); }
 192
 193 BEGIN
 194   {
 195   # tie to enable $rnd_mode to work transparently
 196   tie $rnd_mode, 'Math::BigInt';
 197
 198   # set up some handy alias names
 199   *as_int = \&as_number;
 200   *is_pos = \&is_positive;
 201   *is_neg = \&is_negative;
 202   }
 203
 204 ##############################################################################
 205
 206 sub round_mode
 207   {
 208   no strict 'refs';
 209   # make Class->round_mode() work
 210   my $self = shift;
 211   my $class = ref($self) || $self || __PACKAGE__;
 212   if (defined $_[0])
 213     {
 214     my $m = shift;
 215     if ($m !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
 216       {
 217       require Carp; Carp::croak ("Unknown round mode '$m'");
 218       }
 219     return ${"${class}::round_mode"} = $m;
 220     }
 221   ${"${class}::round_mode"};
 222   }
 223
 224 sub upgrade
 225   {
 226   no strict 'refs';
 227   # make Class->upgrade() work
 228   my $self = shift;
 229   my $class = ref($self) || $self || __PACKAGE__;
 230   # need to set new value?
 231   if (@_ > 0)
 232     {
 233     return ${"${class}::upgrade"} = $_[0];
 234     }
 235   ${"${class}::upgrade"};
 236   }
 237
 238 sub downgrade
 239   {
 240   no strict 'refs';
 241   # make Class->downgrade() work
 242   my $self = shift;
 243   my $class = ref($self) || $self || __PACKAGE__;
 244   # need to set new value?
 245   if (@_ > 0)
 246     {
 247     return ${"${class}::downgrade"} = $_[0];
 248     }
 249   ${"${class}::downgrade"};
 250   }
 251
 252 sub div_scale
 253   {
 254   no strict 'refs';
 255   # make Class->div_scale() work
 256   my $self = shift;
 257   my $class = ref($self) || $self || __PACKAGE__;
 258   if (defined $_[0])
 259     {
 260     if ($_[0] < 0)
 261       {
 262       require Carp; Carp::croak ('div_scale must be greater than zero');
 263       }
 264     ${"${class}::div_scale"} = $_[0];
 265     }
 266   ${"${class}::div_scale"};
 267   }
 268
 269 sub accuracy
 270   {
 271   # $x->accuracy($a);           ref($x) $a
 272   # $x->accuracy();             ref($x)
 273   # Class->accuracy();          class
 274   # Class->accuracy($a);        class $a
 275
 276   my $x = shift;
 277   my $class = ref($x) || $x || __PACKAGE__;
 278
 279   no strict 'refs';
 280   # need to set new value?
 281   if (@_ > 0)
 282     {
 283     my $a = shift;
 284     # convert objects to scalars to avoid deep recursion. If object doesn't
 285     # have numify(), then hopefully it will have overloading for int() and
 286     # boolean test without wandering into a deep recursion path...
 287     $a = $a->numify() if ref($a) && $a->can('numify');
 288
 289     if (defined $a)
 290       {
 291       # also croak on non-numerical
 292       if (!$a || $a <= 0)
 293         {
 294         require Carp;
 295         Carp::croak ('Argument to accuracy must be greater than zero');
 296         }
 297       if (int($a) != $a)
 298         {
 299         require Carp; Carp::croak ('Argument to accuracy must be an integer');
 300         }
 301       }
 302     if (ref($x))
 303       {
 304       # $object->accuracy() or fallback to global
 305       $x->bround($a) if $a;             # not for undef, 0
 306       $x->{_a} = $a;                    # set/overwrite, even if not rounded
 307       delete $x->{_p};                  # clear P
 308       $a = ${"${class}::accuracy"} unless defined $a;   # proper return value
 309       }
 310     else
 311       {
 312       ${"${class}::accuracy"} = $a;     # set global A
 313       ${"${class}::precision"} = undef; # clear global P
 314       }
 315     return $a;                          # shortcut
 316     }
 317
 318   my $a;
 319   # $object->accuracy() or fallback to global
 320   $a = $x->{_a} if ref($x);
 321   # but don't return global undef, when $x's accuracy is 0!
 322   $a = ${"${class}::accuracy"} if !defined $a;
 323   $a;
 324   }
 325
 326 sub precision
 327   {
 328   # $x->precision($p);          ref($x) $p
 329   # $x->precision();            ref($x)
 330   # Class->precision();         class
 331   # Class->precision($p);       class $p
 332
 333   my $x = shift;
 334   my $class = ref($x) || $x || __PACKAGE__;
 335
 336   no strict 'refs';
 337   if (@_ > 0)
 338     {
 339     my $p = shift;
 340     # convert objects to scalars to avoid deep recursion. If object doesn't
 341     # have numify(), then hopefully it will have overloading for int() and
 342     # boolean test without wandering into a deep recursion path...
 343     $p = $p->numify() if ref($p) && $p->can('numify');
 344     if ((defined $p) && (int($p) != $p))
 345       {
 346       require Carp; Carp::croak ('Argument to precision must be an integer');
 347       }
 348     if (ref($x))
 349       {
 350       # $object->precision() or fallback to global
 351       $x->bfround($p) if $p;            # not for undef, 0
 352       $x->{_p} = $p;                    # set/overwrite, even if not rounded
 353       delete $x->{_a};                  # clear A
 354       $p = ${"${class}::precision"} unless defined $p;  # proper return value
 355       }
 356     else
 357       {
 358       ${"${class}::precision"} = $p;    # set global P
 359       ${"${class}::accuracy"} = undef;  # clear global A
 360       }
 361     return $p;                          # shortcut
 362     }
 363
 364   my $p;
 365   # $object->precision() or fallback to global
 366   $p = $x->{_p} if ref($x);
 367   # but don't return global undef, when $x's precision is 0!
 368   $p = ${"${class}::precision"} if !defined $p;
 369   $p;
 370   }
 371
 372 sub config
 373   {
 374   # return (or set) configuration data as hash ref
 375   my $class = shift || 'Math::BigInt';
 376
 377   no strict 'refs';
 378   if (@_ > 0)
 379     {
 380     # try to set given options as arguments from hash
 381
 382     my $args = $_[0];
 383     if (ref($args) ne 'HASH')
 384       {
 385       $args = { @_ };
 386       }
 387     # these values can be "set"
 388     my $set_args = {};
 389     foreach my $key (
 390      qw/trap_inf trap_nan
 391         upgrade downgrade precision accuracy round_mode div_scale/
 392      )
 393       {
 394       $set_args->{$key} = $args->{$key} if exists $args->{$key};
 395       delete $args->{$key};
 396       }
 397     if (keys %$args > 0)
 398       {
 399       require Carp;
 400       Carp::croak ("Illegal key(s) '",
 401        join("','",keys %$args),"' passed to $class\->config()");
 402       }
 403     foreach my $key (keys %$set_args)
 404       {
 405       if ($key =~ /^trap_(inf|nan)\z/)
 406         {
 407         ${"${class}::_trap_$1"} = ($set_args->{"trap_$1"} ? 1 : 0);
 408         next;
 409         }
 410       # use a call instead of just setting the $variable to check argument
 411       $class->$key($set_args->{$key});
 412       }
 413     }
 414
 415   # now return actual configuration
 416
 417   my $cfg = {
 418     lib => $CALC,
 419     lib_version => ${"${CALC}::VERSION"},
 420     class => $class,
 421     trap_nan => ${"${class}::_trap_nan"},
 422     trap_inf => ${"${class}::_trap_inf"},
 423     version => ${"${class}::VERSION"},
 424     };
 425   foreach my $key (qw/
 426      upgrade downgrade precision accuracy round_mode div_scale
 427      /)
 428     {
 429     $cfg->{$key} = ${"${class}::$key"};
 430     };
 431   $cfg;
 432   }
 433
 434 sub _scale_a
 435   {
 436   # select accuracy parameter based on precedence,
 437   # used by bround() and bfround(), may return undef for scale (means no op)
 438   my ($x,$scale,$mode) = @_;
 439
 440   $scale = $x->{_a} unless defined $scale;
 441
 442   no strict 'refs';
 443   my $class = ref($x);
 444
 445   $scale = ${ $class . '::accuracy' } unless defined $scale;
 446   $mode = ${ $class . '::round_mode' } unless defined $mode;
 447
 448   ($scale,$mode);
 449   }
 450
 451 sub _scale_p
 452   {
 453   # select precision parameter based on precedence,
 454   # used by bround() and bfround(), may return undef for scale (means no op)
 455   my ($x,$scale,$mode) = @_;
 456
 457   $scale = $x->{_p} unless defined $scale;
 458
 459   no strict 'refs';
 460   my $class = ref($x);
 461
 462   $scale = ${ $class . '::precision' } unless defined $scale;
 463   $mode = ${ $class . '::round_mode' } unless defined $mode;
 464
 465   ($scale,$mode);
 466   }
 467
 468 ##############################################################################
 469 # constructors
 470
 471 sub copy
 472   {
 473   my ($c,$x);
 474   if (@_ > 1)
 475     {
 476     # if two arguments, the first one is the class to "swallow" subclasses
 477     ($c,$x) = @_;
 478     }
 479   else
 480     {
 481     $x = shift;
 482     $c = ref($x);
 483     }
 484   return unless ref($x); # only for objects
 485
 486   my $self = bless {}, $c;
 487
 488   $self->{sign} = $x->{sign};
 489   $self->{value} = $CALC->_copy($x->{value});
 490   $self->{_a} = $x->{_a} if defined $x->{_a};
 491   $self->{_p} = $x->{_p} if defined $x->{_p};
 492   $self;
 493   }
 494
 495 sub new
 496   {
 497   # create a new BigInt object from a string or another BigInt object.
 498   # see hash keys documented at top
 499
 500   # the argument could be an object, so avoid ||, && etc on it, this would
 501   # cause costly overloaded code to be called. The only allowed ops are
 502   # ref() and defined.
 503
 504   my ($class,$wanted,$a,$p,$r) = @_;
 505
 506   # avoid numify-calls by not using || on $wanted!
 507   return $class->bzero($a,$p) if !defined $wanted;      # default to 0
 508   return $class->copy($wanted,$a,$p,$r)
 509    if ref($wanted) && $wanted->isa($class);             # MBI or subclass
 510
 511   $class->import() if $IMPORT == 0;             # make require work
 512
 513   my $self = bless {}, $class;
 514
 515   # shortcut for "normal" numbers
 516   if ((!ref $wanted) && ($wanted =~ /^([+-]?)[1-9][0-9]*\z/))
 517     {
 518     $self->{sign} = $1 || '+';
 519
 520     if ($wanted =~ /^[+-]/)
 521      {
 522       # remove sign without touching wanted to make it work with constants
 523       my $t = $wanted; $t =~ s/^[+-]//;
 524       $self->{value} = $CALC->_new($t);
 525       }
 526     else
 527       {
 528       $self->{value} = $CALC->_new($wanted);
 529       }
 530     no strict 'refs';
 531     if ( (defined $a) || (defined $p)
 532         || (defined ${"${class}::precision"})
 533         || (defined ${"${class}::accuracy"})
 534        )
 535       {
 536       $self->round($a,$p,$r) unless (@_ == 4 && !defined $a && !defined $p);
 537       }
 538     return $self;
 539     }
 540
 541   # handle '+inf', '-inf' first
 542   if ($wanted =~ /^[+-]?inf\z/)
 543     {
 544     $self->{sign} = $wanted;            # set a default sign for bstr()
 545     return $self->binf($wanted);
 546     }
 547   # split str in m mantissa, e exponent, i integer, f fraction, v value, s sign
 548   my ($mis,$miv,$mfv,$es,$ev) = _split($wanted);
 549   if (!ref $mis)
 550     {
 551     if ($_trap_nan)
 552       {
 553       require Carp; Carp::croak("$wanted is not a number in $class");
 554       }
 555     $self->{value} = $CALC->_zero();
 556     $self->{sign} = $nan;
 557     return $self;
 558     }
 559   if (!ref $miv)
 560     {
 561     # _from_hex or _from_bin
 562     $self->{value} = $mis->{value};
 563     $self->{sign} = $mis->{sign};
 564     return $self;       # throw away $mis
 565     }
 566   # make integer from mantissa by adjusting exp, then convert to bigint
 567   $self->{sign} = $$mis;                        # store sign
 568   $self->{value} = $CALC->_zero();              # for all the NaN cases
 569   my $e = int("$$es$$ev");                      # exponent (avoid recursion)
 570   if ($e > 0)
 571     {
 572     my $diff = $e - CORE::length($$mfv);
 573     if ($diff < 0)                              # Not integer
 574       {
 575       if ($_trap_nan)
 576         {
 577         require Carp; Carp::croak("$wanted not an integer in $class");
 578         }
 579       #print "NOI 1\n";
 580       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 581       $self->{sign} = $nan;
 582       }
 583     else                                        # diff >= 0
 584       {
 585       # adjust fraction and add it to value
 586       #print "diff > 0 $$miv\n";
 587       $$miv = $$miv . ($$mfv . '0' x $diff);
 588       }
 589     }
 590   else
 591     {
 592     if ($$mfv ne '')                            # e <= 0
 593       {
 594       # fraction and negative/zero E => NOI
 595       if ($_trap_nan)
 596         {
 597         require Carp; Carp::croak("$wanted not an integer in $class");
 598         }
 599       #print "NOI 2 \$\$mfv '$$mfv'\n";
 600       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 601       $self->{sign} = $nan;
 602       }
 603     elsif ($e < 0)
 604       {
 605       # xE-y, and empty mfv
 606       #print "xE-y\n";
 607       $e = abs($e);
 608       if ($$miv !~ s/0{$e}$//)          # can strip so many zero's?
 609         {
 610         if ($_trap_nan)
 611           {
 612           require Carp; Carp::croak("$wanted not an integer in $class");
 613           }
 614         #print "NOI 3\n";
 615         return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
 616         $self->{sign} = $nan;
 617         }
 618       }
 619     }
 620   $self->{sign} = '+' if $$miv eq '0';                  # normalize -0 => +0
 621   $self->{value} = $CALC->_new($$miv) if $self->{sign} =~ /^[+-]$/;
 622   # if any of the globals is set, use them to round and store them inside $self
 623   # do not round for new($x,undef,undef) since that is used by MBF to signal
 624   # no rounding
 625   $self->round($a,$p,$r) unless @_ == 4 && !defined $a && !defined $p;
 626   $self;
 627   }
 628
 629 sub bnan
 630   {
 631   # create a bigint 'NaN', if given a BigInt, set it to 'NaN'
 632   my $self = shift;
 633   $self = $class if !defined $self;
 634   if (!ref($self))
 635     {
 636     my $c = $self; $self = {}; bless $self, $c;
 637     }
 638   no strict 'refs';
 639   if (${"${class}::_trap_nan"})
 640     {
 641     require Carp;
 642     Carp::croak ("Tried to set $self to NaN in $class\::bnan()");
 643     }
 644   $self->import() if $IMPORT == 0;              # make require work
 645   return if $self->modify('bnan');
 646   if ($self->can('_bnan'))
 647     {
 648     # use subclass to initialize
 649     $self->_bnan();
 650     }
 651   else
 652     {
 653     # otherwise do our own thing
 654     $self->{value} = $CALC->_zero();
 655     }
 656   $self->{sign} = $nan;
 657   delete $self->{_a}; delete $self->{_p};       # rounding NaN is silly
 658   $self;
 659   }
 660
 661 sub binf
 662   {
 663   # create a bigint '+-inf', if given a BigInt, set it to '+-inf'
 664   # the sign is either '+', or if given, used from there
 665   my $self = shift;
 666   my $sign = shift; $sign = '+' if !defined $sign || $sign !~ /^-(inf)?$/;
 667   $self = $class if !defined $self;
 668   if (!ref($self))
 669     {
 670     my $c = $self; $self = {}; bless $self, $c;
 671     }
 672   no strict 'refs';
 673   if (${"${class}::_trap_inf"})
 674     {
 675     require Carp;
 676     Carp::croak ("Tried to set $self to +-inf in $class\::binf()");
 677     }
 678   $self->import() if $IMPORT == 0;              # make require work
 679   return if $self->modify('binf');
 680   if ($self->can('_binf'))
 681     {
 682     # use subclass to initialize
 683     $self->_binf();
 684     }
 685   else
 686     {
 687     # otherwise do our own thing
 688     $self->{value} = $CALC->_zero();
 689     }
 690   $sign = $sign . 'inf' if $sign !~ /inf$/;     # - => -inf
 691   $self->{sign} = $sign;
 692   ($self->{_a},$self->{_p}) = @_;               # take over requested rounding
 693   $self;
 694   }
 695
 696 sub bzero
 697   {
 698   # create a bigint '+0', if given a BigInt, set it to 0
 699   my $self = shift;
 700   $self = __PACKAGE__ if !defined $self;
 701
 702   if (!ref($self))
 703     {
 704     my $c = $self; $self = {}; bless $self, $c;
 705     }
 706   $self->import() if $IMPORT == 0;              # make require work
 707   return if $self->modify('bzero');
 708
 709   if ($self->can('_bzero'))
 710     {
 711     # use subclass to initialize
 712     $self->_bzero();
 713     }
 714   else
 715     {
 716     # otherwise do our own thing
 717     $self->{value} = $CALC->_zero();
 718     }
 719   $self->{sign} = '+';
 720   if (@_ > 0)
 721     {
 722     if (@_ > 3)
 723       {
 724       # call like: $x->bzero($a,$p,$r,$y);
 725       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 726       }
 727     else
 728       {
 729       $self->{_a} = $_[0]
 730        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 731       $self->{_p} = $_[1]
 732        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 733       }
 734     }
 735   $self;
 736   }
 737
 738 sub bone
 739   {
 740   # create a bigint '+1' (or -1 if given sign '-'),
 741   # if given a BigInt, set it to +1 or -1, respectively
 742   my $self = shift;
 743   my $sign = shift; $sign = '+' if !defined $sign || $sign ne '-';
 744   $self = $class if !defined $self;
 745
 746   if (!ref($self))
 747     {
 748     my $c = $self; $self = {}; bless $self, $c;
 749     }
 750   $self->import() if $IMPORT == 0;              # make require work
 751   return if $self->modify('bone');
 752
 753   if ($self->can('_bone'))
 754     {
 755     # use subclass to initialize
 756     $self->_bone();
 757     }
 758   else
 759     {
 760     # otherwise do our own thing
 761     $self->{value} = $CALC->_one();
 762     }
 763   $self->{sign} = $sign;
 764   if (@_ > 0)
 765     {
 766     if (@_ > 3)
 767       {
 768       # call like: $x->bone($sign,$a,$p,$r,$y);
 769       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
 770       }
 771     else
 772       {
 773       # call like: $x->bone($sign,$a,$p,$r);
 774       $self->{_a} = $_[0]
 775        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
 776       $self->{_p} = $_[1]
 777        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
 778       }
 779     }
 780   $self;
 781   }
 782
 783 ##############################################################################
 784 # string conversation
 785
 786 sub bsstr
 787   {
 788   # (ref to BFLOAT or num_str ) return num_str
 789   # Convert number from internal format to scientific string format.
 790   # internal format is always normalized (no leading zeros, "-0E0" => "+0E0")
 791   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 792
 793   if ($x->{sign} !~ /^[+-]$/)
 794     {
 795     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 796     return 'inf';                                       # +inf
 797     }
 798   my ($m,$e) = $x->parts();
 799   #$m->bstr() . 'e+' . $e->bstr();      # e can only be positive in BigInt
 800   # 'e+' because E can only be positive in BigInt
 801   $m->bstr() . 'e+' . $CALC->_str($e->{value});
 802   }
 803
 804 sub bstr
 805   {
 806   # make a string from bigint object
 807   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 808
 809   if ($x->{sign} !~ /^[+-]$/)
 810     {
 811     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
 812     return 'inf';                                       # +inf
 813     }
 814   my $es = ''; $es = $x->{sign} if $x->{sign} eq '-';
 815   $es.$CALC->_str($x->{value});
 816   }
 817
 818 sub numify
 819   {
 820   # Make a "normal" scalar from a BigInt object
 821   my $x = shift; $x = $class->new($x) unless ref $x;
 822
 823   return $x->bstr() if $x->{sign} !~ /^[+-]$/;
 824   my $num = $CALC->_num($x->{value});
 825   return -$num if $x->{sign} eq '-';
 826   $num;
 827   }
 828
 829 ##############################################################################
 830 # public stuff (usually prefixed with "b")
 831
 832 sub sign
 833   {
 834   # return the sign of the number: +/-/-inf/+inf/NaN
 835   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 836
 837   $x->{sign};
 838   }
 839
 840 sub _find_round_parameters
 841   {
 842   # After any operation or when calling round(), the result is rounded by
 843   # regarding the A & P from arguments, local parameters, or globals.
 844
 845   # !!!!!!! If you change this, remember to change round(), too! !!!!!!!!!!
 846
 847   # This procedure finds the round parameters, but it is for speed reasons
 848   # duplicated in round. Otherwise, it is tested by the testsuite and used
 849   # by fdiv().
 850
 851   # returns ($self) or ($self,$a,$p,$r) - sets $self to NaN of both A and P
 852   # were requested/defined (locally or globally or both)
 853
 854   my ($self,$a,$p,$r,@args) = @_;
 855   # $a accuracy, if given by caller
 856   # $p precision, if given by caller
 857   # $r round_mode, if given by caller
 858   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 859
 860   my $c = ref($self);                           # find out class of argument(s)
 861   no strict 'refs';
 862
 863   # now pick $a or $p, but only if we have got "arguments"
 864   if (!defined $a)
 865     {
 866     foreach ($self,@args)
 867       {
 868       # take the defined one, or if both defined, the one that is smaller
 869       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 870       }
 871     }
 872   if (!defined $p)
 873     {
 874     # even if $a is defined, take $p, to signal error for both defined
 875     foreach ($self,@args)
 876       {
 877       # take the defined one, or if both defined, the one that is bigger
 878       # -2 > -3, and 3 > 2
 879       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 880       }
 881     }
 882   # if still none defined, use globals (#2)
 883   $a = ${"$c\::accuracy"} unless defined $a;
 884   $p = ${"$c\::precision"} unless defined $p;
 885
 886   # A == 0 is useless, so undef it to signal no rounding
 887   $a = undef if defined $a && $a == 0;
 888
 889   # no rounding today?
 890   return ($self) unless defined $a || defined $p;               # early out
 891
 892   # set A and set P is an fatal error
 893   return ($self->bnan()) if defined $a && defined $p;           # error
 894
 895   $r = ${"$c\::round_mode"} unless defined $r;
 896   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
 897     {
 898     require Carp; Carp::croak ("Unknown round mode '$r'");
 899     }
 900
 901   ($self,$a,$p,$r);
 902   }
 903
 904 sub round
 905   {
 906   # Round $self according to given parameters, or given second argument's
 907   # parameters or global defaults
 908
 909   # for speed reasons, _find_round_parameters is embeded here:
 910
 911   my ($self,$a,$p,$r,@args) = @_;
 912   # $a accuracy, if given by caller
 913   # $p precision, if given by caller
 914   # $r round_mode, if given by caller
 915   # @args all 'other' arguments (0 for unary, 1 for binary ops)
 916
 917   my $c = ref($self);                           # find out class of argument(s)
 918   no strict 'refs';
 919
 920   # now pick $a or $p, but only if we have got "arguments"
 921   if (!defined $a)
 922     {
 923     foreach ($self,@args)
 924       {
 925       # take the defined one, or if both defined, the one that is smaller
 926       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
 927       }
 928     }
 929   if (!defined $p)
 930     {
 931     # even if $a is defined, take $p, to signal error for both defined
 932     foreach ($self,@args)
 933       {
 934       # take the defined one, or if both defined, the one that is bigger
 935       # -2 > -3, and 3 > 2
 936       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
 937       }
 938     }
 939   # if still none defined, use globals (#2)
 940   $a = ${"$c\::accuracy"} unless defined $a;
 941   $p = ${"$c\::precision"} unless defined $p;
 942
 943   # A == 0 is useless, so undef it to signal no rounding
 944   $a = undef if defined $a && $a == 0;
 945
 946   # no rounding today?
 947   return $self unless defined $a || defined $p;         # early out
 948
 949   # set A and set P is an fatal error
 950   return $self->bnan() if defined $a && defined $p;
 951
 952   $r = ${"$c\::round_mode"} unless defined $r;
 953   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
 954     {
 955     require Carp; Carp::croak ("Unknown round mode '$r'");
 956     }
 957
 958   # now round, by calling either fround or ffround:
 959   if (defined $a)
 960     {
 961     $self->bround($a,$r) if !defined $self->{_a} || $self->{_a} >= $a;
 962     }
 963   else # both can't be undefined due to early out
 964     {
 965     $self->bfround($p,$r) if !defined $self->{_p} || $self->{_p} <= $p;
 966     }
 967   # bround() or bfround() already callled bnorm() if nec.
 968   $self;
 969   }
 970
 971 sub bnorm
 972   {
 973   # (numstr or BINT) return BINT
 974   # Normalize number -- no-op here
 975   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 976   $x;
 977   }
 978
 979 sub babs
 980   {
 981   # (BINT or num_str) return BINT
 982   # make number absolute, or return absolute BINT from string
 983   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 984
 985   return $x if $x->modify('babs');
 986   # post-normalized abs for internal use (does nothing for NaN)
 987   $x->{sign} =~ s/^-/+/;
 988   $x;
 989   }
 990
 991 sub bneg
 992   {
 993   # (BINT or num_str) return BINT
 994   # negate number or make a negated number from string
 995   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
 996
 997   return $x if $x->modify('bneg');
 998
 999   # for +0 dont negate (to have always normalized +0). Does nothing for 'NaN'
1000   $x->{sign} =~ tr/+-/-+/ unless ($x->{sign} eq '+' && $CALC->_is_zero($x->{value}));
1001   $x;
1002   }
1003
1004 sub bcmp
1005   {
1006   # Compares 2 values.  Returns one of undef, <0, =0, >0. (suitable for sort)
1007   # (BINT or num_str, BINT or num_str) return cond_code
1008
1009   # set up parameters
1010   my ($self,$x,$y) = (ref($_[0]),@_);
1011
1012   # objectify is costly, so avoid it
1013   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1014     {
1015     ($self,$x,$y) = objectify(2,@_);
1016     }
1017
1018   return $upgrade->bcmp($x,$y) if defined $upgrade &&
1019     ((!$x->isa($self)) || (!$y->isa($self)));
1020
1021   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1022     {
1023     # handle +-inf and NaN
1024     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1025     return 0 if $x->{sign} eq $y->{sign} && $x->{sign} =~ /^[+-]inf$/;
1026     return +1 if $x->{sign} eq '+inf';
1027     return -1 if $x->{sign} eq '-inf';
1028     return -1 if $y->{sign} eq '+inf';
1029     return +1;
1030     }
1031   # check sign for speed first
1032   return 1 if $x->{sign} eq '+' && $y->{sign} eq '-';   # does also 0 <=> -y
1033   return -1 if $x->{sign} eq '-' && $y->{sign} eq '+';  # does also -x <=> 0
1034
1035   # have same sign, so compare absolute values. Don't make tests for zero here
1036   # because it's actually slower than testin in Calc (especially w/ Pari et al)
1037
1038   # post-normalized compare for internal use (honors signs)
1039   if ($x->{sign} eq '+')
1040     {
1041     # $x and $y both > 0
1042     return $CALC->_acmp($x->{value},$y->{value});
1043     }
1044
1045   # $x && $y both < 0
1046   $CALC->_acmp($y->{value},$x->{value});        # swaped acmp (lib returns 0,1,-1)
1047   }
1048
1049 sub bacmp
1050   {
1051   # Compares 2 values, ignoring their signs.
1052   # Returns one of undef, <0, =0, >0. (suitable for sort)
1053   # (BINT, BINT) return cond_code
1054
1055   # set up parameters
1056   my ($self,$x,$y) = (ref($_[0]),@_);
1057   # objectify is costly, so avoid it
1058   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1059     {
1060     ($self,$x,$y) = objectify(2,@_);
1061     }
1062
1063   return $upgrade->bacmp($x,$y) if defined $upgrade &&
1064     ((!$x->isa($self)) || (!$y->isa($self)));
1065
1066   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1067     {
1068     # handle +-inf and NaN
1069     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1070     return 0 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} =~ /^[+-]inf$/;
1071     return 1 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} !~ /^[+-]inf$/;
1072     return -1;
1073     }
1074   $CALC->_acmp($x->{value},$y->{value});        # lib does only 0,1,-1
1075   }
1076
1077 sub badd
1078   {
1079   # add second arg (BINT or string) to first (BINT) (modifies first)
1080   # return result as BINT
1081
1082   # set up parameters
1083   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1084   # objectify is costly, so avoid it
1085   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1086     {
1087     ($self,$x,$y,@r) = objectify(2,@_);
1088     }
1089
1090   return $x if $x->modify('badd');
1091   return $upgrade->badd($upgrade->new($x),$upgrade->new($y),@r) if defined $upgrade &&
1092     ((!$x->isa($self)) || (!$y->isa($self)));
1093
1094   $r[3] = $y;                           # no push!
1095   # inf and NaN handling
1096   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1097     {
1098     # NaN first
1099     return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1100     # inf handling
1101     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1102       {
1103       # +inf++inf or -inf+-inf => same, rest is NaN
1104       return $x if $x->{sign} eq $y->{sign};
1105       return $x->bnan();
1106       }
1107     # +-inf + something => +inf
1108     # something +-inf => +-inf
1109     $x->{sign} = $y->{sign}, return $x if $y->{sign} =~ /^[+-]inf$/;
1110     return $x;
1111     }
1112
1113   my ($sx, $sy) = ( $x->{sign}, $y->{sign} );           # get signs
1114
1115   if ($sx eq $sy)
1116     {
1117     $x->{value} = $CALC->_add($x->{value},$y->{value}); # same sign, abs add
1118     }
1119   else
1120     {
1121     my $a = $CALC->_acmp ($y->{value},$x->{value});     # absolute compare
1122     if ($a > 0)
1123       {
1124       $x->{value} = $CALC->_sub($y->{value},$x->{value},1); # abs sub w/ swap
1125       $x->{sign} = $sy;
1126       }
1127     elsif ($a == 0)
1128       {
1129       # speedup, if equal, set result to 0
1130       $x->{value} = $CALC->_zero();
1131       $x->{sign} = '+';
1132       }
1133     else # a < 0
1134       {
1135       $x->{value} = $CALC->_sub($x->{value}, $y->{value}); # abs sub
1136       }
1137     }
1138   $x->round(@r);
1139   }
1140
1141 sub bsub
1142   {
1143   # (BINT or num_str, BINT or num_str) return BINT
1144   # subtract second arg from first, modify first
1145
1146   # set up parameters
1147   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1148
1149   # objectify is costly, so avoid it
1150   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1151     {
1152     ($self,$x,$y,@r) = objectify(2,@_);
1153     }
1154
1155   return $x if $x->modify('bsub');
1156
1157   return $upgrade->new($x)->bsub($upgrade->new($y),@r) if defined $upgrade &&
1158    ((!$x->isa($self)) || (!$y->isa($self)));
1159
1160   return $x->round(@r) if $y->is_zero();
1161
1162   # To correctly handle the lone special case $x->bsub($x), we note the sign
1163   # of $x, then flip the sign from $y, and if the sign of $x did change, too,
1164   # then we caught the special case:
1165   my $xsign = $x->{sign};
1166   $y->{sign} =~ tr/+\-/-+/;     # does nothing for NaN
1167   if ($xsign ne $x->{sign})
1168     {
1169     # special case of $x->bsub($x) results in 0
1170     return $x->bzero(@r) if $xsign =~ /^[+-]$/;
1171     return $x->bnan();          # NaN, -inf, +inf
1172     }
1173   $x->badd($y,@r);              # badd does not leave internal zeros
1174   $y->{sign} =~ tr/+\-/-+/;     # refix $y (does nothing for NaN)
1175   $x;                           # already rounded by badd() or no round nec.
1176   }
1177
1178 sub binc
1179   {
1180   # increment arg by one
1181   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1182   return $x if $x->modify('binc');
1183
1184   if ($x->{sign} eq '+')
1185     {
1186     $x->{value} = $CALC->_inc($x->{value});
1187     return $x->round($a,$p,$r);
1188     }
1189   elsif ($x->{sign} eq '-')
1190     {
1191     $x->{value} = $CALC->_dec($x->{value});
1192     $x->{sign} = '+' if $CALC->_is_zero($x->{value}); # -1 +1 => -0 => +0
1193     return $x->round($a,$p,$r);
1194     }
1195   # inf, nan handling etc
1196   $x->badd($self->bone(),$a,$p,$r);             # badd does round
1197   }
1198
1199 sub bdec
1200   {
1201   # decrement arg by one
1202   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1203   return $x if $x->modify('bdec');
1204
1205   if ($x->{sign} eq '-')
1206     {
1207     # x already < 0
1208     $x->{value} = $CALC->_inc($x->{value});
1209     }
1210   else
1211     {
1212     return $x->badd($self->bone('-'),@r) unless $x->{sign} eq '+';      # inf or NaN
1213     # >= 0
1214     if ($CALC->_is_zero($x->{value}))
1215       {
1216       # == 0
1217       $x->{value} = $CALC->_one(); $x->{sign} = '-';            # 0 => -1
1218       }
1219     else
1220       {
1221       # > 0
1222       $x->{value} = $CALC->_dec($x->{value});
1223       }
1224     }
1225   $x->round(@r);
1226   }
1227
1228 sub blog
1229   {
1230   # calculate $x = $a ** $base + $b and return $a (e.g. the log() to base
1231   # $base of $x)
1232
1233   # set up parameters
1234   my ($self,$x,$base,@r) = (undef,@_);
1235   # objectify is costly, so avoid it
1236   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1237     {
1238     ($self,$x,$base,@r) = objectify(1,ref($x),@_);
1239     }
1240
1241   return $x if $x->modify('blog');
1242
1243   # inf, -inf, NaN, <0 => NaN
1244   return $x->bnan()
1245    if $x->{sign} ne '+' || (defined $base && $base->{sign} ne '+');
1246
1247   return $upgrade->blog($upgrade->new($x),$base,@r) if
1248     defined $upgrade;
1249
1250   # fix for bug #24969:
1251   # the default base is e (Euler's number) which is not an integer
1252   if (!defined $base)
1253     {
1254     require Math::BigFloat;
1255     my $u = Math::BigFloat->blog(Math::BigFloat->new($x))->as_int();
1256     # modify $x in place
1257     $x->{value} = $u->{value};
1258     $x->{sign} = $u->{sign};
1259     return $x;
1260     }
1261
1262   my ($rc,$exact) = $CALC->_log_int($x->{value},$base->{value});
1263   return $x->bnan() unless defined $rc;         # not possible to take log?
1264   $x->{value} = $rc;
1265   $x->round(@r);
1266   }
1267
1268 sub bnok
1269   {
1270   # Calculate n over k (binomial coefficient or "choose" function) as integer.
1271   # set up parameters
1272   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1273
1274   # objectify is costly, so avoid it
1275   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1276     {
1277     ($self,$x,$y,@r) = objectify(2,@_);
1278     }
1279
1280   return $x if $x->modify('bnok');
1281   return $x->bnan() if $x->{sign} eq 'NaN' || $y->{sign} eq 'NaN';
1282   return $x->binf() if $x->{sign} eq '+inf';
1283
1284   # k > n or k < 0 => 0
1285   my $cmp = $x->bacmp($y);
1286   return $x->bzero() if $cmp < 0 || $y->{sign} =~ /^-/;
1287   # k == n => 1
1288   return $x->bone(@r) if $cmp == 0;
1289
1290   if ($CALC->can('_nok'))
1291     {
1292     $x->{value} = $CALC->_nok($x->{value},$y->{value});
1293     }
1294   else
1295     {
1296     # ( 7 )    7!          7*6*5 * 4*3*2*1   7 * 6 * 5
1297     # ( - ) = --------- =  --------------- = ---------
1298     # ( 3 )   3! (7-3)!    3*2*1 * 4*3*2*1   3 * 2 * 1
1299
1300     # compute n - k + 2 (so we start with 5 in the example above)
1301     my $z = $x - $y;
1302     if (!$z->is_one())
1303       {
1304       $z->binc();
1305       my $r = $z->copy(); $z->binc();
1306       my $d = $self->new(2);
1307       while ($z->bacmp($x) <= 0)                # f < x ?
1308         {
1309         $r->bmul($z); $r->bdiv($d);
1310         $z->binc(); $d->binc();
1311         }
1312       $x->{value} = $r->{value}; $x->{sign} = '+';
1313       }
1314     else { $x->bone(); }
1315     }
1316   $x->round(@r);
1317   }
1318
1319 sub bexp
1320   {
1321   # Calculate e ** $x (Euler's number to the power of X), truncated to
1322   # an integer value.
1323   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1324   return $x if $x->modify('bexp');
1325
1326   # inf, -inf, NaN, <0 => NaN
1327   return $x->bnan() if $x->{sign} eq 'NaN';
1328   return $x->bone() if $x->is_zero();
1329   return $x if $x->{sign} eq '+inf';
1330   return $x->bzero() if $x->{sign} eq '-inf';
1331
1332   my $u;
1333   {
1334     # run through Math::BigFloat unless told otherwise
1335     require Math::BigFloat unless defined $upgrade;
1336     local $upgrade = 'Math::BigFloat' unless defined $upgrade;
1337     # calculate result, truncate it to integer
1338     $u = $upgrade->bexp($upgrade->new($x),@r);
1339   }
1340
1341   if (!defined $upgrade)
1342     {
1343     $u = $u->as_int();
1344     # modify $x in place
1345     $x->{value} = $u->{value};
1346     $x->round(@r);
1347     }
1348   else { $x = $u; }
1349   }
1350
1351 sub blcm
1352   {
1353   # (BINT or num_str, BINT or num_str) return BINT
1354   # does not modify arguments, but returns new object
1355   # Lowest Common Multiplicator
1356
1357   my $y = shift; my ($x);
1358   if (ref($y))
1359     {
1360     $x = $y->copy();
1361     }
1362   else
1363     {
1364     $x = $class->new($y);
1365     }
1366   my $self = ref($x);
1367   while (@_)
1368     {
1369     my $y = shift; $y = $self->new($y) if !ref ($y);
1370     $x = __lcm($x,$y);
1371     }
1372   $x;
1373   }
1374
1375 sub bgcd
1376   {
1377   # (BINT or num_str, BINT or num_str) return BINT
1378   # does not modify arguments, but returns new object
1379   # GCD -- Euclids algorithm, variant C (Knuth Vol 3, pg 341 ff)
1380
1381   my $y = shift;
1382   $y = $class->new($y) if !ref($y);
1383   my $self = ref($y);
1384   my $x = $y->copy()->babs();                   # keep arguments
1385   return $x->bnan() if $x->{sign} !~ /^[+-]$/;  # x NaN?
1386
1387   while (@_)
1388     {
1389     $y = shift; $y = $self->new($y) if !ref($y);
1390     return $x->bnan() if $y->{sign} !~ /^[+-]$/;        # y NaN?
1391     $x->{value} = $CALC->_gcd($x->{value},$y->{value});
1392     last if $CALC->_is_one($x->{value});
1393     }
1394   $x;
1395   }
1396
1397 sub bnot
1398   {
1399   # (num_str or BINT) return BINT
1400   # represent ~x as twos-complement number
1401   # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1402   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1403
1404   return $x if $x->modify('bnot');
1405   $x->binc()->bneg();                   # binc already does round
1406   }
1407
1408 ##############################################################################
1409 # is_foo test routines
1410 # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1411
1412 sub is_zero
1413   {
1414   # return true if arg (BINT or num_str) is zero (array '+', '0')
1415   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1416
1417   return 0 if $x->{sign} !~ /^\+$/;                     # -, NaN & +-inf aren't
1418   $CALC->_is_zero($x->{value});
1419   }
1420
1421 sub is_nan
1422   {
1423   # return true if arg (BINT or num_str) is NaN
1424   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1425
1426   $x->{sign} eq $nan ? 1 : 0;
1427   }
1428
1429 sub is_inf
1430   {
1431   # return true if arg (BINT or num_str) is +-inf
1432   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1433
1434   if (defined $sign)
1435     {
1436     $sign = '[+-]inf' if $sign eq '';   # +- doesn't matter, only that's inf
1437     $sign = "[$1]inf" if $sign =~ /^([+-])(inf)?$/;     # extract '+' or '-'
1438     return $x->{sign} =~ /^$sign$/ ? 1 : 0;
1439     }
1440   $x->{sign} =~ /^[+-]inf$/ ? 1 : 0;            # only +-inf is infinity
1441   }
1442
1443 sub is_one
1444   {
1445   # return true if arg (BINT or num_str) is +1, or -1 if sign is given
1446   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1447
1448   $sign = '+' if !defined $sign || $sign ne '-';
1449
1450   return 0 if $x->{sign} ne $sign;      # -1 != +1, NaN, +-inf aren't either
1451   $CALC->_is_one($x->{value});
1452   }
1453
1454 sub is_odd
1455   {
1456   # return true when arg (BINT or num_str) is odd, false for even
1457   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1458
1459   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1460   $CALC->_is_odd($x->{value});
1461   }
1462
1463 sub is_even
1464   {
1465   # return true when arg (BINT or num_str) is even, false for odd
1466   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1467
1468   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1469   $CALC->_is_even($x->{value});
1470   }
1471
1472 sub is_positive
1473   {
1474   # return true when arg (BINT or num_str) is positive (>= 0)
1475   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1476
1477   return 1 if $x->{sign} eq '+inf';                     # +inf is positive
1478
1479   # 0+ is neither positive nor negative
1480   ($x->{sign} eq '+' && !$x->is_zero()) ? 1 : 0;
1481   }
1482
1483 sub is_negative
1484   {
1485   # return true when arg (BINT or num_str) is negative (< 0)
1486   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1487
1488   $x->{sign} =~ /^-/ ? 1 : 0;           # -inf is negative, but NaN is not
1489   }
1490
1491 sub is_int
1492   {
1493   # return true when arg (BINT or num_str) is an integer
1494   # always true for BigInt, but different for BigFloats
1495   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1496
1497   $x->{sign} =~ /^[+-]$/ ? 1 : 0;               # inf/-inf/NaN aren't
1498   }
1499
1500 ###############################################################################
1501
1502 sub bmul
1503   {
1504   # multiply two numbers -- stolen from Knuth Vol 2 pg 233
1505   # (BINT or num_str, BINT or num_str) return BINT
1506
1507   # set up parameters
1508   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1509   # objectify is costly, so avoid it
1510   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1511     {
1512     ($self,$x,$y,@r) = objectify(2,@_);
1513     }
1514
1515   return $x if $x->modify('bmul');
1516
1517   return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1518
1519   # inf handling
1520   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1521     {
1522     return $x->bnan() if $x->is_zero() || $y->is_zero();
1523     # result will always be +-inf:
1524     # +inf * +/+inf => +inf, -inf * -/-inf => +inf
1525     # +inf * -/-inf => -inf, -inf * +/+inf => -inf
1526     return $x->binf() if ($x->{sign} =~ /^\+/ && $y->{sign} =~ /^\+/);
1527     return $x->binf() if ($x->{sign} =~ /^-/ && $y->{sign} =~ /^-/);
1528     return $x->binf('-');
1529     }
1530
1531   return $upgrade->bmul($x,$upgrade->new($y),@r)
1532    if defined $upgrade && !$y->isa($self);
1533
1534   $r[3] = $y;                           # no push here
1535
1536   $x->{sign} = $x->{sign} eq $y->{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 => +
1537
1538   $x->{value} = $CALC->_mul($x->{value},$y->{value});   # do actual math
1539   $x->{sign} = '+' if $CALC->_is_zero($x->{value});     # no -0
1540
1541   $x->round(@r);
1542   }
1543
1544 sub _div_inf
1545   {
1546   # helper function that handles +-inf cases for bdiv()/bmod() to reuse code
1547   my ($self,$x,$y) = @_;
1548
1549   # NaN if x == NaN or y == NaN or x==y==0
1550   return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan()
1551    if (($x->is_nan() || $y->is_nan())   ||
1552        ($x->is_zero() && $y->is_zero()));
1553
1554   # +-inf / +-inf == NaN, reminder also NaN
1555   if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1556     {
1557     return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan();
1558     }
1559   # x / +-inf => 0, remainder x (works even if x == 0)
1560   if ($y->{sign} =~ /^[+-]inf$/)
1561     {
1562     my $t = $x->copy();         # bzero clobbers up $x
1563     return wantarray ? ($x->bzero(),$t) : $x->bzero()
1564     }
1565
1566   # 5 / 0 => +inf, -6 / 0 => -inf
1567   # +inf / 0 = inf, inf,  and -inf / 0 => -inf, -inf
1568   # exception:   -8 / 0 has remainder -8, not 8
1569   # exception: -inf / 0 has remainder -inf, not inf
1570   if ($y->is_zero())
1571     {
1572     # +-inf / 0 => special case for -inf
1573     return wantarray ?  ($x,$x->copy()) : $x if $x->is_inf();
1574     if (!$x->is_zero() && !$x->is_inf())
1575       {
1576       my $t = $x->copy();               # binf clobbers up $x
1577       return wantarray ?
1578        ($x->binf($x->{sign}),$t) : $x->binf($x->{sign})
1579       }
1580     }
1581
1582   # last case: +-inf / ordinary number
1583   my $sign = '+inf';
1584   $sign = '-inf' if substr($x->{sign},0,1) ne $y->{sign};
1585   $x->{sign} = $sign;
1586   return wantarray ? ($x,$self->bzero()) : $x;
1587   }
1588
1589 sub bdiv
1590   {
1591   # (dividend: BINT or num_str, divisor: BINT or num_str) return
1592   # (BINT,BINT) (quo,rem) or BINT (only rem)
1593
1594   # set up parameters
1595   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1596   # objectify is costly, so avoid it
1597   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1598     {
1599     ($self,$x,$y,@r) = objectify(2,@_);
1600     }
1601
1602   return $x if $x->modify('bdiv');
1603
1604   return $self->_div_inf($x,$y)
1605    if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero());
1606
1607   return $upgrade->bdiv($upgrade->new($x),$upgrade->new($y),@r)
1608    if defined $upgrade;
1609
1610   $r[3] = $y;                                   # no push!
1611
1612   # calc new sign and in case $y == +/- 1, return $x
1613   my $xsign = $x->{sign};                               # keep
1614   $x->{sign} = ($x->{sign} ne $y->{sign} ? '-' : '+');
1615
1616   if (wantarray)
1617     {
1618     my $rem = $self->bzero();
1619     ($x->{value},$rem->{value}) = $CALC->_div($x->{value},$y->{value});
1620     $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1621     $rem->{_a} = $x->{_a};
1622     $rem->{_p} = $x->{_p};
1623     $x->round(@r);
1624     if (! $CALC->_is_zero($rem->{value}))
1625       {
1626       $rem->{sign} = $y->{sign};
1627       $rem = $y->copy()->bsub($rem) if $xsign ne $y->{sign}; # one of them '-'
1628       }
1629     else
1630       {
1631       $rem->{sign} = '+';                       # dont leave -0
1632       }
1633     $rem->round(@r);
1634     return ($x,$rem);
1635     }
1636
1637   $x->{value} = $CALC->_div($x->{value},$y->{value});
1638   $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1639
1640   $x->round(@r);
1641   }
1642
1643 ###############################################################################
1644 # modulus functions
1645
1646 sub bmod
1647   {
1648   # modulus (or remainder)
1649   # (BINT or num_str, BINT or num_str) return BINT
1650
1651   # set up parameters
1652   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1653   # objectify is costly, so avoid it
1654   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1655     {
1656     ($self,$x,$y,@r) = objectify(2,@_);
1657     }
1658
1659   return $x if $x->modify('bmod');
1660   $r[3] = $y;                                   # no push!
1661   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero())
1662     {
1663     my ($d,$r) = $self->_div_inf($x,$y);
1664     $x->{sign} = $r->{sign};
1665     $x->{value} = $r->{value};
1666     return $x->round(@r);
1667     }
1668
1669   # calc new sign and in case $y == +/- 1, return $x
1670   $x->{value} = $CALC->_mod($x->{value},$y->{value});
1671   if (!$CALC->_is_zero($x->{value}))
1672     {
1673     $x->{value} = $CALC->_sub($y->{value},$x->{value},1)        # $y-$x
1674       if ($x->{sign} ne $y->{sign});
1675     $x->{sign} = $y->{sign};
1676     }
1677    else
1678     {
1679     $x->{sign} = '+';                           # dont leave -0
1680     }
1681   $x->round(@r);
1682   }
1683
1684 sub bmodinv
1685   {
1686   # Modular inverse.  given a number which is (hopefully) relatively
1687   # prime to the modulus, calculate its inverse using Euclid's
1688   # alogrithm.  If the number is not relatively prime to the modulus
1689   # (i.e. their gcd is not one) then NaN is returned.
1690
1691   # set up parameters
1692   my ($self,$x,$y,@r) = (undef,@_);
1693   # objectify is costly, so avoid it
1694   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1695     {
1696     ($self,$x,$y,@r) = objectify(2,@_);
1697     }
1698
1699   return $x if $x->modify('bmodinv');
1700
1701   return $x->bnan()
1702         if ($y->{sign} ne '+'                           # -, NaN, +inf, -inf
1703          || $x->is_zero()                               # or num == 0
1704          || $x->{sign} !~ /^[+-]$/                      # or num NaN, inf, -inf
1705         );
1706
1707   # put least residue into $x if $x was negative, and thus make it positive
1708   $x->bmod($y) if $x->{sign} eq '-';
1709
1710   my $sign;
1711   ($x->{value},$sign) = $CALC->_modinv($x->{value},$y->{value});
1712   return $x->bnan() if !defined $x->{value};            # in case no GCD found
1713   return $x if !defined $sign;                  # already real result
1714   $x->{sign} = $sign;                           # flip/flop see below
1715   $x->bmod($y);                                 # calc real result
1716   $x;
1717   }
1718
1719 sub bmodpow
1720   {
1721   # takes a very large number to a very large exponent in a given very
1722   # large modulus, quickly, thanks to binary exponentation.  supports
1723   # negative exponents.
1724   my ($self,$num,$exp,$mod,@r) = objectify(3,@_);
1725
1726   return $num if $num->modify('bmodpow');
1727
1728   # check modulus for valid values
1729   return $num->bnan() if ($mod->{sign} ne '+'           # NaN, - , -inf, +inf
1730                        || $mod->is_zero());
1731
1732   # check exponent for valid values
1733   if ($exp->{sign} =~ /\w/)
1734     {
1735     # i.e., if it's NaN, +inf, or -inf...
1736     return $num->bnan();
1737     }
1738
1739   $num->bmodinv ($mod) if ($exp->{sign} eq '-');
1740
1741   # check num for valid values (also NaN if there was no inverse but $exp < 0)
1742   return $num->bnan() if $num->{sign} !~ /^[+-]$/;
1743
1744   # $mod is positive, sign on $exp is ignored, result also positive
1745   $num->{value} = $CALC->_modpow($num->{value},$exp->{value},$mod->{value});
1746   $num;
1747   }
1748
1749 ###############################################################################
1750
1751 sub bfac
1752   {
1753   # (BINT or num_str, BINT or num_str) return BINT
1754   # compute factorial number from $x, modify $x in place
1755   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1756
1757   return $x if $x->modify('bfac') || $x->{sign} eq '+inf';      # inf => inf
1758   return $x->bnan() if $x->{sign} ne '+';                       # NaN, <0 etc => NaN
1759
1760   $x->{value} = $CALC->_fac($x->{value});
1761   $x->round(@r);
1762   }
1763
1764 sub bpow
1765   {
1766   # (BINT or num_str, BINT or num_str) return BINT
1767   # compute power of two numbers -- stolen from Knuth Vol 2 pg 233
1768   # modifies first argument
1769
1770   # set up parameters
1771   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1772   # objectify is costly, so avoid it
1773   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1774     {
1775     ($self,$x,$y,@r) = objectify(2,@_);
1776     }
1777
1778   return $x if $x->modify('bpow');
1779
1780   return $x->bnan() if $x->{sign} eq $nan || $y->{sign} eq $nan;
1781
1782   # inf handling
1783   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1784     {
1785     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1786       {
1787       # +-inf ** +-inf
1788       return $x->bnan();
1789       }
1790     # +-inf ** Y
1791     if ($x->{sign} =~ /^[+-]inf/)
1792       {
1793       # +inf ** 0 => NaN
1794       return $x->bnan() if $y->is_zero();
1795       # -inf ** -1 => 1/inf => 0
1796       return $x->bzero() if $y->is_one('-') && $x->is_negative();
1797
1798       # +inf ** Y => inf
1799       return $x if $x->{sign} eq '+inf';
1800
1801       # -inf ** Y => -inf if Y is odd
1802       return $x if $y->is_odd();
1803       return $x->babs();
1804       }
1805     # X ** +-inf
1806
1807     # 1 ** +inf => 1
1808     return $x if $x->is_one();
1809
1810     # 0 ** inf => 0
1811     return $x if $x->is_zero() && $y->{sign} =~ /^[+]/;
1812
1813     # 0 ** -inf => inf
1814     return $x->binf() if $x->is_zero();
1815
1816     # -1 ** -inf => NaN
1817     return $x->bnan() if $x->is_one('-') && $y->{sign} =~ /^[-]/;
1818
1819     # -X ** -inf => 0
1820     return $x->bzero() if $x->{sign} eq '-' && $y->{sign} =~ /^[-]/;
1821
1822     # -1 ** inf => NaN
1823     return $x->bnan() if $x->{sign} eq '-';
1824
1825     # X ** inf => inf
1826     return $x->binf() if $y->{sign} =~ /^[+]/;
1827     # X ** -inf => 0
1828     return $x->bzero();
1829     }
1830
1831   return $upgrade->bpow($upgrade->new($x),$y,@r)
1832    if defined $upgrade && (!$y->isa($self) || $y->{sign} eq '-');
1833
1834   $r[3] = $y;                                   # no push!
1835
1836   # cases 0 ** Y, X ** 0, X ** 1, 1 ** Y are handled by Calc or Emu
1837
1838   my $new_sign = '+';
1839   $new_sign = $y->is_odd() ? '-' : '+' if ($x->{sign} ne '+');
1840
1841   # 0 ** -7 => ( 1 / (0 ** 7)) => 1 / 0 => +inf
1842   return $x->binf()
1843     if $y->{sign} eq '-' && $x->{sign} eq '+' && $CALC->_is_zero($x->{value});
1844   # 1 ** -y => 1 / (1 ** |y|)
1845   # so do test for negative $y after above's clause
1846   return $x->bnan() if $y->{sign} eq '-' && !$CALC->_is_one($x->{value});
1847
1848   $x->{value} = $CALC->_pow($x->{value},$y->{value});
1849   $x->{sign} = $new_sign;
1850   $x->{sign} = '+' if $CALC->_is_zero($y->{value});
1851   $x->round(@r);
1852   }
1853
1854 sub blsft
1855   {
1856   # (BINT or num_str, BINT or num_str) return BINT
1857   # compute x << y, base n, y >= 0
1858
1859   # set up parameters
1860   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1861   # objectify is costly, so avoid it
1862   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1863     {
1864     ($self,$x,$y,$n,@r) = objectify(2,@_);
1865     }
1866
1867   return $x if $x->modify('blsft');
1868   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1869   return $x->round(@r) if $y->is_zero();
1870
1871   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1872
1873   $x->{value} = $CALC->_lsft($x->{value},$y->{value},$n);
1874   $x->round(@r);
1875   }
1876
1877 sub brsft
1878   {
1879   # (BINT or num_str, BINT or num_str) return BINT
1880   # compute x >> y, base n, y >= 0
1881
1882   # set up parameters
1883   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
1884   # objectify is costly, so avoid it
1885   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1886     {
1887     ($self,$x,$y,$n,@r) = objectify(2,@_);
1888     }
1889
1890   return $x if $x->modify('brsft');
1891   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1892   return $x->round(@r) if $y->is_zero();
1893   return $x->bzero(@r) if $x->is_zero();                # 0 => 0
1894
1895   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
1896
1897    # this only works for negative numbers when shifting in base 2
1898   if (($x->{sign} eq '-') && ($n == 2))
1899     {
1900     return $x->round(@r) if $x->is_one('-');    # -1 => -1
1901     if (!$y->is_one())
1902       {
1903       # although this is O(N*N) in calc (as_bin!) it is O(N) in Pari et al
1904       # but perhaps there is a better emulation for two's complement shift...
1905       # if $y != 1, we must simulate it by doing:
1906       # convert to bin, flip all bits, shift, and be done
1907       $x->binc();                       # -3 => -2
1908       my $bin = $x->as_bin();
1909       $bin =~ s/^-0b//;                 # strip '-0b' prefix
1910       $bin =~ tr/10/01/;                # flip bits
1911       # now shift
1912       if ($y >= CORE::length($bin))
1913         {
1914         $bin = '0';                     # shifting to far right creates -1
1915                                         # 0, because later increment makes
1916                                         # that 1, attached '-' makes it '-1'
1917                                         # because -1 >> x == -1 !
1918         }
1919       else
1920         {
1921         $bin =~ s/.{$y}$//;             # cut off at the right side
1922         $bin = '1' . $bin;              # extend left side by one dummy '1'
1923         $bin =~ tr/10/01/;              # flip bits back
1924         }
1925       my $res = $self->new('0b'.$bin);  # add prefix and convert back
1926       $res->binc();                     # remember to increment
1927       $x->{value} = $res->{value};      # take over value
1928       return $x->round(@r);             # we are done now, magic, isn't?
1929       }
1930     # x < 0, n == 2, y == 1
1931     $x->bdec();                         # n == 2, but $y == 1: this fixes it
1932     }
1933
1934   $x->{value} = $CALC->_rsft($x->{value},$y->{value},$n);
1935   $x->round(@r);
1936   }
1937
1938 sub band
1939   {
1940   #(BINT or num_str, BINT or num_str) return BINT
1941   # compute x & y
1942
1943   # set up parameters
1944   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1945   # objectify is costly, so avoid it
1946   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1947     {
1948     ($self,$x,$y,@r) = objectify(2,@_);
1949     }
1950
1951   return $x if $x->modify('band');
1952
1953   $r[3] = $y;                           # no push!
1954
1955   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1956
1957   my $sx = $x->{sign} eq '+' ? 1 : -1;
1958   my $sy = $y->{sign} eq '+' ? 1 : -1;
1959
1960   if ($sx == 1 && $sy == 1)
1961     {
1962     $x->{value} = $CALC->_and($x->{value},$y->{value});
1963     return $x->round(@r);
1964     }
1965
1966   if ($CAN{signed_and})
1967     {
1968     $x->{value} = $CALC->_signed_and($x->{value},$y->{value},$sx,$sy);
1969     return $x->round(@r);
1970     }
1971
1972   require $EMU_LIB;
1973   __emu_band($self,$x,$y,$sx,$sy,@r);
1974   }
1975
1976 sub bior
1977   {
1978   #(BINT or num_str, BINT or num_str) return BINT
1979   # compute x | y
1980
1981   # set up parameters
1982   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1983   # objectify is costly, so avoid it
1984   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1985     {
1986     ($self,$x,$y,@r) = objectify(2,@_);
1987     }
1988
1989   return $x if $x->modify('bior');
1990   $r[3] = $y;                           # no push!
1991
1992   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
1993
1994   my $sx = $x->{sign} eq '+' ? 1 : -1;
1995   my $sy = $y->{sign} eq '+' ? 1 : -1;
1996
1997   # the sign of X follows the sign of X, e.g. sign of Y irrelevant for bior()
1998
1999   # don't use lib for negative values
2000   if ($sx == 1 && $sy == 1)
2001     {
2002     $x->{value} = $CALC->_or($x->{value},$y->{value});
2003     return $x->round(@r);
2004     }
2005
2006   # if lib can do negative values, let it handle this
2007   if ($CAN{signed_or})
2008     {
2009     $x->{value} = $CALC->_signed_or($x->{value},$y->{value},$sx,$sy);
2010     return $x->round(@r);
2011     }
2012
2013   require $EMU_LIB;
2014   __emu_bior($self,$x,$y,$sx,$sy,@r);
2015   }
2016
2017 sub bxor
2018   {
2019   #(BINT or num_str, BINT or num_str) return BINT
2020   # compute x ^ y
2021
2022   # set up parameters
2023   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2024   # objectify is costly, so avoid it
2025   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
2026     {
2027     ($self,$x,$y,@r) = objectify(2,@_);
2028     }
2029
2030   return $x if $x->modify('bxor');
2031   $r[3] = $y;                           # no push!
2032
2033   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2034
2035   my $sx = $x->{sign} eq '+' ? 1 : -1;
2036   my $sy = $y->{sign} eq '+' ? 1 : -1;
2037
2038   # don't use lib for negative values
2039   if ($sx == 1 && $sy == 1)
2040     {
2041     $x->{value} = $CALC->_xor($x->{value},$y->{value});
2042     return $x->round(@r);
2043     }
2044
2045   # if lib can do negative values, let it handle this
2046   if ($CAN{signed_xor})
2047     {
2048     $x->{value} = $CALC->_signed_xor($x->{value},$y->{value},$sx,$sy);
2049     return $x->round(@r);
2050     }
2051
2052   require $EMU_LIB;
2053   __emu_bxor($self,$x,$y,$sx,$sy,@r);
2054   }
2055
2056 sub length
2057   {
2058   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2059
2060   my $e = $CALC->_len($x->{value});
2061   wantarray ? ($e,0) : $e;
2062   }
2063
2064 sub digit
2065   {
2066   # return the nth decimal digit, negative values count backward, 0 is right
2067   my ($self,$x,$n) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2068
2069   $n = $n->numify() if ref($n);
2070   $CALC->_digit($x->{value},$n||0);
2071   }
2072
2073 sub _trailing_zeros
2074   {
2075   # return the amount of trailing zeros in $x (as scalar)
2076   my $x = shift;
2077   $x = $class->new($x) unless ref $x;
2078
2079   return 0 if $x->{sign} !~ /^[+-]$/;   # NaN, inf, -inf etc
2080
2081   $CALC->_zeros($x->{value});           # must handle odd values, 0 etc
2082   }
2083
2084 sub bsqrt
2085   {
2086   # calculate square root of $x
2087   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2088
2089   return $x if $x->modify('bsqrt');
2090
2091   return $x->bnan() if $x->{sign} !~ /^\+/;     # -x or -inf or NaN => NaN
2092   return $x if $x->{sign} eq '+inf';            # sqrt(+inf) == inf
2093
2094   return $upgrade->bsqrt($x,@r) if defined $upgrade;
2095
2096   $x->{value} = $CALC->_sqrt($x->{value});
2097   $x->round(@r);
2098   }
2099
2100 sub broot
2101   {
2102   # calculate $y'th root of $x
2103
2104   # set up parameters
2105   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2106
2107   $y = $self->new(2) unless defined $y;
2108
2109   # objectify is costly, so avoid it
2110   if ((!ref($x)) || (ref($x) ne ref($y)))
2111     {
2112     ($self,$x,$y,@r) = objectify(2,$self || $class,@_);
2113     }
2114
2115   return $x if $x->modify('broot');
2116
2117   # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
2118   return $x->bnan() if $x->{sign} !~ /^\+/ || $y->is_zero() ||
2119          $y->{sign} !~ /^\+$/;
2120
2121   return $x->round(@r)
2122     if $x->is_zero() || $x->is_one() || $x->is_inf() || $y->is_one();
2123
2124   return $upgrade->new($x)->broot($upgrade->new($y),@r) if defined $upgrade;
2125
2126   $x->{value} = $CALC->_root($x->{value},$y->{value});
2127   $x->round(@r);
2128   }
2129
2130 sub exponent
2131   {
2132   # return a copy of the exponent (here always 0, NaN or 1 for $m == 0)
2133   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2134
2135   if ($x->{sign} !~ /^[+-]$/)
2136     {
2137     my $s = $x->{sign}; $s =~ s/^[+-]//;  # NaN, -inf,+inf => NaN or inf
2138     return $self->new($s);
2139     }
2140   return $self->bone() if $x->is_zero();
2141
2142   # 12300 => 2 trailing zeros => exponent is 2
2143   $self->new( $CALC->_zeros($x->{value}) );
2144   }
2145
2146 sub mantissa
2147   {
2148   # return the mantissa (compatible to Math::BigFloat, e.g. reduced)
2149   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2150
2151   if ($x->{sign} !~ /^[+-]$/)
2152     {
2153     # for NaN, +inf, -inf: keep the sign
2154     return $self->new($x->{sign});
2155     }
2156   my $m = $x->copy(); delete $m->{_p}; delete $m->{_a};
2157
2158   # that's a bit inefficient:
2159   my $zeros = $CALC->_zeros($m->{value});
2160   $m->brsft($zeros,10) if $zeros != 0;
2161   $m;
2162   }
2163
2164 sub parts
2165   {
2166   # return a copy of both the exponent and the mantissa
2167   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2168
2169   ($x->mantissa(),$x->exponent());
2170   }
2171
2172 ##############################################################################
2173 # rounding functions
2174
2175 sub bfround
2176   {
2177   # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
2178   # $n == 0 || $n == 1 => round to integer
2179   my $x = shift; my $self = ref($x) || $x; $x = $self->new($x) unless ref $x;
2180
2181   my ($scale,$mode) = $x->_scale_p(@_);
2182
2183   return $x if !defined $scale || $x->modify('bfround');        # no-op
2184
2185   # no-op for BigInts if $n <= 0
2186   $x->bround( $x->length()-$scale, $mode) if $scale > 0;
2187
2188   delete $x->{_a};      # delete to save memory
2189   $x->{_p} = $scale;    # store new _p
2190   $x;
2191   }
2192
2193 sub _scan_for_nonzero
2194   {
2195   # internal, used by bround() to scan for non-zeros after a '5'
2196   my ($x,$pad,$xs,$len) = @_;
2197
2198   return 0 if $len == 1;                # "5" is trailed by invisible zeros
2199   my $follow = $pad - 1;
2200   return 0 if $follow > $len || $follow < 1;
2201
2202   # use the string form to check whether only '0's follow or not
2203   substr ($xs,-$follow) =~ /[^0]/ ? 1 : 0;
2204   }
2205
2206 sub fround
2207   {
2208   # Exists to make life easier for switch between MBF and MBI (should we
2209   # autoload fxxx() like MBF does for bxxx()?)
2210   my $x = shift; $x = $class->new($x) unless ref $x;
2211   $x->bround(@_);
2212   }
2213
2214 sub bround
2215   {
2216   # accuracy: +$n preserve $n digits from left,
2217   #           -$n preserve $n digits from right (f.i. for 0.1234 style in MBF)
2218   # no-op for $n == 0
2219   # and overwrite the rest with 0's, return normalized number
2220   # do not return $x->bnorm(), but $x
2221
2222   my $x = shift; $x = $class->new($x) unless ref $x;
2223   my ($scale,$mode) = $x->_scale_a(@_);
2224   return $x if !defined $scale || $x->modify('bround'); # no-op
2225
2226   if ($x->is_zero() || $scale == 0)
2227     {
2228     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2229     return $x;
2230     }
2231   return $x if $x->{sign} !~ /^[+-]$/;          # inf, NaN
2232
2233   # we have fewer digits than we want to scale to
2234   my $len = $x->length();
2235   # convert $scale to a scalar in case it is an object (put's a limit on the
2236   # number length, but this would already limited by memory constraints), makes
2237   # it faster
2238   $scale = $scale->numify() if ref ($scale);
2239
2240   # scale < 0, but > -len (not >=!)
2241   if (($scale < 0 && $scale < -$len-1) || ($scale >= $len))
2242     {
2243     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2244     return $x;
2245     }
2246
2247   # count of 0's to pad, from left (+) or right (-): 9 - +6 => 3, or |-6| => 6
2248   my ($pad,$digit_round,$digit_after);
2249   $pad = $len - $scale;
2250   $pad = abs($scale-1) if $scale < 0;
2251
2252   # do not use digit(), it is very costly for binary => decimal
2253   # getting the entire string is also costly, but we need to do it only once
2254   my $xs = $CALC->_str($x->{value});
2255   my $pl = -$pad-1;
2256
2257   # pad:   123: 0 => -1, at 1 => -2, at 2 => -3, at 3 => -4
2258   # pad+1: 123: 0 => 0,  at 1 => -1, at 2 => -2, at 3 => -3
2259   $digit_round = '0'; $digit_round = substr($xs,$pl,1) if $pad <= $len;
2260   $pl++; $pl ++ if $pad >= $len;
2261   $digit_after = '0'; $digit_after = substr($xs,$pl,1) if $pad > 0;
2262
2263   # in case of 01234 we round down, for 6789 up, and only in case 5 we look
2264   # closer at the remaining digits of the original $x, remember decision
2265   my $round_up = 1;                                     # default round up
2266   $round_up -- if
2267     ($mode eq 'trunc')                          ||      # trunc by round down
2268     ($digit_after =~ /[01234]/)                 ||      # round down anyway,
2269                                                         # 6789 => round up
2270     ($digit_after eq '5')                       &&      # not 5000...0000
2271     ($x->_scan_for_nonzero($pad,$xs,$len) == 0)         &&
2272     (
2273      ($mode eq 'even') && ($digit_round =~ /[24680]/) ||
2274      ($mode eq 'odd')  && ($digit_round =~ /[13579]/) ||
2275      ($mode eq '+inf') && ($x->{sign} eq '-')   ||
2276      ($mode eq '-inf') && ($x->{sign} eq '+')   ||
2277      ($mode eq 'zero')          # round down if zero, sign adjusted below
2278     );
2279   my $put_back = 0;                                     # not yet modified
2280
2281   if (($pad > 0) && ($pad <= $len))
2282     {
2283     substr($xs,-$pad,$pad) = '0' x $pad;                # replace with '00...'
2284     $put_back = 1;                                      # need to put back
2285     }
2286   elsif ($pad > $len)
2287     {
2288     $x->bzero();                                        # round to '0'
2289     }
2290
2291   if ($round_up)                                        # what gave test above?
2292     {
2293     $put_back = 1;                                      # need to put back
2294     $pad = $len, $xs = '0' x $pad if $scale < 0;        # tlr: whack 0.51=>1.0
2295
2296     # we modify directly the string variant instead of creating a number and
2297     # adding it, since that is faster (we already have the string)
2298     my $c = 0; $pad ++;                         # for $pad == $len case
2299     while ($pad <= $len)
2300       {
2301       $c = substr($xs,-$pad,1) + 1; $c = '0' if $c eq '10';
2302       substr($xs,-$pad,1) = $c; $pad++;
2303       last if $c != 0;                          # no overflow => early out
2304       }
2305     $xs = '1'.$xs if $c == 0;
2306
2307     }
2308   $x->{value} = $CALC->_new($xs) if $put_back == 1;     # put back, if needed
2309
2310   $x->{_a} = $scale if $scale >= 0;
2311   if ($scale < 0)
2312     {
2313     $x->{_a} = $len+$scale;
2314     $x->{_a} = 0 if $scale < -$len;
2315     }
2316   $x;
2317   }
2318
2319 sub bfloor
2320   {
2321   # return integer less or equal then number; no-op since it's already integer
2322   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2323
2324   $x->round(@r);
2325   }
2326
2327 sub bceil
2328   {
2329   # return integer greater or equal then number; no-op since it's already int
2330   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2331
2332   $x->round(@r);
2333   }
2334
2335 sub as_number
2336   {
2337   # An object might be asked to return itself as bigint on certain overloaded
2338   # operations. This does exactly this, so that sub classes can simple inherit
2339   # it or override with their own integer conversion routine.
2340   $_[0]->copy();
2341   }
2342
2343 sub as_hex
2344   {
2345   # return as hex string, with prefixed 0x
2346   my $x = shift; $x = $class->new($x) if !ref($x);
2347
2348   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2349
2350   my $s = '';
2351   $s = $x->{sign} if $x->{sign} eq '-';
2352   $s . $CALC->_as_hex($x->{value});
2353   }
2354
2355 sub as_bin
2356   {
2357   # return as binary string, with prefixed 0b
2358   my $x = shift; $x = $class->new($x) if !ref($x);
2359
2360   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2361
2362   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2363   return $s . $CALC->_as_bin($x->{value});
2364   }
2365
2366 sub as_oct
2367   {
2368   # return as octal string, with prefixed 0
2369   my $x = shift; $x = $class->new($x) if !ref($x);
2370
2371   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2372
2373   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2374   return $s . $CALC->_as_oct($x->{value});
2375   }
2376
2377 ##############################################################################
2378 # private stuff (internal use only)
2379
2380 sub objectify
2381   {
2382   # check for strings, if yes, return objects instead
2383
2384   # the first argument is number of args objectify() should look at it will
2385   # return $count+1 elements, the first will be a classname. This is because
2386   # overloaded '""' calls bstr($object,undef,undef) and this would result in
2387   # useless objects being created and thrown away. So we cannot simple loop
2388   # over @_. If the given count is 0, all arguments will be used.
2389
2390   # If the second arg is a ref, use it as class.
2391   # If not, try to use it as classname, unless undef, then use $class
2392   # (aka Math::BigInt). The latter shouldn't happen,though.
2393
2394   # caller:                        gives us:
2395   # $x->badd(1);                => ref x, scalar y
2396   # Class->badd(1,2);           => classname x (scalar), scalar x, scalar y
2397   # Class->badd( Class->(1),2); => classname x (scalar), ref x, scalar y
2398   # Math::BigInt::badd(1,2);    => scalar x, scalar y
2399   # In the last case we check number of arguments to turn it silently into
2400   # $class,1,2. (We can not take '1' as class ;o)
2401   # badd($class,1) is not supported (it should, eventually, try to add undef)
2402   # currently it tries 'Math::BigInt' + 1, which will not work.
2403
2404   # some shortcut for the common cases
2405   # $x->unary_op();
2406   return (ref($_[1]),$_[1]) if (@_ == 2) && ($_[0]||0 == 1) && ref($_[1]);
2407
2408   my $count = abs(shift || 0);
2409
2410   my (@a,$k,$d);                # resulting array, temp, and downgrade
2411   if (ref $_[0])
2412     {
2413     # okay, got object as first
2414     $a[0] = ref $_[0];
2415     }
2416   else
2417     {
2418     # nope, got 1,2 (Class->xxx(1) => Class,1 and not supported)
2419     $a[0] = $class;
2420     $a[0] = shift if $_[0] =~ /^[A-Z].*::/;     # classname as first?
2421     }
2422
2423   no strict 'refs';
2424   # disable downgrading, because Math::BigFLoat->foo('1.0','2.0') needs floats
2425   if (defined ${"$a[0]::downgrade"})
2426     {
2427     $d = ${"$a[0]::downgrade"};
2428     ${"$a[0]::downgrade"} = undef;
2429     }
2430
2431   my $up = ${"$a[0]::upgrade"};
2432   # print STDERR "# Now in objectify, my class is today $a[0], count = $count\n";
2433   if ($count == 0)
2434     {
2435     while (@_)
2436       {
2437       $k = shift;
2438       if (!ref($k))
2439         {
2440         $k = $a[0]->new($k);
2441         }
2442       elsif (!defined $up && ref($k) ne $a[0])
2443         {
2444         # foreign object, try to convert to integer
2445         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2446         }
2447       push @a,$k;
2448       }
2449     }
2450   else
2451     {
2452     while ($count > 0)
2453       {
2454       $count--;
2455       $k = shift;
2456       if (!ref($k))
2457         {
2458         $k = $a[0]->new($k);
2459         }
2460       elsif (!defined $up && ref($k) ne $a[0])
2461         {
2462         # foreign object, try to convert to integer
2463         $k->can('as_number') ? $k = $k->as_number() : $k = $a[0]->new($k);
2464         }
2465       push @a,$k;
2466       }
2467     push @a,@_;         # return other params, too
2468     }
2469   if (! wantarray)
2470     {
2471     require Carp; Carp::croak ("$class objectify needs list context");
2472     }
2473   ${"$a[0]::downgrade"} = $d;
2474   @a;
2475   }
2476
2477 sub _register_callback
2478   {
2479   my ($class,$callback) = @_;
2480
2481   if (ref($callback) ne 'CODE')
2482     {
2483     require Carp;
2484     Carp::croak ("$callback is not a coderef");
2485     }
2486   $CALLBACKS{$class} = $callback;
2487   }
2488
2489 sub import
2490   {
2491   my $self = shift;
2492
2493   $IMPORT++;                            # remember we did import()
2494   my @a; my $l = scalar @_;
2495   my $warn_or_die = 0;                  # 0 - no warn, 1 - warn, 2 - die
2496   for ( my $i = 0; $i < $l ; $i++ )
2497     {
2498     if ($_[$i] eq ':constant')
2499       {
2500       # this causes overlord er load to step in
2501       overload::constant
2502         integer => sub { $self->new(shift) },
2503         binary => sub { $self->new(shift) };
2504       }
2505     elsif ($_[$i] eq 'upgrade')
2506       {
2507       # this causes upgrading
2508       $upgrade = $_[$i+1];              # or undef to disable
2509       $i++;
2510       }
2511     elsif ($_[$i] =~ /^(lib|try|only)\z/)
2512       {
2513       # this causes a different low lib to take care...
2514       $CALC = $_[$i+1] || '';
2515       # lib => 1 (warn on fallback), try => 0 (no warn), only => 2 (die on fallback)
2516       $warn_or_die = 1 if $_[$i] eq 'lib';
2517       $warn_or_die = 2 if $_[$i] eq 'only';
2518       $i++;
2519       }
2520     else
2521       {
2522       push @a, $_[$i];
2523       }
2524     }
2525   # any non :constant stuff is handled by our parent, Exporter
2526   if (@a > 0)
2527     {
2528     require Exporter;
2529
2530     $self->SUPER::import(@a);                   # need it for subclasses
2531     $self->export_to_level(1,$self,@a);         # need it for MBF
2532     }
2533
2534   # try to load core math lib
2535   my @c = split /\s*,\s*/,$CALC;
2536   foreach (@c)
2537     {
2538     $_ =~ tr/a-zA-Z0-9://cd;                    # limit to sane characters
2539     }
2540   push @c, \'FastCalc', \'Calc'                 # if all fail, try these
2541     if $warn_or_die < 2;                        # but not for "only"
2542   $CALC = '';                                   # signal error
2543   foreach my $l (@c)
2544     {
2545     # fallback libraries are "marked" as \'string', extract string if nec.
2546     my $lib = $l; $lib = $$l if ref($l);
2547
2548     next if ($lib || '') eq '';
2549     $lib = 'Math::BigInt::'.$lib if $lib !~ /^Math::BigInt/i;
2550     $lib =~ s/\.pm$//;
2551     if ($] < 5.006)
2552       {
2553       # Perl < 5.6.0 dies with "out of memory!" when eval("") and ':constant' is
2554       # used in the same script, or eval("") inside import().
2555       my @parts = split /::/, $lib;             # Math::BigInt => Math BigInt
2556       my $file = pop @parts; $file .= '.pm';    # BigInt => BigInt.pm
2557       require File::Spec;
2558       $file = File::Spec->catfile (@parts, $file);
2559       eval { require "$file"; $lib->import( @c ); }
2560       }
2561     else
2562       {
2563       eval "use $lib qw/@c/;";
2564       }
2565     if ($@ eq '')
2566       {
2567       my $ok = 1;
2568       # loaded it ok, see if the api_version() is high enough
2569       if ($lib->can('api_version') && $lib->api_version() >= 1.0)
2570         {
2571         $ok = 0;
2572         # api_version matches, check if it really provides anything we need
2573         for my $method (qw/
2574                 one two ten
2575                 str num
2576                 add mul div sub dec inc
2577                 acmp len digit is_one is_zero is_even is_odd
2578                 is_two is_ten
2579                 zeros new copy check
2580                 from_hex from_oct from_bin as_hex as_bin as_oct
2581                 rsft lsft xor and or
2582                 mod sqrt root fac pow modinv modpow log_int gcd
2583          /)
2584           {
2585           if (!$lib->can("_$method"))
2586             {
2587             if (($WARN{$lib}||0) < 2)
2588               {
2589               require Carp;
2590               Carp::carp ("$lib is missing method '_$method'");
2591               $WARN{$lib} = 1;          # still warn about the lib
2592               }
2593             $ok++; last;
2594             }
2595           }
2596         }
2597       if ($ok == 0)
2598         {
2599         $CALC = $lib;
2600         if ($warn_or_die > 0 && ref($l))
2601           {
2602           require Carp;
2603           my $msg = "Math::BigInt: couldn't load specified math lib(s), fallback to $lib";
2604           Carp::carp ($msg) if $warn_or_die == 1;
2605           Carp::croak ($msg) if $warn_or_die == 2;
2606           }
2607         last;                   # found a usable one, break
2608         }
2609       else
2610         {
2611         if (($WARN{$lib}||0) < 2)
2612           {
2613           my $ver = eval "\$$lib\::VERSION" || 'unknown';
2614           require Carp;
2615           Carp::carp ("Cannot load outdated $lib v$ver, please upgrade");
2616           $WARN{$lib} = 2;              # never warn again
2617           }
2618         }
2619       }
2620     }
2621   if ($CALC eq '')
2622     {
2623     require Carp;
2624     if ($warn_or_die == 2)
2625       {
2626       Carp::croak ("Couldn't load specified math lib(s) and fallback disallowed");
2627       }
2628     else
2629       {
2630       Carp::croak ("Couldn't load any math lib(s), not even fallback to Calc.pm");
2631       }
2632     }
2633
2634   # notify callbacks
2635   foreach my $class (keys %CALLBACKS)
2636     {
2637     &{$CALLBACKS{$class}}($CALC);
2638     }
2639
2640   # Fill $CAN with the results of $CALC->can(...) for emulating lower math lib
2641   # functions
2642
2643   %CAN = ();
2644   for my $method (qw/ signed_and signed_or signed_xor /)
2645     {
2646     $CAN{$method} = $CALC->can("_$method") ? 1 : 0;
2647     }
2648
2649   # import done
2650   }
2651
2652 sub from_hex
2653   {
2654   # create a bigint from a hexadecimal string
2655   my ($self, $hs) = @_;
2656
2657   my $rc = $self->__from_hex($hs);
2658
2659   return $self->bnan() unless defined $rc;
2660
2661   $rc;
2662   }
2663
2664 sub from_bin
2665   {
2666   # create a bigint from a hexadecimal string
2667   my ($self, $bs) = @_;
2668
2669   my $rc = $self->__from_bin($bs);
2670
2671   return $self->bnan() unless defined $rc;
2672
2673   $rc;
2674   }
2675
2676 sub from_oct
2677   {
2678   # create a bigint from a hexadecimal string
2679   my ($self, $os) = @_;
2680
2681   my $x = $self->bzero();
2682
2683   # strip underscores
2684   $os =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2685   $os =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2686
2687   return $x->bnan() if $os !~ /^[\-\+]?0[0-9]+$/;
2688
2689   my $sign = '+'; $sign = '-' if $os =~ /^-/;
2690
2691   $os =~ s/^[+-]//;                                             # strip sign
2692   $x->{value} = $CALC->_from_oct($os);
2693   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2694   $x;
2695   }
2696
2697 sub __from_hex
2698   {
2699   # internal
2700   # convert a (ref to) big hex string to BigInt, return undef for error
2701   my $hs = shift;
2702
2703   my $x = Math::BigInt->bzero();
2704
2705   # strip underscores
2706   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2707   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;
2708
2709   return $x->bnan() if $hs !~ /^[\-\+]?0x[0-9A-Fa-f]+$/;
2710
2711   my $sign = '+'; $sign = '-' if $hs =~ /^-/;
2712
2713   $hs =~ s/^[+-]//;                                             # strip sign
2714   $x->{value} = $CALC->_from_hex($hs);
2715   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2716   $x;
2717   }
2718
2719 sub __from_bin
2720   {
2721   # internal
2722   # convert a (ref to) big binary string to BigInt, return undef for error
2723   my $bs = shift;
2724
2725   my $x = Math::BigInt->bzero();
2726
2727   # strip underscores
2728   $bs =~ s/([01])_([01])/$1$2/g;
2729   $bs =~ s/([01])_([01])/$1$2/g;
2730   return $x->bnan() if $bs !~ /^[+-]?0b[01]+$/;
2731
2732   my $sign = '+'; $sign = '-' if $bs =~ /^\-/;
2733   $bs =~ s/^[+-]//;                                             # strip sign
2734
2735   $x->{value} = $CALC->_from_bin($bs);
2736   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2737   $x;
2738   }
2739
2740 sub _split
2741   {
2742   # input: num_str; output: undef for invalid or
2743   # (\$mantissa_sign,\$mantissa_value,\$mantissa_fraction,\$exp_sign,\$exp_value)
2744   # Internal, take apart a string and return the pieces.
2745   # Strip leading/trailing whitespace, leading zeros, underscore and reject
2746   # invalid input.
2747   my $x = shift;
2748
2749   # strip white space at front, also extranous leading zeros
2750   $x =~ s/^\s*([-]?)0*([0-9])/$1$2/g;   # will not strip '  .2'
2751   $x =~ s/^\s+//;                       # but this will
2752   $x =~ s/\s+$//g;                      # strip white space at end
2753
2754   # shortcut, if nothing to split, return early
2755   if ($x =~ /^[+-]?[0-9]+\z/)
2756     {
2757     $x =~ s/^([+-])0*([0-9])/$2/; my $sign = $1 || '+';
2758     return (\$sign, \$x, \'', \'', \0);
2759     }
2760
2761   # invalid starting char?
2762   return if $x !~ /^[+-]?(\.?[0-9]|0b[0-1]|0x[0-9a-fA-F])/;
2763
2764   return __from_hex($x) if $x =~ /^[\-\+]?0x/;          # hex string
2765   return __from_bin($x) if $x =~ /^[\-\+]?0b/;          # binary string
2766
2767   # strip underscores between digits
2768   $x =~ s/([0-9])_([0-9])/$1$2/g;
2769   $x =~ s/([0-9])_([0-9])/$1$2/g;               # do twice for 1_2_3
2770
2771   # some possible inputs:
2772   # 2.1234 # 0.12        # 1          # 1E1 # 2.134E1 # 434E-10 # 1.02009E-2
2773   # .2     # 1_2_3.4_5_6 # 1.4E1_2_3  # 1e3 # +.2     # 0e999
2774
2775   my ($m,$e,$last) = split /[Ee]/,$x;
2776   return if defined $last;              # last defined => 1e2E3 or others
2777   $e = '0' if !defined $e || $e eq "";
2778
2779   # sign,value for exponent,mantint,mantfrac
2780   my ($es,$ev,$mis,$miv,$mfv);
2781   # valid exponent?
2782   if ($e =~ /^([+-]?)0*([0-9]+)$/)      # strip leading zeros
2783     {
2784     $es = $1; $ev = $2;
2785     # valid mantissa?
2786     return if $m eq '.' || $m eq '';
2787     my ($mi,$mf,$lastf) = split /\./,$m;
2788     return if defined $lastf;           # lastf defined => 1.2.3 or others
2789     $mi = '0' if !defined $mi;
2790     $mi .= '0' if $mi =~ /^[\-\+]?$/;
2791     $mf = '0' if !defined $mf || $mf eq '';
2792     if ($mi =~ /^([+-]?)0*([0-9]+)$/)           # strip leading zeros
2793       {
2794       $mis = $1||'+'; $miv = $2;
2795       return unless ($mf =~ /^([0-9]*?)0*$/);   # strip trailing zeros
2796       $mfv = $1;
2797       # handle the 0e999 case here
2798       $ev = 0 if $miv eq '0' && $mfv eq '';
2799       return (\$mis,\$miv,\$mfv,\$es,\$ev);
2800       }
2801     }
2802   return; # NaN, not a number
2803   }
2804
2805 ##############################################################################
2806 # internal calculation routines (others are in Math::BigInt::Calc etc)
2807
2808 sub __lcm
2809   {
2810   # (BINT or num_str, BINT or num_str) return BINT
2811   # does modify first argument
2812   # LCM
2813
2814   my ($x,$ty) = @_;
2815   return $x->bnan() if ($x->{sign} eq $nan) || ($ty->{sign} eq $nan);
2816   my $method = ref($x) . '::bgcd';
2817   no strict 'refs';
2818   $x * $ty / &$method($x,$ty);
2819   }
2820
2821 ###############################################################################
2822 # this method returns 0 if the object can be modified, or 1 if not.
2823 # We use a fast constant sub() here, to avoid costly calls. Subclasses
2824 # may override it with special code (f.i. Math::BigInt::Constant does so)
2825
2826 sub modify () { 0; }
2827
2828 1;
2829 __END__
2830
2831 =pod
2832
2833 =head1 NAME
2834
2835 Math::BigInt - Arbitrary size integer/float math package
2836
2837 =head1 SYNOPSIS
2838
2839   use Math::BigInt;
2840
2841   # or make it faster: install (optional) Math::BigInt::GMP
2842   # and always use (it will fall back to pure Perl if the
2843   # GMP library is not installed):
2844
2845   # will warn if Math::BigInt::GMP cannot be found
2846   use Math::BigInt lib => 'GMP';
2847
2848   # to supress the warning use this:
2849   # use Math::BigInt try => 'GMP';
2850
2851   my $str = '1234567890';
2852   my @values = (64,74,18);
2853   my $n = 1; my $sign = '-';
2854
2855   # Number creation
2856   $x = Math::BigInt->new($str);         # defaults to 0
2857   $y = $x->copy();                      # make a true copy
2858   $nan  = Math::BigInt->bnan();         # create a NotANumber
2859   $zero = Math::BigInt->bzero();        # create a +0
2860   $inf = Math::BigInt->binf();          # create a +inf
2861   $inf = Math::BigInt->binf('-');       # create a -inf
2862   $one = Math::BigInt->bone();          # create a +1
2863   $one = Math::BigInt->bone('-');       # create a -1
2864
2865   $h = Math::BigInt->new('0x123');      # from hexadecimal
2866   $b = Math::BigInt->new('0b101');      # from binary
2867   $o = Math::BigInt->from_oct('0101');  # from octal
2868
2869   # Testing (don't modify their arguments)
2870   # (return true if the condition is met, otherwise false)
2871
2872   $x->is_zero();        # if $x is +0
2873   $x->is_nan();         # if $x is NaN
2874   $x->is_one();         # if $x is +1
2875   $x->is_one('-');      # if $x is -1
2876   $x->is_odd();         # if $x is odd
2877   $x->is_even();        # if $x is even
2878   $x->is_pos();         # if $x >= 0
2879   $x->is_neg();         # if $x <  0
2880   $x->is_inf($sign);    # if $x is +inf, or -inf (sign is default '+')
2881   $x->is_int();         # if $x is an integer (not a float)
2882
2883   # comparing and digit/sign extraction
2884   $x->bcmp($y);         # compare numbers (undef,<0,=0,>0)
2885   $x->bacmp($y);        # compare absolutely (undef,<0,=0,>0)
2886   $x->sign();           # return the sign, either +,- or NaN
2887   $x->digit($n);        # return the nth digit, counting from right
2888   $x->digit(-$n);       # return the nth digit, counting from left
2889
2890   # The following all modify their first argument. If you want to preserve
2891   # $x, use $z = $x->copy()->bXXX($y); See under L<CAVEATS> for why this is
2892   # necessary when mixing $a = $b assignments with non-overloaded math.
2893
2894   $x->bzero();          # set $x to 0
2895   $x->bnan();           # set $x to NaN
2896   $x->bone();           # set $x to +1
2897   $x->bone('-');        # set $x to -1
2898   $x->binf();           # set $x to inf
2899   $x->binf('-');        # set $x to -inf
2900
2901   $x->bneg();           # negation
2902   $x->babs();           # absolute value
2903   $x->bnorm();          # normalize (no-op in BigInt)
2904   $x->bnot();           # two's complement (bit wise not)
2905   $x->binc();           # increment $x by 1
2906   $x->bdec();           # decrement $x by 1
2907
2908   $x->badd($y);         # addition (add $y to $x)
2909   $x->bsub($y);         # subtraction (subtract $y from $x)
2910   $x->bmul($y);         # multiplication (multiply $x by $y)
2911   $x->bdiv($y);         # divide, set $x to quotient
2912                         # return (quo,rem) or quo if scalar
2913
2914   $x->bmod($y);            # modulus (x % y)
2915   $x->bmodpow($exp,$mod);  # modular exponentation (($num**$exp) % $mod))
2916   $x->bmodinv($mod);       # the inverse of $x in the given modulus $mod
2917
2918   $x->bpow($y);            # power of arguments (x ** y)
2919   $x->blsft($y);           # left shift in base 2
2920   $x->brsft($y);           # right shift in base 2
2921                            # returns (quo,rem) or quo if in scalar context
2922   $x->blsft($y,$n);        # left shift by $y places in base $n
2923   $x->brsft($y,$n);        # right shift by $y places in base $n
2924                            # returns (quo,rem) or quo if in scalar context
2925
2926   $x->band($y);            # bitwise and
2927   $x->bior($y);            # bitwise inclusive or
2928   $x->bxor($y);            # bitwise exclusive or
2929   $x->bnot();              # bitwise not (two's complement)
2930
2931   $x->bsqrt();             # calculate square-root
2932   $x->broot($y);           # $y'th root of $x (e.g. $y == 3 => cubic root)
2933   $x->bfac();              # factorial of $x (1*2*3*4*..$x)
2934
2935   $x->bnok($y);            # x over y (binomial coefficient n over k)
2936
2937   $x->blog();              # logarithm of $x to base e (Euler's number)
2938   $x->blog($base);         # logarithm of $x to base $base (f.i. 2)
2939   $x->bexp();              # calculate e ** $x where e is Euler's number
2940
2941   $x->round($A,$P,$mode);  # round to accuracy or precision using mode $mode
2942   $x->bround($n);          # accuracy: preserve $n digits
2943   $x->bfround($n);         # round to $nth digit, no-op for BigInts
2944
2945   # The following do not modify their arguments in BigInt (are no-ops),
2946   # but do so in BigFloat:
2947
2948   $x->bfloor();            # return integer less or equal than $x
2949   $x->bceil();             # return integer greater or equal than $x
2950
2951   # The following do not modify their arguments:
2952
2953   # greatest common divisor (no OO style)
2954   my $gcd = Math::BigInt::bgcd(@values);
2955   # lowest common multiplicator (no OO style)
2956   my $lcm = Math::BigInt::blcm(@values);
2957
2958   $x->length();            # return number of digits in number
2959   ($xl,$f) = $x->length(); # length of number and length of fraction part,
2960                            # latter is always 0 digits long for BigInts
2961
2962   $x->exponent();          # return exponent as BigInt
2963   $x->mantissa();          # return (signed) mantissa as BigInt
2964   $x->parts();             # return (mantissa,exponent) as BigInt
2965   $x->copy();              # make a true copy of $x (unlike $y = $x;)
2966   $x->as_int();            # return as BigInt (in BigInt: same as copy())
2967   $x->numify();            # return as scalar (might overflow!)
2968
2969   # conversation to string (do not modify their argument)
2970   $x->bstr();              # normalized string (e.g. '3')
2971   $x->bsstr();             # norm. string in scientific notation (e.g. '3E0')
2972   $x->as_hex();            # as signed hexadecimal string with prefixed 0x
2973   $x->as_bin();            # as signed binary string with prefixed 0b
2974   $x->as_oct();            # as signed octal string with prefixed 0
2975
2976
2977   # precision and accuracy (see section about rounding for more)
2978   $x->precision();         # return P of $x (or global, if P of $x undef)
2979   $x->precision($n);       # set P of $x to $n
2980   $x->accuracy();          # return A of $x (or global, if A of $x undef)
2981   $x->accuracy($n);        # set A $x to $n
2982
2983   # Global methods
2984   Math::BigInt->precision();    # get/set global P for all BigInt objects
2985   Math::BigInt->accuracy();     # get/set global A for all BigInt objects
2986   Math::BigInt->round_mode();   # get/set global round mode, one of
2987                                 # 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'
2988   Math::BigInt->config();       # return hash containing configuration
2989
2990 =head1 DESCRIPTION
2991
2992 All operators (including basic math operations) are overloaded if you
2993 declare your big integers as
2994
2995   $i = new Math::BigInt '123_456_789_123_456_789';
2996
2997 Operations with overloaded operators preserve the arguments which is
2998 exactly what you expect.
2999
3000 =over 2
3001
3002 =item Input
3003
3004 Input values to these routines may be any string, that looks like a number
3005 and results in an integer, including hexadecimal and binary numbers.
3006
3007 Scalars holding numbers may also be passed, but note that non-integer numbers
3008 may already have lost precision due to the conversation to float. Quote
3009 your input if you want BigInt to see all the digits:
3010
3011         $x = Math::BigInt->new(12345678890123456789);   # bad
3012         $x = Math::BigInt->new('12345678901234567890'); # good
3013
3014 You can include one underscore between any two digits.
3015
3016 This means integer values like 1.01E2 or even 1000E-2 are also accepted.
3017 Non-integer values result in NaN.
3018
3019 Hexadecimal (prefixed with "0x") and binary numbers (prefixed with "0b")
3020 are accepted, too. Please note that octal numbers are not recognized
3021 by new(), so the following will print "123":
3022
3023         perl -MMath::BigInt -le 'print Math::BigInt->new("0123")'
3024
3025 To convert an octal number, use from_oct();
3026
3027         perl -MMath::BigInt -le 'print Math::BigInt->from_oct("0123")'
3028
3029 Currently, Math::BigInt::new() defaults to 0, while Math::BigInt::new('')
3030 results in 'NaN'. This might change in the future, so use always the following
3031 explicit forms to get a zero or NaN:
3032
3033         $zero = Math::BigInt->bzero();
3034         $nan = Math::BigInt->bnan();
3035
3036 C<bnorm()> on a BigInt object is now effectively a no-op, since the numbers
3037 are always stored in normalized form. If passed a string, creates a BigInt
3038 object from the input.
3039
3040 =item Output
3041
3042 Output values are BigInt objects (normalized), except for the methods which
3043 return a string (see L<SYNOPSIS>).
3044
3045 Some routines (C<is_odd()>, C<is_even()>, C<is_zero()>, C<is_one()>,
3046 C<is_nan()>, etc.) return true or false, while others (C<bcmp()>, C<bacmp()>)
3047 return either undef (if NaN is involved), <0, 0 or >0 and are suited for sort.
3048
3049 =back
3050
3051 =head1 METHODS
3052
3053 Each of the methods below (except config(), accuracy() and precision())
3054 accepts three additional parameters. These arguments C<$A>, C<$P> and C<$R>
3055 are C<accuracy>, C<precision> and C<round_mode>. Please see the section about
3056 L<ACCURACY and PRECISION> for more information.
3057
3058 =head2 config()
3059
3060         use Data::Dumper;
3061
3062         print Dumper ( Math::BigInt->config() );
3063         print Math::BigInt->config()->{lib},"\n";
3064
3065 Returns a hash containing the configuration, e.g. the version number, lib
3066 loaded etc. The following hash keys are currently filled in with the
3067 appropriate information.
3068
3069         key             Description
3070                         Example
3071         ============================================================
3072         lib             Name of the low-level math library
3073                         Math::BigInt::Calc
3074         lib_version     Version of low-level math library (see 'lib')
3075                         0.30
3076         class           The class name of config() you just called
3077                         Math::BigInt
3078         upgrade         To which class math operations might be upgraded
3079                         Math::BigFloat
3080         downgrade       To which class math operations might be downgraded
3081                         undef
3082         precision       Global precision
3083                         undef
3084         accuracy        Global accuracy
3085                         undef
3086         round_mode      Global round mode
3087                         even
3088         version         version number of the class you used
3089                         1.61
3090         div_scale       Fallback accuracy for div
3091                         40
3092         trap_nan        If true, traps creation of NaN via croak()
3093                         1
3094         trap_inf        If true, traps creation of +inf/-inf via croak()
3095                         1
3096
3097 The following values can be set by passing C<config()> a reference to a hash:
3098
3099         trap_inf trap_nan
3100         upgrade downgrade precision accuracy round_mode div_scale
3101
3102 Example:
3103
3104         $new_cfg = Math::BigInt->config( { trap_inf => 1, precision => 5 } );
3105
3106 =head2 accuracy()
3107
3108         $x->accuracy(5);                # local for $x
3109         CLASS->accuracy(5);             # global for all members of CLASS
3110                                         # Note: This also applies to new()!
3111
3112         $A = $x->accuracy();            # read out accuracy that affects $x
3113         $A = CLASS->accuracy();         # read out global accuracy
3114
3115 Set or get the global or local accuracy, aka how many significant digits the
3116 results have. If you set a global accuracy, then this also applies to new()!
3117
3118 Warning! The accuracy I<sticks>, e.g. once you created a number under the
3119 influence of C<< CLASS->accuracy($A) >>, all results from math operations with
3120 that number will also be rounded.
3121
3122 In most cases, you should probably round the results explicitly using one of
3123 L<round()>, L<bround()> or L<bfround()> or by passing the desired accuracy
3124 to the math operation as additional parameter:
3125
3126         my $x = Math::BigInt->new(30000);
3127         my $y = Math::BigInt->new(7);
3128         print scalar $x->copy()->bdiv($y, 2);           # print 4300
3129         print scalar $x->copy()->bdiv($y)->bround(2);   # print 4300
3130
3131 Please see the section about L<ACCURACY AND PRECISION> for further details.
3132
3133 Value must be greater than zero. Pass an undef value to disable it:
3134
3135         $x->accuracy(undef);
3136         Math::BigInt->accuracy(undef);
3137
3138 Returns the current accuracy. For C<$x->accuracy()> it will return either the
3139 local accuracy, or if not defined, the global. This means the return value
3140 represents the accuracy that will be in effect for $x:
3141
3142         $y = Math::BigInt->new(1234567);        # unrounded
3143         print Math::BigInt->accuracy(4),"\n";   # set 4, print 4
3144         $x = Math::BigInt->new(123456);         # $x will be automatically rounded!
3145         print "$x $y\n";                        # '123500 1234567'
3146         print $x->accuracy(),"\n";              # will be 4
3147         print $y->accuracy(),"\n";              # also 4, since global is 4
3148         print Math::BigInt->accuracy(5),"\n";   # set to 5, print 5
3149         print $x->accuracy(),"\n";              # still 4
3150         print $y->accuracy(),"\n";              # 5, since global is 5
3151
3152 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
3153 globals separated from Math::BigInt, but it is possible to subclass
3154 Math::BigInt and make the globals of the subclass aliases to the ones from
3155 Math::BigInt.
3156
3157 =head2 precision()
3158
3159         $x->precision(-2);      # local for $x, round at the second digit right of the dot
3160         $x->precision(2);       # ditto, round at the second digit left of the dot
3161
3162         CLASS->precision(5);    # Global for all members of CLASS
3163                                 # This also applies to new()!
3164         CLASS->precision(-5);   # ditto
3165
3166         $P = CLASS->precision();        # read out global precision
3167         $P = $x->precision();           # read out precision that affects $x
3168
3169 Note: You probably want to use L<accuracy()> instead. With L<accuracy> you
3170 set the number of digits each result should have, with L<precision> you
3171 set the place where to round!
3172
3173 C<precision()> sets or gets the global or local precision, aka at which digit
3174 before or after the dot to round all results. A set global precision also
3175 applies to all newly created numbers!
3176
3177 In Math::BigInt, passing a negative number precision has no effect since no
3178 numbers have digits after the dot. In L<Math::BigFloat>, it will round all
3179 results to P digits after the dot.
3180
3181 Please see the section about L<ACCURACY AND PRECISION> for further details.
3182
3183 Pass an undef value to disable it:
3184
3185         $x->precision(undef);
3186         Math::BigInt->precision(undef);
3187
3188 Returns the current precision. For C<$x->precision()> it will return either the
3189 local precision of $x, or if not defined, the global. This means the return
3190 value represents the prevision that will be in effect for $x:
3191
3192         $y = Math::BigInt->new(1234567);        # unrounded
3193         print Math::BigInt->precision(4),"\n";  # set 4, print 4
3194         $x = Math::BigInt->new(123456);         # will be automatically rounded
3195         print $x;                               # print "120000"!
3196
3197 Note: Works also for subclasses like L<Math::BigFloat>. Each class has its
3198 own globals separated from Math::BigInt, but it is possible to subclass
3199 Math::BigInt and make the globals of the subclass aliases to the ones from
3200 Math::BigInt.
3201
3202 =head2 brsft()
3203
3204         $x->brsft($y,$n);
3205
3206 Shifts $x right by $y in base $n. Default is base 2, used are usually 10 and
3207 2, but others work, too.
3208
3209 Right shifting usually amounts to dividing $x by $n ** $y and truncating the
3210 result:
3211
3212
3213         $x = Math::BigInt->new(10);
3214         $x->brsft(1);                   # same as $x >> 1: 5
3215         $x = Math::BigInt->new(1234);
3216         $x->brsft(2,10);                # result 12
3217
3218 There is one exception, and that is base 2 with negative $x:
3219
3220
3221         $x = Math::BigInt->new(-5);
3222         print $x->brsft(1);
3223
3224 This will print -3, not -2 (as it would if you divide -5 by 2 and truncate the
3225 result).
3226
3227 =head2 new()
3228
3229         $x = Math::BigInt->new($str,$A,$P,$R);
3230
3231 Creates a new BigInt object from a scalar or another BigInt object. The
3232 input is accepted as decimal, hex (with leading '0x') or binary (with leading
3233 '0b').
3234
3235 See L<Input> for more info on accepted input formats.
3236
3237 =head2 from_oct()
3238
3239         $x = Math::BigIn->from_oct("0775");     # input is octal
3240
3241 =head2 from_hex()
3242
3243         $x = Math::BigIn->from_hex("0xcafe");   # input is hexadecimal
3244
3245 =head2 from_bin()
3246
3247         $x = Math::BigIn->from_oct("0x10011");  # input is binary
3248
3249 =head2 bnan()
3250
3251         $x = Math::BigInt->bnan();
3252
3253 Creates a new BigInt object representing NaN (Not A Number).
3254 If used on an object, it will set it to NaN:
3255
3256         $x->bnan();
3257
3258 =head2 bzero()
3259
3260         $x = Math::BigInt->bzero();
3261
3262 Creates a new BigInt object representing zero.
3263 If used on an object, it will set it to zero:
3264
3265         $x->bzero();
3266
3267 =head2 binf()
3268
3269         $x = Math::BigInt->binf($sign);
3270
3271 Creates a new BigInt object representing infinity. The optional argument is
3272 either '-' or '+', indicating whether you want infinity or minus infinity.
3273 If used on an object, it will set it to infinity:
3274
3275         $x->binf();
3276         $x->binf('-');
3277
3278 =head2 bone()
3279
3280         $x = Math::BigInt->binf($sign);
3281
3282 Creates a new BigInt object representing one. The optional argument is
3283 either '-' or '+', indicating whether you want one or minus one.
3284 If used on an object, it will set it to one:
3285
3286         $x->bone();             # +1
3287         $x->bone('-');          # -1
3288
3289 =head2 is_one()/is_zero()/is_nan()/is_inf()
3290
3291
3292         $x->is_zero();                  # true if arg is +0
3293         $x->is_nan();                   # true if arg is NaN
3294         $x->is_one();                   # true if arg is +1
3295         $x->is_one('-');                # true if arg is -1
3296         $x->is_inf();                   # true if +inf
3297         $x->is_inf('-');                # true if -inf (sign is default '+')
3298
3299 These methods all test the BigInt for being one specific value and return
3300 true or false depending on the input. These are faster than doing something
3301 like:
3302
3303         if ($x == 0)
3304
3305 =head2 is_pos()/is_neg()/is_positive()/is_negative()
3306
3307         $x->is_pos();                   # true if > 0
3308         $x->is_neg();                   # true if < 0
3309
3310 The methods return true if the argument is positive or negative, respectively.
3311 C<NaN> is neither positive nor negative, while C<+inf> counts as positive, and
3312 C<-inf> is negative. A C<zero> is neither positive nor negative.
3313
3314 These methods are only testing the sign, and not the value.
3315
3316 C<is_positive()> and C<is_negative()> are aliases to C<is_pos()> and
3317 C<is_neg()>, respectively. C<is_positive()> and C<is_negative()> were
3318 introduced in v1.36, while C<is_pos()> and C<is_neg()> were only introduced
3319 in v1.68.
3320
3321 =head2 is_odd()/is_even()/is_int()
3322
3323         $x->is_odd();                   # true if odd, false for even
3324         $x->is_even();                  # true if even, false for odd
3325         $x->is_int();                   # true if $x is an integer
3326
3327 The return true when the argument satisfies the condition. C<NaN>, C<+inf>,
3328 C<-inf> are not integers and are neither odd nor even.
3329
3330 In BigInt, all numbers except C<NaN>, C<+inf> and C<-inf> are integers.
3331
3332 =head2 bcmp()
3333
3334         $x->bcmp($y);
3335
3336 Compares $x with $y and takes the sign into account.
3337 Returns -1, 0, 1 or undef.
3338
3339 =head2 bacmp()
3340
3341         $x->bacmp($y);
3342
3343 Compares $x with $y while ignoring their. Returns -1, 0, 1 or undef.
3344
3345 =head2 sign()
3346
3347         $x->sign();
3348
3349 Return the sign, of $x, meaning either C<+>, C<->, C<-inf>, C<+inf> or NaN.
3350
3351 If you want $x to have a certain sign, use one of the following methods:
3352
3353         $x->babs();             # '+'
3354         $x->babs()->bneg();     # '-'
3355         $x->bnan();             # 'NaN'
3356         $x->binf();             # '+inf'
3357         $x->binf('-');          # '-inf'
3358
3359 =head2 digit()
3360
3361         $x->digit($n);          # return the nth digit, counting from right
3362
3363 If C<$n> is negative, returns the digit counting from left.
3364
3365 =head2 bneg()
3366
3367         $x->bneg();
3368
3369 Negate the number, e.g. change the sign between '+' and '-', or between '+inf'
3370 and '-inf', respectively. Does nothing for NaN or zero.
3371
3372 =head2 babs()
3373
3374         $x->babs();
3375
3376 Set the number to it's absolute value, e.g. change the sign from '-' to '+'
3377 and from '-inf' to '+inf', respectively. Does nothing for NaN or positive
3378 numbers.
3379
3380 =head2 bnorm()
3381
3382         $x->bnorm();                    # normalize (no-op)
3383
3384 =head2 bnot()
3385
3386         $x->bnot();
3387
3388 Two's complement (bit wise not). This is equivalent to
3389
3390         $x->binc()->bneg();
3391
3392 but faster.
3393
3394 =head2 binc()
3395
3396         $x->binc();                     # increment x by 1
3397
3398 =head2 bdec()
3399
3400         $x->bdec();                     # decrement x by 1
3401
3402 =head2 badd()
3403
3404         $x->badd($y);                   # addition (add $y to $x)
3405
3406 =head2 bsub()
3407
3408         $x->bsub($y);                   # subtraction (subtract $y from $x)
3409
3410 =head2 bmul()
3411
3412         $x->bmul($y);                   # multiplication (multiply $x by $y)
3413
3414 =head2 bdiv()
3415
3416         $x->bdiv($y);                   # divide, set $x to quotient
3417                                         # return (quo,rem) or quo if scalar
3418
3419 =head2 bmod()
3420
3421         $x->bmod($y);                   # modulus (x % y)
3422
3423 =head2 bmodinv()
3424
3425         num->bmodinv($mod);             # modular inverse
3426
3427 Returns the inverse of C<$num> in the given modulus C<$mod>.  'C<NaN>' is
3428 returned unless C<$num> is relatively prime to C<$mod>, i.e. unless
3429 C<bgcd($num, $mod)==1>.
3430
3431 =head2 bmodpow()
3432
3433         $num->bmodpow($exp,$mod);       # modular exponentation
3434                                         # ($num**$exp % $mod)
3435
3436 Returns the value of C<$num> taken to the power C<$exp> in the modulus
3437 C<$mod> using binary exponentation.  C<bmodpow> is far superior to
3438 writing
3439
3440         $num ** $exp % $mod
3441
3442 because it is much faster - it reduces internal variables into
3443 the modulus whenever possible, so it operates on smaller numbers.
3444
3445 C<bmodpow> also supports negative exponents.
3446
3447         bmodpow($num, -1, $mod)
3448
3449 is exactly equivalent to
3450
3451         bmodinv($num, $mod)
3452
3453 =head2 bpow()
3454
3455         $x->bpow($y);                   # power of arguments (x ** y)
3456
3457 =head2 blog()
3458
3459         $x->blog($base, $accuracy);     # logarithm of x to the base $base
3460
3461 If C<$base> is not defined, Euler's number (e) is used:
3462
3463         print $x->blog(undef, 100);     # log(x) to 100 digits
3464
3465 =head2 bexp()
3466
3467         $x->bexp($accuracy);            # calculate e ** X
3468
3469 Calculates the expression C<e ** $x> where C<e> is Euler's number.
3470
3471 This method was added in v1.82 of Math::BigInt (April 2007).
3472
3473 See also L<blog()>.
3474
3475 =head2 bnok()
3476
3477         $x->bnok($y);              # x over y (binomial coefficient n over k)
3478
3479 Calculates the binomial coefficient n over k, also called the "choose"
3480 function. The result is equivalent to:
3481
3482         ( n )      n!
3483         | - |  = -------
3484         ( k )    k!(n-k)!
3485
3486 This method was added in v1.84 of Math::BigInt (April 2007).
3487
3488 =head2 blsft()
3489
3490         $x->blsft($y);          # left shift in base 2
3491         $x->blsft($y,$n);       # left shift, in base $n (like 10)
3492
3493 =head2 brsft()
3494
3495         $x->brsft($y);          # right shift in base 2
3496         $x->brsft($y,$n);       # right shift, in base $n (like 10)
3497
3498 =head2 band()
3499
3500         $x->band($y);                   # bitwise and
3501
3502 =head2 bior()
3503
3504         $x->bior($y);                   # bitwise inclusive or
3505
3506 =head2 bxor()
3507
3508         $x->bxor($y);                   # bitwise exclusive or
3509
3510 =head2 bnot()
3511
3512         $x->bnot();                     # bitwise not (two's complement)
3513
3514 =head2 bsqrt()
3515
3516         $x->bsqrt();                    # calculate square-root
3517
3518 =head2 bfac()
3519
3520         $x->bfac();                     # factorial of $x (1*2*3*4*..$x)
3521
3522 =head2 round()
3523
3524         $x->round($A,$P,$round_mode);
3525
3526 Round $x to accuracy C<$A> or precision C<$P> using the round mode
3527 C<$round_mode>.
3528
3529 =head2 bround()
3530
3531         $x->bround($N);               # accuracy: preserve $N digits
3532
3533 =head2 bfround()
3534
3535         $x->bfround($N);              # round to $Nth digit, no-op for BigInts
3536
3537 =head2 bfloor()
3538
3539         $x->bfloor();
3540
3541 Set $x to the integer less or equal than $x. This is a no-op in BigInt, but
3542 does change $x in BigFloat.
3543
3544 =head2 bceil()
3545
3546         $x->bceil();
3547
3548 Set $x to the integer greater or equal than $x. This is a no-op in BigInt, but
3549 does change $x in BigFloat.
3550
3551 =head2 bgcd()
3552
3553         bgcd(@values);          # greatest common divisor (no OO style)
3554
3555 =head2 blcm()
3556
3557         blcm(@values);          # lowest common multiplicator (no OO style)
3558
3559 head2 length()
3560
3561         $x->length();
3562         ($xl,$fl) = $x->length();
3563
3564 Returns the number of digits in the decimal representation of the number.
3565 In list context, returns the length of the integer and fraction part. For
3566 BigInt's, the length of the fraction part will always be 0.
3567
3568 =head2 exponent()
3569
3570         $x->exponent();
3571
3572 Return the exponent of $x as BigInt.
3573
3574 =head2 mantissa()
3575
3576         $x->mantissa();
3577
3578 Return the signed mantissa of $x as BigInt.
3579
3580 =head2 parts()
3581
3582         $x->parts();            # return (mantissa,exponent) as BigInt
3583
3584 =head2 copy()
3585
3586         $x->copy();             # make a true copy of $x (unlike $y = $x;)
3587
3588 =head2 as_int()/as_number()
3589
3590         $x->as_int();
3591
3592 Returns $x as a BigInt (truncated towards zero). In BigInt this is the same as
3593 C<copy()>.
3594
3595 C<as_number()> is an alias to this method. C<as_number> was introduced in
3596 v1.22, while C<as_int()> was only introduced in v1.68.
3597
3598 =head2 bstr()
3599
3600         $x->bstr();
3601
3602 Returns a normalized string representation of C<$x>.
3603
3604 =head2 bsstr()
3605
3606         $x->bsstr();            # normalized string in scientific notation
3607
3608 =head2 as_hex()
3609
3610         $x->as_hex();           # as signed hexadecimal string with prefixed 0x
3611
3612 =head2 as_bin()
3613
3614         $x->as_bin();           # as signed binary string with prefixed 0b
3615
3616 =head2 as_oct()
3617
3618         $x->as_oct();           # as signed octal string with prefixed 0
3619
3620 =head2 numify()
3621
3622         print $x->numify();
3623
3624 This returns a normal Perl scalar from $x. It is used automatically
3625 whenever a scalar is needed, for instance in array index operations.
3626
3627 This loses precision, to avoid this use L<as_int()> instead.
3628
3629 =head2 modify()
3630
3631         $x->modify('bpowd');
3632
3633 This method returns 0 if the object can be modified with the given
3634 peration, or 1 if not.
3635
3636 This is used for instance by L<Math::BigInt::Constant>.
3637
3638 =head2 upgrade()/downgrade()
3639
3640 Set/get the class for downgrade/upgrade operations. Thuis is used
3641 for instance by L<bignum>. The defaults are '', thus the following
3642 operation will create a BigInt, not a BigFloat:
3643
3644         my $i = Math::BigInt->new(123);
3645         my $f = Math::BigFloat->new('123.1');
3646
3647         print $i + $f,"\n";                     # print 246
3648
3649 =head2 div_scale()
3650
3651 Set/get the number of digits for the default precision in divide
3652 operations.
3653
3654 =head2 round_mode()
3655
3656 Set/get the current round mode.
3657
3658 =head1 ACCURACY and PRECISION
3659
3660 Since version v1.33, Math::BigInt and Math::BigFloat have full support for
3661 accuracy and precision based rounding, both automatically after every
3662 operation, as well as manually.
3663
3664 This section describes the accuracy/precision handling in Math::Big* as it
3665 used to be and as it is now, complete with an explanation of all terms and
3666 abbreviations.
3667
3668 Not yet implemented things (but with correct description) are marked with '!',
3669 things that need to be answered are marked with '?'.
3670
3671 In the next paragraph follows a short description of terms used here (because
3672 these may differ from terms used by others people or documentation).
3673
3674 During the rest of this document, the shortcuts A (for accuracy), P (for
3675 precision), F (fallback) and R (rounding mode) will be used.
3676
3677 =head2 Precision P
3678
3679 A fixed number of digits before (positive) or after (negative)
3680 the decimal point. For example, 123.45 has a precision of -2. 0 means an
3681 integer like 123 (or 120). A precision of 2 means two digits to the left
3682 of the decimal point are zero, so 123 with P = 1 becomes 120. Note that
3683 numbers with zeros before the decimal point may have different precisions,
3684 because 1200 can have p = 0, 1 or 2 (depending on what the inital value
3685 was). It could also have p < 0, when the digits after the decimal point
3686 are zero.
3687
3688 The string output (of floating point numbers) will be padded with zeros:
3689
3690         Initial value   P       A       Result          String
3691         ------------------------------------------------------------
3692         1234.01         -3              1000            1000
3693         1234            -2              1200            1200
3694         1234.5          -1              1230            1230
3695         1234.001        1               1234            1234.0
3696         1234.01         0               1234            1234
3697         1234.01         2               1234.01         1234.01
3698         1234.01         5               1234.01         1234.01000
3699
3700 For BigInts, no padding occurs.
3701
3702 =head2 Accuracy A
3703
3704 Number of significant digits. Leading zeros are not counted. A
3705 number may have an accuracy greater than the non-zero digits
3706 when there are zeros in it or trailing zeros. For example, 123.456 has
3707 A of 6, 10203 has 5, 123.0506 has 7, 123.450000 has 8 and 0.000123 has 3.
3708
3709 The string output (of floating point numbers) will be padded with zeros:
3710
3711         Initial value   P       A       Result          String
3712         ------------------------------------------------------------
3713         1234.01                 3       1230            1230
3714         1234.01                 6       1234.01         1234.01
3715         1234.1                  8       1234.1          1234.1000
3716
3717 For BigInts, no padding occurs.
3718
3719 =head2 Fallback F
3720
3721 When both A and P are undefined, this is used as a fallback accuracy when
3722 dividing numbers.
3723
3724 =head2 Rounding mode R
3725
3726 When rounding a number, different 'styles' or 'kinds'
3727 of rounding are possible. (Note that random rounding, as in
3728 Math::Round, is not implemented.)
3729
3730 =over 2
3731
3732 =item 'trunc'
3733
3734 truncation invariably removes all digits following the
3735 rounding place, replacing them with zeros. Thus, 987.65 rounded
3736 to tens (P=1) becomes 980, and rounded to the fourth sigdig
3737 becomes 987.6 (A=4). 123.456 rounded to the second place after the
3738 decimal point (P=-2) becomes 123.46.
3739
3740 All other implemented styles of rounding attempt to round to the
3741 "nearest digit." If the digit D immediately to the right of the
3742 rounding place (skipping the decimal point) is greater than 5, the
3743 number is incremented at the rounding place (possibly causing a
3744 cascade of incrementation): e.g. when rounding to units, 0.9 rounds
3745 to 1, and -19.9 rounds to -20. If D < 5, the number is similarly
3746 truncated at the rounding place: e.g. when rounding to units, 0.4
3747 rounds to 0, and -19.4 rounds to -19.
3748
3749 However the results of other styles of rounding differ if the
3750 digit immediately to the right of the rounding place (skipping the
3751 decimal point) is 5 and if there are no digits, or no digits other
3752 than 0, after that 5. In such cases:
3753
3754 =item 'even'
3755
3756 rounds the digit at the rounding place to 0, 2, 4, 6, or 8
3757 if it is not already. E.g., when rounding to the first sigdig, 0.45
3758 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.
3759
3760 =item 'odd'
3761
3762 rounds the digit at the rounding place to 1, 3, 5, 7, or 9 if
3763 it is not already. E.g., when rounding to the first sigdig, 0.45
3764 becomes 0.5, -0.55 becomes -0.5, but 0.5501 becomes 0.6.
3765
3766 =item '+inf'
3767
3768 round to plus infinity, i.e. always round up. E.g., when
3769 rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5,
3770 and 0.4501 also becomes 0.5.
3771
3772 =item '-inf'
3773
3774 round to minus infinity, i.e. always round down. E.g., when
3775 rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6,
3776 but 0.4501 becomes 0.5.
3777
3778 =item 'zero'
3779
3780 round to zero, i.e. positive numbers down, negative ones up.
3781 E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55
3782 becomes -0.5, but 0.4501 becomes 0.5.
3783
3784 =item 'common'
3785
3786 round up if the digit immediately to the right of the rounding place
3787 is 5 or greater, otherwise round down. E.g., 0.15 becomes 0.2 and
3788 0.149 becomes 0.1.
3789
3790 =back
3791
3792 The handling of A & P in MBI/MBF (the old core code shipped with Perl
3793 versions <= 5.7.2) is like this:
3794
3795 =over 2
3796
3797 =item Precision
3798
3799   * ffround($p) is able to round to $p number of digits after the decimal
3800     point
3801   * otherwise P is unused
3802
3803 =item Accuracy (significant digits)
3804
3805   * fround($a) rounds to $a significant digits
3806   * only fdiv() and fsqrt() take A as (optional) paramater
3807     + other operations simply create the same number (fneg etc), or more (fmul)
3808       of digits
3809     + rounding/truncating is only done when explicitly calling one of fround
3810       or ffround, and never for BigInt (not implemented)
3811   * fsqrt() simply hands its accuracy argument over to fdiv.
3812   * the documentation and the comment in the code indicate two different ways
3813     on how fdiv() determines the maximum number of digits it should calculate,
3814     and the actual code does yet another thing
3815     POD:
3816       max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
3817     Comment:
3818       result has at most max(scale, length(dividend), length(divisor)) digits
3819     Actual code:
3820       scale = max(scale, length(dividend)-1,length(divisor)-1);
3821       scale += length(divisor) - length(dividend);
3822     So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10+9-3).
3823     Actually, the 'difference' added to the scale is calculated from the
3824     number of "significant digits" in dividend and divisor, which is derived
3825     by looking at the length of the mantissa. Which is wrong, since it includes
3826     the + sign (oops) and actually gets 2 for '+100' and 4 for '+101'. Oops
3827     again. Thus 124/3 with div_scale=1 will get you '41.3' based on the strange
3828     assumption that 124 has 3 significant digits, while 120/7 will get you
3829     '17', not '17.1' since 120 is thought to have 2 significant digits.
3830     The rounding after the division then uses the remainder and $y to determine
3831     wether it must round up or down.
3832  ?  I have no idea which is the right way. That's why I used a slightly more
3833  ?  simple scheme and tweaked the few failing testcases to match it.
3834
3835 =back
3836
3837 This is how it works now:
3838
3839 =over 2
3840
3841 =item Setting/Accessing
3842
3843   * You can set the A global via C<< Math::BigInt->accuracy() >> or
3844     C<< Math::BigFloat->accuracy() >> or whatever class you are using.
3845   * You can also set P globally by using C<< Math::SomeClass->precision() >>
3846     likewise.
3847   * Globals are classwide, and not inherited by subclasses.
3848   * to undefine A, use C<< Math::SomeCLass->accuracy(undef); >>
3849   * to undefine P, use C<< Math::SomeClass->precision(undef); >>
3850   * Setting C<< Math::SomeClass->accuracy() >> clears automatically
3851     C<< Math::SomeClass->precision() >>, and vice versa.
3852   * To be valid, A must be > 0, P can have any value.
3853   * If P is negative, this means round to the P'th place to the right of the
3854     decimal point; positive values mean to the left of the decimal point.
3855     P of 0 means round to integer.
3856   * to find out the current global A, use C<< Math::SomeClass->accuracy() >>
3857   * to find out the current global P, use C<< Math::SomeClass->precision() >>
3858   * use C<< $x->accuracy() >> respective C<< $x->precision() >> for the local
3859     setting of C<< $x >>.
3860   * Please note that C<< $x->accuracy() >> respective C<< $x->precision() >>
3861     return eventually defined global A or P, when C<< $x >>'s A or P is not
3862     set.
3863
3864 =item Creating numbers
3865
3866   * When you create a number, you can give it's desired A or P via:
3867     $x = Math::BigInt->new($number,$A,$P);
3868   * Only one of A or P can be defined, otherwise the result is NaN
3869   * If no A or P is give ($x = Math::BigInt->new($number) form), then the
3870     globals (if set) will be used. Thus changing the global defaults later on
3871     will not change the A or P of previously created numbers (i.e., A and P of
3872     $x will be what was in effect when $x was created)
3873   * If given undef for A and P, B<no> rounding will occur, and the globals will
3874     B<not> be used. This is used by subclasses to create numbers without
3875     suffering rounding in the parent. Thus a subclass is able to have it's own
3876     globals enforced upon creation of a number by using
3877     C<< $x = Math::BigInt->new($number,undef,undef) >>:
3878
3879         use Math::BigInt::SomeSubclass;
3880         use Math::BigInt;
3881
3882         Math::BigInt->accuracy(2);
3883         Math::BigInt::SomeSubClass->accuracy(3);
3884         $x = Math::BigInt::SomeSubClass->new(1234);
3885
3886     $x is now 1230, and not 1200. A subclass might choose to implement
3887     this otherwise, e.g. falling back to the parent's A and P.
3888
3889 =item Usage
3890
3891   * If A or P are enabled/defined, they are used to round the result of each
3892     operation according to the rules below
3893   * Negative P is ignored in Math::BigInt, since BigInts never have digits
3894     after the decimal point
3895   * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
3896     Math::BigInt as globals does not tamper with the parts of a BigFloat.
3897     A flag is used to mark all Math::BigFloat numbers as 'never round'.
3898
3899 =item Precedence
3900
3901   * It only makes sense that a number has only one of A or P at a time.
3902     If you set either A or P on one object, or globally, the other one will
3903     be automatically cleared.
3904   * If two objects are involved in an operation, and one of them has A in
3905     effect, and the other P, this results in an error (NaN).
3906   * A takes precedence over P (Hint: A comes before P).
3907     If neither of them is defined, nothing is used, i.e. the result will have
3908     as many digits as it can (with an exception for fdiv/fsqrt) and will not
3909     be rounded.
3910   * There is another setting for fdiv() (and thus for fsqrt()). If neither of
3911     A or P is defined, fdiv() will use a fallback (F) of $div_scale digits.
3912     If either the dividend's or the divisor's mantissa has more digits than
3913     the value of F, the higher value will be used instead of F.
3914     This is to limit the digits (A) of the result (just consider what would
3915     happen with unlimited A and P in the case of 1/3 :-)
3916   * fdiv will calculate (at least) 4 more digits than required (determined by
3917     A, P or F), and, if F is not used, round the result
3918     (this will still fail in the case of a result like 0.12345000000001 with A
3919     or P of 5, but this can not be helped - or can it?)
3920   * Thus you can have the math done by on Math::Big* class in two modi:
3921     + never round (this is the default):
3922       This is done by setting A and P to undef. No math operation
3923       will round the result, with fdiv() and fsqrt() as exceptions to guard
3924       against overflows. You must explicitly call bround(), bfround() or
3925       round() (the latter with parameters).
3926       Note: Once you have rounded a number, the settings will 'stick' on it
3927       and 'infect' all other numbers engaged in math operations with it, since
3928       local settings have the highest precedence. So, to get SaferRound[tm],
3929       use a copy() before rounding like this:
3930
3931         $x = Math::BigFloat->new(12.34);
3932         $y = Math::BigFloat->new(98.76);
3933         $z = $x * $y;                           # 1218.6984
3934         print $x->copy()->fround(3);            # 12.3 (but A is now 3!)
3935         $z = $x * $y;                           # still 1218.6984, without
3936                                                 # copy would have been 1210!
3937
3938     + round after each op:
3939       After each single operation (except for testing like is_zero()), the
3940       method round() is called and the result is rounded appropriately. By
3941       setting proper values for A and P, you can have all-the-same-A or
3942       all-the-same-P modes. For example, Math::Currency might set A to undef,
3943       and P to -2, globally.
3944
3945  ?Maybe an extra option that forbids local A & P settings would be in order,
3946  ?so that intermediate rounding does not 'poison' further math?
3947
3948 =item Overriding globals
3949
3950   * you will be able to give A, P and R as an argument to all the calculation
3951     routines; the second parameter is A, the third one is P, and the fourth is
3952     R (shift right by one for binary operations like badd). P is used only if
3953     the first parameter (A) is undefined. These three parameters override the
3954     globals in the order detailed as follows, i.e. the first defined value
3955     wins:
3956     (local: per object, global: global default, parameter: argument to sub)
3957       + parameter A
3958       + parameter P
3959       + local A (if defined on both of the operands: smaller one is taken)
3960       + local P (if defined on both of the operands: bigger one is taken)
3961       + global A
3962       + global P
3963       + global F
3964   * fsqrt() will hand its arguments to fdiv(), as it used to, only now for two
3965     arguments (A and P) instead of one
3966
3967 =item Local settings
3968
3969   * You can set A or P locally by using C<< $x->accuracy() >> or
3970     C<< $x->precision() >>
3971     and thus force different A and P for different objects/numbers.
3972   * Setting A or P this way immediately rounds $x to the new value.
3973   * C<< $x->accuracy() >> clears C<< $x->precision() >>, and vice versa.
3974
3975 =item Rounding
3976
3977   * the rounding routines will use the respective global or local settings.
3978     fround()/bround() is for accuracy rounding, while ffround()/bfround()
3979     is for precision
3980   * the two rounding functions take as the second parameter one of the
3981     following rounding modes (R):
3982     'even', 'odd', '+inf', '-inf', 'zero', 'trunc', 'common'
3983   * you can set/get the global R by using C<< Math::SomeClass->round_mode() >>
3984     or by setting C<< $Math::SomeClass::round_mode >>
3985   * after each operation, C<< $result->round() >> is called, and the result may
3986     eventually be rounded (that is, if A or P were set either locally,
3987     globally or as parameter to the operation)
3988   * to manually round a number, call C<< $x->round($A,$P,$round_mode); >>
3989     this will round the number by using the appropriate rounding function
3990     and then normalize it.
3991   * rounding modifies the local settings of the number:
3992
3993         $x = Math::BigFloat->new(123.456);
3994         $x->accuracy(5);
3995         $x->bround(4);
3996
3997     Here 4 takes precedence over 5, so 123.5 is the result and $x->accuracy()
3998     will be 4 from now on.
3999
4000 =item Default values
4001
4002   * R: 'even'
4003   * F: 40
4004   * A: undef
4005   * P: undef
4006
4007 =item Remarks
4008
4009   * The defaults are set up so that the new code gives the same results as
4010     the old code (except in a few cases on fdiv):
4011     + Both A and P are undefined and thus will not be used for rounding
4012       after each operation.
4013     + round() is thus a no-op, unless given extra parameters A and P
4014
4015 =back
4016
4017 =head1 Infinity and Not a Number
4018
4019 While BigInt has extensive handling of inf and NaN, certain quirks remain.
4020
4021 =over 2
4022
4023 =item oct()/hex()
4024
4025 These perl routines currently (as of Perl v.5.8.6) cannot handle passed
4026 inf.
4027
4028         te@linux:~> perl -wle 'print 2 ** 3333'
4029         inf
4030         te@linux:~> perl -wle 'print 2 ** 3333 == 2 ** 3333'
4031         1
4032         te@linux:~> perl -wle 'print oct(2 ** 3333)'
4033         0
4034         te@linux:~> perl -wle 'print hex(2 ** 3333)'
4035         Illegal hexadecimal digit 'i' ignored at -e line 1.
4036         0
4037
4038 The same problems occur if you pass them Math::BigInt->binf() objects. Since
4039 overloading these routines is not possible, this cannot be fixed from BigInt.
4040
4041 =item ==, !=, <, >, <=, >= with NaNs
4042
4043 BigInt's bcmp() routine currently returns undef to signal that a NaN was
4044 involved in a comparison. However, the overload code turns that into
4045 either 1 or '' and thus operations like C<< NaN != NaN >> might return
4046 wrong values.
4047
4048 =item log(-inf)
4049
4050 C<< log(-inf) >> is highly weird. Since log(-x)=pi*i+log(x), then
4051 log(-inf)=pi*i+inf. However, since the imaginary part is finite, the real
4052 infinity "overshadows" it, so the number might as well just be infinity.
4053 However, the result is a complex number, and since BigInt/BigFloat can only
4054 have real numbers as results, the result is NaN.
4055
4056 =item exp(), cos(), sin(), atan2()
4057
4058 These all might have problems handling infinity right.
4059
4060 =back
4061
4062 =head1 INTERNALS
4063
4064 The actual numbers are stored as unsigned big integers (with seperate sign).
4065
4066 You should neither care about nor depend on the internal representation; it
4067 might change without notice. Use B<ONLY> method calls like C<< $x->sign(); >>
4068 instead relying on the internal representation.
4069
4070 =head2 MATH LIBRARY
4071
4072 Math with the numbers is done (by default) by a module called
4073 C<Math::BigInt::Calc>. This is equivalent to saying:
4074
4075         use Math::BigInt lib => 'Calc';
4076
4077 You can change this by using:
4078
4079         use Math::BigInt lib => 'BitVect';
4080
4081 The following would first try to find Math::BigInt::Foo, then
4082 Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:
4083
4084         use Math::BigInt lib => 'Foo,Math::BigInt::Bar';
4085
4086 Since Math::BigInt::GMP is in almost all cases faster than Calc (especially in
4087 math involving really big numbers, where it is B<much> faster), and there is
4088 no penalty if Math::BigInt::GMP is not installed, it is a good idea to always
4089 use the following:
4090
4091         use Math::BigInt lib => 'GMP';
4092
4093 Different low-level libraries use different formats to store the
4094 numbers. You should B<NOT> depend on the number having a specific format
4095 internally.
4096
4097 See the respective math library module documentation for further details.
4098
4099 =head2 SIGN
4100
4101 The sign is either '+', '-', 'NaN', '+inf' or '-inf'.
4102
4103 A sign of 'NaN' is used to represent the result when input arguments are not
4104 numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively
4105 minus infinity. You will get '+inf' when dividing a positive number by 0, and
4106 '-inf' when dividing any negative number by 0.
4107
4108 =head2 mantissa(), exponent() and parts()
4109
4110 C<mantissa()> and C<exponent()> return the said parts of the BigInt such
4111 that:
4112
4113         $m = $x->mantissa();
4114         $e = $x->exponent();
4115         $y = $m * ( 10 ** $e );
4116         print "ok\n" if $x == $y;
4117
4118 C<< ($m,$e) = $x->parts() >> is just a shortcut that gives you both of them
4119 in one go. Both the returned mantissa and exponent have a sign.
4120
4121 Currently, for BigInts C<$e> is always 0, except +inf and -inf, where it is
4122 C<+inf>; and for NaN, where it is C<NaN>; and for C<$x == 0>, where it is C<1>
4123 (to be compatible with Math::BigFloat's internal representation of a zero as
4124 C<0E1>).
4125
4126 C<$m> is currently just a copy of the original number. The relation between
4127 C<$e> and C<$m> will stay always the same, though their real values might
4128 change.
4129
4130 =head1 EXAMPLES
4131
4132   use Math::BigInt;
4133
4134   sub bint { Math::BigInt->new(shift); }
4135
4136   $x = Math::BigInt->bstr("1234")       # string "1234"
4137   $x = "$x";                            # same as bstr()
4138   $x = Math::BigInt->bneg("1234");      # BigInt "-1234"
4139   $x = Math::BigInt->babs("-12345");    # BigInt "12345"
4140   $x = Math::BigInt->bnorm("-0.00");    # BigInt "0"
4141   $x = bint(1) + bint(2);               # BigInt "3"
4142   $x = bint(1) + "2";                   # ditto (auto-BigIntify of "2")
4143   $x = bint(1);                         # BigInt "1"
4144   $x = $x + 5 / 2;                      # BigInt "3"
4145   $x = $x ** 3;                         # BigInt "27"
4146   $x *= 2;                              # BigInt "54"
4147   $x = Math::BigInt->new(0);            # BigInt "0"
4148   $x--;                                 # BigInt "-1"
4149   $x = Math::BigInt->badd(4,5)          # BigInt "9"
4150   print $x->bsstr();                    # 9e+0
4151
4152 Examples for rounding:
4153
4154   use Math::BigFloat;
4155   use Test;
4156
4157   $x = Math::BigFloat->new(123.4567);
4158   $y = Math::BigFloat->new(123.456789);
4159   Math::BigFloat->accuracy(4);          # no more A than 4
4160
4161   ok ($x->copy()->fround(),123.4);      # even rounding
4162   print $x->copy()->fround(),"\n";      # 123.4
4163   Math::BigFloat->round_mode('odd');    # round to odd
4164   print $x->copy()->fround(),"\n";      # 123.5
4165   Math::BigFloat->accuracy(5);          # no more A than 5
4166   Math::BigFloat->round_mode('odd');    # round to odd
4167   print $x->copy()->fround(),"\n";      # 123.46
4168   $y = $x->copy()->fround(4),"\n";      # A = 4: 123.4
4169   print "$y, ",$y->accuracy(),"\n";     # 123.4, 4
4170
4171   Math::BigFloat->accuracy(undef);      # A not important now
4172   Math::BigFloat->precision(2);         # P important
4173   print $x->copy()->bnorm(),"\n";       # 123.46
4174   print $x->copy()->fround(),"\n";      # 123.46
4175
4176 Examples for converting:
4177
4178   my $x = Math::BigInt->new('0b1'.'01' x 123);
4179   print "bin: ",$x->as_bin()," hex:",$x->as_hex()," dec: ",$x,"\n";
4180
4181 =head1 Autocreating constants
4182
4183 After C<use Math::BigInt ':constant'> all the B<integer> decimal, hexadecimal
4184 and binary constants in the given scope are converted to C<Math::BigInt>.
4185 This conversion happens at compile time.
4186
4187 In particular,
4188
4189   perl -MMath::BigInt=:constant -e 'print 2**100,"\n"'
4190
4191 prints the integer value of C<2**100>. Note that without conversion of
4192 constants the expression 2**100 will be calculated as perl scalar.
4193
4194 Please note that strings and floating point constants are not affected,
4195 so that
4196
4197         use Math::BigInt qw/:constant/;
4198
4199         $x = 1234567890123456789012345678901234567890
4200                 + 123456789123456789;
4201         $y = '1234567890123456789012345678901234567890'
4202                 + '123456789123456789';
4203
4204 do not work. You need an explicit Math::BigInt->new() around one of the
4205 operands. You should also quote large constants to protect loss of precision:
4206
4207         use Math::BigInt;
4208
4209         $x = Math::BigInt->new('1234567889123456789123456789123456789');
4210
4211 Without the quotes Perl would convert the large number to a floating point
4212 constant at compile time and then hand the result to BigInt, which results in
4213 an truncated result or a NaN.
4214
4215 This also applies to integers that look like floating point constants:
4216
4217         use Math::BigInt ':constant';
4218
4219         print ref(123e2),"\n";
4220         print ref(123.2e2),"\n";
4221
4222 will print nothing but newlines. Use either L<bignum> or L<Math::BigFloat>
4223 to get this to work.
4224
4225 =head1 PERFORMANCE
4226
4227 Using the form $x += $y; etc over $x = $x + $y is faster, since a copy of $x
4228 must be made in the second case. For long numbers, the copy can eat up to 20%
4229 of the work (in the case of addition/subtraction, less for
4230 multiplication/division). If $y is very small compared to $x, the form
4231 $x += $y is MUCH faster than $x = $x + $y since making the copy of $x takes
4232 more time then the actual addition.
4233
4234 With a technique called copy-on-write, the cost of copying with overload could
4235 be minimized or even completely avoided. A test implementation of COW did show
4236 performance gains for overloaded math, but introduced a performance loss due
4237 to a constant overhead for all other operations. So Math::BigInt does currently
4238 not COW.
4239
4240 The rewritten version of this module (vs. v0.01) is slower on certain
4241 operations, like C<new()>, C<bstr()> and C<numify()>. The reason are that it
4242 does now more work and handles much more cases. The time spent in these
4243 operations is usually gained in the other math operations so that code on
4244 the average should get (much) faster. If they don't, please contact the author.
4245
4246 Some operations may be slower for small numbers, but are significantly faster
4247 for big numbers. Other operations are now constant (O(1), like C<bneg()>,
4248 C<babs()> etc), instead of O(N) and thus nearly always take much less time.
4249 These optimizations were done on purpose.
4250
4251 If you find the Calc module to slow, try to install any of the replacement
4252 modules and see if they help you.
4253
4254 =head2 Alternative math libraries
4255
4256 You can use an alternative library to drive Math::BigInt via:
4257
4258         use Math::BigInt lib => 'Module';
4259
4260 See L<MATH LIBRARY> for more information.
4261
4262 For more benchmark results see L<http://bloodgate.com/perl/benchmarks.html>.
4263
4264 =head2 SUBCLASSING
4265
4266 =head1 Subclassing Math::BigInt
4267
4268 The basic design of Math::BigInt allows simple subclasses with very little
4269 work, as long as a few simple rules are followed:
4270
4271 =over 2
4272
4273 =item *
4274
4275 The public API must remain consistent, i.e. if a sub-class is overloading
4276 addition, the sub-class must use the same name, in this case badd(). The
4277 reason for this is that Math::BigInt is optimized to call the object methods
4278 directly.
4279
4280 =item *
4281
4282 The private object hash keys like C<$x->{sign}> may not be changed, but
4283 additional keys can be added, like C<$x->{_custom}>.
4284
4285 =item *
4286
4287 Accessor functions are available for all existing object hash keys and should
4288 be used instead of directly accessing the internal hash keys. The reason for
4289 this is that Math::BigInt itself has a pluggable interface which permits it
4290 to support different storage methods.
4291
4292 =back
4293
4294 More complex sub-classes may have to replicate more of the logic internal of
4295 Math::BigInt if they need to change more basic behaviors. A subclass that
4296 needs to merely change the output only needs to overload C<bstr()>.
4297
4298 All other object methods and overloaded functions can be directly inherited
4299 from the parent class.
4300
4301 At the very minimum, any subclass will need to provide it's own C<new()> and can
4302 store additional hash keys in the object. There are also some package globals
4303 that must be defined, e.g.:
4304
4305   # Globals
4306   $accuracy = undef;
4307   $precision = -2;       # round to 2 decimal places
4308   $round_mode = 'even';
4309   $div_scale = 40;
4310
4311 Additionally, you might want to provide the following two globals to allow
4312 auto-upgrading and auto-downgrading to work correctly:
4313
4314   $upgrade = undef;
4315   $downgrade = undef;
4316
4317 This allows Math::BigInt to correctly retrieve package globals from the
4318 subclass, like C<$SubClass::precision>.  See t/Math/BigInt/Subclass.pm or
4319 t/Math/BigFloat/SubClass.pm completely functional subclass examples.
4320
4321 Don't forget to
4322
4323         use overload;
4324
4325 in your subclass to automatically inherit the overloading from the parent. If
4326 you like, you can change part of the overloading, look at Math::String for an
4327 example.
4328
4329 =head1 UPGRADING
4330
4331 When used like this:
4332
4333         use Math::BigInt upgrade => 'Foo::Bar';
4334
4335 certain operations will 'upgrade' their calculation and thus the result to
4336 the class Foo::Bar. Usually this is used in conjunction with Math::BigFloat:
4337
4338         use Math::BigInt upgrade => 'Math::BigFloat';
4339
4340 As a shortcut, you can use the module C<bignum>:
4341
4342         use bignum;
4343
4344 Also good for oneliners:
4345
4346         perl -Mbignum -le 'print 2 ** 255'
4347
4348 This makes it possible to mix arguments of different classes (as in 2.5 + 2)
4349 as well es preserve accuracy (as in sqrt(3)).
4350
4351 Beware: This feature is not fully implemented yet.
4352
4353 =head2 Auto-upgrade
4354
4355 The following methods upgrade themselves unconditionally; that is if upgrade
4356 is in effect, they will always hand up their work:
4357
4358 =over 2
4359
4360 =item bsqrt()
4361
4362 =item div()
4363
4364 =item blog()
4365
4366 =item bexp()
4367
4368 =back
4369
4370 Beware: This list is not complete.
4371
4372 All other methods upgrade themselves only when one (or all) of their
4373 arguments are of the class mentioned in $upgrade (This might change in later
4374 versions to a more sophisticated scheme):
4375
4376 =head1 BUGS
4377
4378 =over 2
4379
4380 =item broot() does not work
4381
4382 The broot() function in BigInt may only work for small values. This will be
4383 fixed in a later version.
4384
4385 =item Out of Memory!
4386
4387 Under Perl prior to 5.6.0 having an C<use Math::BigInt ':constant';> and
4388 C<eval()> in your code will crash with "Out of memory". This is probably an
4389 overload/exporter bug. You can workaround by not having C<eval()>
4390 and ':constant' at the same time or upgrade your Perl to a newer version.
4391
4392 =item Fails to load Calc on Perl prior 5.6.0
4393
4394 Since eval(' use ...') can not be used in conjunction with ':constant', BigInt
4395 will fall back to eval { require ... } when loading the math lib on Perls
4396 prior to 5.6.0. This simple replaces '::' with '/' and thus might fail on
4397 filesystems using a different seperator.
4398
4399 =back
4400
4401 =head1 CAVEATS
4402
4403 Some things might not work as you expect them. Below is documented what is
4404 known to be troublesome:
4405
4406 =over 1
4407
4408 =item bstr(), bsstr() and 'cmp'
4409
4410 Both C<bstr()> and C<bsstr()> as well as automated stringify via overload now
4411 drop the leading '+'. The old code would return '+3', the new returns '3'.
4412 This is to be consistent with Perl and to make C<cmp> (especially with
4413 overloading) to work as you expect. It also solves problems with C<Test.pm>,
4414 because it's C<ok()> uses 'eq' internally.
4415
4416 Mark Biggar said, when asked about to drop the '+' altogether, or make only
4417 C<cmp> work:
4418
4419         I agree (with the first alternative), don't add the '+' on positive
4420         numbers.  It's not as important anymore with the new internal
4421         form for numbers.  It made doing things like abs and neg easier,
4422         but those have to be done differently now anyway.
4423
4424 So, the following examples will now work all as expected:
4425
4426         use Test;
4427         BEGIN { plan tests => 1 }
4428         use Math::BigInt;
4429
4430         my $x = new Math::BigInt 3*3;
4431         my $y = new Math::BigInt 3*3;
4432
4433         ok ($x,3*3);
4434         print "$x eq 9" if $x eq $y;
4435         print "$x eq 9" if $x eq '9';
4436         print "$x eq 9" if $x eq 3*3;
4437
4438 Additionally, the following still works:
4439
4440         print "$x == 9" if $x == $y;
4441         print "$x == 9" if $x == 9;
4442         print "$x == 9" if $x == 3*3;
4443
4444 There is now a C<bsstr()> method to get the string in scientific notation aka
4445 C<1e+2> instead of C<100>. Be advised that overloaded 'eq' always uses bstr()
4446 for comparison, but Perl will represent some numbers as 100 and others
4447 as 1e+308. If in doubt, convert both arguments to Math::BigInt before
4448 comparing them as strings:
4449
4450         use Test;
4451         BEGIN { plan tests => 3 }
4452         use Math::BigInt;
4453
4454         $x = Math::BigInt->new('1e56'); $y = 1e56;
4455         ok ($x,$y);                     # will fail
4456         ok ($x->bsstr(),$y);            # okay
4457         $y = Math::BigInt->new($y);
4458         ok ($x,$y);                     # okay
4459
4460 Alternatively, simple use C<< <=> >> for comparisons, this will get it
4461 always right. There is not yet a way to get a number automatically represented
4462 as a string that matches exactly the way Perl represents it.
4463
4464 See also the section about L<Infinity and Not a Number> for problems in
4465 comparing NaNs.
4466
4467 =item int()
4468
4469 C<int()> will return (at least for Perl v5.7.1 and up) another BigInt, not a
4470 Perl scalar:
4471
4472         $x = Math::BigInt->new(123);
4473         $y = int($x);                           # BigInt 123
4474         $x = Math::BigFloat->new(123.45);
4475         $y = int($x);                           # BigInt 123
4476
4477 In all Perl versions you can use C<as_number()> or C<as_int> for the same
4478 effect:
4479
4480         $x = Math::BigFloat->new(123.45);
4481         $y = $x->as_number();                   # BigInt 123
4482         $y = $x->as_int();                      # ditto
4483
4484 This also works for other subclasses, like Math::String.
4485
4486 If you want a real Perl scalar, use C<numify()>:
4487
4488         $y = $x->numify();                      # 123 as scalar
4489
4490 This is seldom necessary, though, because this is done automatically, like
4491 when you access an array:
4492
4493         $z = $array[$x];                        # does work automatically
4494
4495 =item length
4496
4497 The following will probably not do what you expect:
4498
4499         $c = Math::BigInt->new(123);
4500         print $c->length(),"\n";                # prints 30
4501
4502 It prints both the number of digits in the number and in the fraction part
4503 since print calls C<length()> in list context. Use something like:
4504
4505         print scalar $c->length(),"\n";         # prints 3
4506
4507 =item bdiv
4508
4509 The following will probably not do what you expect:
4510
4511         print $c->bdiv(10000),"\n";
4512
4513 It prints both quotient and remainder since print calls C<bdiv()> in list
4514 context. Also, C<bdiv()> will modify $c, so be careful. You probably want
4515 to use
4516
4517         print $c / 10000,"\n";
4518         print scalar $c->bdiv(10000),"\n";  # or if you want to modify $c
4519
4520 instead.
4521
4522 The quotient is always the greatest integer less than or equal to the
4523 real-valued quotient of the two operands, and the remainder (when it is
4524 nonzero) always has the same sign as the second operand; so, for
4525 example,
4526
4527           1 / 4  => ( 0, 1)
4528           1 / -4 => (-1,-3)
4529          -3 / 4  => (-1, 1)
4530          -3 / -4 => ( 0,-3)
4531         -11 / 2  => (-5,1)
4532          11 /-2  => (-5,-1)
4533
4534 As a consequence, the behavior of the operator % agrees with the
4535 behavior of Perl's built-in % operator (as documented in the perlop
4536 manpage), and the equation
4537
4538         $x == ($x / $y) * $y + ($x % $y)
4539
4540 holds true for any $x and $y, which justifies calling the two return
4541 values of bdiv() the quotient and remainder. The only exception to this rule
4542 are when $y == 0 and $x is negative, then the remainder will also be
4543 negative. See below under "infinity handling" for the reasoning behind this.
4544
4545 Perl's 'use integer;' changes the behaviour of % and / for scalars, but will
4546 not change BigInt's way to do things. This is because under 'use integer' Perl
4547 will do what the underlying C thinks is right and this is different for each
4548 system. If you need BigInt's behaving exactly like Perl's 'use integer', bug
4549 the author to implement it ;)
4550
4551 =item infinity handling
4552
4553 Here are some examples that explain the reasons why certain results occur while
4554 handling infinity:
4555
4556 The following table shows the result of the division and the remainder, so that
4557 the equation above holds true. Some "ordinary" cases are strewn in to show more
4558 clearly the reasoning:
4559
4560         A /  B  =   C,     R so that C *    B +    R =    A
4561      =========================================================
4562         5 /   8 =   0,     5         0 *    8 +    5 =    5
4563         0 /   8 =   0,     0         0 *    8 +    0 =    0
4564         0 / inf =   0,     0         0 *  inf +    0 =    0
4565         0 /-inf =   0,     0         0 * -inf +    0 =    0
4566         5 / inf =   0,     5         0 *  inf +    5 =    5
4567         5 /-inf =   0,     5         0 * -inf +    5 =    5
4568         -5/ inf =   0,    -5         0 *  inf +   -5 =   -5
4569         -5/-inf =   0,    -5         0 * -inf +   -5 =   -5
4570        inf/   5 =  inf,    0       inf *    5 +    0 =  inf
4571       -inf/   5 = -inf,    0      -inf *    5 +    0 = -inf
4572        inf/  -5 = -inf,    0      -inf *   -5 +    0 =  inf
4573       -inf/  -5 =  inf,    0       inf *   -5 +    0 = -inf
4574          5/   5 =    1,    0         1 *    5 +    0 =    5
4575         -5/  -5 =    1,    0         1 *   -5 +    0 =   -5
4576        inf/ inf =    1,    0         1 *  inf +    0 =  inf
4577       -inf/-inf =    1,    0         1 * -inf +    0 = -inf
4578        inf/-inf =   -1,    0        -1 * -inf +    0 =  inf
4579       -inf/ inf =   -1,    0         1 * -inf +    0 = -inf
4580          8/   0 =  inf,    8       inf *    0 +    8 =    8
4581        inf/   0 =  inf,  inf       inf *    0 +  inf =  inf
4582          0/   0 =  NaN
4583
4584 These cases below violate the "remainder has the sign of the second of the two
4585 arguments", since they wouldn't match up otherwise.
4586
4587         A /  B  =   C,     R so that C *    B +    R =    A
4588      ========================================================
4589       -inf/   0 = -inf, -inf      -inf *    0 +  inf = -inf
4590         -8/   0 = -inf,   -8      -inf *    0 +    8 = -8
4591
4592 =item Modifying and =
4593
4594 Beware of:
4595
4596         $x = Math::BigFloat->new(5);
4597         $y = $x;
4598
4599 It will not do what you think, e.g. making a copy of $x. Instead it just makes
4600 a second reference to the B<same> object and stores it in $y. Thus anything
4601 that modifies $x (except overloaded operators) will modify $y, and vice versa.
4602 Or in other words, C<=> is only safe if you modify your BigInts only via
4603 overloaded math. As soon as you use a method call it breaks:
4604
4605         $x->bmul(2);
4606         print "$x, $y\n";       # prints '10, 10'
4607
4608 If you want a true copy of $x, use:
4609
4610         $y = $x->copy();
4611
4612 You can also chain the calls like this, this will make first a copy and then
4613 multiply it by 2:
4614
4615         $y = $x->copy()->bmul(2);
4616
4617 See also the documentation for overload.pm regarding C<=>.
4618
4619 =item bpow
4620
4621 C<bpow()> (and the rounding functions) now modifies the first argument and
4622 returns it, unlike the old code which left it alone and only returned the
4623 result. This is to be consistent with C<badd()> etc. The first three will
4624 modify $x, the last one won't:
4625
4626         print bpow($x,$i),"\n";         # modify $x
4627         print $x->bpow($i),"\n";        # ditto
4628         print $x **= $i,"\n";           # the same
4629         print $x ** $i,"\n";            # leave $x alone
4630
4631 The form C<$x **= $y> is faster than C<$x = $x ** $y;>, though.
4632
4633 =item Overloading -$x
4634
4635 The following:
4636
4637         $x = -$x;
4638
4639 is slower than
4640
4641         $x->bneg();
4642
4643 since overload calls C<sub($x,0,1);> instead of C<neg($x)>. The first variant
4644 needs to preserve $x since it does not know that it later will get overwritten.
4645 This makes a copy of $x and takes O(N), but $x->bneg() is O(1).
4646
4647 =item Mixing different object types
4648
4649 In Perl you will get a floating point value if you do one of the following:
4650
4651         $float = 5.0 + 2;
4652         $float = 2 + 5.0;
4653         $float = 5 / 2;
4654
4655 With overloaded math, only the first two variants will result in a BigFloat:
4656
4657         use Math::BigInt;
4658         use Math::BigFloat;
4659
4660         $mbf = Math::BigFloat->new(5);
4661         $mbi2 = Math::BigInteger->new(5);
4662         $mbi = Math::BigInteger->new(2);
4663
4664                                         # what actually gets called:
4665         $float = $mbf + $mbi;           # $mbf->badd()
4666         $float = $mbf / $mbi;           # $mbf->bdiv()
4667         $integer = $mbi + $mbf;         # $mbi->badd()
4668         $integer = $mbi2 / $mbi;        # $mbi2->bdiv()
4669         $integer = $mbi2 / $mbf;        # $mbi2->bdiv()
4670
4671 This is because math with overloaded operators follows the first (dominating)
4672 operand, and the operation of that is called and returns thus the result. So,
4673 Math::BigInt::bdiv() will always return a Math::BigInt, regardless whether
4674 the result should be a Math::BigFloat or the second operant is one.
4675
4676 To get a Math::BigFloat you either need to call the operation manually,
4677 make sure the operands are already of the proper type or casted to that type
4678 via Math::BigFloat->new():
4679
4680         $float = Math::BigFloat->new($mbi2) / $mbi;     # = 2.5
4681
4682 Beware of simple "casting" the entire expression, this would only convert
4683 the already computed result:
4684
4685         $float = Math::BigFloat->new($mbi2 / $mbi);     # = 2.0 thus wrong!
4686
4687 Beware also of the order of more complicated expressions like:
4688
4689         $integer = ($mbi2 + $mbi) / $mbf;               # int / float => int
4690         $integer = $mbi2 / Math::BigFloat->new($mbi);   # ditto
4691
4692 If in doubt, break the expression into simpler terms, or cast all operands
4693 to the desired resulting type.
4694
4695 Scalar values are a bit different, since:
4696
4697         $float = 2 + $mbf;
4698         $float = $mbf + 2;
4699
4700 will both result in the proper type due to the way the overloaded math works.
4701
4702 This section also applies to other overloaded math packages, like Math::String.
4703
4704 One solution to you problem might be autoupgrading|upgrading. See the
4705 pragmas L<bignum>, L<bigint> and L<bigrat> for an easy way to do this.
4706
4707 =item bsqrt()
4708
4709 C<bsqrt()> works only good if the result is a big integer, e.g. the square
4710 root of 144 is 12, but from 12 the square root is 3, regardless of rounding
4711 mode. The reason is that the result is always truncated to an integer.
4712
4713 If you want a better approximation of the square root, then use:
4714
4715         $x = Math::BigFloat->new(12);
4716         Math::BigFloat->precision(0);
4717         Math::BigFloat->round_mode('even');
4718         print $x->copy->bsqrt(),"\n";           # 4
4719
4720         Math::BigFloat->precision(2);
4721         print $x->bsqrt(),"\n";                 # 3.46
4722         print $x->bsqrt(3),"\n";                # 3.464
4723
4724 =item brsft()
4725
4726 For negative numbers in base see also L<brsft|brsft>.
4727
4728 =back
4729
4730 =head1 LICENSE
4731
4732 This program is free software; you may redistribute it and/or modify it under
4733 the same terms as Perl itself.
4734
4735 =head1 SEE ALSO
4736
4737 L<Math::BigFloat>, L<Math::BigRat> and L<Math::Big> as well as
4738 L<Math::BigInt::BitVect>, L<Math::BigInt::Pari> and  L<Math::BigInt::GMP>.
4739
4740 The pragmas L<bignum>, L<bigint> and L<bigrat> also might be of interest
4741 because they solve the autoupgrading/downgrading issue, at least partly.
4742
4743 The package at
4744 L<http://search.cpan.org/search?mode=module&query=Math%3A%3ABigInt> contains
4745 more documentation including a full version history, testcases, empty
4746 subclass files and benchmarks.
4747
4748 =head1 AUTHORS
4749
4750 Original code by Mark Biggar, overloaded interface by Ilya Zakharevich.
4751 Completely rewritten by Tels http://bloodgate.com in late 2000, 2001 - 2006
4752 and still at it in 2007.
4753
4754 Many people contributed in one or more ways to the final beast, see the file
4755 CREDITS for an (incomplete) list. If you miss your name, please drop me a
4756 mail. Thank you!
4757
4758 =cut