lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even if
  18 your C<mkdir> kernel call won't create more than one level of directory at a
  19 time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined using
  42 the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled. (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted. Symlinks are
  77 treated as ordinary files.
  78
  79 =head1 AUTHORS
  80
  81 Tim Bunce E<lt>F<Tim.Bunce@ig.co.uk>E<gt>
  82 Charles Bailey E<lt>F<bailey@genetics.upenn.edu>E<gt>
  83
  84 =head1 REVISION
  85
  86 This module was last revised 14-Feb-1996, for perl 5.002. $VERSION is
  87 1.01.
  88
  89 =cut
  90
  91 $VERSION = "1.01"; # That's my hobby-horse, A.K.
  92
  93 require 5.000;
  94 use Carp;
  95 require Exporter;
  96 @ISA = qw( Exporter );
  97 @EXPORT = qw( mkpath rmtree );
  98
  99 $Is_VMS = $^O eq 'VMS';
 100
 101 sub mkpath {
 102     my($paths, $verbose, $mode) = @_;
 103     # $paths   -- either a path string or ref to list of paths
 104     # $verbose -- optional print "mkdir $path" for each directory created
 105     # $mode    -- optional permissions, defaults to 0777
 106     local($")="/";
 107     $mode = 0777 unless defined($mode);
 108     $paths = [$paths] unless ref $paths;
 109     my(@created);
 110     foreach $path (@$paths){
 111         next if -d $path;
 112         my(@p);
 113         foreach(split(/\//, $path)){
 114             push(@p, $_);
 115             next if -d "@p/";
 116             print "mkdir @p\n" if $verbose;
 117             mkdir("@p",$mode) || croak "mkdir @p: $!";
 118             push(@created, "@p");
 119         }
 120     }
 121     @created;
 122 }
 123
 124 sub rmtree {
 125     my($roots, $verbose, $safe) = @_;
 126     my(@files);
 127     my($count) = 0;
 128     $roots = [$roots] unless ref $roots;
 129
 130     foreach $root (@{$roots}) {
 131        $root =~ s#/$##;
 132        if (not -l $root and -d _) {
 133            opendir(D,$root);
 134            ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 135            @files = map("$root/$_", grep $_!~/^\.{1,2}$/, readdir(D));
 136            closedir(D);
 137            $count += rmtree(\@files,$verbose,$safe);
 138            if ($safe &&
 139                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 140                print "skipped $root\n" if $verbose;
 141                next;
 142            }
 143            print "rmdir $root\n" if $verbose;
 144            (rmdir $root && ++$count) or carp "Can't remove directory $root: $!";
 145         }
 146         else {
 147            if ($safe &&
 148                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 149                print "skipped $root\n" if $verbose;
 150                next;
 151            }
 152            print "unlink $root\n" if $verbose;
 153            while (-e $root || -l $root) { # delete all versions under VMS
 154                (unlink($root) && ++$count)
 155                    or carp "Can't unlink file $root: $!";
 156            }
 157         }
 158     }
 159
 160     $count;
 161 }
 162
 163 1;
 164
 165 __END__