lib/File/stat.pm

   1 package File::stat;
   2 use 5.006;
   3
   4 use strict;
   5 use warnings;
   6
   7 our(@EXPORT, @EXPORT_OK, %EXPORT_TAGS);
   8
   9 our $VERSION = '1.00';
  10
  11 BEGIN {
  12     use Exporter   ();
  13     @EXPORT      = qw(stat lstat);
  14     @EXPORT_OK   = qw( $st_dev     $st_ino    $st_mode
  15                        $st_nlink   $st_uid    $st_gid
  16                        $st_rdev    $st_size
  17                        $st_atime   $st_mtime  $st_ctime
  18                        $st_blksize $st_blocks
  19                     );
  20     %EXPORT_TAGS = ( FIELDS => [ @EXPORT_OK, @EXPORT ] );
  21 }
  22 use vars @EXPORT_OK;
  23
  24 # Class::Struct forbids use of @ISA
  25 sub import { goto &Exporter::import }
  26
  27 use Class::Struct qw(struct);
  28 struct 'File::stat' => [
  29      map { $_ => '$' } qw{
  30          dev ino mode nlink uid gid rdev size
  31          atime mtime ctime blksize blocks
  32      }
  33 ];
  34
  35 sub populate (@) {
  36     return unless @_;
  37     my $stob = new();
  38     @$stob = (
  39         $st_dev, $st_ino, $st_mode, $st_nlink, $st_uid, $st_gid, $st_rdev,
  40         $st_size, $st_atime, $st_mtime, $st_ctime, $st_blksize, $st_blocks )
  41             = @_;
  42     return $stob;
  43 }
  44
  45 sub lstat ($)  { populate(CORE::lstat(shift)) }
  46
  47 sub stat ($) {
  48     my $arg = shift;
  49     my $st = populate(CORE::stat $arg);
  50     return $st if $st;
  51     no strict 'refs';
  52     require Symbol;
  53     return populate(CORE::stat \*{Symbol::qualify($arg)});
  54 }
  55
  56 1;
  57 __END__
  58
  59 =head1 NAME
  60
  61 File::stat - by-name interface to Perl's built-in stat() functions
  62
  63 =head1 SYNOPSIS
  64
  65  use File::stat;
  66  $st = stat($file) or die "No $file: $!";
  67  if ( ($st->mode & 0111) && $st->nlink > 1) ) {
  68      print "$file is executable with lotsa links\n";
  69  }
  70
  71  use File::stat qw(:FIELDS);
  72  stat($file) or die "No $file: $!";
  73  if ( ($st_mode & 0111) && $st_nlink > 1) ) {
  74      print "$file is executable with lotsa links\n";
  75  }
  76
  77 =head1 DESCRIPTION
  78
  79 This module's default exports override the core stat()
  80 and lstat() functions, replacing them with versions that return
  81 "File::stat" objects.  This object has methods that
  82 return the similarly named structure field name from the
  83 stat(2) function; namely,
  84 dev,
  85 ino,
  86 mode,
  87 nlink,
  88 uid,
  89 gid,
  90 rdev,
  91 size,
  92 atime,
  93 mtime,
  94 ctime,
  95 blksize,
  96 and
  97 blocks.
  98
  99 You may also import all the structure fields directly into your namespace
 100 as regular variables using the :FIELDS import tag.  (Note that this still
 101 overrides your stat() and lstat() functions.)  Access these fields as
 102 variables named with a preceding C<st_> in front their method names.
 103 Thus, C<$stat_obj-E<gt>dev()> corresponds to $st_dev if you import
 104 the fields.
 105
 106 To access this functionality without the core overrides,
 107 pass the C<use> an empty import list, and then access
 108 function functions with their full qualified names.
 109 On the other hand, the built-ins are still available
 110 via the C<CORE::> pseudo-package.
 111
 112 =head1 NOTE
 113
 114 While this class is currently implemented using the Class::Struct
 115 module to build a struct-like class, you shouldn't rely upon this.
 116
 117 =head1 AUTHOR
 118
 119 Tom Christiansen