lib/IPC/Open3.pm

   1 package IPC::Open3;
   2
   3 use strict;
   4 no strict 'refs'; # because users pass me bareword filehandles
   5 our ($VERSION, @ISA, @EXPORT);
   6
   7 require Exporter;
   8
   9 use Carp;
  10 use Symbol qw(gensym qualify);
  11
  12 $VERSION        = 1.03;
  13 @ISA            = qw(Exporter);
  14 @EXPORT         = qw(open3);
  15
  16 =head1 NAME
  17
  18 IPC::Open3, open3 - open a process for reading, writing, and error handling
  19
  20 =head1 SYNOPSIS
  21
  22     $pid = open3(\*CHLD_IN, \*CHLD_OUT, \*CHLD_ERR,
  23                     'some cmd and args', 'optarg', ...);
  24
  25     my($wtr, $rdr, $err);
  26     $pid = open3($wtr, $rdr, $err,
  27                     'some cmd and args', 'optarg', ...);
  28
  29     waitpid( $pid, 0 );
  30     my $child_exit_status = $? >> 8;
  31
  32 =head1 DESCRIPTION
  33
  34 Extremely similar to open2(), open3() spawns the given $cmd and
  35 connects CHLD_OUT for reading from the child, CHLD_IN for writing to
  36 the child, and CHLD_ERR for errors.  If CHLD_ERR is false, or the
  37 same file descriptor as CHLD_OUT, then STDOUT and STDERR of the child
  38 are on the same filehandle.  The CHLD_IN will have autoflush turned
  39 on.
  40
  41 If CHLD_IN begins with C<< <& >>, then CHLD_IN will be closed in the
  42 parent, and the child will read from it directly.  If CHLD_OUT or
  43 CHLD_ERR begins with C<< >& >>, then the child will send output
  44 directly to that filehandle.  In both cases, there will be a dup(2)
  45 instead of a pipe(2) made.
  46
  47 If either reader or writer is the null string, this will be replaced
  48 by an autogenerated filehandle.  If so, you must pass a valid lvalue
  49 in the parameter slot so it can be overwritten in the caller, or
  50 an exception will be raised.
  51
  52 The filehandles may also be integers, in which case they are understood
  53 as file descriptors.
  54
  55 open3() returns the process ID of the child process.  It doesn't return on
  56 failure: it just raises an exception matching C</^open3:/>.  However,
  57 C<exec> failures in the child (such as no such file or permission denied),
  58 are just reported to CHLD_ERR, as it is not possible to trap them.
  59
  60 If the child process dies for any reason, the next write to CHLD_IN is
  61 likely to generate a SIGPIPE in the parent, which is fatal by default.
  62 So you may wish to handle this signal.
  63
  64 Note if you specify C<-> as the command, in an analogous fashion to
  65 C<open(FOO, "-|")> the child process will just be the forked Perl
  66 process rather than an external command.  This feature isn't yet
  67 supported on Win32 platforms.
  68
  69 open3() does not wait for and reap the child process after it exits.
  70 Except for short programs where it's acceptable to let the operating system
  71 take care of this, you need to do this yourself.  This is normally as
  72 simple as calling C<waitpid $pid, 0> when you're done with the process.
  73 Failing to do this can result in an accumulation of defunct or "zombie"
  74 processes.  See L<perlfunc/waitpid> for more information.
  75
  76 If you try to read from the child's stdout writer and their stderr
  77 writer, you'll have problems with blocking, which means you'll want
  78 to use select() or the IO::Select, which means you'd best use
  79 sysread() instead of readline() for normal stuff.
  80
  81 This is very dangerous, as you may block forever.  It assumes it's
  82 going to talk to something like B<bc>, both writing to it and reading
  83 from it.  This is presumably safe because you "know" that commands
  84 like B<bc> will read a line at a time and output a line at a time.
  85 Programs like B<sort> that read their entire input stream first,
  86 however, are quite apt to cause deadlock.
  87
  88 The big problem with this approach is that if you don't have control
  89 over source code being run in the child process, you can't control
  90 what it does with pipe buffering.  Thus you can't just open a pipe to
  91 C<cat -v> and continually read and write a line from it.
  92
  93 =head1 See Also
  94
  95 =over 4
  96
  97 =item L<IPC::Open2>
  98
  99 Like Open3 but without STDERR catpure.
 100
 101 =item L<IPC::Run>
 102
 103 This is a CPAN module that has better error handling and more facilities
 104 than Open3.
 105
 106 =back
 107
 108 =head1 WARNING
 109
 110 The order of arguments differs from that of open2().
 111
 112 =cut
 113
 114 # &open3: Marc Horowitz <marc@mit.edu>
 115 # derived mostly from &open2 by tom christiansen, <tchrist@convex.com>
 116 # fixed for 5.001 by Ulrich Kunitz <kunitz@mai-koeln.com>
 117 # ported to Win32 by Ron Schmidt, Merrill Lynch almost ended my career
 118 # fixed for autovivving FHs, tchrist again
 119 # allow fd numbers to be used, by Frank Tobin
 120 # allow '-' as command (c.f. open "-|"), by Adam Spiers <perl@adamspiers.org>
 121 #
 122 # $Id: open3.pl,v 1.1 1993/11/23 06:26:15 marc Exp $
 123 #
 124 # usage: $pid = open3('wtr', 'rdr', 'err' 'some cmd and args', 'optarg', ...);
 125 #
 126 # spawn the given $cmd and connect rdr for
 127 # reading, wtr for writing, and err for errors.
 128 # if err is '', or the same as rdr, then stdout and
 129 # stderr of the child are on the same fh.  returns pid
 130 # of child (or dies on failure).
 131
 132
 133 # if wtr begins with '<&', then wtr will be closed in the parent, and
 134 # the child will read from it directly.  if rdr or err begins with
 135 # '>&', then the child will send output directly to that fd.  In both
 136 # cases, there will be a dup() instead of a pipe() made.
 137
 138
 139 # WARNING: this is dangerous, as you may block forever
 140 # unless you are very careful.
 141 #
 142 # $wtr is left unbuffered.
 143 #
 144 # abort program if
 145 #   rdr or wtr are null
 146 #   a system call fails
 147
 148 our $Me = 'open3 (bug)';        # you should never see this, it's always localized
 149
 150 # Fatal.pm needs to be fixed WRT prototypes.
 151
 152 sub xfork {
 153     my $pid = fork;
 154     defined $pid or croak "$Me: fork failed: $!";
 155     return $pid;
 156 }
 157
 158 sub xpipe {
 159     pipe $_[0], $_[1] or croak "$Me: pipe($_[0], $_[1]) failed: $!";
 160 }
 161
 162 # I tried using a * prototype character for the filehandle but it still
 163 # disallows a bearword while compiling under strict subs.
 164
 165 sub xopen {
 166     open $_[0], $_[1] or croak "$Me: open($_[0], $_[1]) failed: $!";
 167 }
 168
 169 sub xclose {
 170     close $_[0] or croak "$Me: close($_[0]) failed: $!";
 171 }
 172
 173 sub fh_is_fd {
 174     return $_[0] =~ /\A=?(\d+)\z/;
 175 }
 176
 177 sub xfileno {
 178     return $1 if $_[0] =~ /\A=?(\d+)\z/;  # deal with fh just being an fd
 179     return fileno $_[0];
 180 }
 181
 182 my $do_spawn = $^O eq 'os2' || $^O eq 'MSWin32';
 183
 184 sub _open3 {
 185     local $Me = shift;
 186     my($package, $dad_wtr, $dad_rdr, $dad_err, @cmd) = @_;
 187     my($dup_wtr, $dup_rdr, $dup_err, $kidpid);
 188
 189     if (@cmd > 1 and $cmd[0] eq '-') {
 190         croak "Arguments don't make sense when the command is '-'"
 191     }
 192
 193     # simulate autovivification of filehandles because
 194     # it's too ugly to use @_ throughout to make perl do it for us
 195     # tchrist 5-Mar-00
 196
 197     unless (eval  {
 198         $dad_wtr = $_[1] = gensym unless defined $dad_wtr && length $dad_wtr;
 199         $dad_rdr = $_[2] = gensym unless defined $dad_rdr && length $dad_rdr;
 200         1; })
 201     {
 202         # must strip crud for croak to add back, or looks ugly
 203         $@ =~ s/(?<=value attempted) at .*//s;
 204         croak "$Me: $@";
 205     }
 206
 207     $dad_err ||= $dad_rdr;
 208
 209     $dup_wtr = ($dad_wtr =~ s/^[<>]&//);
 210     $dup_rdr = ($dad_rdr =~ s/^[<>]&//);
 211     $dup_err = ($dad_err =~ s/^[<>]&//);
 212
 213     # force unqualified filehandles into caller's package
 214     $dad_wtr = qualify $dad_wtr, $package unless fh_is_fd($dad_wtr);
 215     $dad_rdr = qualify $dad_rdr, $package unless fh_is_fd($dad_rdr);
 216     $dad_err = qualify $dad_err, $package unless fh_is_fd($dad_err);
 217
 218     my $kid_rdr = gensym;
 219     my $kid_wtr = gensym;
 220     my $kid_err = gensym;
 221
 222     xpipe $kid_rdr, $dad_wtr if !$dup_wtr;
 223     xpipe $dad_rdr, $kid_wtr if !$dup_rdr;
 224     xpipe $dad_err, $kid_err if !$dup_err && $dad_err ne $dad_rdr;
 225
 226     $kidpid = $do_spawn ? -1 : xfork;
 227     if ($kidpid == 0) {         # Kid
 228         # A tie in the parent should not be allowed to cause problems.
 229         untie *STDIN;
 230         untie *STDOUT;
 231         # If she wants to dup the kid's stderr onto her stdout I need to
 232         # save a copy of her stdout before I put something else there.
 233         if ($dad_rdr ne $dad_err && $dup_err
 234                 && xfileno($dad_err) == fileno(STDOUT)) {
 235             my $tmp = gensym;
 236             xopen($tmp, ">&$dad_err");
 237             $dad_err = $tmp;
 238         }
 239
 240         if ($dup_wtr) {
 241             xopen \*STDIN,  "<&$dad_wtr" if fileno(STDIN) != xfileno($dad_wtr);
 242         } else {
 243             xclose $dad_wtr;
 244             xopen \*STDIN,  "<&=" . fileno $kid_rdr;
 245         }
 246         if ($dup_rdr) {
 247             xopen \*STDOUT, ">&$dad_rdr" if fileno(STDOUT) != xfileno($dad_rdr);
 248         } else {
 249             xclose $dad_rdr;
 250             xopen \*STDOUT, ">&=" . fileno $kid_wtr;
 251         }
 252         if ($dad_rdr ne $dad_err) {
 253             if ($dup_err) {
 254                 # I have to use a fileno here because in this one case
 255                 # I'm doing a dup but the filehandle might be a reference
 256                 # (from the special case above).
 257                 xopen \*STDERR, ">&" . xfileno($dad_err)
 258                     if fileno(STDERR) != xfileno($dad_err);
 259             } else {
 260                 xclose $dad_err;
 261                 xopen \*STDERR, ">&=" . fileno $kid_err;
 262             }
 263         } else {
 264             xopen \*STDERR, ">&STDOUT" if fileno(STDERR) != fileno(STDOUT);
 265         }
 266         return 0 if ($cmd[0] eq '-');
 267         local($")=(" ");
 268         exec @cmd or do {
 269             carp "$Me: exec of @cmd failed";
 270             eval { require POSIX; POSIX::_exit(255); };
 271             exit 255;
 272         };
 273     } elsif ($do_spawn) {
 274         # All the bookkeeping of coincidence between handles is
 275         # handled in spawn_with_handles.
 276
 277         my @close;
 278         if ($dup_wtr) {
 279           $kid_rdr = \*{$dad_wtr};
 280           push @close, $kid_rdr;
 281         } else {
 282           push @close, \*{$dad_wtr}, $kid_rdr;
 283         }
 284         if ($dup_rdr) {
 285           $kid_wtr = \*{$dad_rdr};
 286           push @close, $kid_wtr;
 287         } else {
 288           push @close, \*{$dad_rdr}, $kid_wtr;
 289         }
 290         if ($dad_rdr ne $dad_err) {
 291             if ($dup_err) {
 292               $kid_err = \*{$dad_err};
 293               push @close, $kid_err;
 294             } else {
 295               push @close, \*{$dad_err}, $kid_err;
 296             }
 297         } else {
 298           $kid_err = $kid_wtr;
 299         }
 300         require IO::Pipe;
 301         $kidpid = eval {
 302             spawn_with_handles( [ { mode => 'r',
 303                                     open_as => $kid_rdr,
 304                                     handle => \*STDIN },
 305                                   { mode => 'w',
 306                                     open_as => $kid_wtr,
 307                                     handle => \*STDOUT },
 308                                   { mode => 'w',
 309                                     open_as => $kid_err,
 310                                     handle => \*STDERR },
 311                                 ], \@close, @cmd);
 312         };
 313         die "$Me: $@" if $@;
 314     }
 315
 316     xclose $kid_rdr if !$dup_wtr;
 317     xclose $kid_wtr if !$dup_rdr;
 318     xclose $kid_err if !$dup_err && $dad_rdr ne $dad_err;
 319     # If the write handle is a dup give it away entirely, close my copy
 320     # of it.
 321     xclose $dad_wtr if $dup_wtr;
 322
 323     select((select($dad_wtr), $| = 1)[0]); # unbuffer pipe
 324     $kidpid;
 325 }
 326
 327 sub open3 {
 328     if (@_ < 4) {
 329         local $" = ', ';
 330         croak "open3(@_): not enough arguments";
 331     }
 332     return _open3 'open3', scalar caller, @_
 333 }
 334
 335 sub spawn_with_handles {
 336     my $fds = shift;            # Fields: handle, mode, open_as
 337     my $close_in_child = shift;
 338     my ($fd, $pid, @saved_fh, $saved, %saved, @errs);
 339     require Fcntl;
 340
 341     foreach $fd (@$fds) {
 342         $fd->{tmp_copy} = IO::Handle->new_from_fd($fd->{handle}, $fd->{mode});
 343         $saved{fileno $fd->{handle}} = $fd->{tmp_copy};
 344     }
 345     foreach $fd (@$fds) {
 346         bless $fd->{handle}, 'IO::Handle'
 347             unless eval { $fd->{handle}->isa('IO::Handle') } ;
 348         # If some of handles to redirect-to coincide with handles to
 349         # redirect, we need to use saved variants:
 350         $fd->{handle}->fdopen($saved{fileno $fd->{open_as}} || $fd->{open_as},
 351                               $fd->{mode});
 352     }
 353     unless ($^O eq 'MSWin32') {
 354         # Stderr may be redirected below, so we save the err text:
 355         foreach $fd (@$close_in_child) {
 356             fcntl($fd, Fcntl::F_SETFD(), 1) or push @errs, "fcntl $fd: $!"
 357                 unless $saved{fileno $fd}; # Do not close what we redirect!
 358         }
 359     }
 360
 361     unless (@errs) {
 362         $pid = eval { system 1, @_ }; # 1 == P_NOWAIT
 363         push @errs, "IO::Pipe: Can't spawn-NOWAIT: $!" if !$pid || $pid < 0;
 364     }
 365
 366     foreach $fd (@$fds) {
 367         $fd->{handle}->fdopen($fd->{tmp_copy}, $fd->{mode});
 368         $fd->{tmp_copy}->close or croak "Can't close: $!";
 369     }
 370     croak join "\n", @errs if @errs;
 371     return $pid;
 372 }
 373
 374 1; # so require is happy