lib/File/stat.pm

   1 package File::stat;
   2 use strict;
   3
   4 use 5.005_64;
   5 our(@EXPORT, @EXPORT_OK, %EXPORT_TAGS);
   6
   7 our $VERSION = '1.00';
   8
   9 BEGIN {
  10     use Exporter   ();
  11     @EXPORT      = qw(stat lstat);
  12     @EXPORT_OK   = qw( $st_dev     $st_ino    $st_mode
  13                        $st_nlink   $st_uid    $st_gid
  14                        $st_rdev    $st_size
  15                        $st_atime   $st_mtime  $st_ctime
  16                        $st_blksize $st_blocks
  17                     );
  18     %EXPORT_TAGS = ( FIELDS => [ @EXPORT_OK, @EXPORT ] );
  19 }
  20 use vars @EXPORT_OK;
  21
  22 # Class::Struct forbids use of @ISA
  23 sub import { goto &Exporter::import }
  24
  25 use Class::Struct qw(struct);
  26 struct 'File::stat' => [
  27      map { $_ => '$' } qw{
  28          dev ino mode nlink uid gid rdev size
  29          atime mtime ctime blksize blocks
  30      }
  31 ];
  32
  33 sub populate (@) {
  34     return unless @_;
  35     my $stob = new();
  36     @$stob = (
  37         $st_dev, $st_ino, $st_mode, $st_nlink, $st_uid, $st_gid, $st_rdev,
  38         $st_size, $st_atime, $st_mtime, $st_ctime, $st_blksize, $st_blocks )
  39             = @_;
  40     return $stob;
  41 }
  42
  43 sub lstat ($)  { populate(CORE::lstat(shift)) }
  44
  45 sub stat ($) {
  46     my $arg = shift;
  47     my $st = populate(CORE::stat $arg);
  48     return $st if $st;
  49     no strict 'refs';
  50     require Symbol;
  51     return populate(CORE::stat \*{Symbol::qualify($arg)});
  52 }
  53
  54 1;
  55 __END__
  56
  57 =head1 NAME
  58
  59 File::stat - by-name interface to Perl's built-in stat() functions
  60
  61 =head1 SYNOPSIS
  62
  63  use File::stat;
  64  $st = stat($file) or die "No $file: $!";
  65  if ( ($st->mode & 0111) && $st->nlink > 1) ) {
  66      print "$file is executable with lotsa links\n";
  67  }
  68
  69  use File::stat qw(:FIELDS);
  70  stat($file) or die "No $file: $!";
  71  if ( ($st_mode & 0111) && $st_nlink > 1) ) {
  72      print "$file is executable with lotsa links\n";
  73  }
  74
  75 =head1 DESCRIPTION
  76
  77 This module's default exports override the core stat()
  78 and lstat() functions, replacing them with versions that return
  79 "File::stat" objects.  This object has methods that
  80 return the similarly named structure field name from the
  81 stat(2) function; namely,
  82 dev,
  83 ino,
  84 mode,
  85 nlink,
  86 uid,
  87 gid,
  88 rdev,
  89 size,
  90 atime,
  91 mtime,
  92 ctime,
  93 blksize,
  94 and
  95 blocks.
  96
  97 You may also import all the structure fields directly into your namespace
  98 as regular variables using the :FIELDS import tag.  (Note that this still
  99 overrides your stat() and lstat() functions.)  Access these fields as
 100 variables named with a preceding C<st_> in front their method names.
 101 Thus, C<$stat_obj-E<gt>dev()> corresponds to $st_dev if you import
 102 the fields.
 103
 104 To access this functionality without the core overrides,
 105 pass the C<use> an empty import list, and then access
 106 function functions with their full qualified names.
 107 On the other hand, the built-ins are still available
 108 via the C<CORE::> pseudo-package.
 109
 110 =head1 NOTE
 111
 112 While this class is currently implemented using the Class::Struct
 113 module to build a struct-like class, you shouldn't rely upon this.
 114
 115 =head1 AUTHOR
 116
 117 Tom Christiansen