lib/File/Spec/VMS.pm

   1 package File::Spec::VMS;
   2
   3 use strict;
   4 use vars qw(@ISA $VERSION);
   5 require File::Spec::Unix;
   6
   7 $VERSION = '1.1';
   8
   9 @ISA = qw(File::Spec::Unix);
  10
  11 use Cwd;
  12 use File::Basename;
  13 use VMS::Filespec;
  14
  15 =head1 NAME
  16
  17 File::Spec::VMS - methods for VMS file specs
  18
  19 =head1 SYNOPSIS
  20
  21  require File::Spec::VMS; # Done internally by File::Spec if needed
  22
  23 =head1 DESCRIPTION
  24
  25 See File::Spec::Unix for a documentation of the methods provided
  26 there. This package overrides the implementation of these methods, not
  27 the semantics.
  28
  29 =over 4
  30
  31 =item eliminate_macros
  32
  33 Expands MM[KS]/Make macros in a text string, using the contents of
  34 identically named elements of C<%$self>, and returns the result
  35 as a file specification in Unix syntax.
  36
  37 =cut
  38
  39 sub eliminate_macros {
  40     my($self,$path) = @_;
  41     return '' unless $path;
  42     $self = {} unless ref $self;
  43
  44     if ($path =~ /\s/) {
  45       return join ' ', map { $self->eliminate_macros($_) } split /\s+/, $path;
  46     }
  47
  48     my($npath) = unixify($path);
  49     my($complex) = 0;
  50     my($head,$macro,$tail);
  51
  52     # perform m##g in scalar context so it acts as an iterator
  53     while ($npath =~ m#(.*?)\$\((\S+?)\)(.*)#gs) {
  54         if ($self->{$2}) {
  55             ($head,$macro,$tail) = ($1,$2,$3);
  56             if (ref $self->{$macro}) {
  57                 if (ref $self->{$macro} eq 'ARRAY') {
  58                     $macro = join ' ', @{$self->{$macro}};
  59                 }
  60                 else {
  61                     print "Note: can't expand macro \$($macro) containing ",ref($self->{$macro}),
  62                           "\n\t(using MMK-specific deferred substitutuon; MMS will break)\n";
  63                     $macro = "\cB$macro\cB";
  64                     $complex = 1;
  65                 }
  66             }
  67             else { ($macro = unixify($self->{$macro})) =~ s#/\Z(?!\n)##; }
  68             $npath = "$head$macro$tail";
  69         }
  70     }
  71     if ($complex) { $npath =~ s#\cB(.*?)\cB#\${$1}#gs; }
  72     $npath;
  73 }
  74
  75 =item fixpath
  76
  77 Catchall routine to clean up problem MM[SK]/Make macros.  Expands macros
  78 in any directory specification, in order to avoid juxtaposing two
  79 VMS-syntax directories when MM[SK] is run.  Also expands expressions which
  80 are all macro, so that we can tell how long the expansion is, and avoid
  81 overrunning DCL's command buffer when MM[KS] is running.
  82
  83 If optional second argument has a TRUE value, then the return string is
  84 a VMS-syntax directory specification, if it is FALSE, the return string
  85 is a VMS-syntax file specification, and if it is not specified, fixpath()
  86 checks to see whether it matches the name of a directory in the current
  87 default directory, and returns a directory or file specification accordingly.
  88
  89 =cut
  90
  91 sub fixpath {
  92     my($self,$path,$force_path) = @_;
  93     return '' unless $path;
  94     $self = bless {} unless ref $self;
  95     my($fixedpath,$prefix,$name);
  96
  97     if ($path =~ /\s/) {
  98       return join ' ',
  99              map { $self->fixpath($_,$force_path) }
 100              split /\s+/, $path;
 101     }
 102
 103     if ($path =~ m#^\$\([^\)]+\)\Z(?!\n)#s || $path =~ m#[/:>\]]#) {
 104         if ($force_path or $path =~ /(?:DIR\)|\])\Z(?!\n)/) {
 105             $fixedpath = vmspath($self->eliminate_macros($path));
 106         }
 107         else {
 108             $fixedpath = vmsify($self->eliminate_macros($path));
 109         }
 110     }
 111     elsif ((($prefix,$name) = ($path =~ m#^\$\(([^\)]+)\)(.+)#s)) && $self->{$prefix}) {
 112         my($vmspre) = $self->eliminate_macros("\$($prefix)");
 113         # is it a dir or just a name?
 114         $vmspre = ($vmspre =~ m|/| or $prefix =~ /DIR\Z(?!\n)/) ? vmspath($vmspre) : '';
 115         $fixedpath = ($vmspre ? $vmspre : $self->{$prefix}) . $name;
 116         $fixedpath = vmspath($fixedpath) if $force_path;
 117     }
 118     else {
 119         $fixedpath = $path;
 120         $fixedpath = vmspath($fixedpath) if $force_path;
 121     }
 122     # No hints, so we try to guess
 123     if (!defined($force_path) and $fixedpath !~ /[:>(.\]]/) {
 124         $fixedpath = vmspath($fixedpath) if -d $fixedpath;
 125     }
 126
 127     # Trim off root dirname if it's had other dirs inserted in front of it.
 128     $fixedpath =~ s/\.000000([\]>])/$1/;
 129     # Special case for VMS absolute directory specs: these will have had device
 130     # prepended during trip through Unix syntax in eliminate_macros(), since
 131     # Unix syntax has no way to express "absolute from the top of this device's
 132     # directory tree".
 133     if ($path =~ /^[\[>][^.\-]/) { $fixedpath =~ s/^[^\[<]+//; }
 134     $fixedpath;
 135 }
 136
 137 =back
 138
 139 =head2 Methods always loaded
 140
 141 =over 4
 142
 143 =item canonpath (override)
 144
 145 Removes redundant portions of file specifications according to VMS syntax.
 146
 147 =cut
 148
 149 sub canonpath {
 150     my($self,$path) = @_;
 151
 152     if ($path =~ m|/|) { # Fake Unix
 153       my $pathify = $path =~ m|/\Z(?!\n)|;
 154       $path = $self->SUPER::canonpath($path);
 155       if ($pathify) { return vmspath($path); }
 156       else          { return vmsify($path);  }
 157     }
 158     else {
 159       $path =~ s-\]\[--g;  $path =~ s/><//g;            # foo.][bar       ==> foo.bar
 160       $path =~ s/([\[<])000000\./$1/;                   # [000000.foo     ==> [foo
 161       $path =~ s/([^-]+)\.000000([\]\>])/$1$2/;         # foo.000000]     ==> foo]
 162       1 while $path =~ s{([\[<-])\.-}{$1-};             # [.-.-           ==> [--
 163       $path =~ s/\.[^\[<\.]+\.-([\]\>])/$1/;            # bar.foo.-]      ==> bar]
 164       $path =~ s/([\[<])(-+)/$1 . "\cx" x length($2)/e; # encode leading '-'s
 165       $path =~ s/([\[<\.])([^\[<\.\cx]+)\.-\.?/$1/g;    # bar.-.foo       ==> foo
 166       $path =~ s/([\[<])(\cx+)/$1 . '-' x length($2)/e; # then decode
 167       return $path;
 168     }
 169 }
 170
 171 =item catdir
 172
 173 Concatenates a list of file specifications, and returns the result as a
 174 VMS-syntax directory specification.  No check is made for "impossible"
 175 cases (e.g. elements other than the first being absolute filespecs).
 176
 177 =cut
 178
 179 sub catdir {
 180     my ($self,@dirs) = @_;
 181     my $dir = pop @dirs;
 182     @dirs = grep($_,@dirs);
 183     my $rslt;
 184     if (@dirs) {
 185         my $path = (@dirs == 1 ? $dirs[0] : $self->catdir(@dirs));
 186         my ($spath,$sdir) = ($path,$dir);
 187         $spath =~ s/\.dir\Z(?!\n)//; $sdir =~ s/\.dir\Z(?!\n)//;
 188         $sdir = $self->eliminate_macros($sdir) unless $sdir =~ /^[\w\-]+\Z(?!\n)/s;
 189         $rslt = $self->fixpath($self->eliminate_macros($spath)."/$sdir",1);
 190
 191         # Special case for VMS absolute directory specs: these will have had device
 192         # prepended during trip through Unix syntax in eliminate_macros(), since
 193         # Unix syntax has no way to express "absolute from the top of this device's
 194         # directory tree".
 195         if ($spath =~ /^[\[<][^.\-]/s) { $rslt =~ s/^[^\[<]+//s; }
 196     }
 197     else {
 198         if    (not defined $dir or not length $dir) { $rslt = ''; }
 199         elsif ($dir =~ /^\$\([^\)]+\)\Z(?!\n)/s)          { $rslt = $dir; }
 200         else                                        { $rslt = vmspath($dir); }
 201     }
 202     return $self->canonpath($rslt);
 203 }
 204
 205 =item catfile
 206
 207 Concatenates a list of file specifications, and returns the result as a
 208 VMS-syntax file specification.
 209
 210 =cut
 211
 212 sub catfile {
 213     my ($self,@files) = @_;
 214     my $file = pop @files;
 215     @files = grep($_,@files);
 216     my $rslt;
 217     if (@files) {
 218         my $path = (@files == 1 ? $files[0] : $self->catdir(@files));
 219         my $spath = $path;
 220         $spath =~ s/\.dir\Z(?!\n)//;
 221         if ($spath =~ /^[^\)\]\/:>]+\)\Z(?!\n)/s && basename($file) eq $file) {
 222             $rslt = "$spath$file";
 223         }
 224         else {
 225             $rslt = $self->eliminate_macros($spath);
 226             $rslt = vmsify($rslt.($rslt ? '/' : '').unixify($file));
 227         }
 228     }
 229     else { $rslt = (defined($file) && length($file)) ? vmsify($file) : ''; }
 230     return $self->canonpath($rslt);
 231 }
 232
 233
 234 =item curdir (override)
 235
 236 Returns a string representation of the current directory: '[]'
 237
 238 =cut
 239
 240 sub curdir {
 241     return '[]';
 242 }
 243
 244 =item devnull (override)
 245
 246 Returns a string representation of the null device: '_NLA0:'
 247
 248 =cut
 249
 250 sub devnull {
 251     return "_NLA0:";
 252 }
 253
 254 =item rootdir (override)
 255
 256 Returns a string representation of the root directory: 'SYS$DISK:[000000]'
 257
 258 =cut
 259
 260 sub rootdir {
 261     return 'SYS$DISK:[000000]';
 262 }
 263
 264 =item tmpdir (override)
 265
 266 Returns a string representation of the first writable directory
 267 from the following list or '' if none are writable:
 268
 269     sys$scratch:
 270     $ENV{TMPDIR}
 271
 272 =cut
 273
 274 my $tmpdir;
 275 sub tmpdir {
 276     return $tmpdir if defined $tmpdir;
 277     foreach ('sys$scratch:', $ENV{TMPDIR}) {
 278         next unless defined && -d && -w _;
 279         $tmpdir = $_;
 280         last;
 281     }
 282     $tmpdir = '' unless defined $tmpdir;
 283     return $tmpdir;
 284 }
 285
 286 =item updir (override)
 287
 288 Returns a string representation of the parent directory: '[-]'
 289
 290 =cut
 291
 292 sub updir {
 293     return '[-]';
 294 }
 295
 296 =item case_tolerant (override)
 297
 298 VMS file specification syntax is case-tolerant.
 299
 300 =cut
 301
 302 sub case_tolerant {
 303     return 1;
 304 }
 305
 306 =item path (override)
 307
 308 Translate logical name DCL$PATH as a searchlist, rather than trying
 309 to C<split> string value of C<$ENV{'PATH'}>.
 310
 311 =cut
 312
 313 sub path {
 314     my (@dirs,$dir,$i);
 315     while ($dir = $ENV{'DCL$PATH;' . $i++}) { push(@dirs,$dir); }
 316     return @dirs;
 317 }
 318
 319 =item file_name_is_absolute (override)
 320
 321 Checks for VMS directory spec as well as Unix separators.
 322
 323 =cut
 324
 325 sub file_name_is_absolute {
 326     my ($self,$file) = @_;
 327     # If it's a logical name, expand it.
 328     $file = $ENV{$file} while $file =~ /^[\w\$\-]+\Z(?!\n)/s && $ENV{$file};
 329     return scalar($file =~ m!^/!s             ||
 330                   $file =~ m![<\[][^.\-\]>]!  ||
 331                   $file =~ /:[^<\[]/);
 332 }
 333
 334 =item splitpath (override)
 335
 336 Splits using VMS syntax.
 337
 338 =cut
 339
 340 sub splitpath {
 341     my($self,$path) = @_;
 342     my($dev,$dir,$file) = ('','','');
 343
 344     vmsify($path) =~ /(.+:)?([\[<].*[\]>])?(.*)/s;
 345     return ($1 || '',$2 || '',$3);
 346 }
 347
 348 =item splitdir (override)
 349
 350 Split dirspec using VMS syntax.
 351
 352 =cut
 353
 354 sub splitdir {
 355     my($self,$dirspec) = @_;
 356     $dirspec =~ s/\]\[//g;  $dirspec =~ s/\-\-/-.-/g;
 357     $dirspec = "[$dirspec]" unless $dirspec =~ /[\[<]/; # make legal
 358     my(@dirs) = split('\.', vmspath($dirspec));
 359     $dirs[0] =~ s/^[\[<]//s;  $dirs[-1] =~ s/[\]>]\Z(?!\n)//s;
 360     @dirs;
 361 }
 362
 363
 364 =item catpath (override)
 365
 366 Construct a complete filespec using VMS syntax
 367
 368 =cut
 369
 370 sub catpath {
 371     my($self,$dev,$dir,$file) = @_;
 372     if ($dev =~ m|^/+([^/]+)|) { $dev = "$1:"; }
 373     else { $dev .= ':' unless $dev eq '' or $dev =~ /:\Z(?!\n)/; }
 374     if (length($dev) or length($dir)) {
 375       $dir = "[$dir]" unless $dir =~ /[\[<\/]/;
 376       $dir = vmspath($dir);
 377     }
 378     "$dev$dir$file";
 379 }
 380
 381 =item abs2rel (override)
 382
 383 Use VMS syntax when converting filespecs.
 384
 385 =cut
 386
 387 sub abs2rel {
 388     my $self = shift;
 389
 390     return vmspath(File::Spec::Unix::abs2rel( $self, @_ ))
 391         if ( join( '', @_ ) =~ m{/} ) ;
 392
 393     my($path,$base) = @_;
 394
 395     # Note: we use '/' to glue things together here, then let canonpath()
 396     # clean them up at the end.
 397
 398     # Clean up $path
 399     if ( ! $self->file_name_is_absolute( $path ) ) {
 400         $path = $self->rel2abs( $path ) ;
 401     }
 402     else {
 403         $path = $self->canonpath( $path ) ;
 404     }
 405
 406     # Figure out the effective $base and clean it up.
 407     if ( !defined( $base ) || $base eq '' ) {
 408         $base = cwd() ;
 409     }
 410     elsif ( ! $self->file_name_is_absolute( $base ) ) {
 411         $base = $self->rel2abs( $base ) ;
 412     }
 413     else {
 414         $base = $self->canonpath( $base ) ;
 415     }
 416
 417     # Split up paths
 418     my ( $path_directories, $path_file ) =
 419         ($self->splitpath( $path, 1 ))[1,2] ;
 420
 421     $path_directories = $1
 422         if $path_directories =~ /^\[(.*)\]\Z(?!\n)/s ;
 423
 424     my $base_directories = ($self->splitpath( $base, 1 ))[1] ;
 425
 426     $base_directories = $1
 427         if $base_directories =~ /^\[(.*)\]\Z(?!\n)/s ;
 428
 429     # Now, remove all leading components that are the same
 430     my @pathchunks = $self->splitdir( $path_directories );
 431     my @basechunks = $self->splitdir( $base_directories );
 432
 433     while ( @pathchunks &&
 434             @basechunks &&
 435             lc( $pathchunks[0] ) eq lc( $basechunks[0] )
 436           ) {
 437         shift @pathchunks ;
 438         shift @basechunks ;
 439     }
 440
 441     # @basechunks now contains the directories to climb out of,
 442     # @pathchunks now has the directories to descend in to.
 443     $path_directories = '-.' x @basechunks . join( '.', @pathchunks ) ;
 444     $path_directories =~ s{\.\Z(?!\n)}{} ;
 445     return $self->canonpath( $self->catpath( '', $path_directories, $path_file ) ) ;
 446 }
 447
 448
 449 =item rel2abs (override)
 450
 451 Use VMS syntax when converting filespecs.
 452
 453 =cut
 454
 455 sub rel2abs {
 456     my $self = shift ;
 457     return vmspath(File::Spec::Unix::rel2abs( $self, @_ ))
 458         if ( join( '', @_ ) =~ m{/} ) ;
 459
 460     my ($path,$base ) = @_;
 461     # Clean up and split up $path
 462     if ( ! $self->file_name_is_absolute( $path ) ) {
 463         # Figure out the effective $base and clean it up.
 464         if ( !defined( $base ) || $base eq '' ) {
 465             $base = cwd() ;
 466         }
 467         elsif ( ! $self->file_name_is_absolute( $base ) ) {
 468             $base = $self->rel2abs( $base ) ;
 469         }
 470         else {
 471             $base = $self->canonpath( $base ) ;
 472         }
 473
 474         # Split up paths
 475         my ( $path_directories, $path_file ) =
 476             ($self->splitpath( $path ))[1,2] ;
 477
 478         my ( $base_volume, $base_directories ) =
 479             $self->splitpath( $base ) ;
 480
 481         $path_directories = '' if $path_directories eq '[]' ||
 482                                   $path_directories eq '<>';
 483         my $sep = '' ;
 484         $sep = '.'
 485             if ( $base_directories =~ m{[^.\]>]\Z(?!\n)} &&
 486                  $path_directories =~ m{^[^.\[<]}s
 487             ) ;
 488         $base_directories = "$base_directories$sep$path_directories";
 489         $base_directories =~ s{\.?[\]>][\[<]\.?}{.};
 490
 491         $path = $self->catpath( $base_volume, $base_directories, $path_file );
 492    }
 493
 494     return $self->canonpath( $path ) ;
 495 }
 496
 497
 498 =back
 499
 500 =head1 SEE ALSO
 501
 502 L<File::Spec>
 503
 504 =cut
 505
 506 1;