lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove directory trees
   6
   7 =head1 SYNOPSIS
   8
   9     use File::Path;
  10
  11     mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
  12     rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
  13
  14 =head1 DESCRIPTION
  15
  16 The C<mkpath> function provides a convenient way to create directories, even
  17 if your C<mkdir> kernel call won't create more than one level of directory at
  18 a time.  C<mkpath> takes three arguments:
  19
  20 =over 4
  21
  22 =item *
  23
  24 the name of the path to create, or a reference
  25 to a list of paths to create,
  26
  27 =item *
  28
  29 a boolean value, which if TRUE will cause C<mkpath>
  30 to print the name of each directory as it is created
  31 (defaults to FALSE), and
  32
  33 =item *
  34
  35 the numeric mode to use when creating the directories
  36 (defaults to 0777)
  37
  38 =back
  39
  40 It returns a list of all directories (including intermediates, determined
  41 using the Unix '/' separator) created.
  42
  43 Similarly, the C<rmtree> function provides a convenient way to delete a
  44 subtree from the directory structure, much like the Unix command C<rm -r>.
  45 C<rmtree> takes three arguments:
  46
  47 =over 4
  48
  49 =item *
  50
  51 the root of the subtree to delete, or a reference to
  52 a list of roots.  All of the files and directories
  53 below each root, as well as the roots themselves,
  54 will be deleted.
  55
  56 =item *
  57
  58 a boolean value, which if TRUE will cause C<rmtree> to
  59 print a message each time it examines a file, giving the
  60 name of the file, and indicating whether it's using C<rmdir>
  61 or C<unlink> to remove it, or that it's skipping it.
  62 (defaults to FALSE)
  63
  64 =item *
  65
  66 a boolean value, which if TRUE will cause C<rmtree> to
  67 skip any files to which you do not have delete access
  68 (if running under VMS) or write access (if running
  69 under another OS).  This will change in the future when
  70 a criterion for 'delete permission' under OSs other
  71 than VMS is settled.  (defaults to FALSE)
  72
  73 =back
  74
  75 It returns the number of files successfully deleted.  Symlinks are
  76 treated as ordinary files.
  77
  78 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  79 in the face of failure or interruption.  Files and directories which
  80 were not deleted may be left with permissions reset to allow world
  81 read and write access.  Note also that the occurrence of errors in
  82 rmtree can be determined I<only> by trapping diagnostic messages
  83 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  84 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  85 in situations where security is an issue.
  86
  87 =head1 AUTHORS
  88
  89 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  90 Charles Bailey <F<bailey@newman.upenn.edu>>
  91
  92 =cut
  93
  94 use 5.005_64;
  95 use Carp;
  96 use File::Basename ();
  97 use DirHandle ();
  98 use Exporter ();
  99 use strict;
 100
 101 our($VERSION, @ISA, @EXPORT);
 102 $VERSION = "1.0402";
 103 @ISA = qw( Exporter );
 104 @EXPORT = qw( mkpath rmtree );
 105
 106 my $Is_VMS = $^O eq 'VMS';
 107
 108 # These OSes complain if you want to remove a file that you have no
 109 # write permission to:
 110 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32'
 111                        || $^O eq 'amigaos');
 112
 113 sub mkpath {
 114     my($paths, $verbose, $mode) = @_;
 115     # $paths   -- either a path string or ref to list of paths
 116     # $verbose -- optional print "mkdir $path" for each directory created
 117     # $mode    -- optional permissions, defaults to 0777
 118     local($")="/";
 119     $mode = 0777 unless defined($mode);
 120     $paths = [$paths] unless ref $paths;
 121     my(@created,$path);
 122     foreach $path (@$paths) {
 123         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:$/; # feature of CRT
 124         next if -d $path;
 125         # Logic wants Unix paths, so go with the flow.
 126         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 127         my $parent = File::Basename::dirname($path);
 128         # Allow for creation of new logical filesystems under VMS
 129         if (not $Is_VMS or $parent !~ m:/[^/]+/000000/?:) {
 130             unless (-d $parent or $path eq $parent) {
 131                 push(@created,mkpath($parent, $verbose, $mode));
 132             }
 133         }
 134         print "mkdir $path\n" if $verbose;
 135         unless (mkdir($path,$mode)) {
 136             my $e = $!;
 137             # allow for another process to have created it meanwhile
 138             croak "mkdir $path: $e" unless -d $path;
 139         }
 140         push(@created, $path);
 141     }
 142     @created;
 143 }
 144
 145 sub rmtree {
 146     my($roots, $verbose, $safe) = @_;
 147     my(@files);
 148     my($count) = 0;
 149     $verbose ||= 0;
 150     $safe ||= 0;
 151
 152     if ( defined($roots) && length($roots) ) {
 153       $roots = [$roots] unless ref $roots;
 154     }
 155     else {
 156       carp "No root path(s) specified\n";
 157       return 0;
 158     }
 159
 160     my($root);
 161     foreach $root (@{$roots}) {
 162         $root =~ s#/$##;
 163         (undef, undef, my $rp) = lstat $root or next;
 164         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 165         if ( -d _ ) {
 166             # notabene: 0777 is for making readable in the first place,
 167             # it's also intended to change it to writable in case we have
 168             # to recurse in which case we are better than rm -rf for
 169             # subtrees with strange permissions
 170             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 171               or carp "Can't make directory $root read+writeable: $!"
 172                 unless $safe;
 173
 174             my $d = DirHandle->new($root)
 175               or carp "Can't read $root: $!";
 176             @files = $d->read;
 177             $d->close;
 178
 179             # Deleting large numbers of files from VMS Files-11 filesystems
 180             # is faster if done in reverse ASCIIbetical order
 181             @files = reverse @files if $Is_VMS;
 182             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 183             @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 184             $count += rmtree(\@files,$verbose,$safe);
 185             if ($safe &&
 186                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 187                 print "skipped $root\n" if $verbose;
 188                 next;
 189             }
 190             chmod 0777, $root
 191               or carp "Can't make directory $root writeable: $!"
 192                 if $force_writeable;
 193             print "rmdir $root\n" if $verbose;
 194             if (rmdir $root) {
 195                 ++$count;
 196             }
 197             else {
 198                 carp "Can't remove directory $root: $!";
 199                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 200                     or carp("and can't restore permissions to "
 201                             . sprintf("0%o",$rp) . "\n");
 202             }
 203         }
 204         else {
 205             if ($safe &&
 206                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 207                 print "skipped $root\n" if $verbose;
 208                 next;
 209             }
 210             chmod 0666, $root
 211               or carp "Can't make file $root writeable: $!"
 212                 if $force_writeable;
 213             print "unlink $root\n" if $verbose;
 214             # delete all versions under VMS
 215             for (;;) {
 216                 unless (unlink $root) {
 217                     carp "Can't unlink file $root: $!";
 218                     if ($force_writeable) {
 219                         chmod $rp, $root
 220                             or carp("and can't restore permissions to "
 221                                     . sprintf("0%o",$rp) . "\n");
 222                     }
 223                     last;
 224                 }
 225                 ++$count;
 226                 last unless $Is_VMS && lstat $root;
 227             }
 228         }
 229     }
 230
 231     $count;
 232 }
 233
 234 1;