lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even
  18 if your C<mkdir> kernel call won't create more than one level of directory at
  19 a time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined
  42 using the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled. (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted. Symlinks are
  77 treated as ordinary files.
  78
  79 =head1 AUTHORS
  80
  81 Tim Bunce E<lt>F<Tim.Bunce@ig.co.uk>E<gt>
  82 Charles Bailey E<lt>F<bailey@genetics.upenn.edu>E<gt>
  83
  84 =head1 REVISION
  85
  86 Current $VERSION is 1.02.
  87
  88 =cut
  89
  90 use Carp;
  91 use File::Basename ();
  92 use DirHandle ();
  93 use Exporter ();
  94 use strict;
  95
  96 use vars qw( $VERSION @ISA @EXPORT );
  97 $VERSION = "1.02";
  98 @ISA = qw( Exporter );
  99 @EXPORT = qw( mkpath rmtree );
 100
 101 my $Is_VMS = $^O eq 'VMS';
 102
 103 # These OSes complain if you want to remove a file that you have no
 104 # write permission to:
 105 my $force_writeable = ($^O eq 'os2' || $^O eq 'msdos' || $^O eq 'MSWin32'
 106                        || $^O eq 'amigaos');
 107
 108 sub mkpath {
 109     my($paths, $verbose, $mode) = @_;
 110     # $paths   -- either a path string or ref to list of paths
 111     # $verbose -- optional print "mkdir $path" for each directory created
 112     # $mode    -- optional permissions, defaults to 0777
 113     local($")="/";
 114     $mode = 0777 unless defined($mode);
 115     $paths = [$paths] unless ref $paths;
 116     my(@created,$path);
 117     foreach $path (@$paths) {
 118         next if -d $path;
 119         # Logic wants Unix paths, so go with the flow.
 120         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 121         my $parent = File::Basename::dirname($path);
 122         push(@created,mkpath($parent, $verbose, $mode)) unless (-d $parent);
 123         print "mkdir $path\n" if $verbose;
 124         mkdir($path,$mode) || croak "mkdir $path: $!";
 125         push(@created, $path);
 126     }
 127     @created;
 128 }
 129
 130 sub rmtree {
 131     my($roots, $verbose, $safe) = @_;
 132     my(@files);
 133     my($count) = 0;
 134     $roots = [$roots] unless ref $roots;
 135     $verbose ||= 0;
 136     $safe ||= 0;
 137
 138     my($root);
 139     foreach $root (@{$roots}) {
 140         $root =~ s#/$##;
 141         $count++, next unless -e $root;
 142         if (not -l $root and -d _) {
 143             # notabene: 0777 is for making readable in the first place,
 144             # it's also intended to change it to writable in case we have
 145             # to recurse in which case we are better than rm -rf for
 146             # subtrees with strange permissions
 147             chmod 0777, $root
 148               or carp "Can't make directory $root read+writeable: $!"
 149                 unless $safe;
 150
 151             my $d = DirHandle->new($root)
 152               or carp "Can't read $root: $!";
 153             @files = $d->read;
 154             $d->close;
 155
 156             # Deleting large numbers of files from VMS Files-11 filesystems
 157             # is faster if done in reverse ASCIIbetical order
 158             @files = reverse @files if $Is_VMS;
 159             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 160             @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 161             $count += rmtree(\@files,$verbose,$safe);
 162             if ($safe &&
 163                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 164                 print "skipped $root\n" if $verbose;
 165                 next;
 166             }
 167             chmod 0777, $root
 168               or carp "Can't make directory $root writeable: $!"
 169                 if $force_writeable;
 170             print "rmdir $root\n" if $verbose;
 171             rmdir($root) && ++$count
 172               or carp "Can't remove directory $root: $!";
 173         }
 174         else {
 175             if ($safe &&
 176                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 177                 print "skipped $root\n" if $verbose;
 178                 next;
 179             }
 180             chmod 0666, $root
 181               or carp "Can't make file $root writeable: $!"
 182                 if $force_writeable;
 183             print "unlink $root\n" if $verbose;
 184             # delete all versions under VMS
 185             while (-e $root || -l $root) {
 186                 unlink($root) && ++$count
 187                   or croak "Can't unlink file $root: $!";
 188             }
 189         }
 190     }
 191
 192     $count;
 193 }
 194
 195 1;