lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even
  18 if your C<mkdir> kernel call won't create more than one level of directory at
  19 a time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined
  42 using the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled.  (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted.  Symlinks are
  77 treated as ordinary files.
  78
  79 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  80 in the face of failure or interruption.  Files and directories which
  81 were not deleted may be left with permissions reset to allow world
  82 read and write access.  Note also that the occurrence of errors in
  83 rmtree can be determined I<only> by trapping diagnostic messages
  84 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  85 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  86 in situations where security is an issue.
  87
  88 =head1 AUTHORS
  89
  90 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  91 Charles Bailey <F<bailey@genetics.upenn.edu>>
  92
  93 =head1 REVISION
  94
  95 Current $VERSION is 1.03.
  96
  97 =cut
  98
  99 use Carp;
 100 use File::Basename ();
 101 use DirHandle ();
 102 use Exporter ();
 103 use strict;
 104
 105 use vars qw( $VERSION @ISA @EXPORT );
 106 $VERSION = "1.03";
 107 @ISA = qw( Exporter );
 108 @EXPORT = qw( mkpath rmtree );
 109
 110 my $Is_VMS = $^O eq 'VMS';
 111
 112 # These OSes complain if you want to remove a file that you have no
 113 # write permission to:
 114 my $force_writeable = ($^O eq 'os2' || $^O eq 'msdos' || $^O eq 'MSWin32'
 115                        || $^O eq 'amigaos');
 116
 117 sub mkpath {
 118     my($paths, $verbose, $mode) = @_;
 119     # $paths   -- either a path string or ref to list of paths
 120     # $verbose -- optional print "mkdir $path" for each directory created
 121     # $mode    -- optional permissions, defaults to 0777
 122     local($")="/";
 123     $mode = 0777 unless defined($mode);
 124     $paths = [$paths] unless ref $paths;
 125     my(@created,$path);
 126     foreach $path (@$paths) {
 127         next if -d $path;
 128         # Logic wants Unix paths, so go with the flow.
 129         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 130         my $parent = File::Basename::dirname($path);
 131         push(@created,mkpath($parent, $verbose, $mode)) unless (-d $parent);
 132         print "mkdir $path\n" if $verbose;
 133         mkdir($path,$mode) || croak "mkdir $path: $!";
 134         push(@created, $path);
 135     }
 136     @created;
 137 }
 138
 139 sub rmtree {
 140     my($roots, $verbose, $safe) = @_;
 141     my(@files);
 142     my($count) = 0;
 143     $roots = [$roots] unless ref $roots;
 144     $verbose ||= 0;
 145     $safe ||= 0;
 146
 147     my($root);
 148     foreach $root (@{$roots}) {
 149         $root =~ s#/$##;
 150         next unless -e $root;
 151         if (not -l $root and -d _) {
 152             # notabene: 0777 is for making readable in the first place,
 153             # it's also intended to change it to writable in case we have
 154             # to recurse in which case we are better than rm -rf for
 155             # subtrees with strange permissions
 156             my $rp = (stat(_))[2] & 0777;  #Is this portable???
 157             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 158               or carp "Can't make directory $root read+writeable: $!"
 159                 unless $safe;
 160
 161             my $d = DirHandle->new($root)
 162               or carp "Can't read $root: $!";
 163             @files = $d->read;
 164             $d->close;
 165
 166             # Deleting large numbers of files from VMS Files-11 filesystems
 167             # is faster if done in reverse ASCIIbetical order
 168             @files = reverse @files if $Is_VMS;
 169             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 170             @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 171             $count += rmtree(\@files,$verbose,$safe);
 172             if ($safe &&
 173                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 174                 print "skipped $root\n" if $verbose;
 175                 next;
 176             }
 177             chmod 0777, $root
 178               or carp "Can't make directory $root writeable: $!"
 179                 if $force_writeable;
 180             print "rmdir $root\n" if $verbose;
 181             if (rmdir $root) {
 182                 ++$count;
 183             }
 184             else {
 185                 carp "Can't remove directory $root: $!";
 186                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 187                     or carp("and can't restore permissions to "
 188                             . sprintf("0%o",$rp) . "\n");
 189             }
 190         }
 191         else {
 192             if ($safe &&
 193                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 194                 print "skipped $root\n" if $verbose;
 195                 next;
 196             }
 197             my $rp = (stat(_))[2] & 0777;  #Is this portable???
 198             chmod 0666, $root
 199               or carp "Can't make file $root writeable: $!"
 200                 if $force_writeable;
 201             print "unlink $root\n" if $verbose;
 202             # delete all versions under VMS
 203             while (-e $root || -l $root) {
 204                 if (unlink $root) {
 205                     ++$count;
 206                 }
 207                 else {
 208                     carp "Can't unlink file $root: $!";
 209                     if ($force_writeable) {
 210                         chmod $rp, $root
 211                             or carp("and can't restore permissions to "
 212                                     . sprintf("0%o",$rp) . "\n");
 213                     }
 214                 }
 215             }
 216         }
 217     }
 218
 219     $count;
 220 }
 221
 222 1;