lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even if
  18 your C<mkdir> kernel call won't create more than one level of directory at a
  19 time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined using
  42 the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled. (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted. Symlinks are
  77 treated as ordinary files.
  78
  79 =head1 AUTHORS
  80
  81 Tim Bunce <Tim.Bunce@ig.co.uk>
  82 Charles Bailey <bailey@genetics.upenn.edu>
  83
  84 =head1 REVISION
  85
  86 This module was last revised 14-Feb-1996, for perl 5.002. $VERSION is
  87 1.01.
  88
  89 =cut
  90
  91 $VERSION = "1.01"; # That's my hobby-horse, A.K.
  92
  93 require 5.000;
  94 use Config;
  95 use Carp;
  96 require Exporter;
  97 @ISA = qw( Exporter );
  98 @EXPORT = qw( mkpath rmtree );
  99
 100 $Is_VMS = $Config{'osname'} eq 'VMS';
 101
 102 sub mkpath {
 103     my($paths, $verbose, $mode) = @_;
 104     # $paths   -- either a path string or ref to list of paths
 105     # $verbose -- optional print "mkdir $path" for each directory created
 106     # $mode    -- optional permissions, defaults to 0777
 107     local($")="/";
 108     $mode = 0777 unless defined($mode);
 109     $paths = [$paths] unless ref $paths;
 110     my(@created);
 111     foreach $path (@$paths){
 112         next if -d $path;
 113         my(@p);
 114         foreach(split(/\//, $path)){
 115             push(@p, $_);
 116             next if -d "@p/";
 117             print "mkdir @p\n" if $verbose;
 118             mkdir("@p",$mode) || croak "mkdir @p: $!";
 119             push(@created, "@p");
 120         }
 121     }
 122     @created;
 123 }
 124
 125 sub rmtree {
 126     my($roots, $verbose, $safe) = @_;
 127     my(@files);
 128     my($count) = 0;
 129     $roots = [$roots] unless ref $roots;
 130
 131     foreach $root (@{$roots}) {
 132        $root =~ s#/$##;
 133        if (not -l $root and -d _) {
 134            opendir(D,$root);
 135            ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 136            @files = map("$root/$_", grep $_!~/^\.{1,2}$/, readdir(D));
 137            closedir(D);
 138            $count += rmtree(\@files,$verbose,$safe);
 139            if ($safe &&
 140                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 141                print "skipped $root\n" if $verbose;
 142                next;
 143            }
 144            print "rmdir $root\n" if $verbose;
 145            (rmdir $root && ++$count) or carp "Can't remove directory $root: $!";
 146         }
 147         else {
 148            if ($safe &&
 149                ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 150                print "skipped $root\n" if $verbose;
 151                next;
 152            }
 153            print "unlink $root\n" if $verbose;
 154            while (-e $root || -l $root) { # delete all versions under VMS
 155                (unlink($root) && ++$count)
 156                    or carp "Can't unlink file $root: $!";
 157            }
 158         }
 159     }
 160
 161     $count;
 162 }
 163
 164 1;
 165
 166 __END__