lib/Gitalist/Git/CollectionOfRepositories/FromDirectoryRecursive.pm

   1 use MooseX::Declare;
   2
   3 class Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive
   4     with Gitalist::Git::CollectionOfRepositories {
   5     use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
   6     use MooseX::Types::Path::Class qw/Dir/;
   7
   8     has repo_dir => (
   9         isa => Dir,
  10         is => 'ro',
  11         required => 1,
  12         coerce => 1,
  13     );
  14
  15     method BUILD {
  16         # Make sure repo_dir is an absolute path so that
  17         # ->contains() works correctly.
  18         $self->repo_dir->resolve;
  19     }
  20
  21     method _get_path_for_repository_name (NonEmptySimpleStr $name) {
  22         my $path = $self->repo_dir->subdir($name)->resolve;
  23         die "Directory traversal prohibited"
  24             unless $self->repo_dir->contains($path);
  25         return $path;
  26     }
  27
  28     ## Builders
  29     method _build_repositories {
  30         my @ret;
  31         $self->repo_dir->recurse(
  32             callback => sub {
  33                 my ( $dir ) = @_;
  34                 if ( $dir->is_dir ) {
  35                     for my $repo ( @ret ) {
  36                         # no need to go further if parent is git dir
  37                         # never have a git repo in a git repo?
  38                         return if ( $repo->path->contains( $dir ) );
  39                     }
  40                     eval {
  41                         # slight hack since get_repo expects string
  42                         my @list = $dir->dir_list();
  43                         my $p = $self->get_repository($list[$#list]);
  44                         push @ret, $p;
  45                     };
  46                 }
  47                 return;
  48             }
  49         );
  50         return \@ret;
  51     }
  52 }                         # end class
  53
  54 __END__
  55
  56 =head1 NAME
  57
  58 Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive - Model of recursive directories containing git repositories
  59
  60 =head1 SYNOPSIS
  61
  62     my $repo = Gitalist::Git::CollectionOfRepositories::FromDirectoryRecursive->new( repo_dir => $Dir );
  63     my $repository_list = $repo->repositories;
  64     my $first_repository = $repository_list->[0];
  65     my $named_repository = $repo->get_repository('Gitalist');
  66
  67 =head1 DESCRIPTION
  68
  69 This class provides a list of Repositories recursively found in the given directory.
  70
  71 =head1 ATTRIBUTES
  72
  73 =head2 repo_dir (C<Path::Class::Dir>)
  74
  75 The filesystem root of the C<Repo>.
  76
  77 =head1 SEE ALSO
  78
  79 L<Gitalist::Git::CollectionOfRepositories>, L<Gitalist::Git::Repository>
  80
  81 =head1 AUTHORS
  82
  83 See L<Gitalist> for authors.
  84
  85 =head1 LICENSE
  86
  87 See L<Gitalist> for the license.
  88
  89 =cut