lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove directory trees
   6
   7 =head1 SYNOPSIS
   8
   9     use File::Path;
  10
  11     mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
  12     rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
  13
  14 =head1 DESCRIPTION
  15
  16 The C<mkpath> function provides a convenient way to create directories, even
  17 if your C<mkdir> kernel call won't create more than one level of directory at
  18 a time.  C<mkpath> takes three arguments:
  19
  20 =over 4
  21
  22 =item *
  23
  24 the name of the path to create, or a reference
  25 to a list of paths to create,
  26
  27 =item *
  28
  29 a boolean value, which if TRUE will cause C<mkpath>
  30 to print the name of each directory as it is created
  31 (defaults to FALSE), and
  32
  33 =item *
  34
  35 the numeric mode to use when creating the directories
  36 (defaults to 0777)
  37
  38 =back
  39
  40 It returns a list of all directories (including intermediates, determined
  41 using the Unix '/' separator) created.
  42
  43 Similarly, the C<rmtree> function provides a convenient way to delete a
  44 subtree from the directory structure, much like the Unix command C<rm -r>.
  45 C<rmtree> takes three arguments:
  46
  47 =over 4
  48
  49 =item *
  50
  51 the root of the subtree to delete, or a reference to
  52 a list of roots.  All of the files and directories
  53 below each root, as well as the roots themselves,
  54 will be deleted.
  55
  56 =item *
  57
  58 a boolean value, which if TRUE will cause C<rmtree> to
  59 print a message each time it examines a file, giving the
  60 name of the file, and indicating whether it's using C<rmdir>
  61 or C<unlink> to remove it, or that it's skipping it.
  62 (defaults to FALSE)
  63
  64 =item *
  65
  66 a boolean value, which if TRUE will cause C<rmtree> to
  67 skip any files to which you do not have delete access
  68 (if running under VMS) or write access (if running
  69 under another OS).  This will change in the future when
  70 a criterion for 'delete permission' under OSs other
  71 than VMS is settled.  (defaults to FALSE)
  72
  73 =back
  74
  75 It returns the number of files successfully deleted.  Symlinks are
  76 treated as ordinary files.
  77
  78 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  79 in the face of failure or interruption.  Files and directories which
  80 were not deleted may be left with permissions reset to allow world
  81 read and write access.  Note also that the occurrence of errors in
  82 rmtree can be determined I<only> by trapping diagnostic messages
  83 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  84 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  85 in situations where security is an issue.
  86
  87 =head1 AUTHORS
  88
  89 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  90 Charles Bailey <F<bailey@newman.upenn.edu>>
  91
  92 =cut
  93
  94 use 5.005_64;
  95 use Carp;
  96 use File::Basename ();
  97 use Exporter ();
  98 use strict;
  99
 100 our $VERSION = "1.0403";
 101 our @ISA = qw( Exporter );
 102 our @EXPORT = qw( mkpath rmtree );
 103
 104 my $Is_VMS = $^O eq 'VMS';
 105
 106 # These OSes complain if you want to remove a file that you have no
 107 # write permission to:
 108 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32'
 109                        || $^O eq 'amigaos');
 110
 111 sub mkpath {
 112     my($paths, $verbose, $mode) = @_;
 113     # $paths   -- either a path string or ref to list of paths
 114     # $verbose -- optional print "mkdir $path" for each directory created
 115     # $mode    -- optional permissions, defaults to 0777
 116     local($")="/";
 117     $mode = 0777 unless defined($mode);
 118     $paths = [$paths] unless ref $paths;
 119     my(@created,$path);
 120     foreach $path (@$paths) {
 121         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:\z/s; # feature of CRT
 122         next if -d $path;
 123         # Logic wants Unix paths, so go with the flow.
 124         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 125         my $parent = File::Basename::dirname($path);
 126         # Allow for creation of new logical filesystems under VMS
 127         if (not $Is_VMS or $parent !~ m:/[^/]+/000000/?:) {
 128             unless (-d $parent or $path eq $parent) {
 129                 push(@created,mkpath($parent, $verbose, $mode));
 130             }
 131         }
 132         print "mkdir $path\n" if $verbose;
 133         unless (mkdir($path,$mode)) {
 134             my $e = $!;
 135             # allow for another process to have created it meanwhile
 136             croak "mkdir $path: $e" unless -d $path;
 137         }
 138         push(@created, $path);
 139     }
 140     @created;
 141 }
 142
 143 sub rmtree {
 144     my($roots, $verbose, $safe) = @_;
 145     my(@files);
 146     my($count) = 0;
 147     $verbose ||= 0;
 148     $safe ||= 0;
 149
 150     if ( defined($roots) && length($roots) ) {
 151       $roots = [$roots] unless ref $roots;
 152     }
 153     else {
 154       carp "No root path(s) specified\n";
 155       return 0;
 156     }
 157
 158     my($root);
 159     foreach $root (@{$roots}) {
 160         $root =~ s#/\z##;
 161         (undef, undef, my $rp) = lstat $root or next;
 162         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 163         if ( -d _ ) {
 164             # notabene: 0777 is for making readable in the first place,
 165             # it's also intended to change it to writable in case we have
 166             # to recurse in which case we are better than rm -rf for
 167             # subtrees with strange permissions
 168             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 169               or carp "Can't make directory $root read+writeable: $!"
 170                 unless $safe;
 171
 172             if (opendir my $d, $root) {
 173                 @files = readdir $d;
 174                 closedir $d;
 175             }
 176             else {
 177                 carp "Can't read $root: $!";
 178                 @files = ();
 179             }
 180
 181             # Deleting large numbers of files from VMS Files-11 filesystems
 182             # is faster if done in reverse ASCIIbetical order
 183             @files = reverse @files if $Is_VMS;
 184             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir\z## if $Is_VMS;
 185             @files = map("$root/$_", grep $_!~/^\.{1,2}\z/s,@files);
 186             $count += rmtree(\@files,$verbose,$safe);
 187             if ($safe &&
 188                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 189                 print "skipped $root\n" if $verbose;
 190                 next;
 191             }
 192             chmod 0777, $root
 193               or carp "Can't make directory $root writeable: $!"
 194                 if $force_writeable;
 195             print "rmdir $root\n" if $verbose;
 196             if (rmdir $root) {
 197                 ++$count;
 198             }
 199             else {
 200                 carp "Can't remove directory $root: $!";
 201                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 202                     or carp("and can't restore permissions to "
 203                             . sprintf("0%o",$rp) . "\n");
 204             }
 205         }
 206         else {
 207             if ($safe &&
 208                 ($Is_VMS ? !&VMS::Filespec::candelete($root)
 209                          : !(-l $root || -w $root)))
 210             {
 211                 print "skipped $root\n" if $verbose;
 212                 next;
 213             }
 214             chmod 0666, $root
 215               or carp "Can't make file $root writeable: $!"
 216                 if $force_writeable;
 217             print "unlink $root\n" if $verbose;
 218             # delete all versions under VMS
 219             for (;;) {
 220                 unless (unlink $root) {
 221                     carp "Can't unlink file $root: $!";
 222                     if ($force_writeable) {
 223                         chmod $rp, $root
 224                             or carp("and can't restore permissions to "
 225                                     . sprintf("0%o",$rp) . "\n");
 226                     }
 227                     last;
 228                 }
 229                 ++$count;
 230                 last unless $Is_VMS && lstat $root;
 231             }
 232         }
 233     }
 234
 235     $count;
 236 }
 237
 238 1;