lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove directory trees
   6
   7 =head1 SYNOPSIS
   8
   9     use File::Path;
  10
  11     mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
  12     rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
  13
  14 =head1 DESCRIPTION
  15
  16 The C<mkpath> function provides a convenient way to create directories, even
  17 if your C<mkdir> kernel call won't create more than one level of directory at
  18 a time.  C<mkpath> takes three arguments:
  19
  20 =over 4
  21
  22 =item *
  23
  24 the name of the path to create, or a reference
  25 to a list of paths to create,
  26
  27 =item *
  28
  29 a boolean value, which if TRUE will cause C<mkpath>
  30 to print the name of each directory as it is created
  31 (defaults to FALSE), and
  32
  33 =item *
  34
  35 the numeric mode to use when creating the directories
  36 (defaults to 0777)
  37
  38 =back
  39
  40 It returns a list of all directories (including intermediates, determined
  41 using the Unix '/' separator) created.
  42
  43 Similarly, the C<rmtree> function provides a convenient way to delete a
  44 subtree from the directory structure, much like the Unix command C<rm -r>.
  45 C<rmtree> takes three arguments:
  46
  47 =over 4
  48
  49 =item *
  50
  51 the root of the subtree to delete, or a reference to
  52 a list of roots.  All of the files and directories
  53 below each root, as well as the roots themselves,
  54 will be deleted.
  55
  56 =item *
  57
  58 a boolean value, which if TRUE will cause C<rmtree> to
  59 print a message each time it examines a file, giving the
  60 name of the file, and indicating whether it's using C<rmdir>
  61 or C<unlink> to remove it, or that it's skipping it.
  62 (defaults to FALSE)
  63
  64 =item *
  65
  66 a boolean value, which if TRUE will cause C<rmtree> to
  67 skip any files to which you do not have delete access
  68 (if running under VMS) or write access (if running
  69 under another OS).  This will change in the future when
  70 a criterion for 'delete permission' under OSs other
  71 than VMS is settled.  (defaults to FALSE)
  72
  73 =back
  74
  75 It returns the number of files successfully deleted.  Symlinks are
  76 treated as ordinary files.
  77
  78 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  79 in the face of failure or interruption.  Files and directories which
  80 were not deleted may be left with permissions reset to allow world
  81 read and write access.  Note also that the occurrence of errors in
  82 rmtree can be determined I<only> by trapping diagnostic messages
  83 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  84 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  85 in situations where security is an issue.
  86
  87 =head1 AUTHORS
  88
  89 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  90 Charles Bailey <F<bailey@newman.upenn.edu>>
  91
  92 =cut
  93
  94 use Carp;
  95 use File::Basename ();
  96 use DirHandle ();
  97 use Exporter ();
  98 use strict;
  99
 100 use vars qw( $VERSION @ISA @EXPORT );
 101 $VERSION = "1.0402";
 102 @ISA = qw( Exporter );
 103 @EXPORT = qw( mkpath rmtree );
 104
 105 my $Is_VMS = $^O eq 'VMS';
 106
 107 # These OSes complain if you want to remove a file that you have no
 108 # write permission to:
 109 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32'
 110                        || $^O eq 'amigaos');
 111
 112 sub mkpath {
 113     my($paths, $verbose, $mode) = @_;
 114     # $paths   -- either a path string or ref to list of paths
 115     # $verbose -- optional print "mkdir $path" for each directory created
 116     # $mode    -- optional permissions, defaults to 0777
 117     local($")="/";
 118     $mode = 0777 unless defined($mode);
 119     $paths = [$paths] unless ref $paths;
 120     my(@created,$path);
 121     foreach $path (@$paths) {
 122         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:$/; # feature of CRT
 123         next if -d $path;
 124         # Logic wants Unix paths, so go with the flow.
 125         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 126         my $parent = File::Basename::dirname($path);
 127         # Allow for creation of new logical filesystems under VMS
 128         if (not $Is_VMS or $parent !~ m:/[^/]+/000000/?:) {
 129             unless (-d $parent or $path eq $parent) {
 130                 push(@created,mkpath($parent, $verbose, $mode));
 131             }
 132         }
 133         print "mkdir $path\n" if $verbose;
 134         unless (mkdir($path,$mode)) {
 135             my $e = $!;
 136             # allow for another process to have created it meanwhile
 137             croak "mkdir $path: $e" unless -d $path;
 138         }
 139         push(@created, $path);
 140     }
 141     @created;
 142 }
 143
 144 sub rmtree {
 145     my($roots, $verbose, $safe) = @_;
 146     my(@files);
 147     my($count) = 0;
 148     $verbose ||= 0;
 149     $safe ||= 0;
 150
 151     if ( defined($roots) && length($roots) ) {
 152       $roots = [$roots] unless ref $roots;
 153     }
 154     else {
 155       carp "No root path(s) specified\n";
 156       return 0;
 157     }
 158
 159     my($root);
 160     foreach $root (@{$roots}) {
 161         $root =~ s#/$##;
 162         (undef, undef, my $rp) = lstat $root or next;
 163         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 164         if ( -d _ ) {
 165             # notabene: 0777 is for making readable in the first place,
 166             # it's also intended to change it to writable in case we have
 167             # to recurse in which case we are better than rm -rf for
 168             # subtrees with strange permissions
 169             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 170               or carp "Can't make directory $root read+writeable: $!"
 171                 unless $safe;
 172
 173             my $d = DirHandle->new($root)
 174               or carp "Can't read $root: $!";
 175             @files = $d->read;
 176             $d->close;
 177
 178             # Deleting large numbers of files from VMS Files-11 filesystems
 179             # is faster if done in reverse ASCIIbetical order
 180             @files = reverse @files if $Is_VMS;
 181             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 182             @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 183             $count += rmtree(\@files,$verbose,$safe);
 184             if ($safe &&
 185                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 186                 print "skipped $root\n" if $verbose;
 187                 next;
 188             }
 189             chmod 0777, $root
 190               or carp "Can't make directory $root writeable: $!"
 191                 if $force_writeable;
 192             print "rmdir $root\n" if $verbose;
 193             if (rmdir $root) {
 194                 ++$count;
 195             }
 196             else {
 197                 carp "Can't remove directory $root: $!";
 198                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 199                     or carp("and can't restore permissions to "
 200                             . sprintf("0%o",$rp) . "\n");
 201             }
 202         }
 203         else {
 204             if ($safe &&
 205                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 206                 print "skipped $root\n" if $verbose;
 207                 next;
 208             }
 209             chmod 0666, $root
 210               or carp "Can't make file $root writeable: $!"
 211                 if $force_writeable;
 212             print "unlink $root\n" if $verbose;
 213             # delete all versions under VMS
 214             for (;;) {
 215                 unless (unlink $root) {
 216                     carp "Can't unlink file $root: $!";
 217                     if ($force_writeable) {
 218                         chmod $rp, $root
 219                             or carp("and can't restore permissions to "
 220                                     . sprintf("0%o",$rp) . "\n");
 221                     }
 222                     last;
 223                 }
 224                 ++$count;
 225                 last unless $Is_VMS && lstat $root;
 226             }
 227         }
 228     }
 229
 230     $count;
 231 }
 232
 233 1;