lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even
  18 if your C<mkdir> kernel call won't create more than one level of directory at
  19 a time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined
  42 using the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled.  (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted.  Symlinks are
  77 treated as ordinary files.
  78
  79 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  80 in the face of failure or interruption.  Files and directories which
  81 were not deleted may be left with permissions reset to allow world
  82 read and write access.  Note also that the occurrence of errors in
  83 rmtree can be determined I<only> by trapping diagnostic messages
  84 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  85 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  86 in situations where security is an issue.
  87
  88 =head1 AUTHORS
  89
  90 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  91 Charles Bailey <F<bailey@newman.upenn.edu>>
  92
  93 =cut
  94
  95 use Carp;
  96 use File::Basename ();
  97 use DirHandle ();
  98 use Exporter ();
  99 use strict;
 100
 101 use vars qw( $VERSION @ISA @EXPORT );
 102 $VERSION = "1.0402";
 103 @ISA = qw( Exporter );
 104 @EXPORT = qw( mkpath rmtree );
 105
 106 my $Is_VMS = $^O eq 'VMS';
 107
 108 # These OSes complain if you want to remove a file that you have no
 109 # write permission to:
 110 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32'
 111                        || $^O eq 'amigaos');
 112
 113 sub mkpath {
 114     my($paths, $verbose, $mode) = @_;
 115     # $paths   -- either a path string or ref to list of paths
 116     # $verbose -- optional print "mkdir $path" for each directory created
 117     # $mode    -- optional permissions, defaults to 0777
 118     local($")="/";
 119     $mode = 0777 unless defined($mode);
 120     $paths = [$paths] unless ref $paths;
 121     my(@created,$path);
 122     foreach $path (@$paths) {
 123         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:$/; # feature of CRT
 124         next if -d $path;
 125         # Logic wants Unix paths, so go with the flow.
 126         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 127         my $parent = File::Basename::dirname($path);
 128         # Allow for creation of new logical filesystems under VMS
 129         if (not $Is_VMS or $parent !~ m:/[^/]+/000000/?:) {
 130             push(@created,mkpath($parent, $verbose, $mode)) unless (-d $parent);
 131         }
 132         print "mkdir $path\n" if $verbose;
 133         unless (mkdir($path,$mode)) {
 134           my $e = $!;
 135           # allow for another process to have created it meanwhile
 136           croak "mkdir $path: $e" unless -d $path;
 137         }
 138         push(@created, $path);
 139     }
 140     @created;
 141 }
 142
 143 sub rmtree {
 144     my($roots, $verbose, $safe) = @_;
 145     my(@files);
 146     my($count) = 0;
 147     $verbose ||= 0;
 148     $safe ||= 0;
 149
 150     if ( defined($roots) && length($roots) ) {
 151       $roots = [$roots] unless ref $roots;
 152     }
 153     else {
 154       carp "No root path(s) specified\n";
 155       return 0;
 156     }
 157
 158     my($root);
 159     foreach $root (@{$roots}) {
 160         $root =~ s#/$##;
 161         (undef, undef, my $rp) = lstat $root or next;
 162         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 163         if ( -d _ ) {
 164             # notabene: 0777 is for making readable in the first place,
 165             # it's also intended to change it to writable in case we have
 166             # to recurse in which case we are better than rm -rf for
 167             # subtrees with strange permissions
 168             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 169               or carp "Can't make directory $root read+writeable: $!"
 170                 unless $safe;
 171
 172             my $d = DirHandle->new($root)
 173               or carp "Can't read $root: $!";
 174             @files = $d->read;
 175             $d->close;
 176
 177             # Deleting large numbers of files from VMS Files-11 filesystems
 178             # is faster if done in reverse ASCIIbetical order
 179             @files = reverse @files if $Is_VMS;
 180             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 181             @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 182             $count += rmtree(\@files,$verbose,$safe);
 183             if ($safe &&
 184                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 185                 print "skipped $root\n" if $verbose;
 186                 next;
 187             }
 188             chmod 0777, $root
 189               or carp "Can't make directory $root writeable: $!"
 190                 if $force_writeable;
 191             print "rmdir $root\n" if $verbose;
 192             if (rmdir $root) {
 193                 ++$count;
 194             }
 195             else {
 196                 carp "Can't remove directory $root: $!";
 197                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 198                     or carp("and can't restore permissions to "
 199                             . sprintf("0%o",$rp) . "\n");
 200             }
 201         }
 202         else {
 203             if ($safe &&
 204                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 205                 print "skipped $root\n" if $verbose;
 206                 next;
 207             }
 208             chmod 0666, $root
 209               or carp "Can't make file $root writeable: $!"
 210                 if $force_writeable;
 211             print "unlink $root\n" if $verbose;
 212             # delete all versions under VMS
 213             for (;;) {
 214                 unless (unlink $root) {
 215                     carp "Can't unlink file $root: $!";
 216                     if ($force_writeable) {
 217                         chmod $rp, $root
 218                             or carp("and can't restore permissions to "
 219                                     . sprintf("0%o",$rp) . "\n");
 220                     }
 221                     last;
 222                 }
 223                 ++$count;
 224                 last unless $Is_VMS && lstat $root;
 225             }
 226         }
 227     }
 228
 229     $count;
 230 }
 231
 232 1;