lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even
  18 if your C<mkdir> kernel call won't create more than one level of directory at
  19 a time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined
  42 using the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled.  (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted.  Symlinks are
  77 treated as ordinary files.
  78
  79 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  80 in the face of failure or interruption.  Files and directories which
  81 were not deleted may be left with permissions reset to allow world
  82 read and write access.  Note also that the occurrence of errors in
  83 rmtree can be determined I<only> by trapping diagnostic messages
  84 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  85 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  86 in situations where security is an issue.
  87
  88 =head1 AUTHORS
  89
  90 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  91 Charles Bailey <F<bailey@newman.upenn.edu>>
  92
  93 =head1 REVISION
  94
  95 Current $VERSION is 1.0401.
  96
  97 =cut
  98
  99 use Carp;
 100 use File::Basename ();
 101 use DirHandle ();
 102 use Exporter ();
 103 use strict;
 104
 105 use vars qw( $VERSION @ISA @EXPORT );
 106 $VERSION = "1.0401";
 107 @ISA = qw( Exporter );
 108 @EXPORT = qw( mkpath rmtree );
 109
 110 my $Is_VMS = $^O eq 'VMS';
 111
 112 # These OSes complain if you want to remove a file that you have no
 113 # write permission to:
 114 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32'
 115                        || $^O eq 'amigaos');
 116
 117 sub mkpath {
 118     my($paths, $verbose, $mode) = @_;
 119     # $paths   -- either a path string or ref to list of paths
 120     # $verbose -- optional print "mkdir $path" for each directory created
 121     # $mode    -- optional permissions, defaults to 0777
 122     local($")="/";
 123     $mode = 0777 unless defined($mode);
 124     $paths = [$paths] unless ref $paths;
 125     my(@created,$path);
 126     foreach $path (@$paths) {
 127         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:$/; # feature of CRT
 128         next if -d $path;
 129         # Logic wants Unix paths, so go with the flow.
 130         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 131         my $parent = File::Basename::dirname($path);
 132         # Allow for creation of new logical filesystems under VMS
 133         if (not $Is_VMS or $parent !~ m:/[^/]+/000000/?:) {
 134             push(@created,mkpath($parent, $verbose, $mode)) unless (-d $parent);
 135         }
 136         print "mkdir $path\n" if $verbose;
 137         unless (mkdir($path,$mode)) {
 138             # allow for another process to have created it meanwhile
 139             croak "mkdir $path: $!" unless -d $path;
 140         }
 141         push(@created, $path);
 142     }
 143     @created;
 144 }
 145
 146 sub rmtree {
 147     my($roots, $verbose, $safe) = @_;
 148     my(@files);
 149     my($count) = 0;
 150     $roots = [$roots] unless ref $roots;
 151     $verbose ||= 0;
 152     $safe ||= 0;
 153
 154     my($root);
 155     foreach $root (@{$roots}) {
 156         $root =~ s#/$##;
 157         (undef, undef, my $rp) = lstat $root or next;
 158         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 159         if ( -d _ ) {
 160             # notabene: 0777 is for making readable in the first place,
 161             # it's also intended to change it to writable in case we have
 162             # to recurse in which case we are better than rm -rf for
 163             # subtrees with strange permissions
 164             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 165               or carp "Can't make directory $root read+writeable: $!"
 166                 unless $safe;
 167
 168             my $d = DirHandle->new($root)
 169               or carp "Can't read $root: $!";
 170             @files = $d->read;
 171             $d->close;
 172
 173             # Deleting large numbers of files from VMS Files-11 filesystems
 174             # is faster if done in reverse ASCIIbetical order
 175             @files = reverse @files if $Is_VMS;
 176             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 177             @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 178             $count += rmtree(\@files,$verbose,$safe);
 179             if ($safe &&
 180                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 181                 print "skipped $root\n" if $verbose;
 182                 next;
 183             }
 184             chmod 0777, $root
 185               or carp "Can't make directory $root writeable: $!"
 186                 if $force_writeable;
 187             print "rmdir $root\n" if $verbose;
 188             if (rmdir $root) {
 189                 ++$count;
 190             }
 191             else {
 192                 carp "Can't remove directory $root: $!";
 193                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 194                     or carp("and can't restore permissions to "
 195                             . sprintf("0%o",$rp) . "\n");
 196             }
 197         }
 198         else {
 199             if ($safe &&
 200                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 201                 print "skipped $root\n" if $verbose;
 202                 next;
 203             }
 204             chmod 0666, $root
 205               or carp "Can't make file $root writeable: $!"
 206                 if $force_writeable;
 207             print "unlink $root\n" if $verbose;
 208             # delete all versions under VMS
 209             for (;;) {
 210                 unless (unlink $root) {
 211                     carp "Can't unlink file $root: $!";
 212                     if ($force_writeable) {
 213                         chmod $rp, $root
 214                             or carp("and can't restore permissions to "
 215                                     . sprintf("0%o",$rp) . "\n");
 216                     }
 217                     last;
 218                 }
 219                 ++$count;
 220                 last unless $Is_VMS && lstat $root;
 221             }
 222         }
 223     }
 224
 225     $count;
 226 }
 227
 228 1;