lib/Gitalist/Git/Project.pm

   1 use MooseX::Declare;
   2
   3 =head1 NAME
   4
   5 Gitalist::Git::Project - Model of a git repository
   6
   7 =head1 SYNOPSIS
   8
   9     my $gitrepo = dir('/repo/base/Gitalist');
  10     my $project = Gitalist::Git::Project->new($gitrepo);
  11      $project->name;        # 'Gitalist'
  12      $project->path;        # '/repo/base/Gitalist/.git'
  13      $project->description; # 'Unnamed repository.'
  14
  15 =head1 DESCRIPTION
  16
  17 This class models a git repository, referred to in Gitalist
  18 as a "Project".
  19
  20 =cut
  21
  22 class Gitalist::Git::Project with Gitalist::Git::HasUtils {
  23     # FIXME, use Types::Path::Class and coerce
  24     use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
  25     use MooseX::Types::Path::Class qw/Dir/;
  26     use MooseX::Types::Moose qw/Str Maybe Bool HashRef ArrayRef/;
  27     use List::MoreUtils qw/any zip/;
  28     use DateTime;
  29     use aliased 'Gitalist::Git::Object';
  30
  31     our $SHA1RE = qr/[0-9a-fA-F]{40}/;
  32
  33     around BUILDARGS (ClassName $class: Dir $dir) {
  34         # Allows us to be called as Project->new($dir)
  35         # Last path component becomes $self->name
  36         # Full path to git objects becomes $self->path
  37         my $name = $dir->dir_list(-1);
  38         $dir = $dir->subdir('.git') if (-f $dir->file('.git', 'HEAD'));
  39         confess("Can't find a git repository at " . $dir)
  40             unless ( -f $dir->file('HEAD') );
  41         return $class->$orig(name => $name,
  42                              path => $dir);
  43     }
  44
  45 =head1 ATTRIBUTES
  46
  47 =head2 name
  48
  49 The name of the Project.  By default, this is derived from the path to the git repository.
  50
  51 =cut
  52     has name => ( isa => NonEmptySimpleStr,
  53                   is => 'ro', required => 1 );
  54
  55 =head2 path
  56
  57 L<Path::Class:Dir> for the location of the git repository.
  58
  59 =cut
  60     has path => ( isa => Dir,
  61                   is => 'ro', required => 1);
  62
  63 =head2 description
  64
  65 String containing .git/description
  66
  67 =cut
  68     has description => ( isa => Str,
  69                          is => 'ro',
  70                          lazy_build => 1,
  71                      );
  72
  73 =head2 owner
  74
  75 Owner of the files on disk.
  76
  77 =cut
  78     has owner => ( isa => NonEmptySimpleStr,
  79                    is => 'ro',
  80                    lazy_build => 1,
  81                );
  82
  83 =head2 last_change
  84
  85 L<DateTime> for the time of the last update.
  86 undef if the repository has never been used.
  87
  88 =cut
  89     has last_change => ( isa => Maybe['DateTime'],
  90                          is => 'ro',
  91                          lazy_build => 1,
  92                      );
  93
  94 =head2 is_bare
  95
  96 Bool indicating whether this Project is bare.
  97
  98 =cut
  99     has is_bare => ( isa => Bool,
 100                      is => 'ro',
 101                      lazy => 1,
 102                      default => sub {
 103                          -d $_[0]->path->parent->subdir->($_[0]->name)
 104                              ? 1 : 0
 105                          },
 106                      );
 107
 108 =head2 heads
 109
 110 ArrayRef of hashes containing the name and sha1 of all heads.
 111
 112 =cut
 113     has heads => ( isa => ArrayRef[HashRef],
 114                    is => 'ro',
 115                    lazy_build => 1);
 116
 117 =head2 references
 118
 119 Hashref of ArrayRefs for each reference.
 120
 121 =cut
 122     has references => ( isa => HashRef[ArrayRef[Str]],
 123                         is => 'ro',
 124                         lazy_build => 1 );
 125
 126     method BUILD {
 127         $self->$_() for qw/last_change owner description/; # Ensure to build early.
 128     }
 129
 130 =head1 METHODS
 131
 132 =head2 head_hash ($head?)
 133
 134 Return the sha1 for HEAD, or any specified head.
 135
 136 =cut
 137     method head_hash (Str $head?) {
 138         my $output = $self->run_cmd(qw/rev-parse --verify/, $head || 'HEAD' );
 139         confess("No such head: " . $head) unless defined $output;
 140
 141         my($sha1) = $output =~ /^($SHA1RE)$/;
 142         return $sha1;
 143     }
 144
 145 =head2 list_tree ($sha1?)
 146
 147 Return an array of contents for a given tree.
 148 The tree is specified by sha1, and defaults to HEAD.
 149 Each item is a L<Gitalist::Git::Object>.
 150
 151 =cut
 152     method list_tree (Str $sha1?) {
 153         $sha1 ||= $self->head_hash;
 154
 155         my $output = $self->run_cmd(qw/ls-tree -z/, $sha1);
 156         return unless defined $output;
 157
 158         my @ret;
 159         for my $line (split /\0/, $output) {
 160             my ($mode, $type, $object, $file) = split /\s+/, $line, 4;
 161             push @ret, Object->new( mode => oct $mode,
 162                                     type => $type,
 163                                     sha1 => $object,
 164                                     file => $file,
 165                                     project => $self,
 166                                   );
 167         }
 168         return @ret;
 169     }
 170
 171 =head2 get_object ($sha1)
 172
 173 Return a L<Gitalist::Git::Object> for the given sha1.
 174
 175 =cut
 176     method get_object (NonEmptySimpleStr $sha1) {
 177         unless ( $self->_is_valid_rev($sha1) ) {
 178             $sha1 = $self->head_hash($sha1);
 179         }
 180         return Object->new(
 181             project => $self,
 182             sha1 => $sha1,
 183         );
 184     }
 185
 186 =head2 hash_by_path($sha1, $path, $type?)
 187
 188 Returns the sha1 for a given path, optionally limited by type.
 189
 190 =cut
 191     method hash_by_path ($base, $path = '', $type?) {
 192         $path =~ s{/+$}();
 193         # FIXME should this really just take the first result?
 194         my @paths = $self->run_cmd('ls-tree', $base, '--', $path)
 195             or return;
 196         my $line = $paths[0];
 197
 198         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
 199         $line =~ m/^([0-9]+) (.+) ($SHA1RE)\t/;
 200         return defined $type && $type ne $2
 201             ? ()
 202                 : $3;
 203     }
 204
 205 =head2 list_revs($sha1, $count?, $skip?, \%search?, $file?)
 206
 207 Returns a list of revs for the given head ($sha1).
 208
 209 =cut
 210     method list_revs ( NonEmptySimpleStr :$sha1!,
 211                        Int :$count?,
 212                        Int :$skip?,
 213                        HashRef :$search?,
 214                        NonEmptySimpleStr :$file? ) {
 215         $sha1 = $self->head_hash($sha1)
 216             if !$sha1 || $sha1 !~ $SHA1RE;
 217
 218         my @search_opts;
 219         if ($search) {
 220             $search->{type} = 'grep'
 221                 if $search->{type} eq 'commit';
 222             @search_opts = (
 223                 # This seems a little fragile ...
 224                 qq[--$search->{type}=$search->{text}],
 225                 '--regexp-ignore-case',
 226                 $search->{regexp} ? '--extended-regexp' : '--fixed-strings'
 227             );
 228         }
 229
 230         my $output = $self->run_cmd(
 231             'rev-list',
 232             '--header',
 233             (defined $count ? "--max-count=$count" : ()),
 234             (defined $skip ? "--skip=$skip"       : ()),
 235             @search_opts,
 236             $sha1,
 237             '--',
 238             ($file ? $file : ()),
 239         );
 240         return unless $output;
 241
 242         my @revs = $self->_parse_rev_list($output);
 243
 244         return @revs;
 245     }
 246
 247 =head2 diff($commit, $patch?, $parent?, $file?)
 248
 249 Generate a diff from a given L<Gitalist::Git::Object>.
 250
 251 =cut
 252
 253     method diff ( Gitalist::Git::Object :$commit!,
 254                   Bool :$patch?,
 255                   Maybe[NonEmptySimpleStr] :$parent?,
 256                   NonEmptySimpleStr :$file?
 257               ) {
 258               return $commit->diff( patch => $patch,
 259                                     parent => $parent,
 260                                     file => $file);
 261     }
 262
 263 =head2 reflog(@lorgargs)
 264
 265 Return a list of hashes representing each reflog entry.
 266
 267 FIXME Should this return objects?
 268
 269 =cut
 270     method reflog (@logargs) {
 271         my @entries
 272             =  $self->run_cmd(qw(log -g), @logargs)
 273                 =~ /(^commit.+?(?:(?=^commit)|(?=\z)))/msg;
 274
 275         #  commit 02526fc15beddf2c64798a947fecdd8d11bf993d
 276         #  Reflog: HEAD@{14} (The Git Server <git@git.dev.venda.com>)
 277         #  Reflog message: push
 278         #  Author: Foo Barsby <fbarsby@example.com>
 279         #  Date:   Thu Sep 17 12:26:05 2009 +0100
 280         #
 281         #      Merge branch 'abc123'
 282
 283         return map {
 284             # XXX Stuff like this makes me want to switch to Git::PurePerl
 285             my($sha1, $type, $author, $date)
 286                 = m{
 287                        ^ commit \s+ ($SHA1RE)$
 288                        .*?
 289                        Reflog[ ]message: \s+ (.+?)$ \s+
 290                      Author: \s+ ([^<]+) <.*?$ \s+
 291                    Date: \s+ (.+?)$
 292                }xms;
 293
 294             pos($_) = index($_, $date) + length $date;
 295
 296             # Yeah, I just did that.
 297             my($msg) = /\G\s+(\S.*)/sg;
 298             {
 299                 hash    => $sha1,
 300                 type    => $type,
 301                 author  => $author,
 302
 303                 # XXX Add DateTime goodness.
 304                 date    => $date,
 305                 message => $msg,
 306             }
 307             ;
 308         } @entries;
 309     }
 310
 311     ## BUILDERS
 312     method _build__util {
 313         Gitalist::Git::Util->new(
 314             project => $self,
 315         );
 316     }
 317
 318     method _build_description {
 319         eval {
 320             return $self->gpp->description;
 321         };
 322         if ($@) {
 323             return "Unnamed repository.";
 324         }
 325
 326     }
 327
 328     method _build_owner {
 329         my ($gecos, $name) = (getpwuid $self->path->stat->uid)[6,0];
 330         $gecos =~ s/,+$//;
 331         return length($gecos) ? $gecos : $name;
 332     }
 333
 334     method _build_last_change {
 335         my $last_change;
 336         my $output = $self->run_cmd(
 337             qw{ for-each-ref --format=%(committer)
 338                 --sort=-committerdate --count=1 refs/heads
 339           });
 340         if (my ($epoch, $tz) = $output =~ /\s(\d+)\s+([+-]\d+)$/) {
 341             my $dt = DateTime->from_epoch(epoch => $epoch);
 342             $dt->set_time_zone($tz);
 343             $last_change = $dt;
 344         }
 345         return $last_change;
 346     }
 347
 348     method _build_heads {
 349         my @revlines = $self->run_cmd_list(qw/for-each-ref --sort=-committerdate /, '--format=%(objectname)%00%(refname)%00%(committer)', 'refs/heads');
 350         my @ret;
 351         for my $line (@revlines) {
 352             my ($rev, $head, $commiter) = split /\0/, $line, 3;
 353             $head =~ s!^refs/heads/!!;
 354
 355             push @ret, { sha1 => $rev, name => $head };
 356
 357             #FIXME: That isn't the time I'm looking for..
 358             if (my ($epoch, $tz) = $line =~ /\s(\d+)\s+([+-]\d+)$/) {
 359                 my $dt = DateTime->from_epoch(epoch => $epoch);
 360                 $dt->set_time_zone($tz);
 361                 $ret[-1]->{last_change} = $dt;
 362             }
 363         }
 364
 365         return \@ret;
 366     }
 367
 368     method _build_references {
 369         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
 370         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
 371         my @reflist = $self->run_cmd_list(qw(show-ref --dereference))
 372             or return;
 373         my %refs;
 374         for (@reflist) {
 375             push @{$refs{$1}}, $2
 376                 if m!^($SHA1RE)\srefs/(.*)$!;
 377         }
 378
 379         return \%refs;
 380     }
 381
 382     ## Private methods
 383     method _is_valid_rev (Str $rev) {
 384         return ($rev =~ /^($SHA1RE)$/);
 385     }
 386
 387     method _parse_rev_list ($output) {
 388         return
 389             map  $self->get_gpp_object($_),
 390                 grep $self->_is_valid_rev($_),
 391                     map  split(/\n/, $_, 6), split /\0/, $output;
 392     }
 393
 394 =head1 SEE ALSO
 395
 396 L<Gitalist::Git::Util> L<Gitalist::Git::Object>
 397
 398 =head1 AUTHORS AND COPYRIGHT
 399
 400   Catalyst application:
 401     (C) 2009 Venda Ltd and Dan Brook <dbrook@venda.com>
 402
 403   Original gitweb.cgi from which this was derived:
 404     (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
 405     (C) 2005, Christian Gierke
 406
 407 =head1 LICENSE
 408
 409 FIXME - Is this going to be GPLv2 as per gitweb? If so this is broken..
 410
 411 This library is free software. You can redistribute it and/or modify
 412 it under the same terms as Perl itself.
 413
 414 =cut
 415
 416 } # end class