lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove directory trees
   6
   7 =head1 SYNOPSIS
   8
   9     use File::Path;
  10
  11     mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
  12     rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
  13
  14 =head1 DESCRIPTION
  15
  16 The C<mkpath> function provides a convenient way to create directories, even
  17 if your C<mkdir> kernel call won't create more than one level of directory at
  18 a time.  C<mkpath> takes three arguments:
  19
  20 =over 4
  21
  22 =item *
  23
  24 the name of the path to create, or a reference
  25 to a list of paths to create,
  26
  27 =item *
  28
  29 a boolean value, which if TRUE will cause C<mkpath>
  30 to print the name of each directory as it is created
  31 (defaults to FALSE), and
  32
  33 =item *
  34
  35 the numeric mode to use when creating the directories
  36 (defaults to 0777)
  37
  38 =back
  39
  40 It returns a list of all directories (including intermediates, determined
  41 using the Unix '/' separator) created.
  42
  43 Similarly, the C<rmtree> function provides a convenient way to delete a
  44 subtree from the directory structure, much like the Unix command C<rm -r>.
  45 C<rmtree> takes three arguments:
  46
  47 =over 4
  48
  49 =item *
  50
  51 the root of the subtree to delete, or a reference to
  52 a list of roots.  All of the files and directories
  53 below each root, as well as the roots themselves,
  54 will be deleted.
  55
  56 =item *
  57
  58 a boolean value, which if TRUE will cause C<rmtree> to
  59 print a message each time it examines a file, giving the
  60 name of the file, and indicating whether it's using C<rmdir>
  61 or C<unlink> to remove it, or that it's skipping it.
  62 (defaults to FALSE)
  63
  64 =item *
  65
  66 a boolean value, which if TRUE will cause C<rmtree> to
  67 skip any files to which you do not have delete access
  68 (if running under VMS) or write access (if running
  69 under another OS).  This will change in the future when
  70 a criterion for 'delete permission' under OSs other
  71 than VMS is settled.  (defaults to FALSE)
  72
  73 =back
  74
  75 It returns the number of files successfully deleted.  Symlinks are
  76 simply deleted and not followed.
  77
  78 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  79 in the face of failure or interruption.  Files and directories which
  80 were not deleted may be left with permissions reset to allow world
  81 read and write access.  Note also that the occurrence of errors in
  82 rmtree can be determined I<only> by trapping diagnostic messages
  83 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  84 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  85 in situations where security is an issue.
  86
  87 =head1 AUTHORS
  88
  89 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  90 Charles Bailey <F<bailey@newman.upenn.edu>>
  91
  92 =cut
  93
  94 use 5.005_64;
  95 use Carp;
  96 use File::Basename ();
  97 use Exporter ();
  98 use strict;
  99
 100 our $VERSION = "1.0403";
 101 our @ISA = qw( Exporter );
 102 our @EXPORT = qw( mkpath rmtree );
 103
 104 my $Is_VMS = $^O eq 'VMS';
 105
 106 # These OSes complain if you want to remove a file that you have no
 107 # write permission to:
 108 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32' ||
 109                        $^O eq 'amigaos' || $^O eq 'MacOS');
 110
 111 sub mkpath {
 112     my($paths, $verbose, $mode) = @_;
 113     # $paths   -- either a path string or ref to list of paths
 114     # $verbose -- optional print "mkdir $path" for each directory created
 115     # $mode    -- optional permissions, defaults to 0777
 116     local($")="/";
 117     $mode = 0777 unless defined($mode);
 118     $paths = [$paths] unless ref $paths;
 119     my(@created,$path);
 120     foreach $path (@$paths) {
 121         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:\z/s; # feature of CRT
 122         # Logic wants Unix paths, so go with the flow.
 123         if ($Is_VMS) {
 124             next if $path eq '/';
 125             $path = VMS::Filespec::unixify($path);
 126             if ($path =~ m:^(/[^/]+)/?\z:) {
 127                 $path = $1.'/000000';
 128             }
 129         }
 130         next if -d $path;
 131         my $parent = File::Basename::dirname($path);
 132         unless (-d $parent or $path eq $parent) {
 133             push(@created,mkpath($parent, $verbose, $mode));
 134         }
 135         print "mkdir $path\n" if $verbose;
 136         unless (mkdir($path,$mode)) {
 137             my $e = $!;
 138             # allow for another process to have created it meanwhile
 139             croak "mkdir $path: $e" unless -d $path;
 140         }
 141         push(@created, $path);
 142     }
 143     @created;
 144 }
 145
 146 sub rmtree {
 147     my($roots, $verbose, $safe) = @_;
 148     my(@files);
 149     my($count) = 0;
 150     $verbose ||= 0;
 151     $safe ||= 0;
 152
 153     if ( defined($roots) && length($roots) ) {
 154       $roots = [$roots] unless ref $roots;
 155     }
 156     else {
 157       carp "No root path(s) specified\n";
 158       return 0;
 159     }
 160
 161     my($root);
 162     foreach $root (@{$roots}) {
 163         $root =~ s#/\z##;
 164         (undef, undef, my $rp) = lstat $root or next;
 165         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 166         if ( -d _ ) {
 167             # notabene: 0777 is for making readable in the first place,
 168             # it's also intended to change it to writable in case we have
 169             # to recurse in which case we are better than rm -rf for
 170             # subtrees with strange permissions
 171             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 172               or carp "Can't make directory $root read+writeable: $!"
 173                 unless $safe;
 174
 175             if (opendir my $d, $root) {
 176                 @files = readdir $d;
 177                 closedir $d;
 178             }
 179             else {
 180                 carp "Can't read $root: $!";
 181                 @files = ();
 182             }
 183
 184             # Deleting large numbers of files from VMS Files-11 filesystems
 185             # is faster if done in reverse ASCIIbetical order
 186             @files = reverse @files if $Is_VMS;
 187             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir\z## if $Is_VMS;
 188             @files = map("$root/$_", grep $_!~/^\.{1,2}\z/s,@files);
 189             $count += rmtree(\@files,$verbose,$safe);
 190             if ($safe &&
 191                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 192                 print "skipped $root\n" if $verbose;
 193                 next;
 194             }
 195             chmod 0777, $root
 196               or carp "Can't make directory $root writeable: $!"
 197                 if $force_writeable;
 198             print "rmdir $root\n" if $verbose;
 199             if (rmdir $root) {
 200                 ++$count;
 201             }
 202             else {
 203                 carp "Can't remove directory $root: $!";
 204                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 205                     or carp("and can't restore permissions to "
 206                             . sprintf("0%o",$rp) . "\n");
 207             }
 208         }
 209         else {
 210             if ($safe &&
 211                 ($Is_VMS ? !&VMS::Filespec::candelete($root)
 212                          : !(-l $root || -w $root)))
 213             {
 214                 print "skipped $root\n" if $verbose;
 215                 next;
 216             }
 217             chmod 0666, $root
 218               or carp "Can't make file $root writeable: $!"
 219                 if $force_writeable;
 220             print "unlink $root\n" if $verbose;
 221             # delete all versions under VMS
 222             for (;;) {
 223                 unless (unlink $root) {
 224                     carp "Can't unlink file $root: $!";
 225                     if ($force_writeable) {
 226                         chmod $rp, $root
 227                             or carp("and can't restore permissions to "
 228                                     . sprintf("0%o",$rp) . "\n");
 229                     }
 230                     last;
 231                 }
 232                 ++$count;
 233                 last unless $Is_VMS && lstat $root;
 234             }
 235         }
 236     }
 237
 238     $count;
 239 }
 240
 241 1;