lib/Gitalist/Git/Project.pm

   1 use MooseX::Declare;
   2
   3 class Gitalist::Git::Project with Gitalist::Git::HasUtils {
   4     # FIXME, use Types::Path::Class and coerce
   5     use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   6     use MooseX::Types::Path::Class qw/Dir/;
   7     use MooseX::Types::Moose qw/Str Maybe Bool HashRef ArrayRef/;
   8     use Gitalist::Git::Types qw/SHA1/;
   9     use Moose::Autobox;
  10     use List::MoreUtils qw/any zip/;
  11     use DateTime;
  12     use Gitalist::Git::Object::Blob;
  13     use Gitalist::Git::Object::Tree;
  14     use Gitalist::Git::Object::Commit;
  15     use Gitalist::Git::Object::Tag;
  16
  17     our $SHA1RE = qr/[0-9a-fA-F]{40}/;
  18
  19     around BUILDARGS (ClassName $class: Dir $dir) {
  20         # Allows us to be called as Project->new($dir)
  21         # Last path component becomes $self->name
  22         # Full path to git objects becomes $self->path
  23         my $name = $dir->dir_list(-1);
  24         $dir = $dir->subdir('.git') if (-f $dir->file('.git', 'HEAD'));
  25         confess("Can't find a git repository at " . $dir)
  26             unless ( -f $dir->file('HEAD') );
  27         return $class->$orig(name => $name,
  28                              path => $dir);
  29     }
  30
  31     has name => ( isa => NonEmptySimpleStr,
  32                   is => 'ro', required => 1 );
  33
  34     has path => ( isa => Dir,
  35                   is => 'ro', required => 1);
  36
  37     has description => ( isa => Str,
  38                          is => 'ro',
  39                          lazy_build => 1,
  40                      );
  41
  42     has owner => ( isa => NonEmptySimpleStr,
  43                    is => 'ro',
  44                    lazy_build => 1,
  45                );
  46
  47     has last_change => ( isa => Maybe['DateTime'],
  48                          is => 'ro',
  49                          lazy_build => 1,
  50                      );
  51
  52     has is_bare => ( isa => Bool,
  53                      is => 'ro',
  54                      lazy => 1,
  55                      default => sub {
  56                          -d $_[0]->path->parent->subdir->($_[0]->name)
  57                              ? 1 : 0
  58                          },
  59                      );
  60     has heads => ( isa => ArrayRef[HashRef],
  61                    is => 'ro',
  62                    lazy_build => 1);
  63     has tags => ( isa => ArrayRef[HashRef],
  64                    is => 'ro',
  65                    lazy_build => 1);
  66     has references => ( isa => HashRef[ArrayRef[Str]],
  67                         is => 'ro',
  68                         lazy_build => 1 );
  69
  70     method BUILD {
  71         $self->$_() for qw/last_change owner description/; # Ensure to build early.
  72     }
  73
  74     ## Public methods
  75     method head_hash (Str $head?) {
  76         my $output = $self->run_cmd(qw/rev-parse --verify/, $head || 'HEAD' );
  77         confess("No such head: " . $head) unless defined $output;
  78
  79         my($sha1) = $output =~ /^($SHA1RE)$/;
  80         return $sha1;
  81     }
  82
  83     method list_tree (SHA1 $sha1?) {
  84         $sha1 ||= $self->head_hash;
  85         my $object = $self->get_object($sha1);
  86         return @{$object->tree};
  87     }
  88
  89     method get_object (NonEmptySimpleStr $sha1) {
  90         unless (is_SHA1($sha1)) {
  91             $sha1 = $self->head_hash($sha1);
  92         }
  93         my $type = $self->run_cmd('cat-file', '-t', $sha1);
  94         chomp($type);
  95         my $class = 'Gitalist::Git::Object::' . ucfirst($type);
  96         $class->new(
  97             project => $self,
  98             sha1 => $sha1,
  99             type => $type,
 100         );
 101     }
 102
 103     method hash_by_path ($base, $path = '', $type?) {
 104         $path =~ s{/+$}();
 105         # FIXME should this really just take the first result?
 106         my @paths = $self->run_cmd('ls-tree', $base, '--', $path)
 107             or return;
 108         my $line = $paths[0];
 109
 110         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
 111         $line =~ m/^([0-9]+) (.+) ($SHA1RE)\t/;
 112         return defined $type && $type ne $2
 113             ? ()
 114                 : $3;
 115     }
 116
 117     method list_revs ( NonEmptySimpleStr :$sha1!,
 118                        Int :$count?,
 119                        Int :$skip?,
 120                        HashRef :$search?,
 121                        NonEmptySimpleStr :$file? ) {
 122         $sha1 = $self->head_hash($sha1)
 123             if !$sha1 || $sha1 !~ $SHA1RE;
 124
 125         my @search_opts;
 126         if ($search) {
 127             $search->{type} = 'grep'
 128                 if $search->{type} eq 'commit';
 129             @search_opts = (
 130                 # This seems a little fragile ...
 131                 qq[--$search->{type}=$search->{text}],
 132                 '--regexp-ignore-case',
 133                 $search->{regexp} ? '--extended-regexp' : '--fixed-strings'
 134             );
 135         }
 136
 137         my $output = $self->run_cmd(
 138             'rev-list',
 139             '--header',
 140             (defined $count ? "--max-count=$count" : ()),
 141             (defined $skip ? "--skip=$skip"       : ()),
 142             @search_opts,
 143             $sha1,
 144             '--',
 145             ($file ? $file : ()),
 146         );
 147         return unless $output;
 148
 149         my @revs = $self->_parse_rev_list($output);
 150
 151         return @revs;
 152     }
 153
 154     method snapshot (NonEmptySimpleStr :$sha1,
 155                  NonEmptySimpleStr :$format
 156                ) {
 157         # TODO - only valid formats are 'tar' and 'zip'
 158         my $formats = { tgz => 'tar', zip => 'zip' };
 159         unless ($formats->exists($format)) {
 160             die("No such format: $format");
 161         }
 162         $format = $formats->{$format};
 163         my $name = $self->name;
 164         $name =~ s,([^/])/*\.git$,$1,;
 165         my $filename = $name;
 166         $filename .= "-$sha1.$format";
 167         $name =~ s/\047/\047\\\047\047/g;
 168
 169         my @cmd = ('archive', "--format=$format", "--prefix=$name/", $sha1);
 170         return ($filename, $self->run_cmd_fh(@cmd));
 171         # TODO - support compressed archives
 172     }
 173
 174     method diff ( Gitalist::Git::Object :$commit!,
 175                   Bool :$patch?,
 176                   Maybe[NonEmptySimpleStr] :$parent?,
 177                   NonEmptySimpleStr :$file?
 178               ) {
 179               return $commit->diff( patch => $patch,
 180                                     parent => $parent,
 181                                     file => $file);
 182     }
 183
 184     method reflog (@logargs) {
 185         my @entries
 186             =  $self->run_cmd(qw(log -g), @logargs)
 187                 =~ /(^commit.+?(?:(?=^commit)|(?=\z)))/msg;
 188
 189         #  commit 02526fc15beddf2c64798a947fecdd8d11bf993d
 190         #  Reflog: HEAD@{14} (The Git Server <git@git.dev.venda.com>)
 191         #  Reflog message: push
 192         #  Author: Foo Barsby <fbarsby@example.com>
 193         #  Date:   Thu Sep 17 12:26:05 2009 +0100
 194         #
 195         #      Merge branch 'abc123'
 196
 197         return map {
 198             # XXX Stuff like this makes me want to switch to Git::PurePerl
 199             my($sha1, $type, $author, $date)
 200                 = m{
 201                        ^ commit \s+ ($SHA1RE)$
 202                        .*?
 203                        Reflog[ ]message: \s+ (.+?)$ \s+
 204                      Author: \s+ ([^<]+) <.*?$ \s+
 205                    Date: \s+ (.+?)$
 206                }xms;
 207
 208             pos($_) = index($_, $date) + length $date;
 209
 210             # Yeah, I just did that.
 211             my($msg) = /\G\s+(\S.*)/sg;
 212             {
 213                 hash    => $sha1,
 214                 type    => $type,
 215                 author  => $author,
 216
 217                 # XXX Add DateTime goodness.
 218                 date    => $date,
 219                 message => $msg,
 220             }
 221             ;
 222         } @entries;
 223     }
 224
 225     ## BUILDERS
 226     method _build_util {
 227         Gitalist::Git::Util->new(
 228             project => $self,
 229         );
 230     }
 231
 232     method _build_description {
 233         my $description = "";
 234         eval {
 235             $description = $self->path->file('description')->slurp;
 236             chomp $description;
 237         };
 238         return $description;
 239     }
 240
 241     method _build_owner {
 242         my ($gecos, $name) = (getpwuid $self->path->stat->uid)[6,0];
 243         $gecos =~ s/,+$//;
 244         return length($gecos) ? $gecos : $name;
 245     }
 246
 247     method _build_last_change {
 248         my $last_change;
 249         my $output = $self->run_cmd(
 250             qw{ for-each-ref --format=%(committer)
 251                 --sort=-committerdate --count=1 refs/heads
 252           });
 253         if (my ($epoch, $tz) = $output =~ /\s(\d+)\s+([+-]\d+)$/) {
 254             my $dt = DateTime->from_epoch(epoch => $epoch);
 255             $dt->set_time_zone($tz);
 256             $last_change = $dt;
 257         }
 258         return $last_change;
 259     }
 260
 261     method _build_heads {
 262         my @revlines = $self->run_cmd_list(qw/for-each-ref --sort=-committerdate /, '--format=%(objectname)%00%(refname)%00%(committer)', 'refs/heads');
 263         my @ret;
 264         for my $line (@revlines) {
 265             my ($rev, $head, $commiter) = split /\0/, $line, 3;
 266             $head =~ s!^refs/heads/!!;
 267
 268             push @ret, { sha1 => $rev, name => $head };
 269
 270             #FIXME: That isn't the time I'm looking for..
 271             if (my ($epoch, $tz) = $line =~ /\s(\d+)\s+([+-]\d+)$/) {
 272                 my $dt = DateTime->from_epoch(epoch => $epoch);
 273                 $dt->set_time_zone($tz);
 274                 $ret[-1]->{last_change} = $dt;
 275             }
 276         }
 277
 278         return \@ret;
 279     }
 280
 281     method _build_tags {
 282         my @revlines = $self->run_cmd_list('for-each-ref',
 283           '--sort=-creatordate',
 284           '--format=%(objectname) %(objecttype) %(refname) %(*objectname) %(*objecttype) %(subject)%00%(creator)',
 285           'refs/tags'
 286         );
 287         my @ret;
 288         for my $line (@revlines) {
 289             my($refinfo, $creatorinfo) = split /\0/, $line;
 290             my($rev, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
 291             my($creator, $epoch, $tz) = ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
 292             $name =~ s!^refs/tags/!!;
 293
 294             push @ret, { sha1 => $rev, name => $name };
 295
 296             #FIXME: That isn't the time I'm looking for..
 297             if($epoch and $tz) {
 298                 my $dt = DateTime->from_epoch(epoch => $epoch);
 299                 $dt->set_time_zone($tz);
 300                 $ret[-1]->{last_change} = $dt;
 301             }
 302         }
 303
 304         return \@ret;
 305     }
 306
 307     method _build_references {
 308         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
 309         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
 310         my @reflist = $self->run_cmd_list(qw(show-ref --dereference))
 311             or return;
 312         my %refs;
 313         for (@reflist) {
 314             push @{$refs{$1}}, $2
 315                 if m!^($SHA1RE)\srefs/(.*)$!;
 316         }
 317
 318         return \%refs;
 319     }
 320
 321     ## Private methods
 322     method _parse_rev_list ($output) {
 323         return
 324             map  $self->get_gpp_object($_),
 325                 grep is_SHA1($_),
 326                     map  split(/\n/, $_, 6), split /\0/, $output;
 327     }
 328
 329 } # end class
 330
 331 __END__
 332
 333 =head1 NAME
 334
 335 Gitalist::Git::Project - Model of a git repository
 336
 337 =head1 SYNOPSIS
 338
 339     my $gitrepo = dir('/repo/base/Gitalist');
 340     my $project = Gitalist::Git::Project->new($gitrepo);
 341      $project->name;        # 'Gitalist'
 342      $project->path;        # '/repo/base/Gitalist/.git'
 343      $project->description; # 'Unnamed repository.'
 344
 345 =head1 DESCRIPTION
 346
 347 This class models a git repository, referred to in Gitalist
 348 as a "Project".
 349
 350
 351 =head1 ATTRIBUTES
 352
 353 =head2 name
 354
 355 The name of the Project.  If unspecified, this will be derived from the path to the git repository.
 356
 357 =head2 path
 358
 359 L<Path::Class:Dir> for the filesystem path to the git repository.
 360
 361 =head2 description
 362
 363 The contents of .git/description.
 364
 365 =head2 owner
 366
 367 Owner of the files on the filesystem.
 368
 369 =head2 last_change
 370
 371 The L<DateTime> of the last modification of the repository.  This will be C<undef> if the repository has never been used.
 372
 373 =head2 is_bare
 374
 375 True if this is a bare git repository.
 376
 377 =head2 heads
 378
 379 =head2 tags
 380
 381 An array of the name and sha1 of all heads/tags in the repository.
 382
 383 =head2 references
 384
 385 Hashref of ArrayRefs for each reference.
 386
 387
 388 =head1 METHODS
 389
 390 =head2 head_hash ($head?)
 391
 392 Return the sha1 for HEAD, or any specified head.
 393
 394 =head2 list_tree ($sha1?)
 395
 396 Return an array of contents for a given tree.
 397 The tree is specified by sha1, and defaults to HEAD.
 398 Each item is a L<Gitalist::Git::Object>.
 399
 400 =head2 get_object ($sha1)
 401
 402 Return an appropriate subclass of L<Gitalist::Git::Object> for the given sha1.
 403
 404 =head2 hash_by_path ($sha1, $path, $type?)
 405
 406 Returns the sha1 for a given path, optionally limited by type.
 407
 408 =head2 list_revs ($sha1, $count?, $skip?, \%search?, $file?)
 409
 410 Returns a list of revs for the given head ($sha1).
 411
 412 =head2 snapshot ($sha1, $format)
 413
 414 Generate an archived snapshot of the repository.
 415 $sha1 should be a commit or tree.
 416 Returns a filehandle to read from.
 417
 418 =head2 diff ($commit, $patch?, $parent?, $file?)
 419
 420 Generate a diff from a given L<Gitalist::Git::Object>.
 421
 422 =head2 reflog (@lorgargs)
 423
 424 Return a list of hashes representing each reflog entry.
 425
 426 FIXME Should this return objects?
 427
 428
 429 =head1 SEE ALSO
 430
 431 L<Gitalist::Git::Util> L<Gitalist::Git::Object>
 432
 433
 434 =head1 AUTHORS
 435
 436 See L<Gitalist> for authors.
 437
 438 =head1 LICENSE
 439
 440 See L<Gitalist> for the license.
 441
 442 =cut