lib/JSON/MaybeXS.pm

   1 package JSON::MaybeXS;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5 use base qw(Exporter);
   6
   7 our $VERSION = '1.002004';
   8
   9 sub _choose_json_module {
  10     return 'Cpanel::JSON::XS' if $INC{'Cpanel/JSON/XS.pm'};
  11     return 'JSON::XS'         if $INC{'JSON/XS.pm'};
  12
  13     my @err;
  14
  15     return 'Cpanel::JSON::XS' if eval { require Cpanel::JSON::XS; 1; };
  16     push @err, "Error loading Cpanel::JSON::XS: $@";
  17
  18     return 'JSON::XS' if eval { require JSON::XS; 1; };
  19     push @err, "Error loading JSON::XS: $@";
  20
  21     return 'JSON::PP' if eval { require JSON::PP; 1 };
  22     push @err, "Error loading JSON::PP: $@";
  23
  24     die join( "\n", "Couldn't load a JSON module:", @err );
  25
  26 }
  27
  28 BEGIN {
  29     our $JSON_Class = _choose_json_module();
  30     $JSON_Class->import(qw(encode_json decode_json));
  31 }
  32
  33 our @EXPORT = qw(encode_json decode_json JSON);
  34 our @EXPORT_OK = qw(is_bool);
  35 our %EXPORT_TAGS = ( all => [ @EXPORT, @EXPORT_OK ] );
  36
  37 sub JSON () { our $JSON_Class }
  38
  39 sub new {
  40   shift;
  41   my %args = @_ == 1 ? %{$_[0]} : @_;
  42   my $new = (our $JSON_Class)->new;
  43   $new->$_($args{$_}) for keys %args;
  44   return $new;
  45 }
  46
  47 use Safe::Isa;
  48
  49 sub is_bool {
  50   die 'is_bool is not a method' if $_[1];
  51
  52   $_[0]->$_isa('JSON::XS::Boolean')
  53     or $_[0]->$_isa('JSON::PP::Boolean');
  54 }
  55
  56 1;
  57
  58 =head1 NAME
  59
  60 JSON::MaybeXS - Use L<Cpanel::JSON::XS> with a fallback to L<JSON::XS> and L<JSON::PP>
  61
  62 =head1 SYNOPSIS
  63
  64   use JSON::MaybeXS;
  65
  66   my $data_structure = decode_json($json_input);
  67
  68   my $json_output = encode_json($data_structure);
  69
  70   my $json = JSON->new;
  71
  72   my $json_with_args = JSON::MaybeXS->new(utf8 => 1); # or { utf8 => 1 }
  73
  74 =head1 DESCRIPTION
  75
  76 This module first checks to see if either L<Cpanel::JSON::XS> or
  77 L<JSON::XS> is already loaded, in which case it uses that module. Otherwise
  78 it tries to load L<Cpanel::JSON::XS>, then L<JSON::XS>, then L<JSON::PP>
  79 in order, and either uses the first module it finds or throws an error.
  80
  81 It then exports the C<encode_json> and C<decode_json> functions from the
  82 loaded module, along with a C<JSON> constant that returns the class name
  83 for calling C<new> on.
  84
  85 If you're writing fresh code rather than replacing L<JSON.pm|JSON> usage, you might
  86 want to pass options as constructor args rather than calling mutators, so
  87 we provide our own C<new> method that supports that.
  88
  89 =head1 EXPORTS
  90
  91 C<encode_json>, C<decode_json> and C<JSON> are exported by default; C<is_bool>
  92 is exported on request.
  93
  94 To import only some symbols, specify them on the C<use> line:
  95
  96   use JSON::MaybeXS qw(encode_json decode_json is_bool); # functions only
  97
  98   use JSON::MaybeXS qw(JSON); # JSON constant only
  99
 100 To import all available symbols, use C<:all>:
 101
 102   use JSON::MaybeXS ':all';
 103
 104 =head2 encode_json
 105
 106 This is the C<encode_json> function provided by the selected implementation
 107 module, and takes a perl data structure which is serialised to JSON text.
 108
 109   my $json_text = encode_json($data_structure);
 110
 111 =head2 decode_json
 112
 113 This is the C<decode_json> function provided by the selected implementation
 114 module, and takes a string of JSON text to deserialise to a perl data structure.
 115
 116   my $data_structure = decode_json($json_text);
 117
 118 =head2 JSON
 119
 120 The C<JSON> constant returns the selected implementation module's name for
 121 use as a class name - so:
 122
 123   my $json_obj = JSON->new; # returns a Cpanel::JSON::XS or JSON::PP object
 124
 125 and that object can then be used normally:
 126
 127   my $data_structure = $json_obj->decode($json_text); # etc.
 128
 129 =head2 is_bool
 130
 131   $is_boolean = is_bool($scalar)
 132
 133 Returns true if the passed scalar represents either C<true> or
 134 C<false>, two constants that act like C<1> and C<0>, respectively
 135 and are used to represent JSON C<true> and C<false> values in Perl.
 136
 137 Since this is a bare sub in the various backend classes, it cannot be called as
 138 a class method like the other interfaces; it must be called as a function, with
 139 no invocant.  It supports the representation used in all JSON backends.
 140
 141 =head1 CONSTRUCTOR
 142
 143 =head2 new
 144
 145 With L<JSON::PP>, L<JSON::XS> and L<Cpanel::JSON::XS> you are required to call
 146 mutators to set options, such as:
 147
 148   my $json = $class->new->utf8(1)->pretty(1);
 149
 150 Since this is a trifle irritating and noticeably un-perlish, we also offer:
 151
 152   my $json = JSON::MaybeXS->new(utf8 => 1, pretty => 1);
 153
 154 which works equivalently to the above (and in the usual tradition will accept
 155 a hashref instead of a hash, should you so desire).
 156
 157 =head1 BOOLEANS
 158
 159 To include JSON-aware booleans (C<true>, C<false>) in your data, just do:
 160
 161     use JSON::MaybeXS;
 162     my $true = JSON->true;
 163     my $false = JSON->false;
 164
 165 =head1 AUTHOR
 166
 167 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 168
 169 =head1 CONTRIBUTORS
 170
 171 =over 4
 172
 173 =item * Clinton Gormley <drtech@cpan.org>
 174
 175 =item * Karen Etheridge <ether@cpan.org>
 176
 177 =back
 178
 179 =head1 COPYRIGHT
 180
 181 Copyright (c) 2013 the C<JSON::MaybeXS> L</AUTHOR> and L</CONTRIBUTORS>
 182 as listed above.
 183
 184 =head1 LICENSE
 185
 186 This library is free software and may be distributed under the same terms
 187 as perl itself.
 188
 189 =cut