lib/Gitalist/Controller/Root.pm

   1 package Gitalist::Controller::Root;
   2 use Moose;
   3 use namespace::autoclean;
   4
   5 BEGIN { extends 'Catalyst::Controller' }
   6
   7 #
   8 # Sets the actions in this controller to be registered with no prefix
   9 # so they function identically to actions created in MyApp.pm
  10 #
  11 __PACKAGE__->config->{namespace} = '';
  12
  13 =head1 NAME
  14
  15 Gitalist::Controller::Root - Root Controller for Gitalist
  16
  17 =head1 DESCRIPTION
  18
  19 [enter your description here]
  20
  21 =head1 METHODS
  22
  23 =cut
  24
  25 =head2 index
  26
  27 =cut
  28
  29 use IO::Capture::Stdout;
  30
  31 =head2 run_gitweb
  32
  33 The main shim around C<gitweb.pm>.
  34
  35 =cut
  36
  37 sub run_gitweb {
  38   my ( $self, $c ) = @_;
  39
  40   # XXX A slippery slope to be sure.
  41   if($c->req->param('a')) {
  42     my $capture = IO::Capture::Stdout->new();
  43     $capture->start();
  44     eval {
  45       my $action = gitweb::main($c);
  46       $action->();
  47     };
  48     $capture->stop();
  49
  50     use Data::Dumper;
  51     die Dumper($@)
  52       if $@;
  53
  54     my $output = join '', $capture->read;
  55     $c->stash->{gitweb_output} = $output;
  56     $c->stash->{template} = 'gitweb.tt2';
  57   }
  58 }
  59
  60 sub _get_commit {
  61   my($self, $c) = @_;
  62
  63   my $h = $c->req->param('h');
  64   my $f = $c->req->param('f');
  65   my $m = $c->model('Git');
  66
  67   # Either use the provided h(ash) parameter, the f(ile) parameter or just use HEAD.
  68   my $hash = ($h =~ /[^a-f0-9]/ ? $m->head_hash($h) : $h)
  69           || ($f && $m->hash_by_path($f))
  70           || $m->head_hash
  71           # XXX This could definitely use more context.
  72           || Carp::croak("Couldn't find a hash for the commit object!");
  73
  74
  75   (my $pd = $m->project_dir( $m->project )) =~ s{/\.git$}();
  76   my $commit = $m->get_object($hash)
  77     or Carp::croak("Couldn't find a commit object for '$hash' in '$pd'!");
  78
  79   return $commit;
  80 }
  81
  82 =head2 index
  83
  84 Provides the project listing.
  85
  86 =cut
  87
  88 sub index :Path :Args(0) {
  89   my ( $self, $c ) = @_;
  90
  91   # Leave actions up to gitweb at this point.
  92   return $self->run_gitweb($c)
  93     if $c->req->param('a');
  94
  95   my $list = $c->model('Git')->list_projects;
  96   unless(@$list) {
  97     die "No projects found";
  98   }
  99
 100   $c->stash(
 101     searchtext => $c->req->param('searchtext') || '',
 102     projects   => $list,
 103     action     => 'index',
 104   );
 105 }
 106
 107 =head2 summary
 108
 109 A summary of what's happening in the repo.
 110
 111 =cut
 112
 113 sub summary : Local {
 114   my ( $self, $c ) = @_;
 115
 116   my $commit = $self->_get_commit($c);
 117   $c->stash(
 118     commit    => $commit,
 119     info      => $c->model('Git')->project_info($c->model('Git')->project),
 120     log_lines => [$c->model('Git')->list_revs(
 121       sha1 => $commit->sha1, count => Gitalist->config->{paging}{summary}
 122     )],
 123     refs      => $c->model('Git')->references,
 124     heads     => [$c->model('Git')->heads],
 125     action    => 'summary',
 126   );
 127 }
 128
 129 =head2 heads
 130
 131 The current list of heads (aka branches) in the repo.
 132
 133 =cut
 134
 135 sub heads : Local {
 136   my ( $self, $c ) = @_;
 137
 138   $c->stash(
 139     commit => $self->_get_commit($c),
 140     heads  => [$c->model('Git')->heads],
 141     action => 'heads',
 142   );
 143 }
 144
 145 =head2 blob
 146
 147 The blob action i.e the contents of a file.
 148
 149 =cut
 150
 151 sub blob : Local {
 152   my ( $self, $c ) = @_;
 153
 154   my $h  = $c->req->param('h')
 155        || $c->model('Git')->hash_by_path($c->req->param('f'))
 156        || die "No file or sha1 provided.";
 157   my $hb = $c->req->param('hb')
 158        || $c->model('Git')->head_hash
 159        || die "Couldn't discern the corresponding head.";
 160
 161   my $filename = $c->req->param('f') || '';
 162
 163   $c->stash(
 164     blob     => $c->model('Git')->get_object($h)->content,
 165     head     => $c->model('Git')->get_object($hb),
 166     filename => $filename,
 167     # XXX Hack hack hack, see View::SyntaxHighlight
 168     language => ($filename =~ /\.p[lm]$/ ? 'Perl' : ''),
 169     action   => 'blob',
 170   );
 171
 172   $c->forward('View::SyntaxHighlight');
 173 }
 174
 175 =head2 blobdiff
 176
 177 Exposes a given diff of a blob.
 178
 179 =cut
 180
 181 sub blobdiff : Local {
 182   my ( $self, $c ) = @_;
 183
 184   my $commit = $self->_get_commit($c);
 185   my $filename = $c->req->param('f')
 186               || croak("No file specified!");
 187   my @diff = $c->model('Git')->diff(
 188     $commit->parent_sha1, $commit->sha1, '--', $filename
 189   );
 190   $c->stash(
 191     commit    => $commit,
 192     diff      => \@diff,
 193     # XXX Hack hack hack, see View::SyntaxHighlight
 194     blobs     => [$diff[0]->{diff}],
 195     language  => 'Diff',
 196     action    => 'blobdiff',
 197   );
 198
 199   $c->forward('View::SyntaxHighlight');
 200 }
 201
 202 =head2 commit
 203
 204 Exposes a given commit.
 205
 206 =cut
 207
 208 sub commit : Local {
 209   my ( $self, $c ) = @_;
 210
 211   my $commit = $self->_get_commit($c);
 212   $c->stash(
 213       commit      => $commit,
 214       diff_tree   => [$c->model('Git')->diff_tree($commit)],
 215       branches_on => [$c->model('Git')->refs_for($commit->sha1)],
 216       action      => 'commit',
 217   );
 218 }
 219
 220 =head2 commitdiff
 221
 222 Exposes a given diff of a commit.
 223
 224 =cut
 225
 226 sub commitdiff : Local {
 227   my ( $self, $c ) = @_;
 228
 229   my $commit = $self->_get_commit($c);
 230   my @difflist = $c->model('Git')->diff($commit->parent_sha1, $commit->sha1);
 231   $c->stash(
 232     commit    => $commit,
 233     diff_tree => [$c->model('Git')->diff_tree($commit)],
 234     diff      => \@difflist,
 235     # XXX Hack hack hack, see View::SyntaxHighlight
 236     blobs     => [map $_->{diff}, @difflist],
 237     language  => 'Diff',
 238     action    => 'commitdiff',
 239   );
 240
 241   $c->forward('View::SyntaxHighlight');
 242 }
 243
 244 =head2 shortlog
 245
 246 Expose an abbreviated log of a given sha1.
 247
 248 =cut
 249
 250 sub shortlog : Local {
 251   my ( $self, $c ) = @_;
 252
 253   my $commit  = $self->_get_commit($c);
 254   my %logargs = (
 255       sha1   => $commit->sha1,
 256       count  => Gitalist->config->{paging}{log},
 257       ($c->req->param('f') ? (file => $c->req->param('f')) : ())
 258   );
 259
 260   my $page = $c->req->param('pg') || 0;
 261   $logargs{skip} = $c->req->param('pg') * $logargs{count}
 262     if $c->req->param('pg');
 263
 264   $c->stash(
 265       commit    => $commit,
 266       log_lines => [$c->model('Git')->list_revs(%logargs)],
 267       refs      => $c->model('Git')->references,
 268       action    => 'shortlog',
 269       page      => $page + 1,
 270   );
 271 }
 272
 273 =head2 log
 274
 275 Calls shortlog internally. Perhaps that should be reversed ...
 276
 277 =cut
 278 sub log : Local {
 279     $_[0]->shortlog($_[1]);
 280     $_[1]->stash->{action} = 'log';
 281 }
 282
 283 =head2 tree
 284
 285 The tree of a given commit.
 286
 287 =cut
 288
 289 sub tree : Local {
 290   my ( $self, $c ) = @_;
 291
 292   my $commit = $self->_get_commit($c);
 293   $c->stash(
 294       # XXX Useful defaults needed ...
 295       commit    => $commit,
 296       tree      => $c->model('Git')->get_object($c->req->param('hb')),
 297       tree_list => [$c->model('Git')->list_tree($commit->sha1)],
 298       action    => 'tree',
 299   );
 300 }
 301
 302 =head2 reflog
 303
 304 Expose the local reflog. This may go away.
 305
 306 =cut
 307
 308 sub reflog : Local {
 309   my ( $self, $c ) = @_;
 310
 311   my @log = $c->model('Git')->reflog(
 312       '--since=yesterday'
 313   );
 314
 315   $c->stash(
 316       log    => \@log,
 317       action => 'reflog',
 318   );
 319 }
 320
 321 =head2 auto
 322
 323 Populate the header and footer. Perhaps not the best location.
 324
 325 =cut
 326
 327 sub auto : Private {
 328     my($self, $c) = @_;
 329
 330     # Yes, this is hideous.
 331     $self->header($c);
 332     $self->footer($c);
 333 }
 334
 335 # XXX This could probably be dropped altogether.
 336 use Gitalist::Util qw(to_utf8);
 337 # Formally git_header_html
 338 sub header {
 339   my($self, $c) = @_;
 340
 341   my $title = $c->config->{sitename};
 342
 343   my $project   = $c->req->param('project')  || $c->req->param('p');
 344   my $action    = $c->req->param('action')   || $c->req->param('a');
 345   my $file_name = $c->req->param('filename') || $c->req->param('f');
 346   if(defined $project) {
 347     $title .= " - " . to_utf8($project);
 348     if (defined $action) {
 349       $title .= "/$action";
 350       if (defined $file_name) {
 351         $title .= " - " . $file_name;
 352         if ($action eq "tree" && $file_name !~ m|/$|) {
 353           $title .= "/";
 354         }
 355       }
 356     }
 357   }
 358
 359   $c->stash->{version}     = $c->config->{version};
 360   $c->stash->{git_version} = $c->model('Git')->run_cmd('--version');
 361   $c->stash->{title}       = $title;
 362
 363   #$c->stash->{baseurl} = $ENV{PATH_INFO} && uri_escape($base_url);
 364   $c->stash->{stylesheet} = $c->config->{stylesheet} || 'gitweb.css';
 365
 366   $c->stash->{project} = $project;
 367   my @links;
 368   if($project) {
 369     my %href_params = $self->feed_info($c);
 370     $href_params{'-title'} ||= 'log';
 371
 372     foreach my $format qw(RSS Atom) {
 373       my $type = lc($format);
 374       push @links, {
 375         rel   => 'alternate',
 376         title => "$project - $href_params{'-title'} - $format feed",
 377
 378         # XXX A bit hacky and could do with using gitweb::href() features
 379         href  => "?a=$type;p=$project",
 380         type  => "application/$type+xml"
 381         }, {
 382         rel   => 'alternate',
 383
 384         # XXX This duplication also feels a bit awkward
 385         title => "$project - $href_params{'-title'} - $format feed (no merges)",
 386         href  => "?a=$type;p=$project;opt=--no-merges",
 387         type  => "application/$type+xml"
 388         };
 389     }
 390   } else {
 391     push @links, {
 392       rel => "alternate",
 393       title => $c->config->{sitename}." projects list",
 394       href => '?a=project_index',
 395       type => "text/plain; charset=utf-8"
 396       }, {
 397       rel => "alternate",
 398       title => $c->config->{sitename}." projects feeds",
 399       href => '?a=opml',
 400       type => "text/plain; charset=utf-8"
 401       };
 402   }
 403
 404   $c->stash->{favicon} = $c->config->{favicon};
 405
 406   # </head><body>
 407
 408   $c->stash(
 409     logo_url      => $c->config->{logo_url},
 410     logo_label    => $c->config->{logo_label},
 411     logo_img      => $c->config->{logo},
 412     home_link     => $c->config->{home_link},
 413     home_link_str => $c->config->{home_link_str},
 414     );
 415
 416   if(defined $project) {
 417     $c->stash(
 418       search_text => ( $c->req->param('s') || $c->req->param('searchtext') ),
 419       search_hash => ( $c->req->param('hb') || $c->req->param('hashbase')
 420           || $c->req->param('h')  || $c->req->param('hash')
 421           || 'HEAD' ),
 422       );
 423   }
 424 }
 425
 426 # Formally git_footer_html
 427 sub footer {
 428   my($self, $c) = @_;
 429
 430   my $feed_class = 'rss_logo';
 431
 432   my @feeds;
 433   my $project = $c->req->param('project')  || $c->req->param('p');
 434   if(defined $project) {
 435     (my $pstr = $project) =~ s[/?\.git$][];
 436     my $descr = $c->model('Git')->project_info($project)->{description};
 437     $c->stash->{project_description} = defined $descr
 438       ? $descr
 439       : '';
 440
 441     my %href_params = $self->feed_info($c);
 442     if (!%href_params) {
 443       $feed_class .= ' generic';
 444     }
 445     $href_params{'-title'} ||= 'log';
 446
 447     @feeds = [
 448       map +{
 449         class => $feed_class,
 450         title => "$href_params{'-title'} $_ feed",
 451         href  => "/?p=$project;a=\L$_",
 452         name  => lc $_,
 453         }, qw(RSS Atom)
 454       ];
 455   } else {
 456     @feeds = [
 457       map {
 458         class => $feed_class,
 459           title => '',
 460           href  => "/?a=$_->[0]",
 461           name  => $_->[1],
 462         }, [opml=>'OPML'],[project_index=>'TXT'],
 463       ];
 464   }
 465 }
 466
 467 # XXX This feels wrong here, should probably be refactored.
 468 # returns hash to be passed to href to generate gitweb URL
 469 # in -title key it returns description of link
 470 sub feed_info {
 471   my($self, $c) = @_;
 472
 473   my $format = shift || 'Atom';
 474   my %res = (action => lc($format));
 475
 476   # feed links are possible only for project views
 477   return unless $c->req->param('project');
 478
 479   # some views should link to OPML, or to generic project feed,
 480   # or don't have specific feed yet (so they should use generic)
 481   return if $c->req->param('action') =~ /^(?:tags|heads|forks|tag|search)$/x;
 482
 483   my $branch;
 484   my $hash = $c->req->param('h')  || $c->req->param('hash');
 485   my $hash_base = $c->req->param('hb') || $c->req->param('hashbase');
 486
 487   # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
 488   # from tag links; this also makes possible to detect branch links
 489   if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
 490     (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
 491     $branch = $1;
 492   }
 493
 494   # find log type for feed description (title)
 495   my $type = 'log';
 496   my $file_name = $c->req->param('f') || $c->req->param('filename');
 497   if (defined $file_name) {
 498     $type  = "history of $file_name";
 499     $type .= "/" if $c->req->param('action') eq 'tree';
 500     $type .= " on '$branch'" if (defined $branch);
 501   } else {
 502     $type = "log of $branch" if (defined $branch);
 503   }
 504
 505   $res{-title} = $type;
 506   $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
 507   $res{'file_name'} = $file_name;
 508
 509   return %res;
 510 }
 511 =head2 end
 512
 513 Attempt to render a view, if needed.
 514
 515 =cut
 516
 517 sub end : ActionClass('RenderView') {
 518   # Give every view the current HEAD.
 519   $_[1]->stash->{HEAD} = $_[1]->model('Git')->head_hash;
 520 }
 521
 522 =head1 AUTHOR
 523
 524 Dan Brook,,,
 525
 526 =head1 LICENSE
 527
 528 This library is free software. You can redistribute it and/or modify
 529 it under the same terms as Perl itself.
 530
 531 =cut
 532
 533 __PACKAGE__->meta->make_immutable;