lib/FindBin.pm

   1 # FindBin.pm
   2 #
   3 # Copyright (c) 1995 Graham Barr & Nick Ing-Simmons. All rights reserved.
   4 # This program is free software; you can redistribute it and/or modify it
   5 # under the same terms as Perl itself.
   6
   7 =head1 NAME
   8
   9 FindBin - Locate directory of original perl script
  10
  11 =head1 SYNOPSIS
  12
  13  use FindBin;
  14  use lib "$FindBin::Bin/../lib";
  15
  16  or
  17
  18  use FindBin qw($Bin);
  19  use lib "$Bin/../lib";
  20
  21 =head1 DESCRIPTION
  22
  23 Locates the full path to the script bin directory to allow the use
  24 of paths relative to the bin directory.
  25
  26 This allows a user to setup a directory tree for some software with
  27 directories E<lt>rootE<gt>/bin and E<lt>rootE<gt>/lib and then the above example will allow
  28 the use of modules in the lib directory without knowing where the software
  29 tree is installed.
  30
  31 If perl is invoked using the B<-e> option or the perl script is read from
  32 C<STDIN> then FindBin sets both C<$Bin> and C<$RealBin> to the current
  33 directory.
  34
  35 =head1 EXPORTABLE VARIABLES
  36
  37  $Bin         - path to bin directory from where script was invoked
  38  $Script      - basename of script from which perl was invoked
  39  $RealBin     - $Bin with all links resolved
  40  $RealScript  - $Script with all links resolved
  41
  42 =head1 KNOWN BUGS
  43
  44 if perl is invoked as
  45
  46    perl filename
  47
  48 and I<filename> does not have executable rights and a program called I<filename>
  49 exists in the users C<$ENV{PATH}> which satisfies both B<-x> and B<-T> then FindBin
  50 assumes that it was invoked via the C<$ENV{PATH}>.
  51
  52 Workaround is to invoke perl as
  53
  54  perl ./filename
  55
  56 =head1 AUTHORS
  57
  58 Graham Barr E<lt>F<bodg@tiuk.ti.com>E<gt>
  59 Nick Ing-Simmons E<lt>F<nik@tiuk.ti.com>E<gt>
  60
  61 =head1 COPYRIGHT
  62
  63 Copyright (c) 1995 Graham Barr & Nick Ing-Simmons. All rights reserved.
  64 This program is free software; you can redistribute it and/or modify it
  65 under the same terms as Perl itself.
  66
  67 =head1 REVISION
  68
  69 $Revision: 1.4 $
  70
  71 =cut
  72
  73 package FindBin;
  74 use Carp;
  75 require 5.000;
  76 require Exporter;
  77 use File::Spec;
  78 use Cwd qw(getcwd abs_path);
  79 use Config;
  80 use File::Basename;
  81
  82 @EXPORT_OK = qw($Bin $Script $RealBin $RealScript $Dir $RealDir);
  83 %EXPORT_TAGS = (ALL => [qw($Bin $Script $RealBin $RealScript $Dir $RealDir)]);
  84 @ISA = qw(Exporter);
  85
  86 $VERSION = $VERSION = sprintf("%d.%02d", q$Revision: 1.42 $ =~ /(\d+)\.(\d+)/);
  87
  88 BEGIN
  89 {
  90  *Dir = \$Bin;
  91  *RealDir = \$RealBin;
  92
  93  if($0 eq '-e' || $0 eq '-')
  94   {
  95    # perl invoked with -e or script is on C<STDIN>
  96
  97    $Script = $RealScript = $0;
  98    $Bin    = $RealBin    = getcwd();
  99   }
 100  else
 101   {
 102    my $script = $0;
 103
 104    if ($^O eq 'VMS')
 105     {
 106      ($Bin,$Script) = VMS::Filespec::rmsexpand($0) =~ /(.*\])(.*)/;
 107      ($RealBin,$RealScript) = ($Bin,$Script);
 108     }
 109    else
 110     {
 111      my $IsWin32 = $^O eq 'MSWin32';
 112      unless(($script =~ m#/# || ($IsWin32 && $script =~ m#\\#))
 113             && -f $script)
 114       {
 115        my $dir;
 116        my $pathvar = 'PATH';
 117
 118        foreach $dir (split(/$Config{'path_sep'}/,$ENV{$pathvar}))
 119         {
 120         if(-r "$dir/$script" && (!$IsWin32 || -x _))
 121          {
 122           $script = "$dir/$script";
 123
 124           if (-f $0)
 125            {
 126             # $script has been found via PATH but perl could have
 127             # been invoked as 'perl file'. Do a dumb check to see
 128             # if $script is a perl program, if not then $script = $0
 129             #
 130             # well we actually only check that it is an ASCII file
 131             # we know its executable so it is probably a script
 132             # of some sort.
 133
 134             $script = $0 unless(-T $script);
 135            }
 136           last;
 137          }
 138        }
 139      }
 140
 141      croak("Cannot find current script '$0'") unless(-f $script);
 142
 143      # Ensure $script contains the complete path incase we C<chdir>
 144
 145      $script = getcwd() . "/" . $script unless File::Spec->file_name_is_absolute($script);
 146
 147      ($Script,$Bin) = fileparse($script);
 148
 149      # Resolve $script if it is a link
 150      while(1)
 151       {
 152        my $linktext = readlink($script);
 153
 154        ($RealScript,$RealBin) = fileparse($script);
 155        last unless defined $linktext;
 156
 157        $script = (File::Spec->file_name_is_absolute($linktext))
 158                   ? $linktext
 159                   : $RealBin . "/" . $linktext;
 160       }
 161
 162      # Get absolute paths to directories
 163      $Bin     = abs_path($Bin)     if($Bin);
 164      $RealBin = abs_path($RealBin) if($RealBin);
 165     }
 166   }
 167 }
 168
 169 1; # Keep require happy
 170