lib/Gitalist/View/SyntaxHighlight.pm

   1 package Gitalist::View::SyntaxHighlight;
   2 use Moose;
   3 use namespace::autoclean;
   4
   5 extends 'Catalyst::View';
   6
   7 use Syntax::Highlight::Engine::Kate ();
   8 use Syntax::Highlight::Engine::Kate::Perl ();
   9
  10 use HTML::Entities qw(encode_entities);
  11
  12 =begin
  13
  14 B<Notes>
  15
  16 What should be done, but isn't currently:
  17
  18  broquaint> Another Cat question - if I want to have arbitrary things highlighted is pushing things through a View at all costs terribly wrong?
  19  broquaint> e.g modifying this slightly to highlight anything (or arrays of anything) http://github.com/broquaint/Gitalist/blob/a7cc1ede5f9729465bb53da9c3a8b300a3aa8a0a/lib/Gitalist/View/SyntaxHighlight.pm
  20        t0m> no, that's totally fine.. I'd tend to push the rendering logic into a model, so you end up doing something like: $c->model('SyntaxDriver')->highlight_all($stuff, $c->view('SyntaxHighlight'));
  21  broquaint> I'm thinking it's a bad idea because the Controller needs to munge data such that the View knows what to do
  22  broquaint> You just blew my mind ;)
  23        t0m> ^^ That works _much_ better if you split up your view methods into process & render..
  24        t0m> ala TT..
  25        t0m> i.e. I'd have 'highlight this scalar' as the ->render method in the view..
  26        t0m> And then the 'default' thing (i.e. process method) will do that and shove the output in the body..
  27        t0m> but then you can write foreach my $thing (@things) { push(@highlighted_things, $c->view('SyntaxHighlight')->render($thing)); }
  28        t0m> and then I'd move that ^^ loop down into a model which actually knows about / abstracts walking the data structures concerned..
  29        t0m> But splitting render and process is the most important bit.. :) Otherwise you need to jump through hoops to render things that don't fit 'nicely' into the bits of stash / body that the view uses by 'default'
  30        t0m> I wouldn't kill you for putting the structure walking code in the view given you're walking simple arrays / hashes.. It becomes more important if you have a more complex visitor..
  31        t0m> (I use Visitor in the design patterns sense)
  32        t0m> As the visitor is responsible for walking the structure, delegating to the ->render call in the view which is responsible for actually mangling the content..
  33
  34 =cut
  35
  36 sub process {
  37     my($self, $c) = @_;
  38
  39     for($c->stash->{blobs} ? @{$c->stash->{blobs}} : $c->stash->{blob}) {
  40         $_ = $self->highlight($c->stash->{language} => $_);
  41     }
  42
  43     $c->forward('View::Default');
  44 }
  45
  46 # XXX This takes for freakin' ever on big merges. A cache may be needed.
  47 sub highlight {
  48     my($self, $lang, $blob) = @_;
  49
  50     my $ret;
  51     if($lang) {
  52         # via http://github.com/jrockway/angerwhale/blob/master/lib/Angerwhale/Format/Pod.pm#L136
  53         $ret = eval {
  54             no warnings 'redefine';
  55             local *Syntax::Highlight::Engine::Kate::Template::logwarning
  56               = sub { die @_ }; # i really don't care
  57             my $hl = Syntax::Highlight::Engine::Kate->new(
  58                 language      => $lang,
  59                 substitutions => {
  60                     "<"  => "&lt;",
  61                     ">"  => "&gt;",
  62                     "&"  => "&amp;",
  63                     q{'} => "&apos;",
  64                     q{"} => "&quot;",
  65                 },
  66                 format_table => {
  67                     # convert Kate's internal representation into
  68                     # <span class="<internal name>"> value </span>
  69                     map {
  70                         $_ => [ qq{<span class="$_">}, '</span>' ]
  71                     }
  72                       qw/Alert BaseN BString Char Comment DataType
  73                          DecVal Error Float Function IString Keyword
  74                          Normal Operator Others RegionMarker Reserved
  75                          String Variable Warning/,
  76                 },
  77             );
  78
  79             my $hltxt = $hl->highlightText($blob);
  80             $hltxt =~ s/([^[:ascii:]])/encode_entities($1)/eg;
  81             $hltxt;
  82         };
  83         warn $@ if $@;
  84     }
  85
  86     return $ret || encode_entities($blob);
  87 }
  88
  89 __PACKAGE__->meta->make_immutable;
  90
  91 __END__
  92
  93 =head1 NAME
  94
  95 Gitalist::View::SyntaxHighlight - Responsible for syntax highlighting code
  96
  97 =head1 DESCRIPTION
  98
  99 Catalyst View for Syntax highlighting.
 100
 101 =head1 AUTHORS
 102
 103 See L<Gitalist> for authors.
 104
 105 =head1 LICENSE
 106
 107 See L<Gitalist> for the license.
 108
 109 =cut