lib/File/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6 }
   7
   8 use Test::More;
   9 use Config qw( %Config );
  10
  11 BEGIN {
  12     # Check whether the build is configured with -Dmksymlinks
  13     our $Dmksymlinks =
  14         grep { /^config_arg\d+$/ && $Config{$_} eq '-Dmksymlinks' }
  15         keys %Config;
  16
  17     # Resolve symlink to ./TEST if this build is configured with -Dmksymlinks
  18     our $file = 'TEST';
  19     if ( $Dmksymlinks ) {
  20         $file = readlink $file;
  21         die "Can't readlink(TEST): $!" if ! defined $file;
  22     }
  23
  24     our $hasst;
  25     eval { my @n = stat $file };
  26     $hasst = 1 unless $@ && $@ =~ /unimplemented/;
  27     unless ($hasst) { plan skip_all => "no stat"; exit 0 }
  28     use Config;
  29     $hasst = 0 unless $Config{'i_sysstat'} eq 'define';
  30     unless ($hasst) { plan skip_all => "no sys/stat.h"; exit 0 }
  31     our @stat = stat $file; # This is the function stat.
  32     unless (@stat) { plan skip_all => "1..0 # Skip: no file $file"; exit 0 }
  33 }
  34
  35 plan tests => 19 + 24*2 + 3;
  36
  37 use_ok( 'File::stat' );
  38
  39 my $stat = File::stat::stat( $file ); # This is the OO stat.
  40 ok( ref($stat), 'should build a stat object' );
  41
  42 is( $stat->dev, $stat[0], "device number in position 0" );
  43
  44 # On OS/2 (fake) ino is not constant, it is incremented each time
  45 SKIP: {
  46         skip('inode number is not constant on OS/2', 1) if $^O eq 'os2';
  47         is( $stat->ino, $stat[1], "inode number in position 1" );
  48 }
  49
  50 is( $stat->mode, $stat[2], "file mode in position 2" );
  51
  52 is( $stat->nlink, $stat[3], "number of links in position 3" );
  53
  54 is( $stat->uid, $stat[4], "owner uid in position 4" );
  55
  56 is( $stat->gid, $stat[5], "group id in position 5" );
  57
  58 is( $stat->rdev, $stat[6], "device identifier in position 6" );
  59
  60 is( $stat->size, $stat[7], "file size in position 7" );
  61
  62 is( $stat->atime, $stat[8], "last access time in position 8" );
  63
  64 is( $stat->mtime, $stat[9], "last modify time in position 9" );
  65
  66 is( $stat->ctime, $stat[10], "change time in position 10" );
  67
  68 is( $stat->blksize, $stat[11], "IO block size in position 11" );
  69
  70 is( $stat->blocks, $stat[12], "number of blocks in position 12" );
  71
  72 for (split //, "rwxoRWXOezsfdlpSbcugkMCA") {
  73     SKIP: {
  74         $^O eq "VMS" and index("rwxRWX", $_) >= 0
  75             and skip "File::stat ignores VMS ACLs", 2;
  76
  77         my $rv = eval "-$_ \$stat";
  78         ok( !$@,                            "-$_ overload succeeds" )
  79             or diag( $@ );
  80         is( $rv, eval "-$_ \$file",         "correct -$_ overload" );
  81     }
  82 }
  83
  84 for (split //, "tTB") {
  85     eval "-$_ \$stat";
  86     like( $@, qr/\Q-$_ is not implemented/, "-$_ overload fails" );
  87 }
  88
  89 SKIP: {
  90         local *STAT;
  91         skip("Could not open file: $!", 2) unless open(STAT, $file);
  92         ok( File::stat::stat('STAT'), '... should be able to find filehandle' );
  93
  94         package foo;
  95         local *STAT = *main::STAT;
  96         main::ok( my $stat2 = File::stat::stat('STAT'),
  97                 '... and filehandle in another package' );
  98         close STAT;
  99
 100 #       VOS open() updates atime; ignore this error (posix-975).
 101         my $stat3 = $stat2;
 102         if ($^O eq 'vos') {
 103                 $$stat3[8] = $$stat[8];
 104         }
 105
 106         main::skip("Win32: different stat-info on filehandle", 1) if $^O eq 'MSWin32';
 107         main::skip("dos: inode number is fake on dos", 1) if $^O eq 'dos';
 108
 109         main::skip("OS/2: inode number is not constant on os/2", 1) if $^O eq 'os2';
 110
 111         main::is( "@$stat", "@$stat3", '... and must match normal stat' );
 112 }
 113
 114
 115 local $!;
 116 $stat = stat '/notafile';
 117 isnt( $!, '', 'should populate $!, given invalid file' );
 118
 119 # Testing pretty much anything else is unportable.